lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B qw(perlstring);
   6
   7 our %TYPE_MAP;
   8
   9 our $SETUP_DONE;
  10
  11 sub import { return if $SETUP_DONE; inject_all(); $SETUP_DONE = 1; }
  12
  13 sub inject_all {
  14   require Class::MOP;
  15   inject_fake_metaclass_for($_)
  16     for grep $_ ne 'Moo::Object', do { no warnings 'once'; keys %Moo::MAKERS };
  17   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  18   require Moose::Meta::Method::Constructor;
  19   @Moo::HandleMoose::FakeConstructor::ISA = 'Moose::Meta::Method::Constructor';
  20 }
  21
  22 sub inject_fake_metaclass_for {
  23   my ($name) = @_;
  24   require Class::MOP;
  25   Class::MOP::store_metaclass_by_name(
  26     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  27   );
  28 }
  29
  30 our %DID_INJECT;
  31
  32 {
  33   package Moo::HandleMoose::FakeConstructor;
  34
  35   sub _uninlined_body { \&Moose::Object::new }
  36 }
  37
  38
  39 sub inject_real_metaclass_for {
  40   my ($name) = @_;
  41   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  42   require Moose; require Moo; require Moo::Role;
  43   Class::MOP::remove_metaclass_by_name($name);
  44   my ($am_role, $meta, $attr_specs) = do {
  45     if (my $info = $Moo::Role::INFO{$name}) {
  46       (1, Moose::Meta::Role->initialize($name), $info->{attributes})
  47     } else {
  48       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  49       (0, Moose::Meta::Class->initialize($name), $specs);
  50     }
  51   };
  52   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  53   # needed to ensure the method body is stable and get things named
  54   Sub::Defer::undefer_sub($_) for grep defined, values %methods;
  55   my @attrs;
  56   {
  57     # This local is completely not required for roles but harmless
  58     local @{_getstash($name)}{keys %methods};
  59     foreach my $name (keys %$attr_specs) {
  60       my %spec = %{$attr_specs->{$name}};
  61       delete $spec{index};
  62       $spec{is} = 'ro' if $spec{is} eq 'lazy' or $spec{is} eq 'rwp';
  63       delete $spec{asserter};
  64       if (my $isa = $spec{isa}) {
  65         $spec{isa} = do {
  66           if (my $mapped = $TYPE_MAP{$isa}) {
  67             $mapped->();
  68           } else {
  69             Moose::Meta::TypeConstraint->new(
  70               constraint => sub { eval { &$isa; 1 } }
  71             );
  72           }
  73         };
  74         die "Aaaargh" if $spec{coerce};
  75       } elsif (my $coerce = $spec{coerce}) {
  76         my $attr = perlstring($name);
  77         my $tc = Moose::Meta::TypeConstraint->new(
  78                    constraint => sub { die "This is not going to work" },
  79                    inlined => sub {
  80                       'my $r = $_[42]{'.$attr.'}; $_[42]{'.$attr.'} = 1; $r'
  81                    },
  82                  );
  83          $tc->coercion(Moose::Meta::TypeCoercion->new)
  84             ->_compiled_type_coercion($coerce);
  85          $spec{isa} = $tc;
  86          $spec{coerce} = 1;
  87       }
  88       push @attrs, $meta->add_attribute($name => %spec);
  89     }
  90   }
  91   if ($am_role) {
  92     my $info = $Moo::Role::INFO{$name};
  93     $meta->add_required_methods(@{$info->{requires}});
  94     foreach my $modifier (@{$info->{modifiers}}) {
  95       my ($type, @args) = @$modifier;
  96       $meta->${\"add_${type}_method_modifier"}(@args);
  97     }
  98   } else {
  99     foreach my $attr (@attrs) {
 100       foreach my $method (@{$attr->associated_methods}) {
 101         $method->{body} = $name->can($method->name);
 102       }
 103     }
 104     bless(
 105       $meta->find_method_by_name('new'),
 106       'Moo::HandleMoose::FakeConstructor',
 107     );
 108   }
 109   $meta->add_role(Class::MOP::class_of($_))
 110     for do { no warnings 'once'; keys %{$Role::Tiny::APPLIED_TO{$name}} };
 111   $DID_INJECT{$name} = 1;
 112   $meta;
 113 }
 114
 115 {
 116   package Moo::HandleMoose::FakeMetaClass;
 117
 118   sub DESTROY { }
 119
 120   sub AUTOLOAD {
 121     my ($meth) = (our $AUTOLOAD =~ /([^:]+)$/);
 122     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->$meth(@_)
 123   }
 124   sub can {
 125     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->can(@_)
 126   }
 127   sub isa {
 128     Moo::HandleMoose::inject_real_metaclass_for((shift)->{name})->isa(@_)
 129   }
 130 }
 131
 132 1;