lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B qw(perlstring);
   6
   7 our %TYPE_MAP;
   8
   9 our $SETUP_DONE;
  10
  11 sub import { return if $SETUP_DONE; inject_all(); $SETUP_DONE = 1; }
  12
  13 sub inject_all {
  14   require Class::MOP;
  15   inject_fake_metaclass_for($_)
  16     for grep $_ ne 'Moo::Object', do { no warnings 'once'; keys %Moo::MAKERS };
  17   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  18   require Moose::Meta::Method::Constructor;
  19   @Moo::HandleMoose::FakeConstructor::ISA = 'Moose::Meta::Method::Constructor';
  20 }
  21
  22 sub maybe_reinject_fake_metaclass_for {
  23   my ($name) = @_;
  24   our %DID_INJECT;
  25   if (delete $DID_INJECT{$name}) {
  26     unless ($Moo::Role::INFO{$name}) {
  27       Moo->_constructor_maker_for($name)->install_delayed;
  28     }
  29     inject_fake_metaclass_for($name);
  30   }
  31 }
  32
  33 sub inject_fake_metaclass_for {
  34   my ($name) = @_;
  35   require Class::MOP;
  36   require Moo::HandleMoose::FakeMetaClass;
  37   Class::MOP::store_metaclass_by_name(
  38     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  39   );
  40 }
  41
  42 {
  43   package Moo::HandleMoose::FakeConstructor;
  44
  45   sub _uninlined_body { \&Moose::Object::new }
  46 }
  47
  48
  49 sub inject_real_metaclass_for {
  50   my ($name) = @_;
  51   our %DID_INJECT;
  52   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  53   require Moose; require Moo; require Moo::Role;
  54   Class::MOP::remove_metaclass_by_name($name);
  55   my ($am_role, $meta, $attr_specs, $attr_order) = do {
  56     if (my $info = $Moo::Role::INFO{$name}) {
  57       my @attr_info = @{$info->{attributes}||[]};
  58       (1, Moose::Meta::Role->initialize($name),
  59        { @attr_info },
  60        [ @attr_info[grep !($_ % 2), 0..$#attr_info] ]
  61       )
  62     } else {
  63       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  64       (0, Moose::Meta::Class->initialize($name), $specs,
  65        [ sort { $specs->{$a}{index} <=> $specs->{$b}{index} } keys %$specs ]
  66       );
  67     }
  68   };
  69
  70   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  71
  72   # if stuff gets added afterwards, _maybe_reset_handlemoose should
  73   # trigger the recreation of the metaclass but we need to ensure the
  74   # Role::Tiny cache is cleared so we don't confuse Moo itself.
  75   if (my $info = $Role::Tiny::INFO{$name}) {
  76     delete $info->{methods};
  77   }
  78
  79   # needed to ensure the method body is stable and get things named
  80   Sub::Defer::undefer_sub($_) for grep defined, values %methods;
  81   my @attrs;
  82   {
  83     # This local is completely not required for roles but harmless
  84     local @{_getstash($name)}{keys %methods};
  85     my %seen_name;
  86     foreach my $name (@$attr_order) {
  87       $seen_name{$name} = 1;
  88       my %spec = %{$attr_specs->{$name}};
  89       delete $spec{index};
  90       $spec{is} = 'ro' if $spec{is} eq 'lazy' or $spec{is} eq 'rwp';
  91       delete $spec{asserter};
  92       if (my $isa = $spec{isa}) {
  93         my $tc = $spec{isa} = do {
  94           if (my $mapped = $TYPE_MAP{$isa}) {
  95             $mapped->();
  96           } else {
  97             Moose::Meta::TypeConstraint->new(
  98               constraint => sub { eval { &$isa; 1 } }
  99             );
 100           }
 101         };
 102         if (my $coerce = $spec{coerce}) {
 103           $tc->coercion(Moose::Meta::TypeCoercion->new)
 104              ->_compiled_type_coercion($coerce);
 105           $spec{coerce} = 1;
 106         }
 107       } elsif (my $coerce = $spec{coerce}) {
 108         my $attr = perlstring($name);
 109         my $tc = Moose::Meta::TypeConstraint->new(
 110                    constraint => sub { die "This is not going to work" },
 111                    inlined => sub {
 112                       'my $r = $_[42]{'.$attr.'}; $_[42]{'.$attr.'} = 1; $r'
 113                    },
 114                  );
 115         $tc->coercion(Moose::Meta::TypeCoercion->new)
 116            ->_compiled_type_coercion($coerce);
 117         $spec{isa} = $tc;
 118         $spec{coerce} = 1;
 119       }
 120       push @attrs, $meta->add_attribute($name => %spec);
 121     }
 122     foreach my $mouse (do { our %MOUSE; @{$MOUSE{$name}||[]} }) {
 123       foreach my $attr ($mouse->get_all_attributes) {
 124         my %spec = %{$attr};
 125         delete @spec{qw(
 126           associated_class associated_methods __METACLASS__
 127           provides curries
 128         )};
 129         my $name = delete $spec{name};
 130         next if $seen_name{$name}++;
 131         push @attrs, $meta->add_attribute($name => %spec);
 132       }
 133     }
 134   }
 135   if ($am_role) {
 136     my $info = $Moo::Role::INFO{$name};
 137     $meta->add_required_methods(@{$info->{requires}});
 138     foreach my $modifier (@{$info->{modifiers}}) {
 139       my ($type, @args) = @$modifier;
 140       $meta->${\"add_${type}_method_modifier"}(@args);
 141     }
 142   } else {
 143     foreach my $attr (@attrs) {
 144       foreach my $method (@{$attr->associated_methods}) {
 145         $method->{body} = $name->can($method->name);
 146       }
 147     }
 148     bless(
 149       $meta->find_method_by_name('new'),
 150       'Moo::HandleMoose::FakeConstructor',
 151     );
 152   }
 153   $meta->add_role(Class::MOP::class_of($_))
 154     for grep !/\|/ && $_ ne $name, # reject Foo|Bar and same-role-as-self
 155       do { no warnings 'once'; keys %{$Role::Tiny::APPLIED_TO{$name}} };
 156   $DID_INJECT{$name} = 1;
 157   $meta;
 158 }
 159
 160 1;