lib/Moo/HandleMoose.pm

   1 package Moo::HandleMoose;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B qw(perlstring);
   6
   7 our %TYPE_MAP;
   8
   9 our $SETUP_DONE;
  10
  11 sub import { return if $SETUP_DONE; inject_all(); $SETUP_DONE = 1; }
  12
  13 sub inject_all {
  14   require Class::MOP;
  15   inject_fake_metaclass_for($_)
  16     for grep $_ ne 'Moo::Object', do { no warnings 'once'; keys %Moo::MAKERS };
  17   inject_fake_metaclass_for($_) for keys %Moo::Role::INFO;
  18   require Moose::Meta::Method::Constructor;
  19   @Moo::HandleMoose::FakeConstructor::ISA = 'Moose::Meta::Method::Constructor';
  20 }
  21
  22 sub maybe_reinject_fake_metaclass_for {
  23   my ($name) = @_;
  24   our %DID_INJECT;
  25   if (delete $DID_INJECT{$name}) {
  26     unless ($Moo::Role::INFO{$name}) {
  27       Moo->_constructor_maker_for($name)->install_delayed;
  28     }
  29     inject_fake_metaclass_for($name);
  30   }
  31 }
  32
  33 sub inject_fake_metaclass_for {
  34   my ($name) = @_;
  35   require Class::MOP;
  36   require Moo::HandleMoose::FakeMetaClass;
  37   Class::MOP::store_metaclass_by_name(
  38     $name, bless({ name => $name }, 'Moo::HandleMoose::FakeMetaClass')
  39   );
  40   require Moose::Util::TypeConstraints;
  41   if ($Moo::Role::INFO{$name}) {
  42     Moose::Util::TypeConstraints::find_or_create_does_type_constraint($name);
  43   } else {
  44     Moose::Util::TypeConstraints::find_or_create_isa_type_constraint($name);
  45   }
  46 }
  47
  48 {
  49   package Moo::HandleMoose::FakeConstructor;
  50
  51   sub _uninlined_body { \&Moose::Object::new }
  52 }
  53
  54
  55 sub inject_real_metaclass_for {
  56   my ($name) = @_;
  57   our %DID_INJECT;
  58   return Class::MOP::get_metaclass_by_name($name) if $DID_INJECT{$name};
  59   require Moose; require Moo; require Moo::Role;
  60   Class::MOP::remove_metaclass_by_name($name);
  61   my ($am_role, $meta, $attr_specs, $attr_order) = do {
  62     if (my $info = $Moo::Role::INFO{$name}) {
  63       my @attr_info = @{$info->{attributes}||[]};
  64       (1, Moose::Meta::Role->initialize($name),
  65        { @attr_info },
  66        [ @attr_info[grep !($_ % 2), 0..$#attr_info] ]
  67       )
  68     } else {
  69       my $specs = Moo->_constructor_maker_for($name)->all_attribute_specs;
  70       (0, Moose::Meta::Class->initialize($name), $specs,
  71        [ sort { $specs->{$a}{index} <=> $specs->{$b}{index} } keys %$specs ]
  72       );
  73     }
  74   };
  75
  76   for my $spec (values %$attr_specs) {
  77     if (my $inflators = delete $spec->{moosify}) {
  78       $_->($spec) for @$inflators;
  79     }
  80   }
  81
  82   my %methods = %{Role::Tiny->_concrete_methods_of($name)};
  83
  84   # if stuff gets added afterwards, _maybe_reset_handlemoose should
  85   # trigger the recreation of the metaclass but we need to ensure the
  86   # Role::Tiny cache is cleared so we don't confuse Moo itself.
  87   if (my $info = $Role::Tiny::INFO{$name}) {
  88     delete $info->{methods};
  89   }
  90
  91   # needed to ensure the method body is stable and get things named
  92   Sub::Defer::undefer_sub($_) for grep defined, values %methods;
  93   my @attrs;
  94   {
  95     # This local is completely not required for roles but harmless
  96     local @{_getstash($name)}{keys %methods};
  97     my %seen_name;
  98     foreach my $name (@$attr_order) {
  99       $seen_name{$name} = 1;
 100       my %spec = %{$attr_specs->{$name}};
 101       delete $spec{index};
 102       $spec{is} = 'ro' if $spec{is} eq 'lazy' or $spec{is} eq 'rwp';
 103       delete $spec{asserter};
 104       my $coerce = $spec{coerce};
 105       if (my $isa = $spec{isa}) {
 106         my $tc = $spec{isa} = do {
 107           if (my $mapped = $TYPE_MAP{$isa}) {
 108             my $type = $mapped->();
 109             $coerce ? $type->create_child_type(name => $type->name) : $type;
 110           } else {
 111             Moose::Meta::TypeConstraint->new(
 112               constraint => sub { eval { &$isa; 1 } }
 113             );
 114           }
 115         };
 116         if ($coerce) {
 117           $tc->coercion(Moose::Meta::TypeCoercion->new)
 118              ->_compiled_type_coercion($coerce);
 119           $spec{coerce} = 1;
 120         }
 121       } elsif ($coerce) {
 122         my $attr = perlstring($name);
 123         my $tc = Moose::Meta::TypeConstraint->new(
 124                    constraint => sub { die "This is not going to work" },
 125                    inlined => sub {
 126                       'my $r = $_[42]{'.$attr.'}; $_[42]{'.$attr.'} = 1; $r'
 127                    },
 128                  );
 129         $tc->coercion(Moose::Meta::TypeCoercion->new)
 130            ->_compiled_type_coercion($coerce);
 131         $spec{isa} = $tc;
 132         $spec{coerce} = 1;
 133       }
 134       push @attrs, $meta->add_attribute($name => %spec);
 135     }
 136     foreach my $mouse (do { our %MOUSE; @{$MOUSE{$name}||[]} }) {
 137       foreach my $attr ($mouse->get_all_attributes) {
 138         my %spec = %{$attr};
 139         delete @spec{qw(
 140           associated_class associated_methods __METACLASS__
 141           provides curries
 142         )};
 143         my $name = delete $spec{name};
 144         next if $seen_name{$name}++;
 145         push @attrs, $meta->add_attribute($name => %spec);
 146       }
 147     }
 148   }
 149   for my $meth_name (keys %methods) {
 150     my $meth_code = $methods{$meth_name};
 151     $meta->add_method($meth_name, $meth_code) if $meth_code;
 152   }
 153
 154   if ($am_role) {
 155     my $info = $Moo::Role::INFO{$name};
 156     $meta->add_required_methods(@{$info->{requires}});
 157     foreach my $modifier (@{$info->{modifiers}}) {
 158       my ($type, @args) = @$modifier;
 159       $meta->${\"add_${type}_method_modifier"}(@args);
 160     }
 161   } else {
 162     foreach my $attr (@attrs) {
 163       foreach my $method (@{$attr->associated_methods}) {
 164         $method->{body} = $name->can($method->name);
 165       }
 166     }
 167     bless(
 168       $meta->find_method_by_name('new'),
 169       'Moo::HandleMoose::FakeConstructor',
 170     );
 171   }
 172   $meta->add_role(Class::MOP::class_of($_))
 173     for grep !/\|/ && $_ ne $name, # reject Foo|Bar and same-role-as-self
 174       do { no warnings 'once'; keys %{$Role::Tiny::APPLIED_TO{$name}} };
 175   $DID_INJECT{$name} = 1;
 176   $meta;
 177 }
 178
 179 1;