lib/Moo.pm

   1 package Moo;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B 'perlstring';
   6
   7 our $VERSION = '0.009012'; # 0.9.12
   8 $VERSION = eval $VERSION;
   9
  10 our %MAKERS;
  11
  12 sub import {
  13   my $target = caller;
  14   my $class = shift;
  15   strictures->import;
  16   return if $MAKERS{$target}; # already exported into this package
  17   *{_getglob("${target}::extends")} = sub {
  18     _load_module($_) for @_;
  19     # Can't do *{...} = \@_ or 5.10.0's mro.pm stops seeing @ISA
  20     @{*{_getglob("${target}::ISA")}{ARRAY}} = @_;
  21   };
  22   *{_getglob("${target}::with")} = sub {
  23     { local $@; require Moo::Role; }
  24     die "Only one role supported at a time by with" if @_ > 1;
  25     Moo::Role->apply_role_to_package($target, $_[0]);
  26   };
  27   $MAKERS{$target} = {};
  28   *{_getglob("${target}::has")} = sub {
  29     my ($name, %spec) = @_;
  30     ($MAKERS{$target}{accessor} ||= do {
  31       { local $@; require Method::Generate::Accessor; }
  32       Method::Generate::Accessor->new
  33     })->generate_method($target, $name, \%spec);
  34     $class->_constructor_maker_for($target)
  35           ->register_attribute_specs($name, \%spec);
  36   };
  37   foreach my $type (qw(before after around)) {
  38     *{_getglob "${target}::${type}"} = sub {
  39       { local $@; require Class::Method::Modifiers; }
  40       _install_modifier($target, $type, @_);
  41     };
  42   }
  43   {
  44     no strict 'refs';
  45     @{"${target}::ISA"} = do {
  46       {; local $@; require Moo::Object; } ('Moo::Object');
  47     } unless @{"${target}::ISA"};
  48   }
  49 }
  50
  51 sub _constructor_maker_for {
  52   my ($class, $target, $select_super) = @_;
  53   return unless $MAKERS{$target};
  54   $MAKERS{$target}{constructor} ||= do {
  55     {
  56       local $@;
  57       require Method::Generate::Constructor;
  58       require Sub::Defer;
  59     }
  60     my ($moo_constructor, $con);
  61
  62     if ($select_super && $MAKERS{$select_super}) {
  63       $moo_constructor = 1;
  64       $con = $MAKERS{$select_super}{constructor};
  65     } else {
  66       my $t_new = $target->can('new');
  67       if ($t_new) {
  68         if ($t_new == Moo::Object->can('new')) {
  69           $moo_constructor = 1;
  70         } elsif (my $defer_target = (Sub::Defer::defer_info($t_new)||[])->[0]) {
  71           my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/);
  72           if ($MAKERS{$pkg}) {
  73             $moo_constructor = 1;
  74             $con = $MAKERS{$pkg}{constructor};
  75           }
  76         }
  77       } else {
  78         $moo_constructor = 1; # no other constructor, make a Moo one
  79       }
  80     };
  81     Method::Generate::Constructor
  82       ->new(
  83         package => $target,
  84         accessor_generator => do {
  85           { local $@; require Method::Generate::Accessor; }
  86           Method::Generate::Accessor->new;
  87         },
  88         construction_string => (
  89           $moo_constructor
  90             ? ($con ? $con->construction_string : undef)
  91             : ('$class->'.$target.'::SUPER::new(@_)')
  92         ),
  93         subconstructor_generator => (
  94           $class.'->_constructor_maker_for($class,'.perlstring($target).')'
  95         ),
  96       )
  97       ->install_delayed
  98       ->register_attribute_specs(%{$con?$con->all_attribute_specs:{}})
  99   }
 100 }
 101
 102 1;
 103 =pod
 104
 105 =encoding utf-8
 106
 107 =head1 NAME
 108
 109 Moo - Minimalist Object Orientation (with Moose compatiblity)
 110
 111 =head1 SYNOPSIS
 112
 113  package Cat::Food;
 114
 115  use Moo;
 116  use Sub::Quote;
 117
 118  sub feed_lion {
 119    my $self = shift;
 120    my $amount = shift || 1;
 121
 122    $self->pounds( $self->pounds - $amount );
 123  }
 124
 125  has taste => (
 126    is => 'ro',
 127  );
 128
 129  has brand => (
 130    is  => 'ro',
 131    isa => sub {
 132      die "Only SWEET-TREATZ supported!" unless $_[0] eq 'SWEET-TREATZ'
 133    },
 134 );
 135
 136  has pounds => (
 137    is  => 'rw',
 138    isa => quote_sub q{ die "$_[0] is too much cat food!" unless $_[0] < 15 },
 139  );
 140
 141  1;
 142
 143 and else where
 144
 145  my $full = Cat::Food->new(
 146     taste  => 'DELICIOUS.',
 147     brand  => 'SWEET-TREATZ',
 148     pounds => 10,
 149  );
 150
 151  $full->feed_lion;
 152
 153  say $full->pounds;
 154
 155 =head1 DESCRIPTION
 156
 157 This module is an extremely light-weight, high-performance L<Moose> replacement.
 158 It also avoids depending on any XS modules to allow simple deployments.  The
 159 name C<Moo> is based on the idea that it provides almost -but not quite- two
 160 thirds of L<Moose>.
 161
 162 Unlike C<Mouse> this module does not aim at full L<Moose> compatibility.  See
 163 L</INCOMPATIBILITIES> for more details.
 164
 165 =head1 WHY MOO EXISTS
 166
 167 If you want a full object system with a rich Metaprotocol, L<Moose> is
 168 already wonderful.
 169
 170 I've tried several times to use L<Mouse> but it's 3x the size of Moo and
 171 takes longer to load than most of my Moo based CGI scripts take to run.
 172
 173 If you don't want L<Moose>, you don't want "less metaprotocol" like L<Mouse>,
 174 you want "as little as possible" - which means "no metaprotocol", which is
 175 what Moo provides.
 176
 177 By Moo 1.0 I intend to have Moo's equivalent of L<Any::Moose> built in -
 178 if Moose gets loaded, any Moo class or role will act as a Moose equivalent
 179 if treated as such.
 180
 181 Hence - Moo exists as its name - Minimal Object Orientation - with a pledge
 182 to make it smooth to upgrade to L<Moose> when you need more than minimal
 183 features.
 184
 185 =head1 IMPORTED METHODS
 186
 187 =head2 new
 188
 189  Foo::Bar->new( attr1 => 3 );
 190
 191 or
 192
 193  Foo::Bar->new({ attr1 => 3 });
 194
 195 =head2 BUILDARGS
 196
 197  around BUILDARGS => sub {
 198    my $orig = shift;
 199    my ( $class, @args ) = @_;
 200
 201    unshift @args, "attr1" if @args % 2 == 1;
 202
 203    return $class->$orig(@args);
 204  };
 205
 206  Foo::Bar->new( 3 );
 207
 208 The default implementation of this method accepts a hash or hash reference of
 209 named parameters. If it receives a single argument that isn't a hash reference
 210 it throws an error.
 211
 212 You can override this method in your class to handle other types of options
 213 passed to the constructor.
 214
 215 This method should always return a hash reference of named options.
 216
 217 =head2 BUILDALL
 218
 219 Don't override (or probably even call) this method.  Instead, you can define
 220 a C<BUILD> method on your class and the constructor will automatically call the
 221 C<BUILD> method from parent down to child after the object has been
 222 instantiated.  Typically this is used for object validation or possibly logging.
 223
 224 =head2 DESTROY
 225
 226 If you have a C<DEMOLISH> method anywhere in your inheritance hierarchy,
 227 a C<DESTROY> method is created on first object construction which will call
 228 C<< $instance->DEMOLISH($in_global_destruction) >> for each C<DEMOLISH>
 229 method from child upwards to parents.
 230
 231 Note that the C<DESTROY> method is created on first construction of an object
 232 of your class in order to not add overhead to classes without C<DEMOLISH>
 233 methods; this may prove slightly surprising if you try and define your own.
 234
 235 =head2 does
 236
 237  if ($foo->does('Some::Role1')) {
 238    ...
 239  }
 240
 241 Returns true if the object composes in the passed role.
 242
 243 =head1 IMPORTED SUBROUTINES
 244
 245 =head2 extends
 246
 247  extends 'Parent::Class';
 248
 249 Declares base class. Multiple superclasses can be passed for multiple
 250 inheritance (but please use roles instead).
 251
 252 Calling extends more than once will REPLACE your superclasses, not add to
 253 them like 'use base' would.
 254
 255 =head2 with
 256
 257  with 'Some::Role1';
 258  with 'Some::Role2';
 259
 260 Composes a L<Role::Tiny> into current class.  Only one role may be composed in
 261 at a time to allow the code to remain as simple as possible.
 262
 263 =head2 has
 264
 265  has attr => (
 266    is => 'ro',
 267  );
 268
 269 Declares an attribute for the class.
 270
 271 The options for C<has> are as follows:
 272
 273 =over 2
 274
 275 =item * is
 276
 277 B<required>, must be C<ro> or C<rw>.  Unsurprisingly, C<ro> generates an
 278 accessor that will not respond to arguments; to be clear: a getter only. C<rw>
 279 will create a perlish getter/setter.
 280
 281 =item * isa
 282
 283 Takes a coderef which is meant to validate the attribute.  Unlike L<Moose> Moo
 284 does not include a basic type system, so instead of doing C<< isa => 'Num' >>,
 285 one should do
 286
 287  isa => quote_sub q{
 288    die "$_[0] is not a number!" unless looks_like_number $_[0]
 289  },
 290
 291 L<Sub::Quote aware|/SUB QUOTE AWARE>
 292
 293 =item * coerce
 294
 295 Takes a coderef which is meant to coerce the attribute.  The basic idea is to
 296 do something like the following:
 297
 298  coerce => quote_sub q{
 299    $_[0] + 1 unless $_[0] % 2
 300  },
 301
 302 Coerce does not require C<isa> to be defined.
 303
 304 L<Sub::Quote aware|/SUB QUOTE AWARE>
 305
 306 =item * handles
 307
 308 Takes a string
 309
 310   handles => 'Robot'
 311
 312 Takes a list of methods
 313
 314  handles => [ qw( one two ) ]
 315
 316 Takes a hashref
 317
 318  handles => {
 319    un => 'one',
 320  }
 321
 322 =item * trigger
 323
 324 Takes a coderef which will get called any time the attribute is set. Coderef
 325 will be invoked against the object with the new value as an argument.
 326
 327 Note that Moose also passes the old value, if any; this feature is not yet
 328 supported.
 329
 330 L<Sub::Quote aware|/SUB QUOTE AWARE>
 331
 332 =item * default
 333
 334 Takes a coderef which will get called with $self as its only argument
 335 to populate an attribute if no value is supplied to the constructor - or
 336 if the attribute is lazy, when the attribute is first retrieved if no
 337 value has yet been provided.
 338
 339 Note that if your default is fired during new() there is no guarantee that
 340 other attributes have been populated yet so you should not rely on their
 341 existence.
 342
 343 L<Sub::Quote aware|/SUB QUOTE AWARE>
 344
 345 =item * predicate
 346
 347 Takes a method name which will return true if an attribute has a value.
 348
 349 A common example of this would be to call it C<has_$foo>, implying that the
 350 object has a C<$foo> set.
 351
 352 =item * builder
 353
 354 Takes a method name which will be called to create the attribute - functions
 355 exactly like default except that instead of calling
 356
 357   $default->($self);
 358
 359 Moo will call
 360
 361   $self->$builder;
 362
 363 =item * clearer
 364
 365 Takes a method name which will clear the attribute.
 366
 367 =item * lazy
 368
 369 B<Boolean>.  Set this if you want values for the attribute to be grabbed
 370 lazily.  This is usually a good idea if you have a L</builder> which requires
 371 another attribute to be set.
 372
 373 =item * required
 374
 375 B<Boolean>.  Set this if the attribute must be passed on instantiation.
 376
 377 =item * reader
 378
 379 The value of this attribute will be the name of the method to get the value of
 380 the attribute.  If you like Java style methods, you might set this to
 381 C<get_foo>
 382
 383 =item * writer
 384
 385 The value of this attribute will be the name of the method to set the value of
 386 the attribute.  If you like Java style methods, you might set this to
 387 C<set_foo>
 388
 389 =item * weak_ref
 390
 391 B<Boolean>.  Set this if you want the reference that the attribute contains to
 392 be weakened; use this when circular references are possible, which will cause
 393 leaks.
 394
 395 =item * init_arg
 396
 397 Takes the name of the key to look for at instantiation time of the object.  A
 398 common use of this is to make an underscored attribute have a non-underscored
 399 initialization name. C<undef> means that passing the value in on instantiation
 400
 401 =back
 402
 403 =head2 before
 404
 405  before foo => sub { ... };
 406
 407 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 408 documentation.
 409
 410 =head2 around
 411
 412  around foo => sub { ... };
 413
 414 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 415 documentation.
 416
 417 =head2 after
 418
 419  after foo => sub { ... };
 420
 421 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 422 documentation.
 423
 424 =head1 SUB QUOTE AWARE
 425
 426 L<Sub::Quote/quote_sub> allows us to create coderefs that are "inlineable,"
 427 giving us a handy, XS-free speed boost.  Any option that is L<Sub::Quote>
 428 aware can take advantage of this.
 429
 430 =head1 INCOMPATIBILITIES WITH MOOSE
 431
 432 You can only compose one role at a time.  If your application is large or
 433 complex enough to warrant complex composition, you wanted L<Moose>.
 434
 435 There is no complex type system.  C<isa> is verified with a coderef, if you
 436 need complex types, just make a library of coderefs, or better yet, functions
 437 that return quoted subs.
 438
 439 C<initializer> is not supported in core since the author considers it to be a
 440 bad idea but may be supported by an extension in future.
 441
 442 There is no meta object.  If you need this level of complexity you wanted
 443 L<Moose> - Moo succeeds at being small because it explicitly does not
 444 provide a metaprotocol.
 445
 446 No support for C<super>, C<override>, C<inner>, or C<augment> - override can
 447 be handled by around albeit with a little more typing, and the author considers
 448 augment to be a bad idea.
 449
 450 L</default> only supports coderefs, because doing otherwise is usually a
 451 mistake anyway.
 452
 453 C<lazy_build> is not supported per se, but of course it will work if you
 454 manually set all the options it implies.
 455
 456 C<auto_deref> is not supported since the author considers it a bad idea.
 457
 458 C<documentation> is not supported since it's a very poor replacement for POD.
 459
 460 =head1 AUTHOR
 461
 462 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 463
 464 =head1 CONTRIBUTORS
 465
 466 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 467
 468 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 469
 470 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 471
 472 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 473
 474 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 475
 476 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 477
 478 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 479
 480 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 481
 482 =head1 COPYRIGHT
 483
 484 Copyright (c) 2010-2011 the Moo L</AUTHOR> and L</CONTRIBUTORS>
 485 as listed above.
 486
 487 =head1 LICENSE
 488
 489 This library is free software and may be distributed under the same terms
 490 as perl itself.
 491
 492 =cut