lib/Moo.pm

   1 package Moo;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B 'perlstring';
   6
   7 our $VERSION = '0.009010'; # 0.9.10
   8 $VERSION = eval $VERSION;
   9
  10 our %MAKERS;
  11
  12 sub import {
  13   my $target = caller;
  14   my $class = shift;
  15   strictures->import;
  16   return if $MAKERS{$target}; # already exported into this package
  17   *{_getglob("${target}::extends")} = sub {
  18     _load_module($_) for @_;
  19     # Can't do *{...} = \@_ or 5.10.0's mro.pm stops seeing @ISA
  20     @{*{_getglob("${target}::ISA")}{ARRAY}} = @_;
  21   };
  22   *{_getglob("${target}::with")} = sub {
  23     require Moo::Role;
  24     die "Only one role supported at a time by with" if @_ > 1;
  25     Moo::Role->apply_role_to_package($target, $_[0]);
  26   };
  27   $MAKERS{$target} = {};
  28   *{_getglob("${target}::has")} = sub {
  29     my ($name, %spec) = @_;
  30     ($MAKERS{$target}{accessor} ||= do {
  31       require Method::Generate::Accessor;
  32       Method::Generate::Accessor->new
  33     })->generate_method($target, $name, \%spec);
  34     $class->_constructor_maker_for($target)
  35           ->register_attribute_specs($name, \%spec);
  36   };
  37   foreach my $type (qw(before after around)) {
  38     *{_getglob "${target}::${type}"} = sub {
  39       require Class::Method::Modifiers;
  40       _install_modifier($target, $type, @_);
  41     };
  42   }
  43   {
  44     no strict 'refs';
  45     @{"${target}::ISA"} = do {
  46       require Moo::Object; ('Moo::Object');
  47     } unless @{"${target}::ISA"};
  48   }
  49 }
  50
  51 sub _constructor_maker_for {
  52   my ($class, $target, $select_super) = @_;
  53   return unless $MAKERS{$target};
  54   $MAKERS{$target}{constructor} ||= do {
  55     require Method::Generate::Constructor;
  56     require Sub::Defer;
  57     my ($moo_constructor, $con);
  58
  59     if ($select_super && $MAKERS{$select_super}) {
  60       $moo_constructor = 1;
  61       $con = $MAKERS{$select_super}{constructor};
  62     } else {
  63       my $t_new = $target->can('new');
  64       if ($t_new) {
  65         if ($t_new == Moo::Object->can('new')) {
  66           $moo_constructor = 1;
  67         } elsif (my $defer_target = (Sub::Defer::defer_info($t_new)||[])->[0]) {
  68           my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/);
  69           if ($MAKERS{$pkg}) {
  70             $moo_constructor = 1;
  71             $con = $MAKERS{$pkg}{constructor};
  72           }
  73         }
  74       } else {
  75         $moo_constructor = 1; # no other constructor, make a Moo one
  76       }
  77     };
  78     Method::Generate::Constructor
  79       ->new(
  80         package => $target,
  81         accessor_generator => do {
  82           require Method::Generate::Accessor;
  83           Method::Generate::Accessor->new;
  84         },
  85         construction_string => (
  86           $moo_constructor
  87             ? ($con ? $con->construction_string : undef)
  88             : ('$class->'.$target.'::SUPER::new(@_)')
  89         ),
  90         subconstructor_generator => (
  91           $class.'->_constructor_maker_for($class,'.perlstring($target).')'
  92         ),
  93       )
  94       ->install_delayed
  95       ->register_attribute_specs(%{$con?$con->all_attribute_specs:{}})
  96   }
  97 }
  98
  99 1;
 100 =pod
 101
 102 =encoding utf-8
 103
 104 =head1 NAME
 105
 106 Moo - Minimalist Object Orientation (with Moose compatiblity)
 107
 108 =head1 SYNOPSIS
 109
 110  package Cat::Food;
 111
 112  use Moo;
 113  use Sub::Quote;
 114
 115  sub feed_lion {
 116    my $self = shift;
 117    my $amount = shift || 1;
 118
 119    $self->pounds( $self->pounds - $amount );
 120  }
 121
 122  has taste => (
 123    is => 'ro',
 124  );
 125
 126  has brand => (
 127    is  => 'ro',
 128    isa => sub {
 129      die "Only SWEET-TREATZ supported!" unless $_[0] eq 'SWEET-TREATZ'
 130    },
 131 );
 132
 133  has pounds => (
 134    is  => 'rw',
 135    isa => quote_sub q{ die "$_[0] is too much cat food!" unless $_[0] < 15 },
 136  );
 137
 138  1;
 139
 140 and else where
 141
 142  my $full = Cat::Food->new(
 143     taste  => 'DELICIOUS.',
 144     brand  => 'SWEET-TREATZ',
 145     pounds => 10,
 146  );
 147
 148  $full->feed_lion;
 149
 150  say $full->pounds;
 151
 152 =head1 DESCRIPTION
 153
 154 This module is an extremely light-weight, high-performance L<Moose> replacement.
 155 It also avoids depending on any XS modules to allow simple deployments.  The
 156 name C<Moo> is based on the idea that it provides almost -but not quite- two
 157 thirds of L<Moose>.
 158
 159 Unlike C<Mouse> this module does not aim at full L<Moose> compatibility.  See
 160 L</INCOMPATIBILITIES> for more details.
 161
 162 =head1 WHY MOO EXISTS
 163
 164 If you want a full object system with a rich Metaprotocol, L<Moose> is
 165 already wonderful.
 166
 167 I've tried several times to use L<Mouse> but it's 3x the size of Moo and
 168 takes longer to load than most of my Moo based CGI scripts take to run.
 169
 170 If you don't want L<Moose>, you don't want "less metaprotocol" like L<Mouse>,
 171 you want "as little as possible" - which means "no metaprotocol", which is
 172 what Moo provides.
 173
 174 By Moo 1.0 I intend to have Moo's equivalent of L<Any::Moose> built in -
 175 if Moose gets loaded, any Moo class or role will act as a Moose equivalent
 176 if treated as such.
 177
 178 Hence - Moo exists as its name - Minimal Object Orientation - with a pledge
 179 to make it smooth to upgrade to L<Moose> when you need more than minimal
 180 features.
 181
 182 =head1 IMPORTED METHODS
 183
 184 =head2 new
 185
 186  Foo::Bar->new( attr1 => 3 );
 187
 188 or
 189
 190  Foo::Bar->new({ attr1 => 3 });
 191
 192 =head2 BUILDARGS
 193
 194  around BUILDARGS => sub {
 195    my $orig = shift;
 196    my ( $class, @args ) = @_;
 197
 198    unshift @args, "attr1" if @args % 2 == 1;
 199
 200    return $class->$orig(@args);
 201  };
 202
 203  Foo::Bar->new( 3 );
 204
 205 The default implementation of this method accepts a hash or hash reference of
 206 named parameters. If it receives a single argument that isn't a hash reference
 207 it throws an error.
 208
 209 You can override this method in your class to handle other types of options
 210 passed to the constructor.
 211
 212 This method should always return a hash reference of named options.
 213
 214 =head2 BUILDALL
 215
 216 Don't override (or probably even call) this method.  Instead, you can define
 217 a C<BUILD> method on your class and the constructor will automatically call the
 218 C<BUILD> method from parent down to child after the object has been
 219 instantiated.  Typically this is used for object validation or possibly logging.
 220
 221 =head2 does
 222
 223  if ($foo->does('Some::Role1')) {
 224    ...
 225  }
 226
 227 Returns true if the object composes in the passed role.
 228
 229 =head1 IMPORTED SUBROUTINES
 230
 231 =head2 extends
 232
 233  extends 'Parent::Class';
 234
 235 Declares base class. Multiple superclasses can be passed for multiple
 236 inheritance (but please use roles instead).
 237
 238 Calling extends more than once will REPLACE your superclasses, not add to
 239 them like 'use base' would.
 240
 241 =head2 with
 242
 243  with 'Some::Role1';
 244  with 'Some::Role2';
 245
 246 Composes a L<Role::Tiny> into current class.  Only one role may be composed in
 247 at a time to allow the code to remain as simple as possible.
 248
 249 =head2 has
 250
 251  has attr => (
 252    is => 'ro',
 253  );
 254
 255 Declares an attribute for the class.
 256
 257 The options for C<has> are as follows:
 258
 259 =over 2
 260
 261 =item * is
 262
 263 B<required>, must be C<ro> or C<rw>.  Unsurprisingly, C<ro> generates an
 264 accessor that will not respond to arguments; to be clear: a getter only. C<rw>
 265 will create a perlish getter/setter.
 266
 267 =item * isa
 268
 269 Takes a coderef which is meant to validate the attribute.  Unlike L<Moose> Moo
 270 does not include a basic type system, so instead of doing C<< isa => 'Num' >>,
 271 one should do
 272
 273  isa => quote_sub q{
 274    die "$_[0] is not a number!" unless looks_like_number $_[0]
 275  },
 276
 277 L<Sub::Quote aware|/SUB QUOTE AWARE>
 278
 279 =item * coerce
 280
 281 Takes a coderef which is meant to coerce the attribute.  The basic idea is to
 282 do something like the following:
 283
 284  coerce => quote_sub q{
 285    $_[0] + 1 unless $_[0] % 2
 286  },
 287
 288 Coerce does not require C<isa> to be defined.
 289
 290 L<Sub::Quote aware|/SUB QUOTE AWARE>
 291
 292 =item * trigger
 293
 294 Takes a coderef which will get called any time the attribute is set. Coderef
 295 will be invoked against the object with the new value as an argument.
 296
 297 Note that Moose also passes the old value, if any; this feature is not yet
 298 supported.
 299
 300 L<Sub::Quote aware|/SUB QUOTE AWARE>
 301
 302 =item * default
 303
 304 Takes a coderef which will get called with $self as its only argument
 305 to populate an attribute if no value is supplied to the constructor - or
 306 if the attribute is lazy, when the attribute is first retrieved if no
 307 value has yet been provided.
 308
 309 Note that if your default is fired during new() there is no guarantee that
 310 other attributes have been populated yet so you should not rely on their
 311 existence.
 312
 313 L<Sub::Quote aware|/SUB QUOTE AWARE>
 314
 315 =item * predicate
 316
 317 Takes a method name which will return true if an attribute has a value.
 318
 319 A common example of this would be to call it C<has_$foo>, implying that the
 320 object has a C<$foo> set.
 321
 322 =item * builder
 323
 324 Takes a method name which will be called to create the attribute - functions
 325 exactly like default except that instead of calling
 326
 327   $default->($self);
 328
 329 Moo will call
 330
 331   $self->$builder;
 332
 333 =item * clearer
 334
 335 Takes a method name which will clear the attribute.
 336
 337 =item * lazy
 338
 339 B<Boolean>.  Set this if you want values for the attribute to be grabbed
 340 lazily.  This is usually a good idea if you have a L</builder> which requires
 341 another attribute to be set.
 342
 343 =item * required
 344
 345 B<Boolean>.  Set this if the attribute must be passed on instantiation.
 346
 347 =item * reader
 348
 349 The value of this attribute will be the name of the method to get the value of
 350 the attribute.  If you like Java style methods, you might set this to
 351 C<get_foo>
 352
 353 =item * writer
 354
 355 The value of this attribute will be the name of the method to set the value of
 356 the attribute.  If you like Java style methods, you might set this to
 357 C<set_foo>
 358
 359 =item * weak_ref
 360
 361 B<Boolean>.  Set this if you want the reference that the attribute contains to
 362 be weakened; use this when circular references are possible, which will cause
 363 leaks.
 364
 365 =item * init_arg
 366
 367 Takes the name of the key to look for at instantiation time of the object.  A
 368 common use of this is to make an underscored attribute have a non-underscored
 369 initialization name. C<undef> means that passing the value in on instantiation
 370
 371 =back
 372
 373 =head2 before
 374
 375  before foo => sub { ... };
 376
 377 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 378 documentation.
 379
 380 =head2 around
 381
 382  around foo => sub { ... };
 383
 384 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 385 documentation.
 386
 387 =head2 after
 388
 389  after foo => sub { ... };
 390
 391 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 392 documentation.
 393
 394 =head1 SUB QUOTE AWARE
 395
 396 L<Sub::Quote/quote_sub> allows us to create coderefs that are "inlineable,"
 397 giving us a handy, XS-free speed boost.  Any option that is L<Sub::Quote>
 398 aware can take advantage of this.
 399
 400 =head1 INCOMPATIBILITIES WITH MOOSE
 401
 402 You can only compose one role at a time.  If your application is large or
 403 complex enough to warrant complex composition, you wanted L<Moose>.
 404
 405 There is no complex type system.  C<isa> is verified with a coderef, if you
 406 need complex types, just make a library of coderefs, or better yet, functions
 407 that return quoted subs.
 408
 409 C<initializer> is not supported in core since the author considers it to be a
 410 bad idea but may be supported by an extension in future.
 411
 412 There is no meta object.  If you need this level of complexity you wanted
 413 L<Moose> - Moo succeeds at being small because it explicitly does not
 414 provide a metaprotocol.
 415
 416 No support for C<super>, C<override>, C<inner>, or C<augment> - override can
 417 be handled by around albeit with a little more typing, and the author considers
 418 augment to be a bad idea.
 419
 420 L</default> only supports coderefs, because doing otherwise is usually a
 421 mistake anyway.
 422
 423 C<lazy_build> is not supported per se, but of course it will work if you
 424 manually set all the options it implies.
 425
 426 C<auto_deref> is not supported since the author considers it a bad idea.
 427
 428 C<documentation> is not supported since it's a very poor replacement for POD.
 429
 430 =head1 AUTHOR
 431
 432 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 433
 434 =head1 CONTRIBUTORS
 435
 436 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 437
 438 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 439
 440 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 441
 442 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 443
 444 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 445
 446 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 447
 448 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 449
 450 =head1 COPYRIGHT
 451
 452 Copyright (c) 2010-2011 the Moo L</AUTHOR> and L</CONTRIBUTORS>
 453 as listed above.
 454
 455 =head1 LICENSE
 456
 457 This library is free software and may be distributed under the same terms
 458 as perl itself.
 459
 460 =cut