lib/Moo.pm

   1 package Moo;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B 'perlstring';
   6
   7 our $VERSION = '0.009014'; # 0.9.13
   8 $VERSION = eval $VERSION;
   9
  10 our %MAKERS;
  11
  12 sub import {
  13   my $target = caller;
  14   my $class = shift;
  15   strictures->import;
  16   return if $MAKERS{$target}; # already exported into this package
  17   *{_getglob("${target}::extends")} = sub {
  18     _load_module($_) for @_;
  19     # Can't do *{...} = \@_ or 5.10.0's mro.pm stops seeing @ISA
  20     @{*{_getglob("${target}::ISA")}{ARRAY}} = @_;
  21   };
  22   *{_getglob("${target}::with")} = sub {
  23     require Moo::Role;
  24     die "Only one role supported at a time by with" if @_ > 1;
  25     Moo::Role->apply_role_to_package($target, $_[0]);
  26   };
  27   $MAKERS{$target} = {};
  28   *{_getglob("${target}::has")} = sub {
  29     my ($name, %spec) = @_;
  30     ($MAKERS{$target}{accessor} ||= do {
  31       require Method::Generate::Accessor;
  32       Method::Generate::Accessor->new
  33     })->generate_method($target, $name, \%spec);
  34     $class->_constructor_maker_for($target)
  35           ->register_attribute_specs($name, \%spec);
  36   };
  37   foreach my $type (qw(before after around)) {
  38     *{_getglob "${target}::${type}"} = sub {
  39       require Class::Method::Modifiers;
  40       _install_modifier($target, $type, @_);
  41     };
  42   }
  43   {
  44     no strict 'refs';
  45     @{"${target}::ISA"} = do {
  46       require Moo::Object; ('Moo::Object');
  47     } unless @{"${target}::ISA"};
  48   }
  49 }
  50
  51 sub _constructor_maker_for {
  52   my ($class, $target, $select_super) = @_;
  53   return unless $MAKERS{$target};
  54   $MAKERS{$target}{constructor} ||= do {
  55     require Method::Generate::Constructor;
  56     require Sub::Defer;
  57     my ($moo_constructor, $con);
  58
  59     if ($select_super && $MAKERS{$select_super}) {
  60       $moo_constructor = 1;
  61       $con = $MAKERS{$select_super}{constructor};
  62     } else {
  63       my $t_new = $target->can('new');
  64       if ($t_new) {
  65         if ($t_new == Moo::Object->can('new')) {
  66           $moo_constructor = 1;
  67         } elsif (my $defer_target = (Sub::Defer::defer_info($t_new)||[])->[0]) {
  68           my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/);
  69           if ($MAKERS{$pkg}) {
  70             $moo_constructor = 1;
  71             $con = $MAKERS{$pkg}{constructor};
  72           }
  73         }
  74       } else {
  75         $moo_constructor = 1; # no other constructor, make a Moo one
  76       }
  77     };
  78     Method::Generate::Constructor
  79       ->new(
  80         package => $target,
  81         accessor_generator => do {
  82           require Method::Generate::Accessor;
  83           Method::Generate::Accessor->new;
  84         },
  85         construction_string => (
  86           $moo_constructor
  87             ? ($con ? $con->construction_string : undef)
  88             : ('$class->'.$target.'::SUPER::new(@_)')
  89         ),
  90         subconstructor_generator => (
  91           $class.'->_constructor_maker_for($class,'.perlstring($target).')'
  92         ),
  93       )
  94       ->install_delayed
  95       ->register_attribute_specs(%{$con?$con->all_attribute_specs:{}})
  96   }
  97 }
  98
  99 1;
 100 =pod
 101
 102 =encoding utf-8
 103
 104 =head1 NAME
 105
 106 Moo - Minimalist Object Orientation (with Moose compatiblity)
 107
 108 =head1 SYNOPSIS
 109
 110  package Cat::Food;
 111
 112  use Moo;
 113  use Sub::Quote;
 114
 115  sub feed_lion {
 116    my $self = shift;
 117    my $amount = shift || 1;
 118
 119    $self->pounds( $self->pounds - $amount );
 120  }
 121
 122  has taste => (
 123    is => 'ro',
 124  );
 125
 126  has brand => (
 127    is  => 'ro',
 128    isa => sub {
 129      die "Only SWEET-TREATZ supported!" unless $_[0] eq 'SWEET-TREATZ'
 130    },
 131 );
 132
 133  has pounds => (
 134    is  => 'rw',
 135    isa => quote_sub q{ die "$_[0] is too much cat food!" unless $_[0] < 15 },
 136  );
 137
 138  1;
 139
 140 and else where
 141
 142  my $full = Cat::Food->new(
 143     taste  => 'DELICIOUS.',
 144     brand  => 'SWEET-TREATZ',
 145     pounds => 10,
 146  );
 147
 148  $full->feed_lion;
 149
 150  say $full->pounds;
 151
 152 =head1 DESCRIPTION
 153
 154 This module is an extremely light-weight, high-performance L<Moose> replacement.
 155 It also avoids depending on any XS modules to allow simple deployments.  The
 156 name C<Moo> is based on the idea that it provides almost -but not quite- two
 157 thirds of L<Moose>.
 158
 159 Unlike C<Mouse> this module does not aim at full L<Moose> compatibility.  See
 160 L</INCOMPATIBILITIES> for more details.
 161
 162 =head1 WHY MOO EXISTS
 163
 164 If you want a full object system with a rich Metaprotocol, L<Moose> is
 165 already wonderful.
 166
 167 I've tried several times to use L<Mouse> but it's 3x the size of Moo and
 168 takes longer to load than most of my Moo based CGI scripts take to run.
 169
 170 If you don't want L<Moose>, you don't want "less metaprotocol" like L<Mouse>,
 171 you want "as little as possible" - which means "no metaprotocol", which is
 172 what Moo provides.
 173
 174 By Moo 1.0 I intend to have Moo's equivalent of L<Any::Moose> built in -
 175 if Moose gets loaded, any Moo class or role will act as a Moose equivalent
 176 if treated as such.
 177
 178 Hence - Moo exists as its name - Minimal Object Orientation - with a pledge
 179 to make it smooth to upgrade to L<Moose> when you need more than minimal
 180 features.
 181
 182 =head1 IMPORTED METHODS
 183
 184 =head2 new
 185
 186  Foo::Bar->new( attr1 => 3 );
 187
 188 or
 189
 190  Foo::Bar->new({ attr1 => 3 });
 191
 192 =head2 BUILDARGS
 193
 194  around BUILDARGS => sub {
 195    my $orig = shift;
 196    my ( $class, @args ) = @_;
 197
 198    unshift @args, "attr1" if @args % 2 == 1;
 199
 200    return $class->$orig(@args);
 201  };
 202
 203  Foo::Bar->new( 3 );
 204
 205 The default implementation of this method accepts a hash or hash reference of
 206 named parameters. If it receives a single argument that isn't a hash reference
 207 it throws an error.
 208
 209 You can override this method in your class to handle other types of options
 210 passed to the constructor.
 211
 212 This method should always return a hash reference of named options.
 213
 214 =head2 BUILD
 215
 216 Define a C<BUILD> method on your class and the constructor will automatically
 217 call the C<BUILD> method from parent down to child after the object has
 218 been instantiated.  Typically this is used for object validation or possibly
 219 logging.
 220
 221 =head2 DEMOLISH
 222
 223 If you have a C<DEMOLISH> method anywhere in your inheritance hierarchy,
 224 a C<DESTROY> method is created on first object construction which will call
 225 C<< $instance->DEMOLISH($in_global_destruction) >> for each C<DEMOLISH>
 226 method from child upwards to parents.
 227
 228 Note that the C<DESTROY> method is created on first construction of an object
 229 of your class in order to not add overhead to classes without C<DEMOLISH>
 230 methods; this may prove slightly surprising if you try and define your own.
 231
 232 =head2 does
 233
 234  if ($foo->does('Some::Role1')) {
 235    ...
 236  }
 237
 238 Returns true if the object composes in the passed role.
 239
 240 =head1 IMPORTED SUBROUTINES
 241
 242 =head2 extends
 243
 244  extends 'Parent::Class';
 245
 246 Declares base class. Multiple superclasses can be passed for multiple
 247 inheritance (but please use roles instead).
 248
 249 Calling extends more than once will REPLACE your superclasses, not add to
 250 them like 'use base' would.
 251
 252 =head2 with
 253
 254  with 'Some::Role1';
 255  with 'Some::Role2';
 256
 257 Composes a L<Role::Tiny> into current class.  Only one role may be composed in
 258 at a time to allow the code to remain as simple as possible.
 259
 260 =head2 has
 261
 262  has attr => (
 263    is => 'ro',
 264  );
 265
 266 Declares an attribute for the class.
 267
 268 The options for C<has> are as follows:
 269
 270 =over 2
 271
 272 =item * is
 273
 274 B<required>, must be C<ro> or C<rw>.  Unsurprisingly, C<ro> generates an
 275 accessor that will not respond to arguments; to be clear: a getter only. C<rw>
 276 will create a perlish getter/setter.
 277
 278 =item * isa
 279
 280 Takes a coderef which is meant to validate the attribute.  Unlike L<Moose> Moo
 281 does not include a basic type system, so instead of doing C<< isa => 'Num' >>,
 282 one should do
 283
 284  isa => quote_sub q{
 285    die "$_[0] is not a number!" unless looks_like_number $_[0]
 286  },
 287
 288 L<Sub::Quote aware|/SUB QUOTE AWARE>
 289
 290 =item * coerce
 291
 292 Takes a coderef which is meant to coerce the attribute.  The basic idea is to
 293 do something like the following:
 294
 295  coerce => quote_sub q{
 296    $_[0] + 1 unless $_[0] % 2
 297  },
 298
 299 Coerce does not require C<isa> to be defined.
 300
 301 L<Sub::Quote aware|/SUB QUOTE AWARE>
 302
 303 =item * handles
 304
 305 Takes a string
 306
 307   handles => 'RobotRole'
 308
 309 Where C<RobotRole> is a role (L<Moo::Role>) that defines an interface which
 310 becomes the list of methods to handle.
 311
 312 Takes a list of methods
 313
 314  handles => [ qw( one two ) ]
 315
 316 Takes a hashref
 317
 318  handles => {
 319    un => 'one',
 320  }
 321
 322 =item * trigger
 323
 324 Takes a coderef which will get called any time the attribute is set. Coderef
 325 will be invoked against the object with the new value as an argument.
 326
 327 Note that Moose also passes the old value, if any; this feature is not yet
 328 supported.
 329
 330 L<Sub::Quote aware|/SUB QUOTE AWARE>
 331
 332 =item * default
 333
 334 Takes a coderef which will get called with $self as its only argument
 335 to populate an attribute if no value is supplied to the constructor - or
 336 if the attribute is lazy, when the attribute is first retrieved if no
 337 value has yet been provided.
 338
 339 Note that if your default is fired during new() there is no guarantee that
 340 other attributes have been populated yet so you should not rely on their
 341 existence.
 342
 343 L<Sub::Quote aware|/SUB QUOTE AWARE>
 344
 345 =item * predicate
 346
 347 Takes a method name which will return true if an attribute has a value.
 348
 349 A common example of this would be to call it C<has_$foo>, implying that the
 350 object has a C<$foo> set.
 351
 352 =item * builder
 353
 354 Takes a method name which will be called to create the attribute - functions
 355 exactly like default except that instead of calling
 356
 357   $default->($self);
 358
 359 Moo will call
 360
 361   $self->$builder;
 362
 363 =item * clearer
 364
 365 Takes a method name which will clear the attribute.
 366
 367 =item * lazy
 368
 369 B<Boolean>.  Set this if you want values for the attribute to be grabbed
 370 lazily.  This is usually a good idea if you have a L</builder> which requires
 371 another attribute to be set.
 372
 373 =item * required
 374
 375 B<Boolean>.  Set this if the attribute must be passed on instantiation.
 376
 377 =item * reader
 378
 379 The value of this attribute will be the name of the method to get the value of
 380 the attribute.  If you like Java style methods, you might set this to
 381 C<get_foo>
 382
 383 =item * writer
 384
 385 The value of this attribute will be the name of the method to set the value of
 386 the attribute.  If you like Java style methods, you might set this to
 387 C<set_foo>
 388
 389 =item * weak_ref
 390
 391 B<Boolean>.  Set this if you want the reference that the attribute contains to
 392 be weakened; use this when circular references are possible, which will cause
 393 leaks.
 394
 395 =item * init_arg
 396
 397 Takes the name of the key to look for at instantiation time of the object.  A
 398 common use of this is to make an underscored attribute have a non-underscored
 399 initialization name. C<undef> means that passing the value in on instantiation
 400
 401 =back
 402
 403 =head2 before
 404
 405  before foo => sub { ... };
 406
 407 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 408 documentation.
 409
 410 =head2 around
 411
 412  around foo => sub { ... };
 413
 414 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 415 documentation.
 416
 417 =head2 after
 418
 419  after foo => sub { ... };
 420
 421 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 422 documentation.
 423
 424 =head1 SUB QUOTE AWARE
 425
 426 L<Sub::Quote/quote_sub> allows us to create coderefs that are "inlineable,"
 427 giving us a handy, XS-free speed boost.  Any option that is L<Sub::Quote>
 428 aware can take advantage of this.
 429
 430 =head1 INCOMPATIBILITIES WITH MOOSE
 431
 432 You can only compose one role at a time.  If your application is large or
 433 complex enough to warrant complex composition, you wanted L<Moose>.  Note that
 434 this does not mean you can only compose one role per class -
 435
 436   with 'FirstRole';
 437   with 'SecondRole';
 438
 439 is absolutely fine, there's just currently no equivalent of Moose's
 440
 441   with 'FirstRole', 'SecondRole';
 442
 443 which composes the two roles together, and then applies them.
 444
 445 There is no built in type system.  C<isa> is verified with a coderef, if you
 446 need complex types, just make a library of coderefs, or better yet, functions
 447 that return quoted subs. L<MooX::Types::MooseLike> provides a similar API
 448 to L<MooseX::Types::Moose> so that you can write
 449
 450   has days_to_live => (is => 'ro', isa => Int);
 451
 452 and have it work with both; it is hoped that providing only subrefs as an
 453 API will encourage the use of other type systems as well, since it's
 454 probably the weakest part of Moose design-wise.
 455
 456 C<initializer> is not supported in core since the author considers it to be a
 457 bad idea but may be supported by an extension in future.
 458
 459 There is no meta object.  If you need this level of complexity you wanted
 460 L<Moose> - Moo succeeds at being small because it explicitly does not
 461 provide a metaprotocol.
 462
 463 No support for C<super>, C<override>, C<inner>, or C<augment> - override can
 464 be handled by around albeit with a little more typing, and the author considers
 465 augment to be a bad idea.
 466
 467 The C<dump> method is not provided by default. The author suggests loading
 468 L<Devel::Dwarn> into C<main::> (via C<perl -MDevel::Dwarn ...> for example) and
 469 using C<$obj-E<gt>$::Dwarn()> instead.
 470
 471 L</default> only supports coderefs, because doing otherwise is usually a
 472 mistake anyway.
 473
 474 C<lazy_build> is not supported per se, but of course it will work if you
 475 manually set all the options it implies.
 476
 477 C<auto_deref> is not supported since the author considers it a bad idea.
 478
 479 C<documentation> is not supported since it's a very poor replacement for POD.
 480
 481 Handling of warnings: when you C<use Moo> we enable FATAL warnings.  The nearest
 482 similar invocation for L<Moose> would be:
 483
 484   use Moose;
 485   use warnings FATAL => "all";
 486
 487 Additionally, L<Moo> supports a set of attribute option shortcuts intended to
 488 reduce common boilerplate.  The set of shortcuts is the same as in the L<Moose>
 489 module L<MooseX::AttributeShortcuts>.  So if you:
 490
 491     package MyClass;
 492     use Moo;
 493
 494 The nearest L<Moose> invocation would be:
 495
 496     package MyClass;
 497
 498     use Moose;
 499     use warnings FATAL => "all";
 500     use MooseX::AttributeShortcuts;
 501
 502 or, if you're inheriting from a non-Moose class,
 503
 504     package MyClass;
 505
 506     use Moose;
 507     use MooseX::NonMoose;
 508     use warnings FATAL => "all";
 509     use MooseX::AttributeShortcuts;
 510
 511 Finally, Moose requires you to call
 512
 513     __PACKAGE__->meta->make_immutable;
 514
 515 at the end of your class to get an inlined (i.e. not horribly slow)
 516 constructor. Moo does it automatically the first time ->new is called
 517 on your class.
 518
 519 =head1 AUTHOR
 520
 521 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 522
 523 =head1 CONTRIBUTORS
 524
 525 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 526
 527 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 528
 529 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 530
 531 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 532
 533 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 534
 535 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 536
 537 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 538
 539 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 540
 541 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 542
 543 =head1 COPYRIGHT
 544
 545 Copyright (c) 2010-2011 the Moo L</AUTHOR> and L</CONTRIBUTORS>
 546 as listed above.
 547
 548 =head1 LICENSE
 549
 550 This library is free software and may be distributed under the same terms
 551 as perl itself.
 552
 553 =cut