lib/Moo.pm

   1 package Moo;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5
   6 our $VERSION = '0.009008'; # 0.9.8
   7 $VERSION = eval $VERSION;
   8
   9 our %MAKERS;
  10
  11 sub import {
  12   my $target = caller;
  13   my $class = shift;
  14   strictures->import;
  15   return if $MAKERS{$target}; # already exported into this package
  16   *{_getglob("${target}::extends")} = sub {
  17     _load_module($_) for @_;
  18     # Can't do *{...} = \@_ or 5.10.0's mro.pm stops seeing @ISA
  19     @{*{_getglob("${target}::ISA")}{ARRAY}} = @_;
  20   };
  21   *{_getglob("${target}::with")} = sub {
  22     require Moo::Role;
  23     die "Only one role supported at a time by with" if @_ > 1;
  24     Moo::Role->apply_role_to_package($target, $_[0]);
  25   };
  26   $MAKERS{$target} = {};
  27   *{_getglob("${target}::has")} = sub {
  28     my ($name, %spec) = @_;
  29     ($MAKERS{$target}{accessor} ||= do {
  30       require Method::Generate::Accessor;
  31       Method::Generate::Accessor->new
  32     })->generate_method($target, $name, \%spec);
  33     $class->_constructor_maker_for($target)
  34           ->register_attribute_specs($name, \%spec);
  35   };
  36   foreach my $type (qw(before after around)) {
  37     *{_getglob "${target}::${type}"} = sub {
  38       require Class::Method::Modifiers;
  39       _install_modifier($target, $type, @_);
  40     };
  41   }
  42   {
  43     no strict 'refs';
  44     @{"${target}::ISA"} = do {
  45       require Moo::Object; ('Moo::Object');
  46     } unless @{"${target}::ISA"};
  47   }
  48 }
  49
  50 sub _constructor_maker_for {
  51   my ($class, $target, $select_super) = @_;
  52   return unless $MAKERS{$target};
  53   $MAKERS{$target}{constructor} ||= do {
  54     require Method::Generate::Constructor;
  55     require Sub::Defer;
  56     my ($moo_constructor, $con);
  57
  58     if ($select_super && $MAKERS{$select_super}) {
  59       $moo_constructor = 1;
  60       $con = $MAKERS{$select_super}{constructor};
  61     } else {
  62       my $t_new = $target->can('new');
  63       if ($t_new) {
  64         if ($t_new == Moo::Object->can('new')) {
  65           $moo_constructor = 1;
  66         } elsif (my $defer_target = (Sub::Defer::defer_info($t_new)||[])->[0]) {
  67           my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/);
  68           if ($MAKERS{$pkg}) {
  69             $moo_constructor = 1;
  70             $con = $MAKERS{$pkg}{constructor};
  71           }
  72         }
  73       } else {
  74         $moo_constructor = 1; # no other constructor, make a Moo one
  75       }
  76     };
  77     Method::Generate::Constructor
  78       ->new(
  79         package => $target,
  80         accessor_generator => do {
  81           require Method::Generate::Accessor;
  82           Method::Generate::Accessor->new;
  83         },
  84         construction_string => (
  85           $moo_constructor
  86             ? ($con ? $con->construction_string : undef)
  87             : ('$class->'.$target.'::SUPER::new(@_)')
  88         )
  89       )
  90       ->install_delayed
  91       ->register_attribute_specs(%{$con?$con->all_attribute_specs:{}})
  92   }
  93 }
  94
  95 1;
  96
  97 =head1 NAME
  98
  99 Moo - Minimalist Object Orientation (with Moose compatiblity)
 100
 101 =head1 WARNING WARNING WARNING
 102
 103 This is a 0.9 release because we're fairly sure it works. For us. Until it's
 104 tested in the wild, we make no guarantees it also works for you.
 105
 106 If this module does something unexpected, please submit a failing test.
 107
 108 But if it eats your cat, sleeps with your boyfriend, or pushes grandma down
 109 the stairs to save her from the terrible secret of space, it's not our fault.
 110
 111 =head1 SYNOPSIS
 112
 113  package Cat::Food;
 114
 115  use Moo;
 116  use Sub::Quote;
 117
 118  sub feed_lion {
 119    my $self = shift;
 120    my $amount = shift || 1;
 121
 122    $self->pounds( $self->pounds - $amount );
 123  }
 124
 125  has taste => (
 126    is => 'ro',
 127  );
 128
 129  has brand => (
 130    is  => 'ro',
 131    isa => sub {
 132      die "Only SWEET-TREATZ supported!" unless $_[0] eq 'SWEET-TREATZ'
 133    },
 134 );
 135
 136  has pounds => (
 137    is  => 'rw',
 138    isa => quote_sub q{ die "$_[0] is too much cat food!" unless $_[0] < 15 },
 139  );
 140
 141  1;
 142
 143 and else where
 144
 145  my $full = Cat::Food->new(
 146     taste  => 'DELICIOUS.',
 147     brand  => 'SWEET-TREATZ',
 148     pounds => 10,
 149  );
 150
 151  $full->feed_lion;
 152
 153  say $full->pounds;
 154
 155 =head1 DESCRIPTION
 156
 157 This module is an extremely light-weight, high-performance L<Moose> replacement.
 158 It also avoids depending on any XS modules to allow simple deployments.  The
 159 name C<Moo> is based on the idea that it provides almost -but not quite- two
 160 thirds of L<Moose>.
 161
 162 Unlike C<Mouse> this module does not aim at full L<Moose> compatibility.  See
 163 L</INCOMPATIBILITIES> for more details.
 164
 165 =head1 WHY MOO EXISTS
 166
 167 If you want a full object system with a rich Metaprotocol, L<Moose> is
 168 already wonderful.
 169
 170 I've tried several times to use L<Mouse> but it's 3x the size of Moo and
 171 takes longer to load than most of my Moo based CGI scripts take to run.
 172
 173 If you don't want L<Moose>, you don't want "less metaprotocol" like L<Mouse>,
 174 you want "as little as possible" - which means "no metaprotocol", which is
 175 what Moo provides.
 176
 177 By Moo 1.0 I intend to have Moo's equivalent of L<Any::Moose> built in -
 178 if Moose gets loaded, any Moo class or role will act as a Moose equivalent
 179 if treated as such.
 180
 181 Hence - Moo exists as its name - Minimal Object Orientation - with a pledge
 182 to make it smooth to upgrade to L<Moose> when you need more than minimal
 183 features.
 184
 185 =head1 IMPORTED METHODS
 186
 187 =head2 new
 188
 189  Foo::Bar->new( attr1 => 3 );
 190
 191 or
 192
 193  Foo::Bar->new({ attr1 => 3 });
 194
 195 =head2 BUILDARGS
 196
 197 This feature from Moose is not yet supported.
 198
 199 =head2 BUILDALL
 200
 201 Don't override (or probably even call) this method.  Instead, you can define
 202 a C<BUILD> method on your class and the constructor will automatically call the
 203 C<BUILD> method from parent down to child after the object has been
 204 instantiated.  Typically this is used for object validation or possibly logging.
 205
 206 =head2 does
 207
 208  if ($foo->does('Some::Role1')) {
 209    ...
 210  }
 211
 212 Returns true if the object composes in the passed role.
 213
 214 =head1 IMPORTED SUBROUTINES
 215
 216 =head2 extends
 217
 218  extends 'Parent::Class';
 219
 220 Declares base class. Multiple superclasses can be passed for multiple
 221 inheritance (but please use roles instead).
 222
 223 Calling extends more than once will REPLACE your superclasses, not add to
 224 them like 'use base' would.
 225
 226 =head2 with
 227
 228  with 'Some::Role1';
 229  with 'Some::Role2';
 230
 231 Composes a L<Role::Tiny> into current class.  Only one role may be composed in
 232 at a time to allow the code to remain as simple as possible.
 233
 234 =head2 has
 235
 236  has attr => (
 237    is => 'ro',
 238  );
 239
 240 Declares an attribute for the class.
 241
 242 The options for C<has> are as follows:
 243
 244 =over 2
 245
 246 =item * is
 247
 248 B<required>, must be C<ro> or C<rw>.  Unsurprisingly, C<ro> generates an
 249 accessor that will not respond to arguments; to be clear: a getter only. C<rw>
 250 will create a perlish getter/setter.
 251
 252 =item * isa
 253
 254 Takes a coderef which is meant to validate the attribute.  Unlike L<Moose> Moo
 255 does not include a basic type system, so instead of doing C<< isa => 'Num' >>,
 256 one should do
 257
 258  isa => quote_sub q{
 259    die "$_[0] is not a number!" unless looks_like_number $_[0]
 260  },
 261
 262 L<Sub::Quote aware|/SUB QUOTE AWARE>
 263
 264 =item * coerce
 265
 266 Takes a coderef which is meant to coerce the attribute.  The basic idea is to
 267 do something like the following:
 268
 269  coerce => quote_sub q{
 270    $_[0] + 1 unless $_[0] % 2
 271  },
 272
 273 Coerce does not require C<isa> to be defined.
 274
 275 L<Sub::Quote aware|/SUB QUOTE AWARE>
 276
 277 =item * trigger
 278
 279 Takes a coderef which will get called any time the attribute is set. Coderef
 280 will be invoked against the object with the new value as an argument.
 281
 282 Note that Moose also passes the old value, if any; this feature is not yet
 283 supported.
 284
 285 L<Sub::Quote aware|/SUB QUOTE AWARE>
 286
 287 =item * default
 288
 289 Takes a coderef which will get called with $self as its only argument
 290 to populate an attribute if no value is supplied to the constructor - or
 291 if the attribute is lazy, when the attribute is first retrieved if no
 292 value has yet been provided.
 293
 294 Note that if your default is fired during new() there is no guarantee that
 295 other attributes have been populated yet so you should not rely on their
 296 existence.
 297
 298 L<Sub::Quote aware|/SUB QUOTE AWARE>
 299
 300 =item * predicate
 301
 302 Takes a method name which will return true if an attribute has a value.
 303
 304 A common example of this would be to call it C<has_$foo>, implying that the
 305 object has a C<$foo> set.
 306
 307 =item * builder
 308
 309 Takes a method name which will be called to create the attribute - functions
 310 exactly like default except that instead of calling
 311
 312   $default->($self);
 313
 314 Moo will call
 315
 316   $self->$builder;
 317
 318 =item * clearer
 319
 320 Takes a method name which will clear the attribute.
 321
 322 =item * lazy
 323
 324 B<Boolean>.  Set this if you want values for the attribute to be grabbed
 325 lazily.  This is usually a good idea if you have a L</builder> which requires
 326 another attribute to be set.
 327
 328 =item * required
 329
 330 B<Boolean>.  Set this if the attribute must be passed on instantiation.
 331
 332 =item * weak_ref
 333
 334 B<Boolean>.  Set this if you want the reference that the attribute contains to
 335 be weakened; use this when circular references are possible, which will cause
 336 leaks.
 337
 338 =item * init_arg
 339
 340 Takes the name of the key to look for at instantiation time of the object.  A
 341 common use of this is to make an underscored attribute have a non-underscored
 342 initialization name. C<undef> means that passing the value in on instantiation
 343
 344 =back
 345
 346 =head2 before
 347
 348  before foo => sub { ... };
 349
 350 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 351 documentation.
 352
 353 =head2 around
 354
 355  around foo => sub { ... };
 356
 357 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 358 documentation.
 359
 360 =head2 after
 361
 362  after foo => sub { ... };
 363
 364 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 365 documentation.
 366
 367 =head1 SUB QUOTE AWARE
 368
 369 L<Sub::Quote/quote_sub> allows us to create coderefs that are "inlineable,"
 370 giving us a handy, XS-free speed boost.  Any option that is L<Sub::Quote>
 371 aware can take advantage of this.
 372
 373 =head1 INCOMPATIBILITIES WITH MOOSE
 374
 375 You can only compose one role at a time.  If your application is large or
 376 complex enough to warrant complex composition, you wanted L<Moose>.
 377
 378 There is no complex type system.  C<isa> is verified with a coderef, if you
 379 need complex types, just make a library of coderefs, or better yet, functions
 380 that return quoted subs.
 381
 382 C<initializer> is not supported in core since the author considers it to be a
 383 bad idea but may be supported by an extension in future.
 384
 385 There is no meta object.  If you need this level of complexity you wanted
 386 L<Moose> - Moo succeeds at being small because it explicitly does not
 387 provide a metaprotocol.
 388
 389 No support for C<super>, C<override>, C<inner>, or C<augment> - override can
 390 be handled by around albeit with a little more typing, and the author considers
 391 augment to be a bad idea.
 392
 393 L</default> only supports coderefs, because doing otherwise is usually a
 394 mistake anyway.
 395
 396 C<lazy_build> is not supported per se, but of course it will work if you
 397 manually set all the options it implies.
 398
 399 C<auto_deref> is not supported since the author considers it a bad idea.
 400
 401 C<documentation> is not supported since it's a very poor replacement for POD.
 402
 403 =head1 AUTHOR
 404
 405 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 406
 407 =head1 CONTRIBUTORS
 408
 409 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 410
 411 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 412
 413 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 414
 415 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 416
 417 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 418
 419 =head1 COPYRIGHT
 420
 421 Copyright (c) 2010-2011 the Moo L</AUTHOR> and L</CONTRIBUTORS>
 422 as listed above.
 423
 424 =head1 LICENSE
 425
 426 This library is free software and may be distributed under the same terms
 427 as perl itself.
 428
 429 =cut