lib/Moo.pm

   1 package Moo;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use B 'perlstring';
   6 use Sub::Defer ();
   7
   8 our $VERSION = '1.001000'; # 1.1.0
   9 $VERSION = eval $VERSION;
  10
  11 require Moo::sification;
  12
  13 our %MAKERS;
  14
  15 sub _install_tracked {
  16   my ($target, $name, $code) = @_;
  17   $MAKERS{$target}{exports}{$name} = $code;
  18   _install_coderef "${target}::${name}" => "Moo::${name}" => $code;
  19 }
  20
  21 sub import {
  22   my $target = caller;
  23   my $class = shift;
  24   strictures->import;
  25   if ($Moo::Role::INFO{$target} and $Moo::Role::INFO{$target}{is_role}) {
  26     die "Cannot import Moo into a role";
  27   }
  28   $MAKERS{$target} ||= {};
  29   _install_tracked $target => extends => sub {
  30     $class->_set_superclasses($target, @_);
  31     $class->_maybe_reset_handlemoose($target);
  32     return;
  33   };
  34   _install_tracked $target => with => sub {
  35     require Moo::Role;
  36     Moo::Role->apply_roles_to_package($target, @_);
  37     $class->_maybe_reset_handlemoose($target);
  38   };
  39   _install_tracked $target => has => sub {
  40     my ($name_proto, %spec) = @_;
  41     my $name_isref = ref $name_proto eq 'ARRAY';
  42     foreach my $name ($name_isref ? @$name_proto : $name_proto) {
  43       # Note that when $name_proto is an arrayref, each attribute
  44       # needs a separate \%specs hashref
  45       my $spec_ref = $name_isref ? +{%spec} : \%spec;
  46       $class->_constructor_maker_for($target)
  47             ->register_attribute_specs($name, $spec_ref);
  48       $class->_accessor_maker_for($target)
  49             ->generate_method($target, $name, $spec_ref);
  50       $class->_maybe_reset_handlemoose($target);
  51     }
  52     return;
  53   };
  54   foreach my $type (qw(before after around)) {
  55     _install_tracked $target => $type => sub {
  56       require Class::Method::Modifiers;
  57       _install_modifier($target, $type, @_);
  58       return;
  59     };
  60   }
  61   return if $MAKERS{$target}{is_class}; # already exported into this package
  62   $MAKERS{$target}{is_class} = 1;
  63   {
  64     no strict 'refs';
  65     @{"${target}::ISA"} = do {
  66       require Moo::Object; ('Moo::Object');
  67     } unless @{"${target}::ISA"};
  68   }
  69   if ($INC{'Moo/HandleMoose.pm'}) {
  70     Moo::HandleMoose::inject_fake_metaclass_for($target);
  71   }
  72 }
  73
  74 sub unimport {
  75   my $target = caller;
  76   _unimport_coderefs($target, $MAKERS{$target});
  77 }
  78
  79 sub _set_superclasses {
  80   my $class = shift;
  81   my $target = shift;
  82   foreach my $superclass (@_) {
  83     _load_module($superclass);
  84     if ($INC{"Role/Tiny.pm"} && $Role::Tiny::INFO{$superclass}) {
  85       require Carp;
  86       Carp::croak("Can't extend role '$superclass'");
  87     }
  88   }
  89   # Can't do *{...} = \@_ or 5.10.0's mro.pm stops seeing @ISA
  90   @{*{_getglob("${target}::ISA")}{ARRAY}} = @_;
  91   if (my $old = delete $Moo::MAKERS{$target}{constructor}) {
  92     delete _getstash($target)->{new};
  93     Moo->_constructor_maker_for($target)
  94        ->register_attribute_specs(%{$old->all_attribute_specs});
  95   }
  96   no warnings 'once'; # piss off. -- mst
  97   $Moo::HandleMoose::MOUSE{$target} = [
  98     grep defined, map Mouse::Util::find_meta($_), @_
  99   ] if Mouse::Util->can('find_meta');
 100 }
 101
 102 sub _maybe_reset_handlemoose {
 103   my ($class, $target) = @_;
 104   if ($INC{"Moo/HandleMoose.pm"}) {
 105     Moo::HandleMoose::maybe_reinject_fake_metaclass_for($target);
 106   }
 107 }
 108
 109 sub _accessor_maker_for {
 110   my ($class, $target) = @_;
 111   return unless $MAKERS{$target};
 112   $MAKERS{$target}{accessor} ||= do {
 113     my $maker_class = do {
 114       if (my $m = do {
 115             if (my $defer_target =
 116                   (Sub::Defer::defer_info($target->can('new'))||[])->[0]
 117               ) {
 118               my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/);
 119               $MAKERS{$pkg} && $MAKERS{$pkg}{accessor};
 120             } else {
 121               undef;
 122             }
 123           }) {
 124         ref($m);
 125       } else {
 126         require Method::Generate::Accessor;
 127         'Method::Generate::Accessor'
 128       }
 129     };
 130     $maker_class->new;
 131   }
 132 }
 133
 134 sub _constructor_maker_for {
 135   my ($class, $target, $select_super) = @_;
 136   return unless $MAKERS{$target};
 137   $MAKERS{$target}{constructor} ||= do {
 138     require Method::Generate::Constructor;
 139     require Sub::Defer;
 140     my ($moo_constructor, $con);
 141
 142     if ($select_super && $MAKERS{$select_super}) {
 143       $moo_constructor = 1;
 144       $con = $MAKERS{$select_super}{constructor};
 145     } else {
 146       my $t_new = $target->can('new');
 147       if ($t_new) {
 148         if ($t_new == Moo::Object->can('new')) {
 149           $moo_constructor = 1;
 150         } elsif (my $defer_target = (Sub::Defer::defer_info($t_new)||[])->[0]) {
 151           my ($pkg) = ($defer_target =~ /^(.*)::[^:]+$/);
 152           if ($MAKERS{$pkg}) {
 153             $moo_constructor = 1;
 154             $con = $MAKERS{$pkg}{constructor};
 155           }
 156         }
 157       } else {
 158         $moo_constructor = 1; # no other constructor, make a Moo one
 159       }
 160     };
 161     ($con ? ref($con) : 'Method::Generate::Constructor')
 162       ->new(
 163         package => $target,
 164         accessor_generator => $class->_accessor_maker_for($target),
 165         construction_string => (
 166           $moo_constructor
 167             ? ($con ? $con->construction_string : undef)
 168             : ('$class->'.$target.'::SUPER::new($class->can(q[FOREIGNBUILDARGS]) ? $class->FOREIGNBUILDARGS(@_) : @_)')
 169         ),
 170         subconstructor_handler => (
 171           '      if ($Moo::MAKERS{$class}) {'."\n"
 172           .'        '.$class.'->_constructor_maker_for($class,'.perlstring($target).');'."\n"
 173           .'        return $class->new(@_)'.";\n"
 174           .'      } elsif ($INC{"Moose.pm"} and my $meta = Class::MOP::get_metaclass_by_name($class)) {'."\n"
 175           .'        return $meta->new_object($class->BUILDARGS(@_));'."\n"
 176           .'      }'."\n"
 177         ),
 178       )
 179       ->install_delayed
 180       ->register_attribute_specs(%{$con?$con->all_attribute_specs:{}})
 181   }
 182 }
 183
 184 1;
 185 =pod
 186
 187 =encoding utf-8
 188
 189 =head1 NAME
 190
 191 Moo - Minimalist Object Orientation (with Moose compatiblity)
 192
 193 =head1 SYNOPSIS
 194
 195  package Cat::Food;
 196
 197  use Moo;
 198
 199  sub feed_lion {
 200    my $self = shift;
 201    my $amount = shift || 1;
 202
 203    $self->pounds( $self->pounds - $amount );
 204  }
 205
 206  has taste => (
 207    is => 'ro',
 208  );
 209
 210  has brand => (
 211    is  => 'ro',
 212    isa => sub {
 213      die "Only SWEET-TREATZ supported!" unless $_[0] eq 'SWEET-TREATZ'
 214    },
 215  );
 216
 217  has pounds => (
 218    is  => 'rw',
 219    isa => sub { die "$_[0] is too much cat food!" unless $_[0] < 15 },
 220  );
 221
 222  1;
 223
 224 And elsewhere:
 225
 226  my $full = Cat::Food->new(
 227     taste  => 'DELICIOUS.',
 228     brand  => 'SWEET-TREATZ',
 229     pounds => 10,
 230  );
 231
 232  $full->feed_lion;
 233
 234  say $full->pounds;
 235
 236 =head1 DESCRIPTION
 237
 238 This module is an extremely light-weight subset of L<Moose> optimised for
 239 rapid startup and "pay only for what you use".
 240
 241 It also avoids depending on any XS modules to allow simple deployments.  The
 242 name C<Moo> is based on the idea that it provides almost -- but not quite -- two
 243 thirds of L<Moose>.
 244
 245 Unlike L<Mouse> this module does not aim at full compatibility with
 246 L<Moose>'s surface syntax, preferring instead of provide full interoperability
 247 via the metaclass inflation capabilities described in L</MOO AND MOOSE>.
 248
 249 For a full list of the minor differences between L<Moose> and L<Moo>'s surface
 250 syntax, see L</INCOMPATIBILITIES WITH MOOSE>.
 251
 252 =head1 WHY MOO EXISTS
 253
 254 If you want a full object system with a rich Metaprotocol, L<Moose> is
 255 already wonderful.
 256
 257 However, sometimes you're writing a command line script or a CGI script
 258 where fast startup is essential, or code designed to be deployed as a single
 259 file via L<App::FatPacker>, or you're writing a CPAN module and you want it
 260 to be usable by people with those constraints.
 261
 262 I've tried several times to use L<Mouse> but it's 3x the size of Moo and
 263 takes longer to load than most of my Moo based CGI scripts take to run.
 264
 265 If you don't want L<Moose>, you don't want "less metaprotocol" like L<Mouse>,
 266 you want "as little as possible" -- which means "no metaprotocol", which is
 267 what Moo provides.
 268
 269 Better still, if you install and load L<Moose>, we set up metaclasses for your
 270 L<Moo> classes and L<Moo::Role> roles, so you can use them in L<Moose> code
 271 without ever noticing that some of your codebase is using L<Moo>.
 272
 273 Hence, Moo exists as its name -- Minimal Object Orientation -- with a pledge
 274 to make it smooth to upgrade to L<Moose> when you need more than minimal
 275 features.
 276
 277 =head1 MOO AND MOOSE
 278
 279 If L<Moo> detects L<Moose> being loaded, it will automatically register
 280 metaclasses for your L<Moo> and L<Moo::Role> packages, so you should be able
 281 to use them in L<Moose> code without anybody ever noticing you aren't using
 282 L<Moose> everywhere.
 283
 284 L<Moo> will also create L<Moose type constraints|Moose::Manual::Types> for
 285 classes and roles, so that C<< isa => 'MyClass' >> and C<< isa => 'MyRole' >>
 286 work the same as for L<Moose> classes and roles.
 287
 288 Extending a L<Moose> class or consuming a L<Moose::Role> will also work.
 289
 290 So will extending a L<Mouse> class or consuming a L<Mouse::Role> - but note
 291 that we don't provide L<Mouse> metaclasses or metaroles so the other way
 292 around doesn't work. This feature exists for L<Any::Moose> users porting to
 293 L<Moo>; enabling L<Mouse> users to use L<Moo> classes is not a priority for us.
 294
 295 This means that there is no need for anything like L<Any::Moose> for Moo
 296 code - Moo and Moose code should simply interoperate without problem. To
 297 handle L<Mouse> code, you'll likely need an empty Moo role or class consuming
 298 or extending the L<Mouse> stuff since it doesn't register true L<Moose>
 299 metaclasses like L<Moo> does.
 300
 301 If you want types to be upgraded to the L<Moose> types, use
 302 L<MooX::Types::MooseLike> and install the L<MooseX::Types> library to
 303 match the L<MooX::Types::MooseLike> library you're using - L<Moo> will
 304 load the L<MooseX::Types> library and use that type for the newly created
 305 metaclass.
 306
 307 If you need to disable the metaclass creation, add:
 308
 309   no Moo::sification;
 310
 311 to your code before Moose is loaded, but bear in mind that this switch is
 312 currently global and turns the mechanism off entirely so don't put this
 313 in library code.
 314
 315 =head1 MOO VERSUS ANY::MOOSE
 316
 317 L<Any::Moose> will load L<Mouse> normally, and L<Moose> in a program using
 318 L<Moose> - which theoretically allows you to get the startup time of L<Mouse>
 319 without disadvantaging L<Moose> users.
 320
 321 Sadly, this doesn't entirely work, since the selection is load order dependent
 322 - L<Moo>'s metaclass inflation system explained above in L</MOO AND MOOSE> is
 323 significantly more reliable.
 324
 325 So if you want to write a CPAN module that loads fast or has only pure perl
 326 dependencies but is also fully usable by L<Moose> users, you should be using
 327 L<Moo>.
 328
 329 For a full explanation, see the article
 330 L<http://shadow.cat/blog/matt-s-trout/moo-versus-any-moose> which explains
 331 the differing strategies in more detail and provides a direct example of
 332 where L<Moo> succeeds and L<Any::Moose> fails.
 333
 334 =head1 IMPORTED METHODS
 335
 336 =head2 new
 337
 338  Foo::Bar->new( attr1 => 3 );
 339
 340 or
 341
 342  Foo::Bar->new({ attr1 => 3 });
 343
 344 =head2 BUILDARGS
 345
 346  sub BUILDARGS {
 347    my ( $class, @args ) = @_;
 348
 349    unshift @args, "attr1" if @args % 2 == 1;
 350
 351    return { @args };
 352  };
 353
 354  Foo::Bar->new( 3 );
 355
 356 The default implementation of this method accepts a hash or hash reference of
 357 named parameters. If it receives a single argument that isn't a hash reference
 358 it throws an error.
 359
 360 You can override this method in your class to handle other types of options
 361 passed to the constructor.
 362
 363 This method should always return a hash reference of named options.
 364
 365 =head2 BUILD
 366
 367 Define a C<BUILD> method on your class and the constructor will automatically
 368 call the C<BUILD> method from parent down to child after the object has
 369 been instantiated.  Typically this is used for object validation or possibly
 370 logging.
 371
 372 =head2 DEMOLISH
 373
 374 If you have a C<DEMOLISH> method anywhere in your inheritance hierarchy,
 375 a C<DESTROY> method is created on first object construction which will call
 376 C<< $instance->DEMOLISH($in_global_destruction) >> for each C<DEMOLISH>
 377 method from child upwards to parents.
 378
 379 Note that the C<DESTROY> method is created on first construction of an object
 380 of your class in order to not add overhead to classes without C<DEMOLISH>
 381 methods; this may prove slightly surprising if you try and define your own.
 382
 383 =head2 does
 384
 385  if ($foo->does('Some::Role1')) {
 386    ...
 387  }
 388
 389 Returns true if the object composes in the passed role.
 390
 391 =head1 IMPORTED SUBROUTINES
 392
 393 =head2 extends
 394
 395  extends 'Parent::Class';
 396
 397 Declares base class. Multiple superclasses can be passed for multiple
 398 inheritance (but please use roles instead).
 399
 400 Calling extends more than once will REPLACE your superclasses, not add to
 401 them like 'use base' would.
 402
 403 =head2 with
 404
 405  with 'Some::Role1';
 406
 407 or
 408
 409  with 'Some::Role1', 'Some::Role2';
 410
 411 Composes one or more L<Moo::Role> (or L<Role::Tiny>) roles into the current
 412 class.  An error will be raised if these roles have conflicting methods.
 413
 414 =head2 has
 415
 416  has attr => (
 417    is => 'ro',
 418  );
 419
 420 Declares an attribute for the class.
 421
 422  package Foo;
 423  use Moo;
 424  has 'attr' => (
 425    is => 'ro'
 426  );
 427
 428  package Bar;
 429  use Moo;
 430  extends 'Foo';
 431  has '+attr' => (
 432    default => sub { "blah" },
 433  );
 434
 435 Using the C<+> notation, it's possible to override an attribute.
 436
 437 The options for C<has> are as follows:
 438
 439 =over 2
 440
 441 =item * is
 442
 443 B<required>, may be C<ro>, C<lazy>, C<rwp> or C<rw>.
 444
 445 C<ro> generates an accessor that dies if you attempt to write to it - i.e.
 446 a getter only - by defaulting C<reader> to the name of the attribute.
 447
 448 C<lazy> generates a reader like C<ro>, but also sets C<lazy> to 1 and
 449 C<builder> to C<_build_${attribute_name}> to allow on-demand generated
 450 attributes.  This feature was my attempt to fix my incompetence when
 451 originally designing C<lazy_build>, and is also implemented by
 452 L<MooseX::AttributeShortcuts>. There is, however, nothing to stop you
 453 using C<lazy> and C<builder> yourself with C<rwp> or C<rw> - it's just that
 454 this isn't generally a good idea so we don't provide a shortcut for it.
 455
 456 C<rwp> generates a reader like C<ro>, but also sets C<writer> to
 457 C<_set_${attribute_name}> for attributes that are designed to be written
 458 from inside of the class, but read-only from outside.
 459 This feature comes from L<MooseX::AttributeShortcuts>.
 460
 461 C<rw> generates a normal getter/setter by defaulting C<accessor> to the
 462 name of the attribute.
 463
 464 =item * isa
 465
 466 Takes a coderef which is meant to validate the attribute.  Unlike L<Moose>, Moo
 467 does not include a basic type system, so instead of doing C<< isa => 'Num' >>,
 468 one should do
 469
 470  isa => sub {
 471    die "$_[0] is not a number!" unless looks_like_number $_[0]
 472  },
 473
 474 Note that the return value is ignored, only whether the sub lives or
 475 dies matters.
 476
 477 L<Sub::Quote aware|/SUB QUOTE AWARE>
 478
 479 Since L<Moo> does B<not> run the C<isa> check before C<coerce> if a coercion
 480 subroutine has been supplied, C<isa> checks are not structural to your code
 481 and can, if desired, be omitted on non-debug builds (although if this results
 482 in an uncaught bug causing your program to break, the L<Moo> authors guarantee
 483 nothing except that you get to keep both halves).
 484
 485 If you want L<MooseX::Types> style named types, look at
 486 L<MooX::Types::MooseLike>.
 487
 488 To cause your C<isa> entries to be automatically mapped to named
 489 L<Moose::Meta::TypeConstraint> objects (rather than the default behaviour
 490 of creating an anonymous type), set:
 491
 492   $Moo::HandleMoose::TYPE_MAP{$isa_coderef} = sub {
 493     require MooseX::Types::Something;
 494     return MooseX::Types::Something::TypeName();
 495   };
 496
 497 Note that this example is purely illustrative; anything that returns a
 498 L<Moose::Meta::TypeConstraint> object or something similar enough to it to
 499 make L<Moose> happy is fine.
 500
 501 =item * coerce
 502
 503 Takes a coderef which is meant to coerce the attribute.  The basic idea is to
 504 do something like the following:
 505
 506  coerce => sub {
 507    $_[0] + 1 unless $_[0] % 2
 508  },
 509
 510 Note that L<Moo> will always fire your coercion: this is to permit
 511 C<isa> entries to be used purely for bug trapping, whereas coercions are
 512 always structural to your code. We do, however, apply any supplied C<isa>
 513 check after the coercion has run to ensure that it returned a valid value.
 514
 515 L<Sub::Quote aware|/SUB QUOTE AWARE>
 516
 517 =item * handles
 518
 519 Takes a string
 520
 521   handles => 'RobotRole'
 522
 523 Where C<RobotRole> is a role (L<Moo::Role>) that defines an interface which
 524 becomes the list of methods to handle.
 525
 526 Takes a list of methods
 527
 528  handles => [ qw( one two ) ]
 529
 530 Takes a hashref
 531
 532  handles => {
 533    un => 'one',
 534  }
 535
 536 =item * C<trigger>
 537
 538 Takes a coderef which will get called any time the attribute is set. This
 539 includes the constructor, but not default or built values. Coderef will be
 540 invoked against the object with the new value as an argument.
 541
 542 If you set this to just C<1>, it generates a trigger which calls the
 543 C<_trigger_${attr_name}> method on C<$self>. This feature comes from
 544 L<MooseX::AttributeShortcuts>.
 545
 546 Note that Moose also passes the old value, if any; this feature is not yet
 547 supported.
 548
 549 L<Sub::Quote aware|/SUB QUOTE AWARE>
 550
 551 =item * C<default>
 552
 553 Takes a coderef which will get called with $self as its only argument
 554 to populate an attribute if no value is supplied to the constructor - or
 555 if the attribute is lazy, when the attribute is first retrieved if no
 556 value has yet been provided.
 557
 558 If a simple scalar is provided, it will be inlined as a string. Any non-code
 559 reference (hash, array) will result in an error - for that case instead use
 560 a code reference that returns the desired value.
 561
 562 Note that if your default is fired during new() there is no guarantee that
 563 other attributes have been populated yet so you should not rely on their
 564 existence.
 565
 566 L<Sub::Quote aware|/SUB QUOTE AWARE>
 567
 568 =item * C<predicate>
 569
 570 Takes a method name which will return true if an attribute has a value.
 571
 572 If you set this to just C<1>, the predicate is automatically named
 573 C<has_${attr_name}> if your attribute's name does not start with an
 574 underscore, or C<_has_${attr_name_without_the_underscore}> if it does.
 575 This feature comes from L<MooseX::AttributeShortcuts>.
 576
 577 =item * C<builder>
 578
 579 Takes a method name which will be called to create the attribute - functions
 580 exactly like default except that instead of calling
 581
 582   $default->($self);
 583
 584 Moo will call
 585
 586   $self->$builder;
 587
 588 The following features come from L<MooseX::AttributeShortcuts>:
 589
 590 If you set this to just C<1>, the builder is automatically named
 591 C<_build_${attr_name}>.
 592
 593 If you set this to a coderef or code-convertible object, that variable will be
 594 installed under C<$class::_build_${attr_name}> and the builder set to the same
 595 name.
 596
 597 =item * C<clearer>
 598
 599 Takes a method name which will clear the attribute.
 600
 601 If you set this to just C<1>, the clearer is automatically named
 602 C<clear_${attr_name}> if your attribute's name does not start with an
 603 underscore, or <_clear_${attr_name_without_the_underscore}> if it does.
 604 This feature comes from L<MooseX::AttributeShortcuts>.
 605
 606 =item * C<lazy>
 607
 608 B<Boolean>.  Set this if you want values for the attribute to be grabbed
 609 lazily.  This is usually a good idea if you have a L</builder> which requires
 610 another attribute to be set.
 611
 612 =item * C<required>
 613
 614 B<Boolean>.  Set this if the attribute must be passed on instantiation.
 615
 616 =item * C<reader>
 617
 618 The value of this attribute will be the name of the method to get the value of
 619 the attribute.  If you like Java style methods, you might set this to
 620 C<get_foo>
 621
 622 =item * C<writer>
 623
 624 The value of this attribute will be the name of the method to set the value of
 625 the attribute.  If you like Java style methods, you might set this to
 626 C<set_foo>.
 627
 628 =item * C<weak_ref>
 629
 630 B<Boolean>.  Set this if you want the reference that the attribute contains to
 631 be weakened; use this when circular references are possible, which will cause
 632 leaks.
 633
 634 =item * C<init_arg>
 635
 636 Takes the name of the key to look for at instantiation time of the object.  A
 637 common use of this is to make an underscored attribute have a non-underscored
 638 initialization name. C<undef> means that passing the value in on instantiation
 639 is ignored.
 640
 641 =back
 642
 643 =head2 before
 644
 645  before foo => sub { ... };
 646
 647 See L<< Class::Method::Modifiers/before method(s) => sub { ... } >> for full
 648 documentation.
 649
 650 =head2 around
 651
 652  around foo => sub { ... };
 653
 654 See L<< Class::Method::Modifiers/around method(s) => sub { ... } >> for full
 655 documentation.
 656
 657 =head2 after
 658
 659  after foo => sub { ... };
 660
 661 See L<< Class::Method::Modifiers/after method(s) => sub { ... } >> for full
 662 documentation.
 663
 664 =head1 SUB QUOTE AWARE
 665
 666 L<Sub::Quote/quote_sub> allows us to create coderefs that are "inlineable,"
 667 giving us a handy, XS-free speed boost.  Any option that is L<Sub::Quote>
 668 aware can take advantage of this.
 669
 670 To do this, you can write
 671
 672   use Moo;
 673   use Sub::Quote;
 674
 675   has foo => (
 676     is => 'ro',
 677     isa => quote_sub(q{ die "Not <3" unless $_[0] < 3 })
 678   );
 679
 680 which will be inlined as
 681
 682   do {
 683     local @_ = ($_[0]->{foo});
 684     die "Not <3" unless $_[0] < 3;
 685   }
 686
 687 or to avoid localizing @_,
 688
 689   has foo => (
 690     is => 'ro',
 691     isa => quote_sub(q{ my ($val) = @_; die "Not <3" unless $val < 3 })
 692   );
 693
 694 which will be inlined as
 695
 696   do {
 697     my ($val) = ($_[0]->{foo});
 698     die "Not <3" unless $val < 3;
 699   }
 700
 701 See L<Sub::Quote> for more information, including how to pass lexical
 702 captures that will also be compiled into the subroutine.
 703
 704 =head1 INCOMPATIBILITIES WITH MOOSE
 705
 706 There is no built-in type system.  C<isa> is verified with a coderef; if you
 707 need complex types, just make a library of coderefs, or better yet, functions
 708 that return quoted subs. L<MooX::Types::MooseLike> provides a similar API
 709 to L<MooseX::Types::Moose> so that you can write
 710
 711   has days_to_live => (is => 'ro', isa => Int);
 712
 713 and have it work with both; it is hoped that providing only subrefs as an
 714 API will encourage the use of other type systems as well, since it's
 715 probably the weakest part of Moose design-wise.
 716
 717 C<initializer> is not supported in core since the author considers it to be a
 718 bad idea and Moose best practices recommend avoiding it. Meanwhile C<trigger> or
 719 C<coerce> are more likely to be able to fulfill your needs.
 720
 721 There is no meta object.  If you need this level of complexity you wanted
 722 L<Moose> - Moo succeeds at being small because it explicitly does not
 723 provide a metaprotocol. However, if you load L<Moose>, then
 724
 725   Class::MOP::class_of($moo_class_or_role)
 726
 727 will return an appropriate metaclass pre-populated by L<Moo>.
 728
 729 No support for C<super>, C<override>, C<inner>, or C<augment> - the author
 730 considers augment to be a bad idea, and override can be translated:
 731
 732   override foo => sub {
 733     ...
 734     super();
 735     ...
 736   };
 737
 738   around foo => sub {
 739     my ($orig, $self) = (shift, shift);
 740     ...
 741     $self->$orig(@_);
 742     ...
 743   };
 744
 745 The C<dump> method is not provided by default. The author suggests loading
 746 L<Devel::Dwarn> into C<main::> (via C<perl -MDevel::Dwarn ...> for example) and
 747 using C<$obj-E<gt>$::Dwarn()> instead.
 748
 749 L</default> only supports coderefs and plain scalars, because passing a hash
 750 or array reference as a default is almost always incorrect since the value is
 751 then shared between all objects using that default.
 752
 753 C<lazy_build> is not supported; you are instead encouraged to use the
 754 C<< is => 'lazy' >> option supported by L<Moo> and L<MooseX::AttributeShortcuts>.
 755
 756 C<auto_deref> is not supported since the author considers it a bad idea and
 757 it has been considered best practice to avoid it for some time.
 758
 759 C<documentation> will show up in a L<Moose> metaclass created from your class
 760 but is otherwise ignored. Then again, L<Moose> ignores it as well, so this
 761 is arguably not an incompatibility.
 762
 763 Since C<coerce> does not require C<isa> to be defined but L<Moose> does
 764 require it, the metaclass inflation for coerce alone is a trifle insane
 765 and if you attempt to subtype the result will almost certainly break.
 766
 767 Handling of warnings: when you C<use Moo> we enable FATAL warnings.  The nearest
 768 similar invocation for L<Moose> would be:
 769
 770   use Moose;
 771   use warnings FATAL => "all";
 772
 773 Additionally, L<Moo> supports a set of attribute option shortcuts intended to
 774 reduce common boilerplate.  The set of shortcuts is the same as in the L<Moose>
 775 module L<MooseX::AttributeShortcuts> as of its version 0.009+.  So if you:
 776
 777     package MyClass;
 778     use Moo;
 779
 780 The nearest L<Moose> invocation would be:
 781
 782     package MyClass;
 783
 784     use Moose;
 785     use warnings FATAL => "all";
 786     use MooseX::AttributeShortcuts;
 787
 788 or, if you're inheriting from a non-Moose class,
 789
 790     package MyClass;
 791
 792     use Moose;
 793     use MooseX::NonMoose;
 794     use warnings FATAL => "all";
 795     use MooseX::AttributeShortcuts;
 796
 797 Finally, Moose requires you to call
 798
 799     __PACKAGE__->meta->make_immutable;
 800
 801 at the end of your class to get an inlined (i.e. not horribly slow)
 802 constructor. Moo does it automatically the first time ->new is called
 803 on your class. (C<make_immutable> is a no-op in Moo to ease migration.)
 804
 805 An extension L<MooX::late> exists to ease translating Moose packages
 806 to Moo by providing a more Moose-like interface.
 807
 808 =head1 SUPPORT
 809
 810 Users' IRC: #moose on irc.perl.org
 811
 812 =for html <a href="http://chat.mibbit.com/#moose@irc.perl.org">(click for instant chatroom login)</a>
 813
 814 Development and contribution IRC: #web-simple on irc.perl.org
 815
 816 =for html <a href="http://chat.mibbit.com/#web-simple@irc.perl.org">(click for instant chatroom login)</a>
 817
 818 Bugtracker: L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=Moo>
 819
 820 Git repository: L<git://git.shadowcat.co.uk/gitmo/Moo.git>
 821
 822 Git web access: L<http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=gitmo/Moo.git>
 823
 824 =head1 AUTHOR
 825
 826 mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>
 827
 828 =head1 CONTRIBUTORS
 829
 830 dg - David Leadbeater (cpan:DGL) <dgl@dgl.cx>
 831
 832 frew - Arthur Axel "fREW" Schmidt (cpan:FREW) <frioux@gmail.com>
 833
 834 hobbs - Andrew Rodland (cpan:ARODLAND) <arodland@cpan.org>
 835
 836 jnap - John Napiorkowski (cpan:JJNAPIORK) <jjn1056@yahoo.com>
 837
 838 ribasushi - Peter Rabbitson (cpan:RIBASUSHI) <ribasushi@cpan.org>
 839
 840 chip - Chip Salzenberg (cpan:CHIPS) <chip@pobox.com>
 841
 842 ajgb - Alex J. G. Burzyński (cpan:AJGB) <ajgb@cpan.org>
 843
 844 doy - Jesse Luehrs (cpan:DOY) <doy at tozt dot net>
 845
 846 perigrin - Chris Prather (cpan:PERIGRIN) <chris@prather.org>
 847
 848 Mithaldu - Christian Walde (cpan:MITHALDU) <walde.christian@googlemail.com>
 849
 850 ilmari - Dagfinn Ilmari Mannsåker (cpan:ILMARI) <ilmari@ilmari.org>
 851
 852 tobyink - Toby Inkster (cpan:TOBYINK) <tobyink@cpan.org>
 853
 854 haarg - Graham Knop (cpan:HAARG) <haarg@cpan.org>
 855
 856 mattp - Matt Phillips (cpan:MATTP) <mattp@cpan.org>
 857
 858 =head1 COPYRIGHT
 859
 860 Copyright (c) 2010-2011 the Moo L</AUTHOR> and L</CONTRIBUTORS>
 861 as listed above.
 862
 863 =head1 LICENSE
 864
 865 This library is free software and may be distributed under the same terms
 866 as perl itself. See L<http://dev.perl.org/licenses/>.
 867
 868 =cut