lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     _maybe_load_module('Class::XSAccessor')
  11       &&
  12     (Class::XSAccessor->VERSION > 1.06)
  13   ;
  14 }
  15
  16 sub generate_method {
  17   my ($self, $into, $name, $spec, $quote_opts) = @_;
  18   die "Must have an is" unless my $is = $spec->{is};
  19   if ($is eq 'ro') {
  20     $spec->{reader} = $name unless exists $spec->{reader};
  21   } elsif ($is eq 'rw') {
  22     $spec->{accessor} = $name unless exists $spec->{accessor};
  23   } elsif ($is eq 'lazy') {
  24     $spec->{init_arg} = undef unless exists $spec->{init_arg};
  25     $spec->{reader} = $name unless exists $spec->{reader};
  26     $spec->{lazy} = 1;
  27     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  28   } elsif ($is ne 'bare') {
  29     die "Unknown is ${is}";
  30   }
  31   my %methods;
  32   if (my $reader = $spec->{reader}) {
  33     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  34       $methods{$reader} = $self->_generate_xs(
  35         getters => $into, $reader, $name
  36       );
  37     } else {
  38       $self->{captures} = {};
  39       $methods{$reader} =
  40         quote_sub "${into}::${reader}"
  41           => $self->_generate_get($name, $spec)
  42           => delete $self->{captures}
  43         ;
  44     }
  45   }
  46   if (my $accessor = $spec->{accessor}) {
  47     if (
  48       our $CAN_HAZ_XS
  49       && $self->is_simple_get($name, $spec)
  50       && $self->is_simple_set($name, $spec)
  51     ) {
  52       $methods{$accessor} = $self->_generate_xs(
  53         accessors => $into, $accessor, $name
  54       );
  55     } else {
  56       $self->{captures} = {};
  57       $methods{$accessor} =
  58         quote_sub "${into}::${accessor}"
  59           => $self->_generate_getset($name, $spec)
  60           => delete $self->{captures}
  61         ;
  62     }
  63   }
  64   if (my $writer = $spec->{writer}) {
  65     if (
  66       our $CAN_HAZ_XS
  67       && $self->is_simple_set($name, $spec)
  68     ) {
  69       $methods{$writer} = $self->_generate_xs(
  70         setters => $into, $writer, $name
  71       );
  72     } else {
  73       $self->{captures} = {};
  74       $methods{$writer} =
  75         quote_sub "${into}::${writer}"
  76           => $self->_generate_set($name, $spec)
  77           => delete $self->{captures}
  78         ;
  79     }
  80   }
  81   if (my $pred = $spec->{predicate}) {
  82     $methods{$pred} =
  83       quote_sub "${into}::${pred}" =>
  84         '    '.$self->_generate_simple_has('$_[0]', $name)."\n"
  85       ;
  86   }
  87   if (my $cl = $spec->{clearer}) {
  88     $methods{$cl} =
  89       quote_sub "${into}::${cl}" =>
  90         "    delete \$_[0]->{${\perlstring $name}}\n"
  91       ;
  92   }
  93   if (my $hspec = $spec->{handles}) {
  94     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
  95     my @specs = do {
  96       if (ref($hspec) eq 'ARRAY') {
  97         map [ $_ => $_ ], @$hspec;
  98       } elsif (ref($hspec) eq 'HASH') {
  99         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 100           keys %$hspec;
 101       } elsif (!ref($hspec)) {
 102         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 103       } else {
 104         die "You gave me a handles of ${hspec} and I have no idea why";
 105       }
 106     };
 107     foreach my $spec (@specs) {
 108       my ($proxy, $target, @args) = @$spec;
 109       $self->{captures} = {};
 110       $methods{$proxy} =
 111         quote_sub "${into}::${proxy}" =>
 112           $self->_generate_delegation($asserter, $target, \@args),
 113           delete $self->{captures}
 114         ;
 115     }
 116   }
 117   if (my $asserter = $spec->{asserter}) {
 118     $self->{captures} = {};
 119     $methods{$asserter} =
 120       quote_sub "${into}::${asserter}" =>
 121         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 122         delete $self->{captures}
 123       ;
 124   }
 125   \%methods;
 126 }
 127
 128 sub is_simple_attribute {
 129   my ($self, $name, $spec) = @_;
 130   # clearer doesn't have to be listed because it doesn't
 131   # affect whether defined/exists makes a difference
 132   !grep $spec->{$_},
 133     qw(lazy default builder isa trigger predicate);
 134 }
 135
 136 sub is_simple_get {
 137   my ($self, $name, $spec) = @_;
 138   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 139 }
 140
 141 sub is_simple_set {
 142   my ($self, $name, $spec) = @_;
 143   !grep $spec->{$_}, qw(isa trigger);
 144 }
 145
 146 sub _generate_get {
 147   my ($self, $name, $spec) = @_;
 148   my $simple = $self->_generate_simple_get('$_[0]', $name);
 149   if ($self->is_simple_get($name, $spec)) {
 150     $simple;
 151   } else {
 152     'do { '.$self->_generate_use_default(
 153       '$_[0]', $name, $spec,
 154       $self->_generate_simple_has('$_[0]', $name),
 155     ).'; '.$simple.' }';
 156   }
 157 }
 158
 159 sub _generate_simple_has {
 160   my ($self, $me, $name) = @_;
 161   "exists ${me}->{${\perlstring $name}}";
 162 }
 163
 164 sub generate_get_default {
 165   my $self = shift;
 166   $self->{captures} = {};
 167   my $code = $self->_generate_get_default(@_);
 168   ($code, delete $self->{captures});
 169 }
 170
 171 sub _generate_use_default {
 172   my ($self, $me, $name, $spec, $test) = @_;
 173   $self->_generate_simple_set(
 174     $me, $name, $self->_generate_get_default($me, $name, $spec)
 175   ).' unless '.$test;
 176 }
 177
 178 sub _generate_get_default {
 179   my ($self, $me, $name, $spec) = @_;
 180   $spec->{default}
 181     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 182     : "${me}->${\$spec->{builder}}"
 183 }
 184
 185 sub generate_simple_get {
 186   my ($self, @args) = @_;
 187   $self->_generate_simple_get(@args);
 188 }
 189
 190 sub _generate_simple_get {
 191   my ($self, $me, $name) = @_;
 192   my $name_str = perlstring $name;
 193   "${me}->{${name_str}}";
 194 }
 195
 196 sub _generate_set {
 197   my ($self, $name, $spec) = @_;
 198   if ($self->is_simple_set($name, $spec)) {
 199     $self->_generate_simple_set('$_[0]', $name, '$_[1]');
 200   } else {
 201     my ($trigger, $isa_check) = @{$spec}{qw(trigger isa)};
 202     my $simple = $self->_generate_simple_set('$self', $name, '$value');
 203     my $code = "do { my (\$self, \$value) = \@_;\n";
 204     if ($isa_check) {
 205       $code .=
 206         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 207     }
 208     if ($trigger) {
 209       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 210       $code .=
 211         "        ".$simple.";\n        ".$fire.";\n"
 212         ."        \$value;\n";
 213     } else {
 214       $code .= "        ".$simple.";\n";
 215     }
 216     $code .= "      }";
 217     $code;
 218   }
 219 }
 220
 221 sub generate_trigger {
 222   my $self = shift;
 223   $self->{captures} = {};
 224   my $code = $self->_generate_trigger(@_);
 225   ($code, delete $self->{captures});
 226 }
 227
 228 sub _generate_trigger {
 229   my ($self, $name, $obj, $value, $trigger) = @_;
 230   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 231 }
 232
 233 sub generate_isa_check {
 234   my ($self, @args) = @_;
 235   $self->{captures} = {};
 236   my $code = $self->_generate_isa_check(@args);
 237   ($code, delete $self->{captures});
 238 }
 239
 240 sub _generate_isa_check {
 241   my ($self, $name, $value, $check) = @_;
 242   $self->_generate_call_code($name, 'isa_check', $value, $check);
 243 }
 244
 245 sub _generate_call_code {
 246   my ($self, $name, $type, $values, $sub) = @_;
 247   if (my $quoted = quoted_from_sub($sub)) {
 248     my $code = $quoted->[1];
 249     my $at_ = '@_ = ('.$values.');';
 250     if (my $captures = $quoted->[2]) {
 251       my $cap_name = qq{\$${type}_captures_for_${name}};
 252       $self->{captures}->{$cap_name} = \$captures;
 253       Sub::Quote::inlinify(
 254         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 255       );
 256     } else {
 257       Sub::Quote::inlinify($code, $values);
 258     }
 259   } else {
 260     my $cap_name = qq{\$${type}_for_${name}};
 261     $self->{captures}->{$cap_name} = \$sub;
 262     "${cap_name}->(${values})";
 263   }
 264 }
 265
 266 sub generate_populate_set {
 267   my $self = shift;
 268   $self->{captures} = {};
 269   my $code = $self->_generate_populate_set(@_);
 270   ($code, delete $self->{captures});
 271 }
 272
 273 sub _generate_populate_set {
 274   my ($self, $me, $name, $spec, $source, $test) = @_;
 275   if (!$spec->{lazy} and
 276         ($spec->{default} or $spec->{builder})) {
 277     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 278     my $get_value =
 279       "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 280         .$self->_generate_get_default(
 281           '$new', $_, $spec
 282         )
 283         ."\n${get_indent})";
 284     ($spec->{isa}
 285       ? "    {\n      my \$value = ".$get_value.";\n      "
 286         .$self->_generate_isa_check(
 287           $name, '$value', $spec->{isa}
 288         ).";\n"
 289         .'      '.$self->_generate_simple_set($me, $name, '$value').";\n"
 290         ."    }\n"
 291       : '    '.$self->_generate_simple_set($me, $name, $get_value).";\n"
 292     )
 293     .($spec->{trigger}
 294       ? '    '
 295         .$self->_generate_trigger(
 296           $name, $me, $self->_generate_simple_get($me, $name),
 297           $spec->{trigger}
 298         )." if ${test};\n"
 299       : ''
 300     );
 301   } else {
 302     "    if (${test}) {\n"
 303       .($spec->{isa}
 304         ? "      "
 305           .$self->_generate_isa_check(
 306             $name, $source, $spec->{isa}
 307           ).";\n"
 308         : ""
 309       )
 310       ."      ".$self->_generate_simple_set($me, $name, $source).";\n"
 311       .($spec->{trigger}
 312         ? "      "
 313           .$self->_generate_trigger(
 314             $name, $me, $self->_generate_simple_get($me, $name),
 315             $spec->{trigger}
 316           ).";\n"
 317         : ""
 318       )
 319       ."    }\n";
 320   }
 321 }
 322
 323 sub generate_multi_set {
 324   my ($self, $me, $to_set, $from) = @_;
 325   "\@{${me}}{qw(${\join ' ', @$to_set})} = $from";
 326 }
 327
 328 sub generate_simple_set {
 329   my $self = shift;
 330   $self->{captures} = {};
 331   my $code = $self->_generate_simple_set(@_);
 332   ($code, delete $self->{captures});
 333 }
 334
 335 sub _generate_simple_set {
 336   my ($self, $me, $name, $value) = @_;
 337   my $name_str = perlstring $name;
 338   "${me}->{${name_str}} = ${value}";
 339 }
 340
 341 sub _generate_getset {
 342   my ($self, $name, $spec) = @_;
 343   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 344     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 345 }
 346
 347 sub _generate_delegation {
 348   my ($self, $asserter, $target, $args) = @_;
 349   my $arg_string = do {
 350     if (@$args) {
 351       # I could, I reckon, linearise out non-refs here using perlstring
 352       # plus something to check for numbers but I'm unsure if it's worth it
 353       $self->{captures}{'@curries'} = $args;
 354       '@curries, @_';
 355     } else {
 356       '@_';
 357     }
 358   };
 359   "shift->${asserter}->${target}(${arg_string});";
 360 }
 361
 362 sub _generate_xs {
 363   my ($self, $type, $into, $name, $slot) = @_;
 364   Class::XSAccessor->import(
 365     class => $into,
 366     $type => { $name => $slot }
 367   );
 368   $into->can($name);
 369 }
 370
 371 1;