lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 use Module::Runtime qw(use_module);
  11 BEGIN {
  12   our $CAN_HAZ_XS =
  13     !$ENV{MOO_XS_DISABLE}
  14       &&
  15     _maybe_load_module('Class::XSAccessor')
  16       &&
  17     (eval { Class::XSAccessor->VERSION('1.07') })
  18   ;
  19 }
  20
  21 sub generate_method {
  22   my ($self, $into, $name, $spec, $quote_opts) = @_;
  23   $name =~ s/^\+//;
  24   die "Must have an is" unless my $is = $spec->{is};
  25   if ($is eq 'ro') {
  26     $spec->{reader} = $name unless exists $spec->{reader};
  27   } elsif ($is eq 'rw') {
  28     $spec->{accessor} = $name unless exists $spec->{accessor}
  29       or ( $spec->{reader} and $spec->{writer} );
  30   } elsif ($is eq 'lazy') {
  31     $spec->{reader} = $name unless exists $spec->{reader};
  32     $spec->{lazy} = 1;
  33     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  34   } elsif ($is eq 'rwp') {
  35     $spec->{reader} = $name unless exists $spec->{reader};
  36     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  37   } elsif ($is ne 'bare') {
  38     die "Unknown is ${is}";
  39   }
  40   if (exists $spec->{builder}) {
  41     if(ref $spec->{builder}) {
  42       die "Invalid builder for $into->$name - not a method name, coderef or"
  43         . " code-convertible object"
  44         unless ref $spec->{builder} eq 'CODE'
  45         or (blessed($spec->{builder}) and eval { \&{$spec->{builder}} });
  46       $spec->{builder_sub} = $spec->{builder};
  47       $spec->{builder} = 1;
  48     }
  49     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  50     die "Invalid builder for $into->$name - not a valid method name"
  51       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  52   }
  53   if (($spec->{predicate}||0) eq 1) {
  54     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  55   }
  56   if (($spec->{clearer}||0) eq 1) {
  57     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  58   }
  59   if (($spec->{trigger}||0) eq 1) {
  60     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  61   }
  62
  63   for my $setting (qw( default coerce )) {
  64     next if !exists $spec->{$setting};
  65     my $value = $spec->{$setting};
  66     my $invalid = "Invalid $setting '" . overload::StrVal($value)
  67       . "' for $into->$name - not a coderef";
  68     die "$invalid or code-convertible object"
  69       unless ref $value and (ref $value eq 'CODE' or blessed($value));
  70     die "$invalid and could not be converted to a coderef: $@"
  71       if !eval { \&$value };
  72   }
  73
  74   my %methods;
  75   if (my $reader = $spec->{reader}) {
  76     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  77       $methods{$reader} = $self->_generate_xs(
  78         getters => $into, $reader, $name, $spec
  79       );
  80     } else {
  81       $self->{captures} = {};
  82       $methods{$reader} =
  83         quote_sub "${into}::${reader}"
  84           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  85              .$self->_generate_get($name, $spec)
  86           => delete $self->{captures}
  87         ;
  88     }
  89   }
  90   if (my $accessor = $spec->{accessor}) {
  91     if (
  92       our $CAN_HAZ_XS
  93       && $self->is_simple_get($name, $spec)
  94       && $self->is_simple_set($name, $spec)
  95     ) {
  96       $methods{$accessor} = $self->_generate_xs(
  97         accessors => $into, $accessor, $name, $spec
  98       );
  99     } else {
 100       $self->{captures} = {};
 101       $methods{$accessor} =
 102         quote_sub "${into}::${accessor}"
 103           => $self->_generate_getset($name, $spec)
 104           => delete $self->{captures}
 105         ;
 106     }
 107   }
 108   if (my $writer = $spec->{writer}) {
 109     if (
 110       our $CAN_HAZ_XS
 111       && $self->is_simple_set($name, $spec)
 112     ) {
 113       $methods{$writer} = $self->_generate_xs(
 114         setters => $into, $writer, $name, $spec
 115       );
 116     } else {
 117       $self->{captures} = {};
 118       $methods{$writer} =
 119         quote_sub "${into}::${writer}"
 120           => $self->_generate_set($name, $spec)
 121           => delete $self->{captures}
 122         ;
 123     }
 124   }
 125   if (my $pred = $spec->{predicate}) {
 126     $methods{$pred} =
 127       quote_sub "${into}::${pred}" =>
 128         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 129       ;
 130   }
 131   if (my $pred = $spec->{builder_sub}) {
 132     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 133   }
 134   if (my $cl = $spec->{clearer}) {
 135     $methods{$cl} =
 136       quote_sub "${into}::${cl}" =>
 137         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 138       ;
 139   }
 140   if (my $hspec = $spec->{handles}) {
 141     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 142     my @specs = do {
 143       if (ref($hspec) eq 'ARRAY') {
 144         map [ $_ => $_ ], @$hspec;
 145       } elsif (ref($hspec) eq 'HASH') {
 146         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 147           keys %$hspec;
 148       } elsif (!ref($hspec)) {
 149         map [ $_ => $_ ], use_module('Role::Tiny')->methods_provided_by(use_module($hspec))
 150       } else {
 151         die "You gave me a handles of ${hspec} and I have no idea why";
 152       }
 153     };
 154     foreach my $spec (@specs) {
 155       my ($proxy, $target, @args) = @$spec;
 156       $self->{captures} = {};
 157       $methods{$proxy} =
 158         quote_sub "${into}::${proxy}" =>
 159           $self->_generate_delegation($asserter, $target, \@args),
 160           delete $self->{captures}
 161         ;
 162     }
 163   }
 164   if (my $asserter = $spec->{asserter}) {
 165     $self->{captures} = {};
 166     $methods{$asserter} =
 167       quote_sub "${into}::${asserter}" =>
 168         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 169         delete $self->{captures}
 170       ;
 171   }
 172   \%methods;
 173 }
 174
 175 sub is_simple_attribute {
 176   my ($self, $name, $spec) = @_;
 177   # clearer doesn't have to be listed because it doesn't
 178   # affect whether defined/exists makes a difference
 179   !grep $spec->{$_},
 180     qw(lazy default builder coerce isa trigger predicate weak_ref);
 181 }
 182
 183 sub is_simple_get {
 184   my ($self, $name, $spec) = @_;
 185   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 186 }
 187
 188 sub is_simple_set {
 189   my ($self, $name, $spec) = @_;
 190   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 191 }
 192
 193 sub has_eager_default {
 194   my ($self, $name, $spec) = @_;
 195   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 196 }
 197
 198 sub _generate_get {
 199   my ($self, $name, $spec) = @_;
 200   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 201   if ($self->is_simple_get($name, $spec)) {
 202     $simple;
 203   } else {
 204     'do { '.$self->_generate_use_default(
 205       '$_[0]', $name, $spec,
 206       $self->_generate_simple_has('$_[0]', $name, $spec),
 207     ).'; '
 208     .($spec->{isa}
 209       ?($self->_generate_isa_check($name, $simple, $spec->{isa}).'; ')
 210       :''
 211     )
 212     .$simple.' }';
 213   }
 214 }
 215
 216 sub _generate_simple_has {
 217   my ($self, $me, $name) = @_;
 218   "exists ${me}->{${\perlstring $name}}";
 219 }
 220
 221 sub _generate_simple_clear {
 222   my ($self, $me, $name) = @_;
 223   "    delete ${me}->{${\perlstring $name}}\n"
 224 }
 225
 226 sub generate_get_default {
 227   my $self = shift;
 228   $self->{captures} = {};
 229   my $code = $self->_generate_get_default(@_);
 230   ($code, delete $self->{captures});
 231 }
 232
 233 sub _generate_use_default {
 234   my ($self, $me, $name, $spec, $test) = @_;
 235   my $get_value = $self->_generate_get_default($me, $name, $spec);
 236   if ($spec->{coerce}) {
 237     $get_value = $self->_generate_coerce(
 238       $name, $get_value,
 239       $spec->{coerce}
 240     )
 241   }
 242   $self->_generate_simple_set(
 243     $me, $name, $spec, $get_value
 244   ).' unless '.$test;
 245 }
 246
 247 sub _generate_get_default {
 248   my ($self, $me, $name, $spec) = @_;
 249   $spec->{default}
 250     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 251     : "${me}->${\$spec->{builder}}"
 252 }
 253
 254 sub generate_simple_get {
 255   my ($self, @args) = @_;
 256   $self->_generate_simple_get(@args);
 257 }
 258
 259 sub _generate_simple_get {
 260   my ($self, $me, $name) = @_;
 261   my $name_str = perlstring $name;
 262   "${me}->{${name_str}}";
 263 }
 264
 265 sub _generate_set {
 266   my ($self, $name, $spec) = @_;
 267   if ($self->is_simple_set($name, $spec)) {
 268     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 269   } else {
 270     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 271     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 272     my $code = "do { my (\$self, \$value) = \@_;\n";
 273     if ($coerce) {
 274       $code .=
 275         "        \$value = "
 276         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 277     }
 278     if ($isa_check) {
 279       $code .=
 280         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 281     }
 282     if ($trigger) {
 283       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 284       $code .=
 285         "        ".$simple.";\n        ".$fire.";\n"
 286         ."        \$value;\n";
 287     } else {
 288       $code .= "        ".$simple.";\n";
 289     }
 290     $code .= "      }";
 291     $code;
 292   }
 293 }
 294
 295 sub generate_coerce {
 296   my $self = shift;
 297   $self->{captures} = {};
 298   my $code = $self->_generate_coerce(@_);
 299   ($code, delete $self->{captures});
 300 }
 301
 302 sub _attr_desc {
 303   my ($name, $init_arg) = @_;
 304   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 305   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 306 }
 307
 308 sub _generate_coerce {
 309   my ($self, $name, $value, $coerce, $init_arg) = @_;
 310   $self->_generate_die_prefix(
 311     "coercion for ${\_attr_desc($name, $init_arg)} failed: ",
 312     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 313   );
 314 }
 315
 316 sub generate_trigger {
 317   my $self = shift;
 318   $self->{captures} = {};
 319   my $code = $self->_generate_trigger(@_);
 320   ($code, delete $self->{captures});
 321 }
 322
 323 sub _generate_trigger {
 324   my ($self, $name, $obj, $value, $trigger) = @_;
 325   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 326 }
 327
 328 sub generate_isa_check {
 329   my ($self, @args) = @_;
 330   $self->{captures} = {};
 331   my $code = $self->_generate_isa_check(@args);
 332   ($code, delete $self->{captures});
 333 }
 334
 335 sub _generate_die_prefix {
 336   my ($self, $prefix, $inside) = @_;
 337   "do {\n"
 338   .'  my $sig_die = $SIG{__DIE__} || sub { die $_[0] };'."\n"
 339   .'  local $SIG{__DIE__} = sub {'."\n"
 340   .'    $sig_die->(ref($_[0]) ? $_[0] : '.perlstring($prefix).'.$_[0]);'."\n"
 341   .'  };'."\n"
 342   .$inside
 343   ."}\n"
 344 }
 345
 346 sub _generate_isa_check {
 347   my ($self, $name, $value, $check, $init_arg) = @_;
 348   $self->_generate_die_prefix(
 349     "isa check for ${\_attr_desc($name, $init_arg)} failed: ",
 350     $self->_generate_call_code($name, 'isa_check', $value, $check)
 351   );
 352 }
 353
 354 sub _generate_call_code {
 355   my ($self, $name, $type, $values, $sub) = @_;
 356   if (my $quoted = quoted_from_sub($sub)) {
 357     my $code = $quoted->[1];
 358     if (my $captures = $quoted->[2]) {
 359       my $cap_name = qq{\$${type}_captures_for_${name}};
 360       $self->{captures}->{$cap_name} = \$captures;
 361       Sub::Quote::inlinify(
 362         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), 1
 363       );
 364     } else {
 365       Sub::Quote::inlinify($code, $values, undef, 1);
 366     }
 367   } else {
 368     my $cap_name = qq{\$${type}_for_${name}};
 369     $self->{captures}->{$cap_name} = \$sub;
 370     "${cap_name}->(${values})";
 371   }
 372 }
 373
 374 sub generate_populate_set {
 375   my $self = shift;
 376   $self->{captures} = {};
 377   my $code = $self->_generate_populate_set(@_);
 378   ($code, delete $self->{captures});
 379 }
 380
 381 sub _generate_populate_set {
 382   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 383   if ($self->has_eager_default($name, $spec)) {
 384     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 385     my $get_default = $self->_generate_get_default(
 386                         '$new', $_, $spec
 387                       );
 388     my $get_value =
 389       defined($spec->{init_arg})
 390         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 391             .$get_default
 392             ."\n${get_indent})"
 393         : $get_default;
 394     if ($spec->{coerce}) {
 395       $get_value = $self->_generate_coerce(
 396         $name, $get_value,
 397         $spec->{coerce}, $init_arg
 398       )
 399     }
 400     ($spec->{isa}
 401       ? "    {\n      my \$value = ".$get_value.";\n      "
 402         .$self->_generate_isa_check(
 403           $name, '$value', $spec->{isa}, $init_arg
 404         ).";\n"
 405         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 406         ."    }\n"
 407       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 408     )
 409     .($spec->{trigger}
 410       ? '    '
 411         .$self->_generate_trigger(
 412           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 413           $spec->{trigger}
 414         )." if ${test};\n"
 415       : ''
 416     );
 417   } else {
 418     "    if (${test}) {\n"
 419       .($spec->{coerce}
 420         ? "      $source = "
 421           .$self->_generate_coerce(
 422             $name, $source,
 423             $spec->{coerce}, $init_arg
 424           ).";\n"
 425         : ""
 426       )
 427       .($spec->{isa}
 428         ? "      "
 429           .$self->_generate_isa_check(
 430             $name, $source, $spec->{isa}, $init_arg
 431           ).";\n"
 432         : ""
 433       )
 434       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 435       .($spec->{trigger}
 436         ? "      "
 437           .$self->_generate_trigger(
 438             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 439             $spec->{trigger}
 440           ).";\n"
 441         : ""
 442       )
 443       ."    }\n";
 444   }
 445 }
 446
 447 sub _generate_core_set {
 448   my ($self, $me, $name, $spec, $value) = @_;
 449   my $name_str = perlstring $name;
 450   "${me}->{${name_str}} = ${value}";
 451 }
 452
 453 sub _generate_simple_set {
 454   my ($self, $me, $name, $spec, $value) = @_;
 455   my $name_str = perlstring $name;
 456
 457   if ($spec->{weak_ref}) {
 458     $value = '$preserve = '.$value;
 459     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 460     require Scalar::Util;
 461
 462     # Perl < 5.8.3 can't weaken refs to readonly vars
 463     # (e.g. string constants). This *can* be solved by:
 464     #
 465     #Internals::SetReadWrite($foo);
 466     #Scalar::Util::weaken ($foo);
 467     #Internals::SetReadOnly($foo);
 468     #
 469     # but requires XS and is just too damn crazy
 470     # so simply throw a better exception
 471     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple}); no warnings 'void'; \$preserve";
 472     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 473
 474       my \$preserve;
 475       eval { Scalar::Util::weaken($simple); 1 }
 476         ? do { no warnings 'void'; \$preserve; }
 477         : do {
 478           if( \$@ =~ /Modification of a read-only value attempted/) {
 479             require Carp;
 480             Carp::croak( sprintf (
 481               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 482               $name_str,
 483             ) );
 484           } else {
 485             die \$@;
 486           }
 487         }
 488 EOC
 489   } else {
 490     $self->_generate_core_set($me, $name, $spec, $value);
 491   }
 492 }
 493
 494 sub _generate_getset {
 495   my ($self, $name, $spec) = @_;
 496   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 497     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 498 }
 499
 500 sub _generate_delegation {
 501   my ($self, $asserter, $target, $args) = @_;
 502   my $arg_string = do {
 503     if (@$args) {
 504       # I could, I reckon, linearise out non-refs here using perlstring
 505       # plus something to check for numbers but I'm unsure if it's worth it
 506       $self->{captures}{'@curries'} = $args;
 507       '@curries, @_';
 508     } else {
 509       '@_';
 510     }
 511   };
 512   "shift->${asserter}->${target}(${arg_string});";
 513 }
 514
 515 sub _generate_xs {
 516   my ($self, $type, $into, $name, $slot) = @_;
 517   Class::XSAccessor->import(
 518     class => $into,
 519     $type => { $name => $slot },
 520     replace => 1,
 521   );
 522   $into->can($name);
 523 }
 524
 525 sub default_construction_string { '{}' }
 526
 527 1;