lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 use Module::Runtime qw(use_module);
  11 BEGIN {
  12   our $CAN_HAZ_XS =
  13     !$ENV{MOO_XS_DISABLE}
  14       &&
  15     _maybe_load_module('Class::XSAccessor')
  16       &&
  17     (eval { Class::XSAccessor->VERSION('1.07') })
  18   ;
  19 }
  20
  21 sub _die_overwrite
  22 {
  23   my ($pkg, $method, $type) = @_;
  24   die "You cannot overwrite a locally defined method ($method) with @{[ $type || 'an accessor' ]}";
  25 }
  26
  27 sub generate_method {
  28   my ($self, $into, $name, $spec, $quote_opts) = @_;
  29   $spec->{allow_overwrite}++ if $name =~ s/^\+//;
  30   die "Must have an is" unless my $is = $spec->{is};
  31   if ($is eq 'ro') {
  32     $spec->{reader} = $name unless exists $spec->{reader};
  33   } elsif ($is eq 'rw') {
  34     $spec->{accessor} = $name unless exists $spec->{accessor}
  35       or ( $spec->{reader} and $spec->{writer} );
  36   } elsif ($is eq 'lazy') {
  37     $spec->{reader} = $name unless exists $spec->{reader};
  38     $spec->{lazy} = 1;
  39     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  40   } elsif ($is eq 'rwp') {
  41     $spec->{reader} = $name unless exists $spec->{reader};
  42     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  43   } elsif ($is ne 'bare') {
  44     die "Unknown is ${is}";
  45   }
  46   if (exists $spec->{builder}) {
  47     if(ref $spec->{builder}) {
  48       die "Invalid builder for $into->$name - not a method name, coderef or"
  49         . " code-convertible object"
  50         unless ref $spec->{builder} eq 'CODE'
  51         or (blessed($spec->{builder}) and eval { \&{$spec->{builder}} });
  52       $spec->{builder_sub} = $spec->{builder};
  53       $spec->{builder} = 1;
  54     }
  55     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  56     die "Invalid builder for $into->$name - not a valid method name"
  57       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  58   }
  59   if (($spec->{predicate}||0) eq 1) {
  60     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  61   }
  62   if (($spec->{clearer}||0) eq 1) {
  63     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  64   }
  65   if (($spec->{trigger}||0) eq 1) {
  66     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  67   }
  68
  69   for my $setting (qw( isa coerce )) {
  70     next if !exists $spec->{$setting};
  71     $self->_validate_codulatable($setting, $spec->{$setting}, "$into->$name");
  72   }
  73
  74   if (exists $spec->{default}) {
  75     if (!defined $spec->{default} || ref $spec->{default}) {
  76       $self->_validate_codulatable('default', $spec->{default}, "$into->$name", 'or a non-ref');
  77     }
  78   }
  79
  80   if (exists $spec->{moosify}) {
  81     if (ref $spec->{moosify} ne 'ARRAY') {
  82       $spec->{moosify} = [$spec->{moosify}];
  83     }
  84
  85     for my $spec (@{$spec->{moosify}}) {
  86       $self->_validate_codulatable('moosify', $spec, "$into->$name");
  87     }
  88   }
  89
  90   my %methods;
  91   if (my $reader = $spec->{reader}) {
  92     _die_overwrite($into, $reader, 'a reader')
  93       if !$spec->{allow_overwrite} && *{_getglob("${into}::${reader}")}{CODE};
  94     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  95       $methods{$reader} = $self->_generate_xs(
  96         getters => $into, $reader, $name, $spec
  97       );
  98     } else {
  99       $self->{captures} = {};
 100       $methods{$reader} =
 101         quote_sub "${into}::${reader}"
 102           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
 103              .$self->_generate_get($name, $spec)
 104           => delete $self->{captures}
 105         ;
 106     }
 107   }
 108   if (my $accessor = $spec->{accessor}) {
 109     _die_overwrite($into, $accessor, 'an accessor')
 110       if !$spec->{allow_overwrite} && *{_getglob("${into}::${accessor}")}{CODE};
 111     if (
 112       our $CAN_HAZ_XS
 113       && $self->is_simple_get($name, $spec)
 114       && $self->is_simple_set($name, $spec)
 115     ) {
 116       $methods{$accessor} = $self->_generate_xs(
 117         accessors => $into, $accessor, $name, $spec
 118       );
 119     } else {
 120       $self->{captures} = {};
 121       $methods{$accessor} =
 122         quote_sub "${into}::${accessor}"
 123           => $self->_generate_getset($name, $spec)
 124           => delete $self->{captures}
 125         ;
 126     }
 127   }
 128   if (my $writer = $spec->{writer}) {
 129     _die_overwrite($into, $writer, 'a writer')
 130       if !$spec->{allow_overwrite} && *{_getglob("${into}::${writer}")}{CODE};
 131     if (
 132       our $CAN_HAZ_XS
 133       && $self->is_simple_set($name, $spec)
 134     ) {
 135       $methods{$writer} = $self->_generate_xs(
 136         setters => $into, $writer, $name, $spec
 137       );
 138     } else {
 139       $self->{captures} = {};
 140       $methods{$writer} =
 141         quote_sub "${into}::${writer}"
 142           => $self->_generate_set($name, $spec)
 143           => delete $self->{captures}
 144         ;
 145     }
 146   }
 147   if (my $pred = $spec->{predicate}) {
 148     _die_overwrite($into, $pred, 'a predicate')
 149       if !$spec->{allow_overwrite} && *{_getglob("${into}::${pred}")}{CODE};
 150     $methods{$pred} =
 151       quote_sub "${into}::${pred}" =>
 152         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 153       ;
 154   }
 155   if (my $pred = $spec->{builder_sub}) {
 156     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 157   }
 158   if (my $cl = $spec->{clearer}) {
 159     _die_overwrite($into, $cl, 'a clearer')
 160       if !$spec->{allow_overwrite} && *{_getglob("${into}::${cl}")}{CODE};
 161     $methods{$cl} =
 162       quote_sub "${into}::${cl}" =>
 163         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 164       ;
 165   }
 166   if (my $hspec = $spec->{handles}) {
 167     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 168     my @specs = do {
 169       if (ref($hspec) eq 'ARRAY') {
 170         map [ $_ => $_ ], @$hspec;
 171       } elsif (ref($hspec) eq 'HASH') {
 172         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 173           keys %$hspec;
 174       } elsif (!ref($hspec)) {
 175         map [ $_ => $_ ], use_module('Role::Tiny')->methods_provided_by(use_module($hspec))
 176       } else {
 177         die "You gave me a handles of ${hspec} and I have no idea why";
 178       }
 179     };
 180     foreach my $delegation_spec (@specs) {
 181       my ($proxy, $target, @args) = @$delegation_spec;
 182       _die_overwrite($into, $proxy, 'a delegation')
 183         if !$spec->{allow_overwrite} && *{_getglob("${into}::${proxy}")}{CODE};
 184       $self->{captures} = {};
 185       $methods{$proxy} =
 186         quote_sub "${into}::${proxy}" =>
 187           $self->_generate_delegation($asserter, $target, \@args),
 188           delete $self->{captures}
 189         ;
 190     }
 191   }
 192   if (my $asserter = $spec->{asserter}) {
 193     $self->{captures} = {};
 194
 195
 196     $methods{$asserter} =
 197       quote_sub "${into}::${asserter}" => $self->_generate_asserter($name, $spec),
 198         delete $self->{captures}
 199       ;
 200   }
 201   \%methods;
 202 }
 203
 204 sub is_simple_attribute {
 205   my ($self, $name, $spec) = @_;
 206   # clearer doesn't have to be listed because it doesn't
 207   # affect whether defined/exists makes a difference
 208   !grep $spec->{$_},
 209     qw(lazy default builder coerce isa trigger predicate weak_ref);
 210 }
 211
 212 sub is_simple_get {
 213   my ($self, $name, $spec) = @_;
 214   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 215 }
 216
 217 sub is_simple_set {
 218   my ($self, $name, $spec) = @_;
 219   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 220 }
 221
 222 sub has_eager_default {
 223   my ($self, $name, $spec) = @_;
 224   (!$spec->{lazy} and (exists $spec->{default} or $spec->{builder}));
 225 }
 226
 227 sub _generate_get {
 228   my ($self, $name, $spec) = @_;
 229   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 230   if ($self->is_simple_get($name, $spec)) {
 231     $simple;
 232   } else {
 233     $self->_generate_use_default(
 234       '$_[0]', $name, $spec,
 235       $self->_generate_simple_has('$_[0]', $name, $spec),
 236     );
 237   }
 238 }
 239
 240 sub _generate_simple_has {
 241   my ($self, $me, $name) = @_;
 242   "exists ${me}->{${\perlstring $name}}";
 243 }
 244
 245 sub _generate_simple_clear {
 246   my ($self, $me, $name) = @_;
 247   "    delete ${me}->{${\perlstring $name}}\n"
 248 }
 249
 250 sub generate_get_default {
 251   my $self = shift;
 252   $self->{captures} = {};
 253   my $code = $self->_generate_get_default(@_);
 254   ($code, delete $self->{captures});
 255 }
 256
 257 sub _generate_use_default {
 258   my ($self, $me, $name, $spec, $test) = @_;
 259   my $get_value = $self->_generate_get_default($me, $name, $spec);
 260   if ($spec->{coerce}) {
 261     $get_value = $self->_generate_coerce(
 262       $name, $get_value,
 263       $spec->{coerce}
 264     )
 265   }
 266   $test." ? \n"
 267   .$self->_generate_simple_get($me, $name, $spec)."\n:"
 268   .($spec->{isa}
 269     ? "    do {\n      my \$value = ".$get_value.";\n"
 270       ."      ".$self->_generate_isa_check($name, '$value', $spec->{isa}).";\n"
 271       ."      ".$self->_generate_simple_set($me, $name, $spec, '$value')."\n"
 272       ."    }\n"
 273     : '    ('.$self->_generate_simple_set($me, $name, $spec, $get_value).")\n");
 274 }
 275
 276 sub _generate_get_default {
 277   my ($self, $me, $name, $spec) = @_;
 278   if (exists $spec->{default}) {
 279     ref $spec->{default}
 280       ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 281       : perlstring $spec->{default};
 282   }
 283   else {
 284     "${me}->${\$spec->{builder}}"
 285   }
 286 }
 287
 288 sub generate_simple_get {
 289   my ($self, @args) = @_;
 290   $self->_generate_simple_get(@args);
 291 }
 292
 293 sub _generate_simple_get {
 294   my ($self, $me, $name) = @_;
 295   my $name_str = perlstring $name;
 296   "${me}->{${name_str}}";
 297 }
 298
 299 sub _generate_set {
 300   my ($self, $name, $spec) = @_;
 301   if ($self->is_simple_set($name, $spec)) {
 302     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 303   } else {
 304     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 305     my $value_store = '$_[0]';
 306     my $code;
 307     if ($coerce) {
 308       $value_store = '$value';
 309       $code = "do { my (\$self, \$value) = \@_;\n"
 310         ."        \$value = "
 311         .$self->_generate_coerce($name, $value_store, $coerce).";\n";
 312     }
 313     else {
 314       $code = "do { my \$self = shift;\n";
 315     }
 316     if ($isa_check) {
 317       $code .=
 318         "        ".$self->_generate_isa_check($name, $value_store, $isa_check).";\n";
 319     }
 320     my $simple = $self->_generate_simple_set('$self', $name, $spec, $value_store);
 321     if ($trigger) {
 322       my $fire = $self->_generate_trigger($name, '$self', $value_store, $trigger);
 323       $code .=
 324         "        ".$simple.";\n        ".$fire.";\n"
 325         ."        $value_store;\n";
 326     } else {
 327       $code .= "        ".$simple.";\n";
 328     }
 329     $code .= "      }";
 330     $code;
 331   }
 332 }
 333
 334 sub generate_coerce {
 335   my $self = shift;
 336   $self->{captures} = {};
 337   my $code = $self->_generate_coerce(@_);
 338   ($code, delete $self->{captures});
 339 }
 340
 341 sub _attr_desc {
 342   my ($name, $init_arg) = @_;
 343   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 344   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 345 }
 346
 347 sub _generate_coerce {
 348   my ($self, $name, $value, $coerce, $init_arg) = @_;
 349   $self->_generate_die_prefix(
 350     "coercion for ${\_attr_desc($name, $init_arg)} failed: ",
 351     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 352   );
 353 }
 354
 355 sub generate_trigger {
 356   my $self = shift;
 357   $self->{captures} = {};
 358   my $code = $self->_generate_trigger(@_);
 359   ($code, delete $self->{captures});
 360 }
 361
 362 sub _generate_trigger {
 363   my ($self, $name, $obj, $value, $trigger) = @_;
 364   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 365 }
 366
 367 sub generate_isa_check {
 368   my ($self, @args) = @_;
 369   $self->{captures} = {};
 370   my $code = $self->_generate_isa_check(@args);
 371   ($code, delete $self->{captures});
 372 }
 373
 374 sub _generate_die_prefix {
 375   my ($self, $prefix, $inside) = @_;
 376   "do {\n"
 377   .'  my $sig_die = $SIG{__DIE__} || sub { die $_[0] };'."\n"
 378   .'  local $SIG{__DIE__} = sub {'."\n"
 379   .'    $sig_die->(ref($_[0]) ? $_[0] : '.perlstring($prefix).'.$_[0]);'."\n"
 380   .'  };'."\n"
 381   .$inside
 382   ."}\n"
 383 }
 384
 385 sub _generate_isa_check {
 386   my ($self, $name, $value, $check, $init_arg) = @_;
 387   $self->_generate_die_prefix(
 388     "isa check for ${\_attr_desc($name, $init_arg)} failed: ",
 389     $self->_generate_call_code($name, 'isa_check', $value, $check)
 390   );
 391 }
 392
 393 sub _generate_call_code {
 394   my ($self, $name, $type, $values, $sub) = @_;
 395   $sub = \&{$sub} if blessed($sub);  # coderef if blessed
 396   if (my $quoted = quoted_from_sub($sub)) {
 397     my $local = 1;
 398     if ($values eq '@_' || $values eq '$_[0]') {
 399       $local = 0;
 400       $values = '@_';
 401     }
 402     my $code = $quoted->[1];
 403     if (my $captures = $quoted->[2]) {
 404       my $cap_name = qq{\$${type}_captures_for_${name}};
 405       $self->{captures}->{$cap_name} = \$captures;
 406       Sub::Quote::inlinify(
 407         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), $local
 408       );
 409     } else {
 410       Sub::Quote::inlinify($code, $values, undef, $local);
 411     }
 412   } else {
 413     my $cap_name = qq{\$${type}_for_${name}};
 414     $self->{captures}->{$cap_name} = \$sub;
 415     "${cap_name}->(${values})";
 416   }
 417 }
 418
 419 sub generate_populate_set {
 420   my $self = shift;
 421   $self->{captures} = {};
 422   my $code = $self->_generate_populate_set(@_);
 423   ($code, delete $self->{captures});
 424 }
 425
 426 sub _generate_populate_set {
 427   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 428   if ($self->has_eager_default($name, $spec)) {
 429     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 430     my $get_default = $self->_generate_get_default(
 431                         '$new', $_, $spec
 432                       );
 433     my $get_value =
 434       defined($spec->{init_arg})
 435         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 436             .$get_default
 437             ."\n${get_indent})"
 438         : $get_default;
 439     if ($spec->{coerce}) {
 440       $get_value = $self->_generate_coerce(
 441         $name, $get_value,
 442         $spec->{coerce}, $init_arg
 443       )
 444     }
 445     ($spec->{isa}
 446       ? "    {\n      my \$value = ".$get_value.";\n      "
 447         .$self->_generate_isa_check(
 448           $name, '$value', $spec->{isa}, $init_arg
 449         ).";\n"
 450         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 451         ."    }\n"
 452       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 453     )
 454     .($spec->{trigger}
 455       ? '    '
 456         .$self->_generate_trigger(
 457           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 458           $spec->{trigger}
 459         )." if ${test};\n"
 460       : ''
 461     );
 462   } else {
 463     "    if (${test}) {\n"
 464       .($spec->{coerce}
 465         ? "      $source = "
 466           .$self->_generate_coerce(
 467             $name, $source,
 468             $spec->{coerce}, $init_arg
 469           ).";\n"
 470         : ""
 471       )
 472       .($spec->{isa}
 473         ? "      "
 474           .$self->_generate_isa_check(
 475             $name, $source, $spec->{isa}, $init_arg
 476           ).";\n"
 477         : ""
 478       )
 479       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 480       .($spec->{trigger}
 481         ? "      "
 482           .$self->_generate_trigger(
 483             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 484             $spec->{trigger}
 485           ).";\n"
 486         : ""
 487       )
 488       ."    }\n";
 489   }
 490 }
 491
 492 sub _generate_core_set {
 493   my ($self, $me, $name, $spec, $value) = @_;
 494   my $name_str = perlstring $name;
 495   "${me}->{${name_str}} = ${value}";
 496 }
 497
 498 sub _generate_simple_set {
 499   my ($self, $me, $name, $spec, $value) = @_;
 500   my $name_str = perlstring $name;
 501   my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 502
 503   if ($spec->{weak_ref}) {
 504     require Scalar::Util;
 505     my $get = $self->_generate_simple_get($me, $name, $spec);
 506
 507     # Perl < 5.8.3 can't weaken refs to readonly vars
 508     # (e.g. string constants). This *can* be solved by:
 509     #
 510     #Internals::SetReadWrite($foo);
 511     #Scalar::Util::weaken ($foo);
 512     #Internals::SetReadOnly($foo);
 513     #
 514     # but requires XS and is just too damn crazy
 515     # so simply throw a better exception
 516     my $weak_simple = "do { Scalar::Util::weaken(${simple}); no warnings 'void'; $get }";
 517     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 518       eval { Scalar::Util::weaken($simple); 1 }
 519         ? do { no warnings 'void'; $get }
 520         : do {
 521           if( \$@ =~ /Modification of a read-only value attempted/) {
 522             require Carp;
 523             Carp::croak( sprintf (
 524               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 525               $name_str,
 526             ) );
 527           } else {
 528             die \$@;
 529           }
 530         }
 531 EOC
 532   } else {
 533     $simple;
 534   }
 535 }
 536
 537 sub _generate_getset {
 538   my ($self, $name, $spec) = @_;
 539   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 540     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 541 }
 542
 543 sub _generate_asserter {
 544   my ($self, $name, $spec) = @_;
 545
 546   "do {\n"
 547    ."  my \$val = ".$self->_generate_get($name, $spec).";\n"
 548    ."  unless (".$self->_generate_simple_has('$_[0]', $name, $spec).") {\n"
 549    .qq!    die "Attempted to access '${name}' but it is not set";\n!
 550    ."  }\n"
 551    ."  \$val;\n"
 552    ."}\n";
 553 }
 554 sub _generate_delegation {
 555   my ($self, $asserter, $target, $args) = @_;
 556   my $arg_string = do {
 557     if (@$args) {
 558       # I could, I reckon, linearise out non-refs here using perlstring
 559       # plus something to check for numbers but I'm unsure if it's worth it
 560       $self->{captures}{'@curries'} = $args;
 561       '@curries, @_';
 562     } else {
 563       '@_';
 564     }
 565   };
 566   "shift->${asserter}->${target}(${arg_string});";
 567 }
 568
 569 sub _generate_xs {
 570   my ($self, $type, $into, $name, $slot) = @_;
 571   Class::XSAccessor->import(
 572     class => $into,
 573     $type => { $name => $slot },
 574     replace => 1,
 575   );
 576   $into->can($name);
 577 }
 578
 579 sub default_construction_string { '{}' }
 580
 581 sub _validate_codulatable {
 582   my ($self, $setting, $value, $into, $appended) = @_;
 583   my $invalid = "Invalid $setting '" . overload::StrVal($value)
 584     . "' for $into not a coderef";
 585   $invalid .= " $appended" if $appended;
 586
 587   unless (ref $value and (ref $value eq 'CODE' or blessed($value))) {
 588     die "$invalid or code-convertible object";
 589   }
 590
 591   unless (eval { \&$value }) {
 592     die "$invalid and could not be converted to a coderef: $@";
 593   }
 594
 595   1;
 596 }
 597
 598 1;