lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     !$ENV{MOO_XS_DISABLE}
  11       &&
  12     _maybe_load_module('Class::XSAccessor')
  13       &&
  14     (eval { Class::XSAccessor->VERSION('1.07') })
  15   ;
  16 }
  17
  18 sub generate_method {
  19   my ($self, $into, $name, $spec, $quote_opts) = @_;
  20   $name =~ s/^\+//;
  21   die "Must have an is" unless my $is = $spec->{is};
  22   if ($is eq 'ro') {
  23     $spec->{reader} = $name unless exists $spec->{reader};
  24   } elsif ($is eq 'rw') {
  25     $spec->{accessor} = $name unless exists $spec->{accessor};
  26   } elsif ($is eq 'lazy') {
  27     $spec->{reader} = $name unless exists $spec->{reader};
  28     $spec->{lazy} = 1;
  29     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  30   } elsif ($is eq 'rwp') {
  31     $spec->{reader} = $name unless exists $spec->{reader};
  32     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  33   } elsif ($is ne 'bare') {
  34     die "Unknown is ${is}";
  35   }
  36   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  37   if (($spec->{predicate}||0) eq 1) {
  38     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  39   }
  40   if (($spec->{clearer}||0) eq 1) {
  41     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  42   }
  43   if (($spec->{trigger}||0) eq 1) {
  44     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  45   }
  46   if (exists $spec->{default}) {
  47     my $default = $spec->{default};
  48     unless (ref $default) {
  49       die "Invalid default $default";
  50     }
  51     if (ref $default ne 'CODE') {
  52       unless (eval { \&$default }) {
  53         die "Invalid default $default";
  54       }
  55     }
  56   }
  57
  58   my %methods;
  59   if (my $reader = $spec->{reader}) {
  60     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  61       $methods{$reader} = $self->_generate_xs(
  62         getters => $into, $reader, $name, $spec
  63       );
  64     } else {
  65       $self->{captures} = {};
  66       $methods{$reader} =
  67         quote_sub "${into}::${reader}"
  68           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  69              .$self->_generate_get($name, $spec)
  70           => delete $self->{captures}
  71         ;
  72     }
  73   }
  74   if (my $accessor = $spec->{accessor}) {
  75     if (
  76       our $CAN_HAZ_XS
  77       && $self->is_simple_get($name, $spec)
  78       && $self->is_simple_set($name, $spec)
  79     ) {
  80       $methods{$accessor} = $self->_generate_xs(
  81         accessors => $into, $accessor, $name, $spec
  82       );
  83     } else {
  84       $self->{captures} = {};
  85       $methods{$accessor} =
  86         quote_sub "${into}::${accessor}"
  87           => $self->_generate_getset($name, $spec)
  88           => delete $self->{captures}
  89         ;
  90     }
  91   }
  92   if (my $writer = $spec->{writer}) {
  93     if (
  94       our $CAN_HAZ_XS
  95       && $self->is_simple_set($name, $spec)
  96     ) {
  97       $methods{$writer} = $self->_generate_xs(
  98         setters => $into, $writer, $name, $spec
  99       );
 100     } else {
 101       $self->{captures} = {};
 102       $methods{$writer} =
 103         quote_sub "${into}::${writer}"
 104           => $self->_generate_set($name, $spec)
 105           => delete $self->{captures}
 106         ;
 107     }
 108   }
 109   if (my $pred = $spec->{predicate}) {
 110     $methods{$pred} =
 111       quote_sub "${into}::${pred}" =>
 112         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 113       ;
 114   }
 115   if (my $cl = $spec->{clearer}) {
 116     $methods{$cl} =
 117       quote_sub "${into}::${cl}" =>
 118         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 119       ;
 120   }
 121   if (my $hspec = $spec->{handles}) {
 122     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 123     my @specs = do {
 124       if (ref($hspec) eq 'ARRAY') {
 125         map [ $_ => $_ ], @$hspec;
 126       } elsif (ref($hspec) eq 'HASH') {
 127         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 128           keys %$hspec;
 129       } elsif (!ref($hspec)) {
 130         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 131       } else {
 132         die "You gave me a handles of ${hspec} and I have no idea why";
 133       }
 134     };
 135     foreach my $spec (@specs) {
 136       my ($proxy, $target, @args) = @$spec;
 137       $self->{captures} = {};
 138       $methods{$proxy} =
 139         quote_sub "${into}::${proxy}" =>
 140           $self->_generate_delegation($asserter, $target, \@args),
 141           delete $self->{captures}
 142         ;
 143     }
 144   }
 145   if (my $asserter = $spec->{asserter}) {
 146     $self->{captures} = {};
 147     $methods{$asserter} =
 148       quote_sub "${into}::${asserter}" =>
 149         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 150         delete $self->{captures}
 151       ;
 152   }
 153   \%methods;
 154 }
 155
 156 sub is_simple_attribute {
 157   my ($self, $name, $spec) = @_;
 158   # clearer doesn't have to be listed because it doesn't
 159   # affect whether defined/exists makes a difference
 160   !grep $spec->{$_},
 161     qw(lazy default builder coerce isa trigger predicate weak_ref);
 162 }
 163
 164 sub is_simple_get {
 165   my ($self, $name, $spec) = @_;
 166   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 167 }
 168
 169 sub is_simple_set {
 170   my ($self, $name, $spec) = @_;
 171   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 172 }
 173
 174 sub has_eager_default {
 175   my ($self, $name, $spec) = @_;
 176   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 177 }
 178
 179 sub _generate_get {
 180   my ($self, $name, $spec) = @_;
 181   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 182   if ($self->is_simple_get($name, $spec)) {
 183     $simple;
 184   } else {
 185     'do { '.$self->_generate_use_default(
 186       '$_[0]', $name, $spec,
 187       $self->_generate_simple_has('$_[0]', $name, $spec),
 188     ).'; '.$simple.' }';
 189   }
 190 }
 191
 192 sub _generate_simple_has {
 193   my ($self, $me, $name) = @_;
 194   "exists ${me}->{${\perlstring $name}}";
 195 }
 196
 197 sub _generate_simple_clear {
 198   my ($self, $me, $name) = @_;
 199   "    delete ${me}->{${\perlstring $name}}\n"
 200 }
 201
 202 sub generate_get_default {
 203   my $self = shift;
 204   $self->{captures} = {};
 205   my $code = $self->_generate_get_default(@_);
 206   ($code, delete $self->{captures});
 207 }
 208
 209 sub _generate_use_default {
 210   my ($self, $me, $name, $spec, $test) = @_;
 211   my $get_value = $self->_generate_get_default($me, $name, $spec);
 212   if ($spec->{coerce}) {
 213     $get_value = $self->_generate_coerce(
 214       $name, $get_value,
 215       $spec->{coerce}
 216     )
 217   }
 218   $self->_generate_simple_set(
 219     $me, $name, $spec, $get_value
 220   ).' unless '.$test;
 221 }
 222
 223 sub _generate_get_default {
 224   my ($self, $me, $name, $spec) = @_;
 225   $spec->{default}
 226     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 227     : "${me}->${\$spec->{builder}}"
 228 }
 229
 230 sub generate_simple_get {
 231   my ($self, @args) = @_;
 232   $self->_generate_simple_get(@args);
 233 }
 234
 235 sub _generate_simple_get {
 236   my ($self, $me, $name) = @_;
 237   my $name_str = perlstring $name;
 238   "${me}->{${name_str}}";
 239 }
 240
 241 sub _generate_set {
 242   my ($self, $name, $spec) = @_;
 243   if ($self->is_simple_set($name, $spec)) {
 244     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 245   } else {
 246     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 247     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 248     my $code = "do { my (\$self, \$value) = \@_;\n";
 249     if ($coerce) {
 250       $code .=
 251         "        \$value = "
 252         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 253     }
 254     if ($isa_check) {
 255       $code .=
 256         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 257     }
 258     if ($trigger) {
 259       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 260       $code .=
 261         "        ".$simple.";\n        ".$fire.";\n"
 262         ."        \$value;\n";
 263     } else {
 264       $code .= "        ".$simple.";\n";
 265     }
 266     $code .= "      }";
 267     $code;
 268   }
 269 }
 270
 271 sub generate_coerce {
 272   my $self = shift;
 273   $self->{captures} = {};
 274   my $code = $self->_generate_coerce(@_);
 275   ($code, delete $self->{captures});
 276 }
 277
 278 sub _generate_coerce {
 279   my ($self, $name, $value, $coerce) = @_;
 280   $self->_generate_call_code($name, 'coerce', "${value}", $coerce);
 281 }
 282
 283 sub generate_trigger {
 284   my $self = shift;
 285   $self->{captures} = {};
 286   my $code = $self->_generate_trigger(@_);
 287   ($code, delete $self->{captures});
 288 }
 289
 290 sub _generate_trigger {
 291   my ($self, $name, $obj, $value, $trigger) = @_;
 292   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 293 }
 294
 295 sub generate_isa_check {
 296   my ($self, @args) = @_;
 297   $self->{captures} = {};
 298   my $code = $self->_generate_isa_check(@args);
 299   ($code, delete $self->{captures});
 300 }
 301
 302 sub _generate_isa_check {
 303   my ($self, $name, $value, $check) = @_;
 304   $self->_generate_call_code($name, 'isa_check', $value, $check);
 305 }
 306
 307 sub _generate_call_code {
 308   my ($self, $name, $type, $values, $sub) = @_;
 309   if (my $quoted = quoted_from_sub($sub)) {
 310     my $code = $quoted->[1];
 311     my $at_ = '@_ = ('.$values.');';
 312     if (my $captures = $quoted->[2]) {
 313       my $cap_name = qq{\$${type}_captures_for_${name}};
 314       $self->{captures}->{$cap_name} = \$captures;
 315       Sub::Quote::inlinify(
 316         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 317       );
 318     } else {
 319       Sub::Quote::inlinify($code, $values);
 320     }
 321   } else {
 322     my $cap_name = qq{\$${type}_for_${name}};
 323     $self->{captures}->{$cap_name} = \$sub;
 324     "${cap_name}->(${values})";
 325   }
 326 }
 327
 328 sub generate_populate_set {
 329   my $self = shift;
 330   $self->{captures} = {};
 331   my $code = $self->_generate_populate_set(@_);
 332   ($code, delete $self->{captures});
 333 }
 334
 335 sub _generate_populate_set {
 336   my ($self, $me, $name, $spec, $source, $test) = @_;
 337   if ($self->has_eager_default($name, $spec)) {
 338     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 339     my $get_default = $self->_generate_get_default(
 340                         '$new', $_, $spec
 341                       );
 342     my $get_value =
 343       defined($spec->{init_arg})
 344         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 345             .$get_default
 346             ."\n${get_indent})"
 347         : $get_default;
 348     if ($spec->{coerce}) {
 349       $get_value = $self->_generate_coerce(
 350         $name, $get_value,
 351         $spec->{coerce}
 352       )
 353     }
 354     ($spec->{isa}
 355       ? "    {\n      my \$value = ".$get_value.";\n      "
 356         .$self->_generate_isa_check(
 357           $name, '$value', $spec->{isa}
 358         ).";\n"
 359         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 360         ."    }\n"
 361       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 362     )
 363     .($spec->{trigger}
 364       ? '    '
 365         .$self->_generate_trigger(
 366           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 367           $spec->{trigger}
 368         )." if ${test};\n"
 369       : ''
 370     );
 371   } else {
 372     "    if (${test}) {\n"
 373       .($spec->{coerce}
 374         ? "      $source = "
 375           .$self->_generate_coerce(
 376             $name, $source,
 377             $spec->{coerce}
 378           ).";\n"
 379         : ""
 380       )
 381       .($spec->{isa}
 382         ? "      "
 383           .$self->_generate_isa_check(
 384             $name, $source, $spec->{isa}
 385           ).";\n"
 386         : ""
 387       )
 388       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 389       .($spec->{trigger}
 390         ? "      "
 391           .$self->_generate_trigger(
 392             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 393             $spec->{trigger}
 394           ).";\n"
 395         : ""
 396       )
 397       ."    }\n";
 398   }
 399 }
 400
 401 sub _generate_core_set {
 402   my ($self, $me, $name, $spec, $value) = @_;
 403   my $name_str = perlstring $name;
 404   "${me}->{${name_str}} = ${value}";
 405 }
 406
 407 sub _generate_simple_set {
 408   my ($self, $me, $name, $spec, $value) = @_;
 409   my $name_str = perlstring $name;
 410
 411   if ($spec->{weak_ref}) {
 412     $value = '$preserve = '.$value;
 413     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 414     require Scalar::Util;
 415
 416     # Perl < 5.8.3 can't weaken refs to readonly vars
 417     # (e.g. string constants). This *can* be solved by:
 418     #
 419     #Internals::SetReadWrite($foo);
 420     #Scalar::Util::weaken ($foo);
 421     #Internals::SetReadOnly($foo);
 422     #
 423     # but requires XS and is just too damn crazy
 424     # so simply throw a better exception
 425     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple})";
 426     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 427
 428       my \$preserve;
 429       eval { Scalar::Util::weaken($simple); 1 } or do {
 430         if( \$@ =~ /Modification of a read-only value attempted/) {
 431           require Carp;
 432           Carp::croak( sprintf (
 433             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 434             $name_str,
 435           ) );
 436         } else {
 437           die \$@;
 438         }
 439       };
 440 EOC
 441   } else {
 442     $self->_generate_core_set($me, $name, $spec, $value);
 443   }
 444 }
 445
 446 sub _generate_getset {
 447   my ($self, $name, $spec) = @_;
 448   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 449     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 450 }
 451
 452 sub _generate_delegation {
 453   my ($self, $asserter, $target, $args) = @_;
 454   my $arg_string = do {
 455     if (@$args) {
 456       # I could, I reckon, linearise out non-refs here using perlstring
 457       # plus something to check for numbers but I'm unsure if it's worth it
 458       $self->{captures}{'@curries'} = $args;
 459       '@curries, @_';
 460     } else {
 461       '@_';
 462     }
 463   };
 464   "shift->${asserter}->${target}(${arg_string});";
 465 }
 466
 467 sub _generate_xs {
 468   my ($self, $type, $into, $name, $slot) = @_;
 469   Class::XSAccessor->import(
 470     class => $into,
 471     $type => { $name => $slot },
 472     replace => 1,
 473   );
 474   $into->can($name);
 475 }
 476
 477 sub default_construction_string { '{}' }
 478
 479 1;