lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     !$ENV{MOO_XS_DISABLE}
  11       &&
  12     _maybe_load_module('Class::XSAccessor')
  13       &&
  14     (eval { Class::XSAccessor->VERSION('1.07') })
  15   ;
  16 }
  17
  18 sub generate_method {
  19   my ($self, $into, $name, $spec, $quote_opts) = @_;
  20   die "Must have an is" unless my $is = $spec->{is};
  21   if ($is eq 'ro') {
  22     $spec->{reader} = $name unless exists $spec->{reader};
  23   } elsif ($is eq 'rw') {
  24     $spec->{accessor} = $name unless exists $spec->{accessor};
  25   } elsif ($is eq 'lazy') {
  26     $spec->{reader} = $name unless exists $spec->{reader};
  27     $spec->{lazy} = 1;
  28     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  29   } elsif ($is eq 'rwp') {
  30     $spec->{reader} = $name unless exists $spec->{reader};
  31     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  32   } elsif ($is ne 'bare') {
  33     die "Unknown is ${is}";
  34   }
  35   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  36   if (($spec->{predicate}||0) eq 1) {
  37     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  38   }
  39   if (($spec->{clearer}||0) eq 1) {
  40     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  41   }
  42   if (($spec->{trigger}||0) eq 1) {
  43     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  44   }
  45   my %methods;
  46   if (my $reader = $spec->{reader}) {
  47     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  48       $methods{$reader} = $self->_generate_xs(
  49         getters => $into, $reader, $name
  50       );
  51     } else {
  52       $self->{captures} = {};
  53       $methods{$reader} =
  54         quote_sub "${into}::${reader}"
  55           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  56              .$self->_generate_get($name, $spec)
  57           => delete $self->{captures}
  58         ;
  59     }
  60   }
  61   if (my $accessor = $spec->{accessor}) {
  62     if (
  63       our $CAN_HAZ_XS
  64       && $self->is_simple_get($name, $spec)
  65       && $self->is_simple_set($name, $spec)
  66     ) {
  67       $methods{$accessor} = $self->_generate_xs(
  68         accessors => $into, $accessor, $name
  69       );
  70     } else {
  71       $self->{captures} = {};
  72       $methods{$accessor} =
  73         quote_sub "${into}::${accessor}"
  74           => $self->_generate_getset($name, $spec)
  75           => delete $self->{captures}
  76         ;
  77     }
  78   }
  79   if (my $writer = $spec->{writer}) {
  80     if (
  81       our $CAN_HAZ_XS
  82       && $self->is_simple_set($name, $spec)
  83     ) {
  84       $methods{$writer} = $self->_generate_xs(
  85         setters => $into, $writer, $name
  86       );
  87     } else {
  88       $self->{captures} = {};
  89       $methods{$writer} =
  90         quote_sub "${into}::${writer}"
  91           => $self->_generate_set($name, $spec)
  92           => delete $self->{captures}
  93         ;
  94     }
  95   }
  96   if (my $pred = $spec->{predicate}) {
  97     $methods{$pred} =
  98       quote_sub "${into}::${pred}" =>
  99         '    '.$self->_generate_simple_has('$_[0]', $name)."\n"
 100       ;
 101   }
 102   if (my $cl = $spec->{clearer}) {
 103     $methods{$cl} =
 104       quote_sub "${into}::${cl}" =>
 105         "    delete \$_[0]->{${\perlstring $name}}\n"
 106       ;
 107   }
 108   if (my $hspec = $spec->{handles}) {
 109     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 110     my @specs = do {
 111       if (ref($hspec) eq 'ARRAY') {
 112         map [ $_ => $_ ], @$hspec;
 113       } elsif (ref($hspec) eq 'HASH') {
 114         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 115           keys %$hspec;
 116       } elsif (!ref($hspec)) {
 117         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 118       } else {
 119         die "You gave me a handles of ${hspec} and I have no idea why";
 120       }
 121     };
 122     foreach my $spec (@specs) {
 123       my ($proxy, $target, @args) = @$spec;
 124       $self->{captures} = {};
 125       $methods{$proxy} =
 126         quote_sub "${into}::${proxy}" =>
 127           $self->_generate_delegation($asserter, $target, \@args),
 128           delete $self->{captures}
 129         ;
 130     }
 131   }
 132   if (my $asserter = $spec->{asserter}) {
 133     $self->{captures} = {};
 134     $methods{$asserter} =
 135       quote_sub "${into}::${asserter}" =>
 136         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 137         delete $self->{captures}
 138       ;
 139   }
 140   \%methods;
 141 }
 142
 143 sub is_simple_attribute {
 144   my ($self, $name, $spec) = @_;
 145   # clearer doesn't have to be listed because it doesn't
 146   # affect whether defined/exists makes a difference
 147   !grep $spec->{$_},
 148     qw(lazy default builder coerce isa trigger predicate weak_ref);
 149 }
 150
 151 sub is_simple_get {
 152   my ($self, $name, $spec) = @_;
 153   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 154 }
 155
 156 sub is_simple_set {
 157   my ($self, $name, $spec) = @_;
 158   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 159 }
 160
 161 sub has_eager_default {
 162   my ($self, $name, $spec) = @_;
 163   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 164 }
 165
 166 sub _generate_get {
 167   my ($self, $name, $spec) = @_;
 168   my $simple = $self->_generate_simple_get('$_[0]', $name);
 169   if ($self->is_simple_get($name, $spec)) {
 170     $simple;
 171   } else {
 172     'do { '.$self->_generate_use_default(
 173       '$_[0]', $name, $spec,
 174       $self->_generate_simple_has('$_[0]', $name),
 175     ).'; '.$simple.' }';
 176   }
 177 }
 178
 179 sub _generate_simple_has {
 180   my ($self, $me, $name) = @_;
 181   "exists ${me}->{${\perlstring $name}}";
 182 }
 183
 184 sub generate_get_default {
 185   my $self = shift;
 186   $self->{captures} = {};
 187   my $code = $self->_generate_get_default(@_);
 188   ($code, delete $self->{captures});
 189 }
 190
 191 sub _generate_use_default {
 192   my ($self, $me, $name, $spec, $test) = @_;
 193   my $get_value = $self->_generate_get_default($me, $name, $spec);
 194   if ($spec->{coerce}) {
 195     $get_value = $self->_generate_coerce(
 196       $name, $get_value,
 197       $spec->{coerce}
 198     )
 199   }
 200   $self->_generate_simple_set(
 201     $me, $name, $spec, $get_value
 202   ).' unless '.$test;
 203 }
 204
 205 sub _generate_get_default {
 206   my ($self, $me, $name, $spec) = @_;
 207   $spec->{default}
 208     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 209     : "${me}->${\$spec->{builder}}"
 210 }
 211
 212 sub generate_simple_get {
 213   my ($self, @args) = @_;
 214   $self->_generate_simple_get(@args);
 215 }
 216
 217 sub _generate_simple_get {
 218   my ($self, $me, $name) = @_;
 219   my $name_str = perlstring $name;
 220   "${me}->{${name_str}}";
 221 }
 222
 223 sub _generate_set {
 224   my ($self, $name, $spec) = @_;
 225   if ($self->is_simple_set($name, $spec)) {
 226     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 227   } else {
 228     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 229     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 230     my $code = "do { my (\$self, \$value) = \@_;\n";
 231     if ($coerce) {
 232       $code .=
 233         "        \$value = "
 234         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 235     }
 236     if ($isa_check) {
 237       $code .=
 238         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 239     }
 240     if ($trigger) {
 241       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 242       $code .=
 243         "        ".$simple.";\n        ".$fire.";\n"
 244         ."        \$value;\n";
 245     } else {
 246       $code .= "        ".$simple.";\n";
 247     }
 248     $code .= "      }";
 249     $code;
 250   }
 251 }
 252
 253 sub generate_coerce {
 254   my $self = shift;
 255   $self->{captures} = {};
 256   my $code = $self->_generate_coerce(@_);
 257   ($code, delete $self->{captures});
 258 }
 259
 260 sub _generate_coerce {
 261   my ($self, $name, $value, $coerce) = @_;
 262   $self->_generate_call_code($name, 'coerce', "${value}", $coerce);
 263 }
 264
 265 sub generate_trigger {
 266   my $self = shift;
 267   $self->{captures} = {};
 268   my $code = $self->_generate_trigger(@_);
 269   ($code, delete $self->{captures});
 270 }
 271
 272 sub _generate_trigger {
 273   my ($self, $name, $obj, $value, $trigger) = @_;
 274   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 275 }
 276
 277 sub generate_isa_check {
 278   my ($self, @args) = @_;
 279   $self->{captures} = {};
 280   my $code = $self->_generate_isa_check(@args);
 281   ($code, delete $self->{captures});
 282 }
 283
 284 sub _generate_isa_check {
 285   my ($self, $name, $value, $check) = @_;
 286   $self->_generate_call_code($name, 'isa_check', $value, $check);
 287 }
 288
 289 sub _generate_call_code {
 290   my ($self, $name, $type, $values, $sub) = @_;
 291   if (my $quoted = quoted_from_sub($sub)) {
 292     my $code = $quoted->[1];
 293     my $at_ = '@_ = ('.$values.');';
 294     if (my $captures = $quoted->[2]) {
 295       my $cap_name = qq{\$${type}_captures_for_${name}};
 296       $self->{captures}->{$cap_name} = \$captures;
 297       Sub::Quote::inlinify(
 298         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 299       );
 300     } else {
 301       Sub::Quote::inlinify($code, $values);
 302     }
 303   } else {
 304     my $cap_name = qq{\$${type}_for_${name}};
 305     $self->{captures}->{$cap_name} = \$sub;
 306     "${cap_name}->(${values})";
 307   }
 308 }
 309
 310 sub generate_populate_set {
 311   my $self = shift;
 312   $self->{captures} = {};
 313   my $code = $self->_generate_populate_set(@_);
 314   ($code, delete $self->{captures});
 315 }
 316
 317 sub _generate_populate_set {
 318   my ($self, $me, $name, $spec, $source, $test) = @_;
 319   if ($self->has_eager_default($name, $spec)) {
 320     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 321     my $get_default = $self->_generate_get_default(
 322                         '$new', $_, $spec
 323                       );
 324     my $get_value =
 325       defined($spec->{init_arg})
 326         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 327             .$get_default
 328             ."\n${get_indent})"
 329         : $get_default;
 330     if ($spec->{coerce}) {
 331       $get_value = $self->_generate_coerce(
 332         $name, $get_value,
 333         $spec->{coerce}
 334       )
 335     }
 336     ($spec->{isa}
 337       ? "    {\n      my \$value = ".$get_value.";\n      "
 338         .$self->_generate_isa_check(
 339           $name, '$value', $spec->{isa}
 340         ).";\n"
 341         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 342         ."    }\n"
 343       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 344     )
 345     .($spec->{trigger}
 346       ? '    '
 347         .$self->_generate_trigger(
 348           $name, $me, $self->_generate_simple_get($me, $name),
 349           $spec->{trigger}
 350         )." if ${test};\n"
 351       : ''
 352     );
 353   } else {
 354     "    if (${test}) {\n"
 355       .($spec->{coerce}
 356         ? "      $source = "
 357           .$self->_generate_coerce(
 358             $name, $source,
 359             $spec->{coerce}
 360           ).";\n"
 361         : ""
 362       )
 363       .($spec->{isa}
 364         ? "      "
 365           .$self->_generate_isa_check(
 366             $name, $source, $spec->{isa}
 367           ).";\n"
 368         : ""
 369       )
 370       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 371       .($spec->{trigger}
 372         ? "      "
 373           .$self->_generate_trigger(
 374             $name, $me, $self->_generate_simple_get($me, $name),
 375             $spec->{trigger}
 376           ).";\n"
 377         : ""
 378       )
 379       ."    }\n";
 380   }
 381 }
 382
 383 sub generate_multi_set {
 384   my ($self, $me, $to_set, $from) = @_;
 385   "\@{${me}}{qw(${\join ' ', @$to_set})} = $from";
 386 }
 387
 388 sub _generate_simple_set {
 389   my ($self, $me, $name, $spec, $value) = @_;
 390   my $name_str = perlstring $name;
 391   my $simple = "${me}->{${name_str}} = ${value}";
 392
 393   if ($spec->{weak_ref}) {
 394     require Scalar::Util;
 395
 396     # Perl < 5.8.3 can't weaken refs to readonly vars
 397     # (e.g. string constants). This *can* be solved by:
 398     #
 399     #Internals::SetReadWrite($foo);
 400     #Scalar::Util::weaken ($foo);
 401     #Internals::SetReadOnly($foo);
 402     #
 403     # but requires XS and is just too damn crazy
 404     # so simply throw a better exception
 405     Moo::_Utils::lt_5_8_3() ? <<"EOC" : "Scalar::Util::weaken(${simple})";
 406
 407       eval { Scalar::Util::weaken($simple); 1 } or do {
 408         if( \$@ =~ /Modification of a read-only value attempted/) {
 409           require Carp;
 410           Carp::croak( sprintf (
 411             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 412             $name_str,
 413           ) );
 414         } else {
 415           die \$@;
 416         }
 417       };
 418 EOC
 419   } else {
 420     $simple;
 421   }
 422 }
 423
 424 sub _generate_getset {
 425   my ($self, $name, $spec) = @_;
 426   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 427     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 428 }
 429
 430 sub _generate_delegation {
 431   my ($self, $asserter, $target, $args) = @_;
 432   my $arg_string = do {
 433     if (@$args) {
 434       # I could, I reckon, linearise out non-refs here using perlstring
 435       # plus something to check for numbers but I'm unsure if it's worth it
 436       $self->{captures}{'@curries'} = $args;
 437       '@curries, @_';
 438     } else {
 439       '@_';
 440     }
 441   };
 442   "shift->${asserter}->${target}(${arg_string});";
 443 }
 444
 445 sub _generate_xs {
 446   my ($self, $type, $into, $name, $slot) = @_;
 447   Class::XSAccessor->import(
 448     class => $into,
 449     $type => { $name => $slot }
 450   );
 451   $into->can($name);
 452 }
 453
 454 1;