lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 use Module::Runtime qw(use_module);
  11 BEGIN {
  12   our $CAN_HAZ_XS =
  13     !$ENV{MOO_XS_DISABLE}
  14       &&
  15     _maybe_load_module('Class::XSAccessor')
  16       &&
  17     (eval { Class::XSAccessor->VERSION('1.07') })
  18   ;
  19 }
  20
  21 sub _die_overwrite
  22 {
  23   my ($pkg, $method, $type) = @_;
  24   die "You cannot overwrite a locally defined method ($method) with @{[ $type || 'an accessor' ]}";
  25 }
  26
  27 sub generate_method {
  28   my ($self, $into, $name, $spec, $quote_opts) = @_;
  29   $spec->{allow_overwrite}++ if $name =~ s/^\+//;
  30   die "Must have an is" unless my $is = $spec->{is};
  31   if ($is eq 'ro') {
  32     $spec->{reader} = $name unless exists $spec->{reader};
  33   } elsif ($is eq 'rw') {
  34     $spec->{accessor} = $name unless exists $spec->{accessor}
  35       or ( $spec->{reader} and $spec->{writer} );
  36   } elsif ($is eq 'lazy') {
  37     $spec->{reader} = $name unless exists $spec->{reader};
  38     $spec->{lazy} = 1;
  39     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  40   } elsif ($is eq 'rwp') {
  41     $spec->{reader} = $name unless exists $spec->{reader};
  42     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  43   } elsif ($is ne 'bare') {
  44     die "Unknown is ${is}";
  45   }
  46   if (exists $spec->{builder}) {
  47     if(ref $spec->{builder}) {
  48       die "Invalid builder for $into->$name - not a method name, coderef or"
  49         . " code-convertible object"
  50         unless ref $spec->{builder} eq 'CODE'
  51         or (blessed($spec->{builder}) and eval { \&{$spec->{builder}} });
  52       $spec->{builder_sub} = $spec->{builder};
  53       $spec->{builder} = 1;
  54     }
  55     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  56     die "Invalid builder for $into->$name - not a valid method name"
  57       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  58   }
  59   if (($spec->{predicate}||0) eq 1) {
  60     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  61   }
  62   if (($spec->{clearer}||0) eq 1) {
  63     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  64   }
  65   if (($spec->{trigger}||0) eq 1) {
  66     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  67   }
  68
  69   for my $setting (qw( isa coerce )) {
  70     next if !exists $spec->{$setting};
  71     $self->_validate_codulatable($setting, $spec->{$setting}, "$into->$name");
  72   }
  73
  74   if (exists $spec->{default}) {
  75     if (!defined $spec->{default} || ref $spec->{default}) {
  76       $self->_validate_codulatable('default', $spec->{default}, "$into->$name", 'or a non-ref');
  77     }
  78   }
  79
  80   if (exists $spec->{moosify}) {
  81     if (ref $spec->{moosify} ne 'ARRAY') {
  82       $spec->{moosify} = [$spec->{moosify}];
  83     }
  84
  85     for my $spec (@{$spec->{moosify}}) {
  86       $self->_validate_codulatable('moosify', $spec, "$into->$name");
  87     }
  88   }
  89
  90   my %methods;
  91   if (my $reader = $spec->{reader}) {
  92     _die_overwrite($into, $reader, 'a reader')
  93       if !$spec->{allow_overwrite} && *{_getglob("${into}::${reader}")}{CODE};
  94     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  95       $methods{$reader} = $self->_generate_xs(
  96         getters => $into, $reader, $name, $spec
  97       );
  98     } else {
  99       $self->{captures} = {};
 100       $methods{$reader} =
 101         quote_sub "${into}::${reader}"
 102           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
 103              .$self->_generate_get($name, $spec)
 104           => delete $self->{captures}
 105         ;
 106     }
 107   }
 108   if (my $accessor = $spec->{accessor}) {
 109     _die_overwrite($into, $accessor, 'an accessor')
 110       if !$spec->{allow_overwrite} && *{_getglob("${into}::${accessor}")}{CODE};
 111     if (
 112       our $CAN_HAZ_XS
 113       && $self->is_simple_get($name, $spec)
 114       && $self->is_simple_set($name, $spec)
 115     ) {
 116       $methods{$accessor} = $self->_generate_xs(
 117         accessors => $into, $accessor, $name, $spec
 118       );
 119     } else {
 120       $self->{captures} = {};
 121       $methods{$accessor} =
 122         quote_sub "${into}::${accessor}"
 123           => $self->_generate_getset($name, $spec)
 124           => delete $self->{captures}
 125         ;
 126     }
 127   }
 128   if (my $writer = $spec->{writer}) {
 129     _die_overwrite($into, $writer, 'a writer')
 130       if !$spec->{allow_overwrite} && *{_getglob("${into}::${writer}")}{CODE};
 131     if (
 132       our $CAN_HAZ_XS
 133       && $self->is_simple_set($name, $spec)
 134     ) {
 135       $methods{$writer} = $self->_generate_xs(
 136         setters => $into, $writer, $name, $spec
 137       );
 138     } else {
 139       $self->{captures} = {};
 140       $methods{$writer} =
 141         quote_sub "${into}::${writer}"
 142           => $self->_generate_set($name, $spec)
 143           => delete $self->{captures}
 144         ;
 145     }
 146   }
 147   if (my $pred = $spec->{predicate}) {
 148     _die_overwrite($into, $pred, 'a predicate')
 149       if !$spec->{allow_overwrite} && *{_getglob("${into}::${pred}")}{CODE};
 150     $methods{$pred} =
 151       quote_sub "${into}::${pred}" =>
 152         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 153       ;
 154   }
 155   if (my $pred = $spec->{builder_sub}) {
 156     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 157   }
 158   if (my $cl = $spec->{clearer}) {
 159     _die_overwrite($into, $cl, 'a clearer')
 160       if !$spec->{allow_overwrite} && *{_getglob("${into}::${cl}")}{CODE};
 161     $methods{$cl} =
 162       quote_sub "${into}::${cl}" =>
 163         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 164       ;
 165   }
 166   if (my $hspec = $spec->{handles}) {
 167     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 168     my @specs = do {
 169       if (ref($hspec) eq 'ARRAY') {
 170         map [ $_ => $_ ], @$hspec;
 171       } elsif (ref($hspec) eq 'HASH') {
 172         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 173           keys %$hspec;
 174       } elsif (!ref($hspec)) {
 175         map [ $_ => $_ ], use_module('Role::Tiny')->methods_provided_by(use_module($hspec))
 176       } else {
 177         die "You gave me a handles of ${hspec} and I have no idea why";
 178       }
 179     };
 180     foreach my $delegation_spec (@specs) {
 181       my ($proxy, $target, @args) = @$delegation_spec;
 182       _die_overwrite($into, $proxy, 'a delegation')
 183         if !$spec->{allow_overwrite} && *{_getglob("${into}::${proxy}")}{CODE};
 184       $self->{captures} = {};
 185       $methods{$proxy} =
 186         quote_sub "${into}::${proxy}" =>
 187           $self->_generate_delegation($asserter, $target, \@args),
 188           delete $self->{captures}
 189         ;
 190     }
 191   }
 192   if (my $asserter = $spec->{asserter}) {
 193     $self->{captures} = {};
 194
 195
 196     $methods{$asserter} =
 197       quote_sub "${into}::${asserter}" => $self->_generate_asserter($name, $spec),
 198         delete $self->{captures}
 199       ;
 200   }
 201   \%methods;
 202 }
 203
 204 sub is_simple_attribute {
 205   my ($self, $name, $spec) = @_;
 206   # clearer doesn't have to be listed because it doesn't
 207   # affect whether defined/exists makes a difference
 208   !grep $spec->{$_},
 209     qw(lazy default builder coerce isa trigger predicate weak_ref);
 210 }
 211
 212 sub is_simple_get {
 213   my ($self, $name, $spec) = @_;
 214   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 215 }
 216
 217 sub is_simple_set {
 218   my ($self, $name, $spec) = @_;
 219   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 220 }
 221
 222 sub has_eager_default {
 223   my ($self, $name, $spec) = @_;
 224   (!$spec->{lazy} and (exists $spec->{default} or $spec->{builder}));
 225 }
 226
 227 sub _generate_get {
 228   my ($self, $name, $spec) = @_;
 229   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 230   if ($self->is_simple_get($name, $spec)) {
 231     $simple;
 232   } else {
 233     $self->_generate_use_default(
 234       '$_[0]', $name, $spec,
 235       $self->_generate_simple_has('$_[0]', $name, $spec),
 236     );
 237   }
 238 }
 239
 240 sub _generate_simple_has {
 241   my ($self, $me, $name) = @_;
 242   "exists ${me}->{${\perlstring $name}}";
 243 }
 244
 245 sub _generate_simple_clear {
 246   my ($self, $me, $name) = @_;
 247   "    delete ${me}->{${\perlstring $name}}\n"
 248 }
 249
 250 sub generate_get_default {
 251   my $self = shift;
 252   $self->{captures} = {};
 253   my $code = $self->_generate_get_default(@_);
 254   ($code, delete $self->{captures});
 255 }
 256
 257 sub _generate_use_default {
 258   my ($self, $me, $name, $spec, $test) = @_;
 259   my $get_value = $self->_generate_get_default($me, $name, $spec);
 260   if ($spec->{coerce}) {
 261     $get_value = $self->_generate_coerce(
 262       $name, $get_value,
 263       $spec->{coerce}
 264     )
 265   }
 266   $test." ? \n"
 267   .$self->_generate_simple_get($me, $name, $spec)."\n:"
 268   .($spec->{isa}
 269     ? "    do {\n      my \$value = ".$get_value.";\n"
 270       ."      ".$self->_generate_isa_check($name, '$value', $spec->{isa}).";\n"
 271       ."      ".$self->_generate_simple_set($me, $name, $spec, '$value')."\n"
 272       ."    }\n"
 273     : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value)."\n");
 274 }
 275
 276 sub _generate_get_default {
 277   my ($self, $me, $name, $spec) = @_;
 278   if (exists $spec->{default}) {
 279     ref $spec->{default}
 280       ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 281       : perlstring $spec->{default};
 282   }
 283   else {
 284     "${me}->${\$spec->{builder}}"
 285   }
 286 }
 287
 288 sub generate_simple_get {
 289   my ($self, @args) = @_;
 290   $self->_generate_simple_get(@args);
 291 }
 292
 293 sub _generate_simple_get {
 294   my ($self, $me, $name) = @_;
 295   my $name_str = perlstring $name;
 296   "${me}->{${name_str}}";
 297 }
 298
 299 sub _generate_set {
 300   my ($self, $name, $spec) = @_;
 301   if ($self->is_simple_set($name, $spec)) {
 302     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 303   } else {
 304     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 305     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 306     my $code = "do { my (\$self, \$value) = \@_;\n";
 307     if ($coerce) {
 308       $code .=
 309         "        \$value = "
 310         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 311     }
 312     if ($isa_check) {
 313       $code .=
 314         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 315     }
 316     if ($trigger) {
 317       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 318       $code .=
 319         "        ".$simple.";\n        ".$fire.";\n"
 320         ."        \$value;\n";
 321     } else {
 322       $code .= "        ".$simple.";\n";
 323     }
 324     $code .= "      }";
 325     $code;
 326   }
 327 }
 328
 329 sub generate_coerce {
 330   my $self = shift;
 331   $self->{captures} = {};
 332   my $code = $self->_generate_coerce(@_);
 333   ($code, delete $self->{captures});
 334 }
 335
 336 sub _attr_desc {
 337   my ($name, $init_arg) = @_;
 338   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 339   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 340 }
 341
 342 sub _generate_coerce {
 343   my ($self, $name, $value, $coerce, $init_arg) = @_;
 344   $self->_generate_die_prefix(
 345     "coercion for ${\_attr_desc($name, $init_arg)} failed: ",
 346     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 347   );
 348 }
 349
 350 sub generate_trigger {
 351   my $self = shift;
 352   $self->{captures} = {};
 353   my $code = $self->_generate_trigger(@_);
 354   ($code, delete $self->{captures});
 355 }
 356
 357 sub _generate_trigger {
 358   my ($self, $name, $obj, $value, $trigger) = @_;
 359   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 360 }
 361
 362 sub generate_isa_check {
 363   my ($self, @args) = @_;
 364   $self->{captures} = {};
 365   my $code = $self->_generate_isa_check(@args);
 366   ($code, delete $self->{captures});
 367 }
 368
 369 sub _generate_die_prefix {
 370   my ($self, $prefix, $inside) = @_;
 371   "do {\n"
 372   .'  my $sig_die = $SIG{__DIE__} || sub { die $_[0] };'."\n"
 373   .'  local $SIG{__DIE__} = sub {'."\n"
 374   .'    $sig_die->(ref($_[0]) ? $_[0] : '.perlstring($prefix).'.$_[0]);'."\n"
 375   .'  };'."\n"
 376   .$inside
 377   ."}\n"
 378 }
 379
 380 sub _generate_isa_check {
 381   my ($self, $name, $value, $check, $init_arg) = @_;
 382   $self->_generate_die_prefix(
 383     "isa check for ${\_attr_desc($name, $init_arg)} failed: ",
 384     $self->_generate_call_code($name, 'isa_check', $value, $check)
 385   );
 386 }
 387
 388 sub _generate_call_code {
 389   my ($self, $name, $type, $values, $sub) = @_;
 390   $sub = \&{$sub} if blessed($sub);  # coderef if blessed
 391   if (my $quoted = quoted_from_sub($sub)) {
 392     my $code = $quoted->[1];
 393     if (my $captures = $quoted->[2]) {
 394       my $cap_name = qq{\$${type}_captures_for_${name}};
 395       $self->{captures}->{$cap_name} = \$captures;
 396       Sub::Quote::inlinify(
 397         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), 1
 398       );
 399     } else {
 400       Sub::Quote::inlinify($code, $values, undef, 1);
 401     }
 402   } else {
 403     my $cap_name = qq{\$${type}_for_${name}};
 404     $self->{captures}->{$cap_name} = \$sub;
 405     "${cap_name}->(${values})";
 406   }
 407 }
 408
 409 sub generate_populate_set {
 410   my $self = shift;
 411   $self->{captures} = {};
 412   my $code = $self->_generate_populate_set(@_);
 413   ($code, delete $self->{captures});
 414 }
 415
 416 sub _generate_populate_set {
 417   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 418   if ($self->has_eager_default($name, $spec)) {
 419     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 420     my $get_default = $self->_generate_get_default(
 421                         '$new', $_, $spec
 422                       );
 423     my $get_value =
 424       defined($spec->{init_arg})
 425         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 426             .$get_default
 427             ."\n${get_indent})"
 428         : $get_default;
 429     if ($spec->{coerce}) {
 430       $get_value = $self->_generate_coerce(
 431         $name, $get_value,
 432         $spec->{coerce}, $init_arg
 433       )
 434     }
 435     ($spec->{isa}
 436       ? "    {\n      my \$value = ".$get_value.";\n      "
 437         .$self->_generate_isa_check(
 438           $name, '$value', $spec->{isa}, $init_arg
 439         ).";\n"
 440         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 441         ."    }\n"
 442       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 443     )
 444     .($spec->{trigger}
 445       ? '    '
 446         .$self->_generate_trigger(
 447           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 448           $spec->{trigger}
 449         )." if ${test};\n"
 450       : ''
 451     );
 452   } else {
 453     "    if (${test}) {\n"
 454       .($spec->{coerce}
 455         ? "      $source = "
 456           .$self->_generate_coerce(
 457             $name, $source,
 458             $spec->{coerce}, $init_arg
 459           ).";\n"
 460         : ""
 461       )
 462       .($spec->{isa}
 463         ? "      "
 464           .$self->_generate_isa_check(
 465             $name, $source, $spec->{isa}, $init_arg
 466           ).";\n"
 467         : ""
 468       )
 469       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 470       .($spec->{trigger}
 471         ? "      "
 472           .$self->_generate_trigger(
 473             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 474             $spec->{trigger}
 475           ).";\n"
 476         : ""
 477       )
 478       ."    }\n";
 479   }
 480 }
 481
 482 sub _generate_core_set {
 483   my ($self, $me, $name, $spec, $value) = @_;
 484   my $name_str = perlstring $name;
 485   "${me}->{${name_str}} = ${value}";
 486 }
 487
 488 sub _generate_simple_set {
 489   my ($self, $me, $name, $spec, $value) = @_;
 490   my $name_str = perlstring $name;
 491   my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 492
 493   if ($spec->{weak_ref}) {
 494     require Scalar::Util;
 495     my $get = $self->_generate_simple_get($me, $name, $spec);
 496
 497     # Perl < 5.8.3 can't weaken refs to readonly vars
 498     # (e.g. string constants). This *can* be solved by:
 499     #
 500     #Internals::SetReadWrite($foo);
 501     #Scalar::Util::weaken ($foo);
 502     #Internals::SetReadOnly($foo);
 503     #
 504     # but requires XS and is just too damn crazy
 505     # so simply throw a better exception
 506     my $weak_simple = "do { Scalar::Util::weaken(${simple}); no warnings 'void'; $get }";
 507     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 508       eval { Scalar::Util::weaken($simple); 1 }
 509         ? do { no warnings 'void'; $get }
 510         : do {
 511           if( \$@ =~ /Modification of a read-only value attempted/) {
 512             require Carp;
 513             Carp::croak( sprintf (
 514               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 515               $name_str,
 516             ) );
 517           } else {
 518             die \$@;
 519           }
 520         }
 521 EOC
 522   } else {
 523     $simple;
 524   }
 525 }
 526
 527 sub _generate_getset {
 528   my ($self, $name, $spec) = @_;
 529   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 530     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 531 }
 532
 533 sub _generate_asserter {
 534   my ($self, $name, $spec) = @_;
 535
 536   "do {\n"
 537    ."  my \$val = ".$self->_generate_get($name, $spec).";\n"
 538    ."  unless (".$self->_generate_simple_has('$_[0]', $name, $spec).") {\n"
 539    .qq!    die "Attempted to access '${name}' but it is not set";\n!
 540    ."  }\n"
 541    ."  \$val;\n"
 542    ."}\n";
 543 }
 544 sub _generate_delegation {
 545   my ($self, $asserter, $target, $args) = @_;
 546   my $arg_string = do {
 547     if (@$args) {
 548       # I could, I reckon, linearise out non-refs here using perlstring
 549       # plus something to check for numbers but I'm unsure if it's worth it
 550       $self->{captures}{'@curries'} = $args;
 551       '@curries, @_';
 552     } else {
 553       '@_';
 554     }
 555   };
 556   "shift->${asserter}->${target}(${arg_string});";
 557 }
 558
 559 sub _generate_xs {
 560   my ($self, $type, $into, $name, $slot) = @_;
 561   Class::XSAccessor->import(
 562     class => $into,
 563     $type => { $name => $slot },
 564     replace => 1,
 565   );
 566   $into->can($name);
 567 }
 568
 569 sub default_construction_string { '{}' }
 570
 571 sub _validate_codulatable {
 572   my ($self, $setting, $value, $into, $appended) = @_;
 573   my $invalid = "Invalid $setting '" . overload::StrVal($value)
 574     . "' for $into not a coderef";
 575   $invalid .= " $appended" if $appended;
 576
 577   unless (ref $value and (ref $value eq 'CODE' or blessed($value))) {
 578     die "$invalid or code-convertible object";
 579   }
 580
 581   unless (eval { \&$value }) {
 582     die "$invalid and could not be converted to a coderef: $@";
 583   }
 584
 585   1;
 586 }
 587
 588 1;