lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     _maybe_load_module('Class::XSAccessor')
  11       &&
  12     (Class::XSAccessor->VERSION > 1.06)
  13   ;
  14 }
  15
  16 sub generate_method {
  17   my ($self, $into, $name, $spec, $quote_opts) = @_;
  18   die "Must have an is" unless my $is = $spec->{is};
  19   if ($is eq 'ro') {
  20     $spec->{reader} = $name unless exists $spec->{reader};
  21   } elsif ($is eq 'rw') {
  22     $spec->{accessor} = $name unless exists $spec->{accessor};
  23   } elsif ($is eq 'lazy') {
  24     $spec->{init_arg} = undef unless exists $spec->{init_arg};
  25     $spec->{reader} = $name unless exists $spec->{reader};
  26     $spec->{lazy} = 1;
  27     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  28   } elsif ($is ne 'bare') {
  29     die "Unknown is ${is}";
  30   }
  31   my %methods;
  32   if (my $reader = $spec->{reader}) {
  33     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  34       $methods{$reader} = $self->_generate_xs(
  35         getters => $into, $reader, $name
  36       );
  37     } else {
  38       $self->{captures} = {};
  39       $methods{$reader} =
  40         quote_sub "${into}::${reader}"
  41           => $self->_generate_get($name, $spec)
  42           => delete $self->{captures}
  43         ;
  44     }
  45   }
  46   if (my $accessor = $spec->{accessor}) {
  47     if (
  48       our $CAN_HAZ_XS
  49       && $self->is_simple_get($name, $spec)
  50       && $self->is_simple_set($name, $spec)
  51     ) {
  52       $methods{$accessor} = $self->_generate_xs(
  53         accessors => $into, $accessor, $name
  54       );
  55     } else {
  56       $self->{captures} = {};
  57       $methods{$accessor} =
  58         quote_sub "${into}::${accessor}"
  59           => $self->_generate_getset($name, $spec)
  60           => delete $self->{captures}
  61         ;
  62     }
  63   }
  64   if (my $writer = $spec->{writer}) {
  65     if (
  66       our $CAN_HAZ_XS
  67       && $self->is_simple_set($name, $spec)
  68     ) {
  69       $methods{$writer} = $self->_generate_xs(
  70         setters => $into, $writer, $name
  71       );
  72     } else {
  73       $self->{captures} = {};
  74       $methods{$writer} =
  75         quote_sub "${into}::${writer}"
  76           => $self->_generate_set($name, $spec)
  77           => delete $self->{captures}
  78         ;
  79     }
  80   }
  81   if (my $pred = $spec->{predicate}) {
  82     $methods{$pred} =
  83       quote_sub "${into}::${pred}" =>
  84         '    '.$self->_generate_simple_has('$_[0]', $name)."\n"
  85       ;
  86   }
  87   if (my $cl = $spec->{clearer}) {
  88     $methods{$cl} =
  89       quote_sub "${into}::${cl}" =>
  90         "    delete \$_[0]->{${\perlstring $name}}\n"
  91       ;
  92   }
  93   if (my $hspec = $spec->{handles}) {
  94     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
  95     my @specs = do {
  96       if (ref($hspec) eq 'ARRAY') {
  97         map [ $_ => $_ ], @$hspec;
  98       } elsif (ref($hspec) eq 'HASH') {
  99         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 100           keys %$hspec;
 101       } elsif (!ref($hspec)) {
 102         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 103       } else {
 104         die "You gave me a handles of ${hspec} and I have no idea why";
 105       }
 106     };
 107     foreach my $spec (@specs) {
 108       my ($proxy, $target, @args) = @$spec;
 109       $self->{captures} = {};
 110       $methods{$proxy} =
 111         quote_sub "${into}::${proxy}" =>
 112           $self->_generate_delegation($asserter, $target, \@args),
 113           delete $self->{captures}
 114         ;
 115     }
 116   }
 117   if (my $asserter = $spec->{asserter}) {
 118     $self->{captures} = {};
 119     $methods{$asserter} =
 120       quote_sub "${into}::${asserter}" =>
 121         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 122         delete $self->{captures}
 123       ;
 124   }
 125   \%methods;
 126 }
 127
 128 sub is_simple_attribute {
 129   my ($self, $name, $spec) = @_;
 130   # clearer doesn't have to be listed because it doesn't
 131   # affect whether defined/exists makes a difference
 132   !grep $spec->{$_},
 133     qw(lazy default builder isa trigger predicate weak_ref);
 134 }
 135
 136 sub is_simple_get {
 137   my ($self, $name, $spec) = @_;
 138   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 139 }
 140
 141 sub is_simple_set {
 142   my ($self, $name, $spec) = @_;
 143   !grep $spec->{$_}, qw(isa trigger weak_ref);
 144 }
 145
 146 sub has_eager_default {
 147   my ($self, $name, $spec) = @_;
 148   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 149 }
 150
 151 sub _generate_get {
 152   my ($self, $name, $spec) = @_;
 153   my $simple = $self->_generate_simple_get('$_[0]', $name);
 154   if ($self->is_simple_get($name, $spec)) {
 155     $simple;
 156   } else {
 157     'do { '.$self->_generate_use_default(
 158       '$_[0]', $name, $spec,
 159       $self->_generate_simple_has('$_[0]', $name),
 160     ).'; '.$simple.' }';
 161   }
 162 }
 163
 164 sub _generate_simple_has {
 165   my ($self, $me, $name) = @_;
 166   "exists ${me}->{${\perlstring $name}}";
 167 }
 168
 169 sub generate_get_default {
 170   my $self = shift;
 171   $self->{captures} = {};
 172   my $code = $self->_generate_get_default(@_);
 173   ($code, delete $self->{captures});
 174 }
 175
 176 sub _generate_use_default {
 177   my ($self, $me, $name, $spec, $test) = @_;
 178   $self->_generate_simple_set(
 179     $me, $name, $spec, $self->_generate_get_default($me, $name, $spec)
 180   ).' unless '.$test;
 181 }
 182
 183 sub _generate_get_default {
 184   my ($self, $me, $name, $spec) = @_;
 185   $spec->{default}
 186     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 187     : "${me}->${\$spec->{builder}}"
 188 }
 189
 190 sub generate_simple_get {
 191   my ($self, @args) = @_;
 192   $self->_generate_simple_get(@args);
 193 }
 194
 195 sub _generate_simple_get {
 196   my ($self, $me, $name) = @_;
 197   my $name_str = perlstring $name;
 198   "${me}->{${name_str}}";
 199 }
 200
 201 sub _generate_set {
 202   my ($self, $name, $spec) = @_;
 203   if ($self->is_simple_set($name, $spec)) {
 204     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 205   } else {
 206     my ($trigger, $isa_check) = @{$spec}{qw(trigger isa)};
 207     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 208     my $code = "do { my (\$self, \$value) = \@_;\n";
 209     if ($isa_check) {
 210       $code .=
 211         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 212     }
 213     if ($trigger) {
 214       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 215       $code .=
 216         "        ".$simple.";\n        ".$fire.";\n"
 217         ."        \$value;\n";
 218     } else {
 219       $code .= "        ".$simple.";\n";
 220     }
 221     $code .= "      }";
 222     $code;
 223   }
 224 }
 225
 226 sub generate_trigger {
 227   my $self = shift;
 228   $self->{captures} = {};
 229   my $code = $self->_generate_trigger(@_);
 230   ($code, delete $self->{captures});
 231 }
 232
 233 sub _generate_trigger {
 234   my ($self, $name, $obj, $value, $trigger) = @_;
 235   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 236 }
 237
 238 sub generate_isa_check {
 239   my ($self, @args) = @_;
 240   $self->{captures} = {};
 241   my $code = $self->_generate_isa_check(@args);
 242   ($code, delete $self->{captures});
 243 }
 244
 245 sub _generate_isa_check {
 246   my ($self, $name, $value, $check) = @_;
 247   $self->_generate_call_code($name, 'isa_check', $value, $check);
 248 }
 249
 250 sub _generate_call_code {
 251   my ($self, $name, $type, $values, $sub) = @_;
 252   if (my $quoted = quoted_from_sub($sub)) {
 253     my $code = $quoted->[1];
 254     my $at_ = '@_ = ('.$values.');';
 255     if (my $captures = $quoted->[2]) {
 256       my $cap_name = qq{\$${type}_captures_for_${name}};
 257       $self->{captures}->{$cap_name} = \$captures;
 258       Sub::Quote::inlinify(
 259         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 260       );
 261     } else {
 262       Sub::Quote::inlinify($code, $values);
 263     }
 264   } else {
 265     my $cap_name = qq{\$${type}_for_${name}};
 266     $self->{captures}->{$cap_name} = \$sub;
 267     "${cap_name}->(${values})";
 268   }
 269 }
 270
 271 sub generate_populate_set {
 272   my $self = shift;
 273   $self->{captures} = {};
 274   my $code = $self->_generate_populate_set(@_);
 275   ($code, delete $self->{captures});
 276 }
 277
 278 sub _generate_populate_set {
 279   my ($self, $me, $name, $spec, $source, $test) = @_;
 280   if ($self->has_eager_default($name, $spec)) {
 281     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 282     my $get_default = $self->_generate_get_default(
 283                         '$new', $_, $spec
 284                       );
 285     my $get_value =
 286       defined($spec->{init_arg})
 287         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 288             .$get_default
 289             ."\n${get_indent})"
 290         : $get_default;
 291     ($spec->{isa}
 292       ? "    {\n      my \$value = ".$get_value.";\n      "
 293         .$self->_generate_isa_check(
 294           $name, '$value', $spec->{isa}
 295         ).";\n"
 296         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 297         ."    }\n"
 298       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 299     )
 300     .($spec->{trigger}
 301       ? '    '
 302         .$self->_generate_trigger(
 303           $name, $me, $self->_generate_simple_get($me, $name),
 304           $spec->{trigger}
 305         )." if ${test};\n"
 306       : ''
 307     );
 308   } else {
 309     "    if (${test}) {\n"
 310       .($spec->{isa}
 311         ? "      "
 312           .$self->_generate_isa_check(
 313             $name, $source, $spec->{isa}
 314           ).";\n"
 315         : ""
 316       )
 317       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 318       .($spec->{trigger}
 319         ? "      "
 320           .$self->_generate_trigger(
 321             $name, $me, $self->_generate_simple_get($me, $name),
 322             $spec->{trigger}
 323           ).";\n"
 324         : ""
 325       )
 326       ."    }\n";
 327   }
 328 }
 329
 330 sub generate_multi_set {
 331   my ($self, $me, $to_set, $from) = @_;
 332   "\@{${me}}{qw(${\join ' ', @$to_set})} = $from";
 333 }
 334
 335 sub _generate_simple_set {
 336   my ($self, $me, $name, $spec, $value) = @_;
 337   my $name_str = perlstring $name;
 338   my $simple = "${me}->{${name_str}} = ${value}";
 339
 340   if ($spec->{weak_ref}) {
 341     require Scalar::Util;
 342
 343     # Perl < 5.8.3 can't weaken refs to readonly vars
 344     # (e.g. string constants). This *can* be solved by:
 345     #
 346     #Internals::SetReadWrite($foo);
 347     #Scalar::Util::weaken ($foo);
 348     #Internals::SetReadOnly($foo);
 349     #
 350     # but requires XS and is just too damn crazy
 351     # so simply throw a better exception
 352     Moo::_Utils::lt_5_8_3() ? <<"EOC" : "Scalar::Util::weaken(${simple})";
 353
 354       eval { Scalar::Util::weaken($simple); 1 } or do {
 355         if( \$@ =~ /Modification of a read-only value attempted/) {
 356           require Carp;
 357           Carp::croak( sprintf (
 358             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 359             $name_str,
 360           ) );
 361         } else {
 362           die \$@;
 363         }
 364       };
 365 EOC
 366   } else {
 367     $simple;
 368   }
 369 }
 370
 371 sub _generate_getset {
 372   my ($self, $name, $spec) = @_;
 373   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 374     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 375 }
 376
 377 sub _generate_delegation {
 378   my ($self, $asserter, $target, $args) = @_;
 379   my $arg_string = do {
 380     if (@$args) {
 381       # I could, I reckon, linearise out non-refs here using perlstring
 382       # plus something to check for numbers but I'm unsure if it's worth it
 383       $self->{captures}{'@curries'} = $args;
 384       '@curries, @_';
 385     } else {
 386       '@_';
 387     }
 388   };
 389   "shift->${asserter}->${target}(${arg_string});";
 390 }
 391
 392 sub _generate_xs {
 393   my ($self, $type, $into, $name, $slot) = @_;
 394   Class::XSAccessor->import(
 395     class => $into,
 396     $type => { $name => $slot }
 397   );
 398   $into->can($name);
 399 }
 400
 401 1;