lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 use Module::Runtime qw(use_module);
  11 BEGIN {
  12   our $CAN_HAZ_XS =
  13     !$ENV{MOO_XS_DISABLE}
  14       &&
  15     _maybe_load_module('Class::XSAccessor')
  16       &&
  17     (eval { Class::XSAccessor->VERSION('1.07') })
  18   ;
  19 }
  20
  21 sub _die_overwrite
  22 {
  23   my ($pkg, $method, $type) = @_;
  24   die "You cannot overwrite a locally defined method ($method) with @{[ $type || 'an accessor' ]}";
  25 }
  26
  27 sub generate_method {
  28   my ($self, $into, $name, $spec, $quote_opts) = @_;
  29   $spec->{allow_overwrite}++ if $name =~ s/^\+//;
  30   die "Must have an is" unless my $is = $spec->{is};
  31   if ($is eq 'ro') {
  32     $spec->{reader} = $name unless exists $spec->{reader};
  33   } elsif ($is eq 'rw') {
  34     $spec->{accessor} = $name unless exists $spec->{accessor}
  35       or ( $spec->{reader} and $spec->{writer} );
  36   } elsif ($is eq 'lazy') {
  37     $spec->{reader} = $name unless exists $spec->{reader};
  38     $spec->{lazy} = 1;
  39     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  40   } elsif ($is eq 'rwp') {
  41     $spec->{reader} = $name unless exists $spec->{reader};
  42     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  43   } elsif ($is ne 'bare') {
  44     die "Unknown is ${is}";
  45   }
  46   if (exists $spec->{builder}) {
  47     if(ref $spec->{builder}) {
  48       die "Invalid builder for $into->$name - not a method name, coderef or"
  49         . " code-convertible object"
  50         unless ref $spec->{builder} eq 'CODE'
  51         or (blessed($spec->{builder}) and eval { \&{$spec->{builder}} });
  52       $spec->{builder_sub} = $spec->{builder};
  53       $spec->{builder} = 1;
  54     }
  55     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  56     die "Invalid builder for $into->$name - not a valid method name"
  57       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  58   }
  59   if (($spec->{predicate}||0) eq 1) {
  60     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  61   }
  62   if (($spec->{clearer}||0) eq 1) {
  63     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  64   }
  65   if (($spec->{trigger}||0) eq 1) {
  66     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  67   }
  68
  69   if (exists $spec->{coerce}) {
  70     my $value = $spec->{coerce};
  71     my $invalid = "Invalid coerce '" . overload::StrVal($value)
  72       . "' for $into->$name - not a coderef";
  73     die "$invalid or code-convertible object"
  74       unless ref $value and (ref $value eq 'CODE' or blessed($value));
  75     die "$invalid and could not be converted to a coderef: $@"
  76       if !eval { \&$value };
  77   }
  78
  79   if (exists $spec->{default}) {
  80     my $value = $spec->{default};
  81     if (!defined $value || ref $value) {
  82       my $invalid = "Invalid default '" . overload::StrVal($value)
  83         . "' for $into->$name - not a coderef or non-ref";
  84       die "$invalid or code-convertible object"
  85         unless ref $value and (ref $value eq 'CODE' or blessed($value));
  86       die "$invalid and could not be converted to a coderef: $@"
  87         if !eval { \&$value };
  88     }
  89   }
  90
  91
  92   my %methods;
  93   if (my $reader = $spec->{reader}) {
  94     _die_overwrite($into, $reader, 'a reader')
  95       if !$spec->{allow_overwrite} && *{_getglob("${into}::${reader}")}{CODE};
  96     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  97       $methods{$reader} = $self->_generate_xs(
  98         getters => $into, $reader, $name, $spec
  99       );
 100     } else {
 101       $self->{captures} = {};
 102       $methods{$reader} =
 103         quote_sub "${into}::${reader}"
 104           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
 105              .$self->_generate_get($name, $spec)
 106           => delete $self->{captures}
 107         ;
 108     }
 109   }
 110   if (my $accessor = $spec->{accessor}) {
 111     _die_overwrite($into, $accessor, 'an accessor')
 112       if !$spec->{allow_overwrite} && *{_getglob("${into}::${accessor}")}{CODE};
 113     if (
 114       our $CAN_HAZ_XS
 115       && $self->is_simple_get($name, $spec)
 116       && $self->is_simple_set($name, $spec)
 117     ) {
 118       $methods{$accessor} = $self->_generate_xs(
 119         accessors => $into, $accessor, $name, $spec
 120       );
 121     } else {
 122       $self->{captures} = {};
 123       $methods{$accessor} =
 124         quote_sub "${into}::${accessor}"
 125           => $self->_generate_getset($name, $spec)
 126           => delete $self->{captures}
 127         ;
 128     }
 129   }
 130   if (my $writer = $spec->{writer}) {
 131     _die_overwrite($into, $writer, 'a writer')
 132       if !$spec->{allow_overwrite} && *{_getglob("${into}::${writer}")}{CODE};
 133     if (
 134       our $CAN_HAZ_XS
 135       && $self->is_simple_set($name, $spec)
 136     ) {
 137       $methods{$writer} = $self->_generate_xs(
 138         setters => $into, $writer, $name, $spec
 139       );
 140     } else {
 141       $self->{captures} = {};
 142       $methods{$writer} =
 143         quote_sub "${into}::${writer}"
 144           => $self->_generate_set($name, $spec)
 145           => delete $self->{captures}
 146         ;
 147     }
 148   }
 149   if (my $pred = $spec->{predicate}) {
 150     _die_overwrite($into, $pred, 'a predicate')
 151       if !$spec->{allow_overwrite} && *{_getglob("${into}::${pred}")}{CODE};
 152     $methods{$pred} =
 153       quote_sub "${into}::${pred}" =>
 154         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 155       ;
 156   }
 157   if (my $pred = $spec->{builder_sub}) {
 158     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 159   }
 160   if (my $cl = $spec->{clearer}) {
 161     _die_overwrite($into, $cl, 'a clearer')
 162       if !$spec->{allow_overwrite} && *{_getglob("${into}::${cl}")}{CODE};
 163     $methods{$cl} =
 164       quote_sub "${into}::${cl}" =>
 165         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 166       ;
 167   }
 168   if (my $hspec = $spec->{handles}) {
 169     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 170     my @specs = do {
 171       if (ref($hspec) eq 'ARRAY') {
 172         map [ $_ => $_ ], @$hspec;
 173       } elsif (ref($hspec) eq 'HASH') {
 174         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 175           keys %$hspec;
 176       } elsif (!ref($hspec)) {
 177         map [ $_ => $_ ], use_module('Role::Tiny')->methods_provided_by(use_module($hspec))
 178       } else {
 179         die "You gave me a handles of ${hspec} and I have no idea why";
 180       }
 181     };
 182     foreach my $spec (@specs) {
 183       my ($proxy, $target, @args) = @$spec;
 184       _die_overwrite($into, $proxy, 'a delegation')
 185         if !$spec->{allow_overwrite} && *{_getglob("${into}::${proxy}")}{CODE};
 186       $self->{captures} = {};
 187       $methods{$proxy} =
 188         quote_sub "${into}::${proxy}" =>
 189           $self->_generate_delegation($asserter, $target, \@args),
 190           delete $self->{captures}
 191         ;
 192     }
 193   }
 194   if (my $asserter = $spec->{asserter}) {
 195     $self->{captures} = {};
 196
 197     my $code = "do {\n"
 198                ."  my \$val = ".$self->_generate_get($name, $spec).";\n"
 199                ."  unless (".$self->_generate_simple_has('$_[0]', $name).") {\n"
 200                .qq!    die "Attempted to access '${name}' but it is not set";\n!
 201                ."  }\n"
 202                ."  \$val;\n"
 203                ."}\n";
 204
 205     $methods{$asserter} =
 206       quote_sub "${into}::${asserter}" => $code,
 207         delete $self->{captures}
 208       ;
 209   }
 210   \%methods;
 211 }
 212
 213 sub is_simple_attribute {
 214   my ($self, $name, $spec) = @_;
 215   # clearer doesn't have to be listed because it doesn't
 216   # affect whether defined/exists makes a difference
 217   !grep $spec->{$_},
 218     qw(lazy default builder coerce isa trigger predicate weak_ref);
 219 }
 220
 221 sub is_simple_get {
 222   my ($self, $name, $spec) = @_;
 223   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 224 }
 225
 226 sub is_simple_set {
 227   my ($self, $name, $spec) = @_;
 228   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 229 }
 230
 231 sub has_eager_default {
 232   my ($self, $name, $spec) = @_;
 233   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 234 }
 235
 236 sub _generate_get {
 237   my ($self, $name, $spec) = @_;
 238   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 239   if ($self->is_simple_get($name, $spec)) {
 240     $simple;
 241   } else {
 242     'do { '.$self->_generate_use_default(
 243       '$_[0]', $name, $spec,
 244       $self->_generate_simple_has('$_[0]', $name, $spec),
 245     ).'; '
 246     .($spec->{isa}
 247       ?($self->_generate_isa_check($name, $simple, $spec->{isa}).'; ')
 248       :''
 249     )
 250     .$simple.' }';
 251   }
 252 }
 253
 254 sub _generate_simple_has {
 255   my ($self, $me, $name) = @_;
 256   "exists ${me}->{${\perlstring $name}}";
 257 }
 258
 259 sub _generate_simple_clear {
 260   my ($self, $me, $name) = @_;
 261   "    delete ${me}->{${\perlstring $name}}\n"
 262 }
 263
 264 sub generate_get_default {
 265   my $self = shift;
 266   $self->{captures} = {};
 267   my $code = $self->_generate_get_default(@_);
 268   ($code, delete $self->{captures});
 269 }
 270
 271 sub _generate_use_default {
 272   my ($self, $me, $name, $spec, $test) = @_;
 273   my $get_value = $self->_generate_get_default($me, $name, $spec);
 274   if ($spec->{coerce}) {
 275     $get_value = $self->_generate_coerce(
 276       $name, $get_value,
 277       $spec->{coerce}
 278     )
 279   }
 280   $self->_generate_simple_set(
 281     $me, $name, $spec, $get_value
 282   ).' unless '.$test;
 283 }
 284
 285 sub _generate_get_default {
 286   my ($self, $me, $name, $spec) = @_;
 287   if (exists $spec->{default}) {
 288     ref $spec->{default}
 289       ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 290       : perlstring $spec->{default};
 291   }
 292   else {
 293     "${me}->${\$spec->{builder}}"
 294   }
 295 }
 296
 297 sub generate_simple_get {
 298   my ($self, @args) = @_;
 299   $self->_generate_simple_get(@args);
 300 }
 301
 302 sub _generate_simple_get {
 303   my ($self, $me, $name) = @_;
 304   my $name_str = perlstring $name;
 305   "${me}->{${name_str}}";
 306 }
 307
 308 sub _generate_set {
 309   my ($self, $name, $spec) = @_;
 310   if ($self->is_simple_set($name, $spec)) {
 311     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 312   } else {
 313     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 314     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 315     my $code = "do { my (\$self, \$value) = \@_;\n";
 316     if ($coerce) {
 317       $code .=
 318         "        \$value = "
 319         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 320     }
 321     if ($isa_check) {
 322       $code .=
 323         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 324     }
 325     if ($trigger) {
 326       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 327       $code .=
 328         "        ".$simple.";\n        ".$fire.";\n"
 329         ."        \$value;\n";
 330     } else {
 331       $code .= "        ".$simple.";\n";
 332     }
 333     $code .= "      }";
 334     $code;
 335   }
 336 }
 337
 338 sub generate_coerce {
 339   my $self = shift;
 340   $self->{captures} = {};
 341   my $code = $self->_generate_coerce(@_);
 342   ($code, delete $self->{captures});
 343 }
 344
 345 sub _attr_desc {
 346   my ($name, $init_arg) = @_;
 347   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 348   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 349 }
 350
 351 sub _generate_coerce {
 352   my ($self, $name, $value, $coerce, $init_arg) = @_;
 353   $self->_generate_die_prefix(
 354     "coercion for ${\_attr_desc($name, $init_arg)} failed: ",
 355     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 356   );
 357 }
 358
 359 sub generate_trigger {
 360   my $self = shift;
 361   $self->{captures} = {};
 362   my $code = $self->_generate_trigger(@_);
 363   ($code, delete $self->{captures});
 364 }
 365
 366 sub _generate_trigger {
 367   my ($self, $name, $obj, $value, $trigger) = @_;
 368   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 369 }
 370
 371 sub generate_isa_check {
 372   my ($self, @args) = @_;
 373   $self->{captures} = {};
 374   my $code = $self->_generate_isa_check(@args);
 375   ($code, delete $self->{captures});
 376 }
 377
 378 sub _generate_die_prefix {
 379   my ($self, $prefix, $inside) = @_;
 380   "do {\n"
 381   .'  my $sig_die = $SIG{__DIE__} || sub { die $_[0] };'."\n"
 382   .'  local $SIG{__DIE__} = sub {'."\n"
 383   .'    $sig_die->(ref($_[0]) ? $_[0] : '.perlstring($prefix).'.$_[0]);'."\n"
 384   .'  };'."\n"
 385   .$inside
 386   ."}\n"
 387 }
 388
 389 sub _generate_isa_check {
 390   my ($self, $name, $value, $check, $init_arg) = @_;
 391   $self->_generate_die_prefix(
 392     "isa check for ${\_attr_desc($name, $init_arg)} failed: ",
 393     $self->_generate_call_code($name, 'isa_check', $value, $check)
 394   );
 395 }
 396
 397 sub _generate_call_code {
 398   my ($self, $name, $type, $values, $sub) = @_;
 399   if (my $quoted = quoted_from_sub($sub)) {
 400     my $code = $quoted->[1];
 401     if (my $captures = $quoted->[2]) {
 402       my $cap_name = qq{\$${type}_captures_for_${name}};
 403       $self->{captures}->{$cap_name} = \$captures;
 404       Sub::Quote::inlinify(
 405         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), 1
 406       );
 407     } else {
 408       Sub::Quote::inlinify($code, $values, undef, 1);
 409     }
 410   } else {
 411     my $cap_name = qq{\$${type}_for_${name}};
 412     $self->{captures}->{$cap_name} = \$sub;
 413     "${cap_name}->(${values})";
 414   }
 415 }
 416
 417 sub generate_populate_set {
 418   my $self = shift;
 419   $self->{captures} = {};
 420   my $code = $self->_generate_populate_set(@_);
 421   ($code, delete $self->{captures});
 422 }
 423
 424 sub _generate_populate_set {
 425   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 426   if ($self->has_eager_default($name, $spec)) {
 427     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 428     my $get_default = $self->_generate_get_default(
 429                         '$new', $_, $spec
 430                       );
 431     my $get_value =
 432       defined($spec->{init_arg})
 433         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 434             .$get_default
 435             ."\n${get_indent})"
 436         : $get_default;
 437     if ($spec->{coerce}) {
 438       $get_value = $self->_generate_coerce(
 439         $name, $get_value,
 440         $spec->{coerce}, $init_arg
 441       )
 442     }
 443     ($spec->{isa}
 444       ? "    {\n      my \$value = ".$get_value.";\n      "
 445         .$self->_generate_isa_check(
 446           $name, '$value', $spec->{isa}, $init_arg
 447         ).";\n"
 448         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 449         ."    }\n"
 450       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 451     )
 452     .($spec->{trigger}
 453       ? '    '
 454         .$self->_generate_trigger(
 455           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 456           $spec->{trigger}
 457         )." if ${test};\n"
 458       : ''
 459     );
 460   } else {
 461     "    if (${test}) {\n"
 462       .($spec->{coerce}
 463         ? "      $source = "
 464           .$self->_generate_coerce(
 465             $name, $source,
 466             $spec->{coerce}, $init_arg
 467           ).";\n"
 468         : ""
 469       )
 470       .($spec->{isa}
 471         ? "      "
 472           .$self->_generate_isa_check(
 473             $name, $source, $spec->{isa}, $init_arg
 474           ).";\n"
 475         : ""
 476       )
 477       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 478       .($spec->{trigger}
 479         ? "      "
 480           .$self->_generate_trigger(
 481             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 482             $spec->{trigger}
 483           ).";\n"
 484         : ""
 485       )
 486       ."    }\n";
 487   }
 488 }
 489
 490 sub _generate_core_set {
 491   my ($self, $me, $name, $spec, $value) = @_;
 492   my $name_str = perlstring $name;
 493   "${me}->{${name_str}} = ${value}";
 494 }
 495
 496 sub _generate_simple_set {
 497   my ($self, $me, $name, $spec, $value) = @_;
 498   my $name_str = perlstring $name;
 499
 500   if ($spec->{weak_ref}) {
 501     $value = '$preserve = '.$value;
 502     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 503     require Scalar::Util;
 504
 505     # Perl < 5.8.3 can't weaken refs to readonly vars
 506     # (e.g. string constants). This *can* be solved by:
 507     #
 508     #Internals::SetReadWrite($foo);
 509     #Scalar::Util::weaken ($foo);
 510     #Internals::SetReadOnly($foo);
 511     #
 512     # but requires XS and is just too damn crazy
 513     # so simply throw a better exception
 514     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple}); no warnings 'void'; \$preserve";
 515     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 516
 517       my \$preserve;
 518       eval { Scalar::Util::weaken($simple); 1 }
 519         ? do { no warnings 'void'; \$preserve; }
 520         : do {
 521           if( \$@ =~ /Modification of a read-only value attempted/) {
 522             require Carp;
 523             Carp::croak( sprintf (
 524               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 525               $name_str,
 526             ) );
 527           } else {
 528             die \$@;
 529           }
 530         }
 531 EOC
 532   } else {
 533     $self->_generate_core_set($me, $name, $spec, $value);
 534   }
 535 }
 536
 537 sub _generate_getset {
 538   my ($self, $name, $spec) = @_;
 539   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 540     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 541 }
 542
 543 sub _generate_delegation {
 544   my ($self, $asserter, $target, $args) = @_;
 545   my $arg_string = do {
 546     if (@$args) {
 547       # I could, I reckon, linearise out non-refs here using perlstring
 548       # plus something to check for numbers but I'm unsure if it's worth it
 549       $self->{captures}{'@curries'} = $args;
 550       '@curries, @_';
 551     } else {
 552       '@_';
 553     }
 554   };
 555   "shift->${asserter}->${target}(${arg_string});";
 556 }
 557
 558 sub _generate_xs {
 559   my ($self, $type, $into, $name, $slot) = @_;
 560   Class::XSAccessor->import(
 561     class => $into,
 562     $type => { $name => $slot },
 563     replace => 1,
 564   );
 565   $into->can($name);
 566 }
 567
 568 sub default_construction_string { '{}' }
 569
 570 1;