lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     !$ENV{MOO_XS_DISABLE}
  11       &&
  12     _maybe_load_module('Class::XSAccessor')
  13       &&
  14     (eval { Class::XSAccessor->VERSION('1.07') })
  15   ;
  16 }
  17
  18 sub generate_method {
  19   my ($self, $into, $name, $spec, $quote_opts) = @_;
  20   $name =~ s/^\+//;
  21   die "Must have an is" unless my $is = $spec->{is};
  22   if ($is eq 'ro') {
  23     $spec->{reader} = $name unless exists $spec->{reader};
  24   } elsif ($is eq 'rw') {
  25     $spec->{accessor} = $name unless exists $spec->{accessor};
  26   } elsif ($is eq 'lazy') {
  27     $spec->{reader} = $name unless exists $spec->{reader};
  28     $spec->{lazy} = 1;
  29     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  30   } elsif ($is eq 'rwp') {
  31     $spec->{reader} = $name unless exists $spec->{reader};
  32     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  33   } elsif ($is ne 'bare') {
  34     die "Unknown is ${is}";
  35   }
  36   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  37   if (($spec->{predicate}||0) eq 1) {
  38     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  39   }
  40   if (($spec->{clearer}||0) eq 1) {
  41     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  42   }
  43   if (($spec->{trigger}||0) eq 1) {
  44     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  45   }
  46   if (exists $spec->{default}) {
  47     my $default = $spec->{default};
  48     require Scalar::Util;
  49     unless (
  50       ref $default
  51       and (
  52         Scalar::Util::reftype $default eq 'CODE'
  53         or Scalar::Util::blessed $default and $default->can('(&{}')
  54       )
  55     ) {
  56       die "Invalid default $default";
  57     }
  58   }
  59
  60   my %methods;
  61   if (my $reader = $spec->{reader}) {
  62     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  63       $methods{$reader} = $self->_generate_xs(
  64         getters => $into, $reader, $name, $spec
  65       );
  66     } else {
  67       $self->{captures} = {};
  68       $methods{$reader} =
  69         quote_sub "${into}::${reader}"
  70           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  71              .$self->_generate_get($name, $spec)
  72           => delete $self->{captures}
  73         ;
  74     }
  75   }
  76   if (my $accessor = $spec->{accessor}) {
  77     if (
  78       our $CAN_HAZ_XS
  79       && $self->is_simple_get($name, $spec)
  80       && $self->is_simple_set($name, $spec)
  81     ) {
  82       $methods{$accessor} = $self->_generate_xs(
  83         accessors => $into, $accessor, $name, $spec
  84       );
  85     } else {
  86       $self->{captures} = {};
  87       $methods{$accessor} =
  88         quote_sub "${into}::${accessor}"
  89           => $self->_generate_getset($name, $spec)
  90           => delete $self->{captures}
  91         ;
  92     }
  93   }
  94   if (my $writer = $spec->{writer}) {
  95     if (
  96       our $CAN_HAZ_XS
  97       && $self->is_simple_set($name, $spec)
  98     ) {
  99       $methods{$writer} = $self->_generate_xs(
 100         setters => $into, $writer, $name, $spec
 101       );
 102     } else {
 103       $self->{captures} = {};
 104       $methods{$writer} =
 105         quote_sub "${into}::${writer}"
 106           => $self->_generate_set($name, $spec)
 107           => delete $self->{captures}
 108         ;
 109     }
 110   }
 111   if (my $pred = $spec->{predicate}) {
 112     $methods{$pred} =
 113       quote_sub "${into}::${pred}" =>
 114         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 115       ;
 116   }
 117   if (my $cl = $spec->{clearer}) {
 118     $methods{$cl} =
 119       quote_sub "${into}::${cl}" =>
 120         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 121       ;
 122   }
 123   if (my $hspec = $spec->{handles}) {
 124     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 125     my @specs = do {
 126       if (ref($hspec) eq 'ARRAY') {
 127         map [ $_ => $_ ], @$hspec;
 128       } elsif (ref($hspec) eq 'HASH') {
 129         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 130           keys %$hspec;
 131       } elsif (!ref($hspec)) {
 132         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 133       } else {
 134         die "You gave me a handles of ${hspec} and I have no idea why";
 135       }
 136     };
 137     foreach my $spec (@specs) {
 138       my ($proxy, $target, @args) = @$spec;
 139       $self->{captures} = {};
 140       $methods{$proxy} =
 141         quote_sub "${into}::${proxy}" =>
 142           $self->_generate_delegation($asserter, $target, \@args),
 143           delete $self->{captures}
 144         ;
 145     }
 146   }
 147   if (my $asserter = $spec->{asserter}) {
 148     $self->{captures} = {};
 149     $methods{$asserter} =
 150       quote_sub "${into}::${asserter}" =>
 151         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 152         delete $self->{captures}
 153       ;
 154   }
 155   \%methods;
 156 }
 157
 158 sub is_simple_attribute {
 159   my ($self, $name, $spec) = @_;
 160   # clearer doesn't have to be listed because it doesn't
 161   # affect whether defined/exists makes a difference
 162   !grep $spec->{$_},
 163     qw(lazy default builder coerce isa trigger predicate weak_ref);
 164 }
 165
 166 sub is_simple_get {
 167   my ($self, $name, $spec) = @_;
 168   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 169 }
 170
 171 sub is_simple_set {
 172   my ($self, $name, $spec) = @_;
 173   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 174 }
 175
 176 sub has_eager_default {
 177   my ($self, $name, $spec) = @_;
 178   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 179 }
 180
 181 sub _generate_get {
 182   my ($self, $name, $spec) = @_;
 183   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 184   if ($self->is_simple_get($name, $spec)) {
 185     $simple;
 186   } else {
 187     'do { '.$self->_generate_use_default(
 188       '$_[0]', $name, $spec,
 189       $self->_generate_simple_has('$_[0]', $name, $spec),
 190     ).'; '.$simple.' }';
 191   }
 192 }
 193
 194 sub _generate_simple_has {
 195   my ($self, $me, $name) = @_;
 196   "exists ${me}->{${\perlstring $name}}";
 197 }
 198
 199 sub _generate_simple_clear {
 200   my ($self, $me, $name) = @_;
 201   "    delete ${me}->{${\perlstring $name}}\n"
 202 }
 203
 204 sub generate_get_default {
 205   my $self = shift;
 206   $self->{captures} = {};
 207   my $code = $self->_generate_get_default(@_);
 208   ($code, delete $self->{captures});
 209 }
 210
 211 sub _generate_use_default {
 212   my ($self, $me, $name, $spec, $test) = @_;
 213   my $get_value = $self->_generate_get_default($me, $name, $spec);
 214   if ($spec->{coerce}) {
 215     $get_value = $self->_generate_coerce(
 216       $name, $get_value,
 217       $spec->{coerce}
 218     )
 219   }
 220   $self->_generate_simple_set(
 221     $me, $name, $spec, $get_value
 222   ).' unless '.$test;
 223 }
 224
 225 sub _generate_get_default {
 226   my ($self, $me, $name, $spec) = @_;
 227   $spec->{default}
 228     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 229     : "${me}->${\$spec->{builder}}"
 230 }
 231
 232 sub generate_simple_get {
 233   my ($self, @args) = @_;
 234   $self->_generate_simple_get(@args);
 235 }
 236
 237 sub _generate_simple_get {
 238   my ($self, $me, $name) = @_;
 239   my $name_str = perlstring $name;
 240   "${me}->{${name_str}}";
 241 }
 242
 243 sub _generate_set {
 244   my ($self, $name, $spec) = @_;
 245   if ($self->is_simple_set($name, $spec)) {
 246     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 247   } else {
 248     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 249     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 250     my $code = "do { my (\$self, \$value) = \@_;\n";
 251     if ($coerce) {
 252       $code .=
 253         "        \$value = "
 254         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 255     }
 256     if ($isa_check) {
 257       $code .=
 258         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 259     }
 260     if ($trigger) {
 261       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 262       $code .=
 263         "        ".$simple.";\n        ".$fire.";\n"
 264         ."        \$value;\n";
 265     } else {
 266       $code .= "        ".$simple.";\n";
 267     }
 268     $code .= "      }";
 269     $code;
 270   }
 271 }
 272
 273 sub generate_coerce {
 274   my $self = shift;
 275   $self->{captures} = {};
 276   my $code = $self->_generate_coerce(@_);
 277   ($code, delete $self->{captures});
 278 }
 279
 280 sub _generate_coerce {
 281   my ($self, $name, $value, $coerce) = @_;
 282   $self->_generate_call_code($name, 'coerce', "${value}", $coerce);
 283 }
 284
 285 sub generate_trigger {
 286   my $self = shift;
 287   $self->{captures} = {};
 288   my $code = $self->_generate_trigger(@_);
 289   ($code, delete $self->{captures});
 290 }
 291
 292 sub _generate_trigger {
 293   my ($self, $name, $obj, $value, $trigger) = @_;
 294   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 295 }
 296
 297 sub generate_isa_check {
 298   my ($self, @args) = @_;
 299   $self->{captures} = {};
 300   my $code = $self->_generate_isa_check(@args);
 301   ($code, delete $self->{captures});
 302 }
 303
 304 sub _generate_isa_check {
 305   my ($self, $name, $value, $check) = @_;
 306   $self->_generate_call_code($name, 'isa_check', $value, $check);
 307 }
 308
 309 sub _generate_call_code {
 310   my ($self, $name, $type, $values, $sub) = @_;
 311   if (my $quoted = quoted_from_sub($sub)) {
 312     my $code = $quoted->[1];
 313     my $at_ = '@_ = ('.$values.');';
 314     if (my $captures = $quoted->[2]) {
 315       my $cap_name = qq{\$${type}_captures_for_${name}};
 316       $self->{captures}->{$cap_name} = \$captures;
 317       Sub::Quote::inlinify(
 318         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 319       );
 320     } else {
 321       Sub::Quote::inlinify($code, $values);
 322     }
 323   } else {
 324     my $cap_name = qq{\$${type}_for_${name}};
 325     $self->{captures}->{$cap_name} = \$sub;
 326     "${cap_name}->(${values})";
 327   }
 328 }
 329
 330 sub generate_populate_set {
 331   my $self = shift;
 332   $self->{captures} = {};
 333   my $code = $self->_generate_populate_set(@_);
 334   ($code, delete $self->{captures});
 335 }
 336
 337 sub _generate_populate_set {
 338   my ($self, $me, $name, $spec, $source, $test) = @_;
 339   if ($self->has_eager_default($name, $spec)) {
 340     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 341     my $get_default = $self->_generate_get_default(
 342                         '$new', $_, $spec
 343                       );
 344     my $get_value =
 345       defined($spec->{init_arg})
 346         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 347             .$get_default
 348             ."\n${get_indent})"
 349         : $get_default;
 350     if ($spec->{coerce}) {
 351       $get_value = $self->_generate_coerce(
 352         $name, $get_value,
 353         $spec->{coerce}
 354       )
 355     }
 356     ($spec->{isa}
 357       ? "    {\n      my \$value = ".$get_value.";\n      "
 358         .$self->_generate_isa_check(
 359           $name, '$value', $spec->{isa}
 360         ).";\n"
 361         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 362         ."    }\n"
 363       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 364     )
 365     .($spec->{trigger}
 366       ? '    '
 367         .$self->_generate_trigger(
 368           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 369           $spec->{trigger}
 370         )." if ${test};\n"
 371       : ''
 372     );
 373   } else {
 374     "    if (${test}) {\n"
 375       .($spec->{coerce}
 376         ? "      $source = "
 377           .$self->_generate_coerce(
 378             $name, $source,
 379             $spec->{coerce}
 380           ).";\n"
 381         : ""
 382       )
 383       .($spec->{isa}
 384         ? "      "
 385           .$self->_generate_isa_check(
 386             $name, $source, $spec->{isa}
 387           ).";\n"
 388         : ""
 389       )
 390       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 391       .($spec->{trigger}
 392         ? "      "
 393           .$self->_generate_trigger(
 394             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 395             $spec->{trigger}
 396           ).";\n"
 397         : ""
 398       )
 399       ."    }\n";
 400   }
 401 }
 402
 403 sub generate_multi_set {
 404   my ($self, $me, $to_set, $from) = @_;
 405   "\@{${me}}{qw(${\join ' ', @$to_set})} = $from";
 406 }
 407
 408 sub _generate_core_set {
 409   my ($self, $me, $name, $spec, $value) = @_;
 410   my $name_str = perlstring $name;
 411   "${me}->{${name_str}} = ${value}";
 412 }
 413
 414 sub _generate_simple_set {
 415   my ($self, $me, $name, $spec, $value) = @_;
 416   my $name_str = perlstring $name;
 417
 418   if ($spec->{weak_ref}) {
 419     $value = '$preserve = '.$value;
 420     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 421     require Scalar::Util;
 422
 423     # Perl < 5.8.3 can't weaken refs to readonly vars
 424     # (e.g. string constants). This *can* be solved by:
 425     #
 426     #Internals::SetReadWrite($foo);
 427     #Scalar::Util::weaken ($foo);
 428     #Internals::SetReadOnly($foo);
 429     #
 430     # but requires XS and is just too damn crazy
 431     # so simply throw a better exception
 432     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple})";
 433     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 434
 435       my \$preserve;
 436       eval { Scalar::Util::weaken($simple); 1 } or do {
 437         if( \$@ =~ /Modification of a read-only value attempted/) {
 438           require Carp;
 439           Carp::croak( sprintf (
 440             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 441             $name_str,
 442           ) );
 443         } else {
 444           die \$@;
 445         }
 446       };
 447 EOC
 448   } else {
 449     $self->_generate_core_set($me, $name, $spec, $value);
 450   }
 451 }
 452
 453 sub _generate_getset {
 454   my ($self, $name, $spec) = @_;
 455   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 456     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 457 }
 458
 459 sub _generate_delegation {
 460   my ($self, $asserter, $target, $args) = @_;
 461   my $arg_string = do {
 462     if (@$args) {
 463       # I could, I reckon, linearise out non-refs here using perlstring
 464       # plus something to check for numbers but I'm unsure if it's worth it
 465       $self->{captures}{'@curries'} = $args;
 466       '@curries, @_';
 467     } else {
 468       '@_';
 469     }
 470   };
 471   "shift->${asserter}->${target}(${arg_string});";
 472 }
 473
 474 sub _generate_xs {
 475   my ($self, $type, $into, $name, $slot) = @_;
 476   Class::XSAccessor->import(
 477     class => $into,
 478     $type => { $name => $slot },
 479     replace => 1,
 480   );
 481   $into->can($name);
 482 }
 483
 484 sub default_construction_string { '{}' }
 485
 486 1;