lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 BEGIN {
  11   our $CAN_HAZ_XS =
  12     !$ENV{MOO_XS_DISABLE}
  13       &&
  14     _maybe_load_module('Class::XSAccessor')
  15       &&
  16     (eval { Class::XSAccessor->VERSION('1.07') })
  17   ;
  18 }
  19
  20 sub generate_method {
  21   my ($self, $into, $name, $spec, $quote_opts) = @_;
  22   $name =~ s/^\+//;
  23   die "Must have an is" unless my $is = $spec->{is};
  24   if ($is eq 'ro') {
  25     $spec->{reader} = $name unless exists $spec->{reader};
  26   } elsif ($is eq 'rw') {
  27     $spec->{accessor} = $name unless exists $spec->{accessor};
  28   } elsif ($is eq 'lazy') {
  29     $spec->{reader} = $name unless exists $spec->{reader};
  30     $spec->{lazy} = 1;
  31     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  32   } elsif ($is eq 'rwp') {
  33     $spec->{reader} = $name unless exists $spec->{reader};
  34     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  35   } elsif ($is ne 'bare') {
  36     die "Unknown is ${is}";
  37   }
  38   if (exists $spec->{builder}) {
  39     if(ref $spec->{builder}) {
  40       die "Invalid builder for $into->$name - not a method name, coderef or"
  41         . " code-convertible object"
  42         unless ref $spec->{builder} eq 'CODE'
  43         or (blessed($spec->{builder}) and eval { \&{$spec->{builder}} });
  44       $spec->{builder_sub} = $spec->{builder};
  45       $spec->{builder} = 1;
  46     }
  47     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  48     die "Invalid builder for $into->$name - not a valid method name"
  49       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  50   }
  51   if (($spec->{predicate}||0) eq 1) {
  52     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  53   }
  54   if (($spec->{clearer}||0) eq 1) {
  55     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  56   }
  57   if (($spec->{trigger}||0) eq 1) {
  58     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  59   }
  60
  61   for my $setting (qw( default coerce )) {
  62     next if !exists $spec->{$setting};
  63     my $value = $spec->{$setting};
  64     my $invalid = "Invalid $setting '" . overload::StrVal($value)
  65       . "' for $into->$name - not a coderef";
  66     die "$invalid or code-convertible object"
  67       unless ref $value and (ref $value eq 'CODE' or blessed($value));
  68     die "$invalid and could not be converted to a coderef: $@"
  69       if !eval { \&$value };
  70   }
  71
  72   my %methods;
  73   if (my $reader = $spec->{reader}) {
  74     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  75       $methods{$reader} = $self->_generate_xs(
  76         getters => $into, $reader, $name, $spec
  77       );
  78     } else {
  79       $self->{captures} = {};
  80       $methods{$reader} =
  81         quote_sub "${into}::${reader}"
  82           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  83              .$self->_generate_get($name, $spec)
  84           => delete $self->{captures}
  85         ;
  86     }
  87   }
  88   if (my $accessor = $spec->{accessor}) {
  89     if (
  90       our $CAN_HAZ_XS
  91       && $self->is_simple_get($name, $spec)
  92       && $self->is_simple_set($name, $spec)
  93     ) {
  94       $methods{$accessor} = $self->_generate_xs(
  95         accessors => $into, $accessor, $name, $spec
  96       );
  97     } else {
  98       $self->{captures} = {};
  99       $methods{$accessor} =
 100         quote_sub "${into}::${accessor}"
 101           => $self->_generate_getset($name, $spec)
 102           => delete $self->{captures}
 103         ;
 104     }
 105   }
 106   if (my $writer = $spec->{writer}) {
 107     if (
 108       our $CAN_HAZ_XS
 109       && $self->is_simple_set($name, $spec)
 110     ) {
 111       $methods{$writer} = $self->_generate_xs(
 112         setters => $into, $writer, $name, $spec
 113       );
 114     } else {
 115       $self->{captures} = {};
 116       $methods{$writer} =
 117         quote_sub "${into}::${writer}"
 118           => $self->_generate_set($name, $spec)
 119           => delete $self->{captures}
 120         ;
 121     }
 122   }
 123   if (my $pred = $spec->{predicate}) {
 124     $methods{$pred} =
 125       quote_sub "${into}::${pred}" =>
 126         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 127       ;
 128   }
 129   if (my $pred = $spec->{builder_sub}) {
 130     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 131   }
 132   if (my $cl = $spec->{clearer}) {
 133     $methods{$cl} =
 134       quote_sub "${into}::${cl}" =>
 135         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 136       ;
 137   }
 138   if (my $hspec = $spec->{handles}) {
 139     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 140     my @specs = do {
 141       if (ref($hspec) eq 'ARRAY') {
 142         map [ $_ => $_ ], @$hspec;
 143       } elsif (ref($hspec) eq 'HASH') {
 144         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 145           keys %$hspec;
 146       } elsif (!ref($hspec)) {
 147         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 148       } else {
 149         die "You gave me a handles of ${hspec} and I have no idea why";
 150       }
 151     };
 152     foreach my $spec (@specs) {
 153       my ($proxy, $target, @args) = @$spec;
 154       $self->{captures} = {};
 155       $methods{$proxy} =
 156         quote_sub "${into}::${proxy}" =>
 157           $self->_generate_delegation($asserter, $target, \@args),
 158           delete $self->{captures}
 159         ;
 160     }
 161   }
 162   if (my $asserter = $spec->{asserter}) {
 163     $self->{captures} = {};
 164     $methods{$asserter} =
 165       quote_sub "${into}::${asserter}" =>
 166         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 167         delete $self->{captures}
 168       ;
 169   }
 170   \%methods;
 171 }
 172
 173 sub is_simple_attribute {
 174   my ($self, $name, $spec) = @_;
 175   # clearer doesn't have to be listed because it doesn't
 176   # affect whether defined/exists makes a difference
 177   !grep $spec->{$_},
 178     qw(lazy default builder coerce isa trigger predicate weak_ref);
 179 }
 180
 181 sub is_simple_get {
 182   my ($self, $name, $spec) = @_;
 183   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 184 }
 185
 186 sub is_simple_set {
 187   my ($self, $name, $spec) = @_;
 188   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 189 }
 190
 191 sub has_eager_default {
 192   my ($self, $name, $spec) = @_;
 193   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 194 }
 195
 196 sub _generate_get {
 197   my ($self, $name, $spec) = @_;
 198   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 199   if ($self->is_simple_get($name, $spec)) {
 200     $simple;
 201   } else {
 202     'do { '.$self->_generate_use_default(
 203       '$_[0]', $name, $spec,
 204       $self->_generate_simple_has('$_[0]', $name, $spec),
 205     ).'; '
 206     .($spec->{isa}
 207       ?($self->_generate_isa_check($name, $simple, $spec->{isa}).'; ')
 208       :''
 209     )
 210     .$simple.' }';
 211   }
 212 }
 213
 214 sub _generate_simple_has {
 215   my ($self, $me, $name) = @_;
 216   "exists ${me}->{${\perlstring $name}}";
 217 }
 218
 219 sub _generate_simple_clear {
 220   my ($self, $me, $name) = @_;
 221   "    delete ${me}->{${\perlstring $name}}\n"
 222 }
 223
 224 sub generate_get_default {
 225   my $self = shift;
 226   $self->{captures} = {};
 227   my $code = $self->_generate_get_default(@_);
 228   ($code, delete $self->{captures});
 229 }
 230
 231 sub _generate_use_default {
 232   my ($self, $me, $name, $spec, $test) = @_;
 233   my $get_value = $self->_generate_get_default($me, $name, $spec);
 234   if ($spec->{coerce}) {
 235     $get_value = $self->_generate_coerce(
 236       $name, $get_value,
 237       $spec->{coerce}
 238     )
 239   }
 240   $self->_generate_simple_set(
 241     $me, $name, $spec, $get_value
 242   ).' unless '.$test;
 243 }
 244
 245 sub _generate_get_default {
 246   my ($self, $me, $name, $spec) = @_;
 247   $spec->{default}
 248     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 249     : "${me}->${\$spec->{builder}}"
 250 }
 251
 252 sub generate_simple_get {
 253   my ($self, @args) = @_;
 254   $self->_generate_simple_get(@args);
 255 }
 256
 257 sub _generate_simple_get {
 258   my ($self, $me, $name) = @_;
 259   my $name_str = perlstring $name;
 260   "${me}->{${name_str}}";
 261 }
 262
 263 sub _generate_set {
 264   my ($self, $name, $spec) = @_;
 265   if ($self->is_simple_set($name, $spec)) {
 266     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 267   } else {
 268     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 269     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 270     my $code = "do { my (\$self, \$value) = \@_;\n";
 271     if ($coerce) {
 272       $code .=
 273         "        \$value = "
 274         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 275     }
 276     if ($isa_check) {
 277       $code .=
 278         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 279     }
 280     if ($trigger) {
 281       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 282       $code .=
 283         "        ".$simple.";\n        ".$fire.";\n"
 284         ."        \$value;\n";
 285     } else {
 286       $code .= "        ".$simple.";\n";
 287     }
 288     $code .= "      }";
 289     $code;
 290   }
 291 }
 292
 293 sub generate_coerce {
 294   my $self = shift;
 295   $self->{captures} = {};
 296   my $code = $self->_generate_coerce(@_);
 297   ($code, delete $self->{captures});
 298 }
 299
 300 sub _attr_desc {
 301   my ($name, $init_arg) = @_;
 302   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 303   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 304 }
 305
 306 sub _generate_coerce {
 307   my ($self, $name, $value, $coerce, $init_arg) = @_;
 308   $self->_generate_die_prefix(
 309     "coercion for ${\_attr_desc($name, $init_arg)} failed: ",
 310     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 311   );
 312 }
 313
 314 sub generate_trigger {
 315   my $self = shift;
 316   $self->{captures} = {};
 317   my $code = $self->_generate_trigger(@_);
 318   ($code, delete $self->{captures});
 319 }
 320
 321 sub _generate_trigger {
 322   my ($self, $name, $obj, $value, $trigger) = @_;
 323   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 324 }
 325
 326 sub generate_isa_check {
 327   my ($self, @args) = @_;
 328   $self->{captures} = {};
 329   my $code = $self->_generate_isa_check(@args);
 330   ($code, delete $self->{captures});
 331 }
 332
 333 sub _generate_die_prefix {
 334   my ($self, $prefix, $inside) = @_;
 335   "do {\n"
 336   .'  my $sig_die = $SIG{__DIE__} || sub { die $_[0] };'."\n"
 337   .'  local $SIG{__DIE__} = sub {'."\n"
 338   .'    $sig_die->(ref($_[0]) ? $_[0] : '.perlstring($prefix).'.$_[0]);'."\n"
 339   .'  };'."\n"
 340   .$inside
 341   ."}\n"
 342 }
 343
 344 sub _generate_isa_check {
 345   my ($self, $name, $value, $check, $init_arg) = @_;
 346   $self->_generate_die_prefix(
 347     "isa check for ${\_attr_desc($name, $init_arg)} failed: ",
 348     $self->_generate_call_code($name, 'isa_check', $value, $check)
 349   );
 350 }
 351
 352 sub _generate_call_code {
 353   my ($self, $name, $type, $values, $sub) = @_;
 354   if (my $quoted = quoted_from_sub($sub)) {
 355     my $code = $quoted->[1];
 356     if (my $captures = $quoted->[2]) {
 357       my $cap_name = qq{\$${type}_captures_for_${name}};
 358       $self->{captures}->{$cap_name} = \$captures;
 359       Sub::Quote::inlinify(
 360         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), 1
 361       );
 362     } else {
 363       Sub::Quote::inlinify($code, $values, undef, 1);
 364     }
 365   } else {
 366     my $cap_name = qq{\$${type}_for_${name}};
 367     $self->{captures}->{$cap_name} = \$sub;
 368     "${cap_name}->(${values})";
 369   }
 370 }
 371
 372 sub generate_populate_set {
 373   my $self = shift;
 374   $self->{captures} = {};
 375   my $code = $self->_generate_populate_set(@_);
 376   ($code, delete $self->{captures});
 377 }
 378
 379 sub _generate_populate_set {
 380   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 381   if ($self->has_eager_default($name, $spec)) {
 382     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 383     my $get_default = $self->_generate_get_default(
 384                         '$new', $_, $spec
 385                       );
 386     my $get_value =
 387       defined($spec->{init_arg})
 388         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 389             .$get_default
 390             ."\n${get_indent})"
 391         : $get_default;
 392     if ($spec->{coerce}) {
 393       $get_value = $self->_generate_coerce(
 394         $name, $get_value,
 395         $spec->{coerce}, $init_arg
 396       )
 397     }
 398     ($spec->{isa}
 399       ? "    {\n      my \$value = ".$get_value.";\n      "
 400         .$self->_generate_isa_check(
 401           $name, '$value', $spec->{isa}, $init_arg
 402         ).";\n"
 403         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 404         ."    }\n"
 405       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 406     )
 407     .($spec->{trigger}
 408       ? '    '
 409         .$self->_generate_trigger(
 410           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 411           $spec->{trigger}
 412         )." if ${test};\n"
 413       : ''
 414     );
 415   } else {
 416     "    if (${test}) {\n"
 417       .($spec->{coerce}
 418         ? "      $source = "
 419           .$self->_generate_coerce(
 420             $name, $source,
 421             $spec->{coerce}, $init_arg
 422           ).";\n"
 423         : ""
 424       )
 425       .($spec->{isa}
 426         ? "      "
 427           .$self->_generate_isa_check(
 428             $name, $source, $spec->{isa}, $init_arg
 429           ).";\n"
 430         : ""
 431       )
 432       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 433       .($spec->{trigger}
 434         ? "      "
 435           .$self->_generate_trigger(
 436             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 437             $spec->{trigger}
 438           ).";\n"
 439         : ""
 440       )
 441       ."    }\n";
 442   }
 443 }
 444
 445 sub _generate_core_set {
 446   my ($self, $me, $name, $spec, $value) = @_;
 447   my $name_str = perlstring $name;
 448   "${me}->{${name_str}} = ${value}";
 449 }
 450
 451 sub _generate_simple_set {
 452   my ($self, $me, $name, $spec, $value) = @_;
 453   my $name_str = perlstring $name;
 454
 455   if ($spec->{weak_ref}) {
 456     $value = '$preserve = '.$value;
 457     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 458     require Scalar::Util;
 459
 460     # Perl < 5.8.3 can't weaken refs to readonly vars
 461     # (e.g. string constants). This *can* be solved by:
 462     #
 463     #Internals::SetReadWrite($foo);
 464     #Scalar::Util::weaken ($foo);
 465     #Internals::SetReadOnly($foo);
 466     #
 467     # but requires XS and is just too damn crazy
 468     # so simply throw a better exception
 469     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple}); no warnings 'void'; \$preserve";
 470     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 471
 472       my \$preserve;
 473       eval { Scalar::Util::weaken($simple); 1 }
 474         ? do { no warnings 'void'; \$preserve; }
 475         : do {
 476           if( \$@ =~ /Modification of a read-only value attempted/) {
 477             require Carp;
 478             Carp::croak( sprintf (
 479               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 480               $name_str,
 481             ) );
 482           } else {
 483             die \$@;
 484           }
 485         }
 486 EOC
 487   } else {
 488     $self->_generate_core_set($me, $name, $spec, $value);
 489   }
 490 }
 491
 492 sub _generate_getset {
 493   my ($self, $name, $spec) = @_;
 494   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 495     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 496 }
 497
 498 sub _generate_delegation {
 499   my ($self, $asserter, $target, $args) = @_;
 500   my $arg_string = do {
 501     if (@$args) {
 502       # I could, I reckon, linearise out non-refs here using perlstring
 503       # plus something to check for numbers but I'm unsure if it's worth it
 504       $self->{captures}{'@curries'} = $args;
 505       '@curries, @_';
 506     } else {
 507       '@_';
 508     }
 509   };
 510   "shift->${asserter}->${target}(${arg_string});";
 511 }
 512
 513 sub _generate_xs {
 514   my ($self, $type, $into, $name, $slot) = @_;
 515   Class::XSAccessor->import(
 516     class => $into,
 517     $type => { $name => $slot },
 518     replace => 1,
 519   );
 520   $into->can($name);
 521 }
 522
 523 sub default_construction_string { '{}' }
 524
 525 1;