lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 BEGIN {
  11   our $CAN_HAZ_XS =
  12     !$ENV{MOO_XS_DISABLE}
  13       &&
  14     _maybe_load_module('Class::XSAccessor')
  15       &&
  16     (eval { Class::XSAccessor->VERSION('1.07') })
  17   ;
  18 }
  19
  20 sub generate_method {
  21   my ($self, $into, $name, $spec, $quote_opts) = @_;
  22   $name =~ s/^\+//;
  23   die "Must have an is" unless my $is = $spec->{is};
  24   if ($is eq 'ro') {
  25     $spec->{reader} = $name unless exists $spec->{reader};
  26   } elsif ($is eq 'rw') {
  27     $spec->{accessor} = $name unless exists $spec->{accessor};
  28   } elsif ($is eq 'lazy') {
  29     $spec->{reader} = $name unless exists $spec->{reader};
  30     $spec->{lazy} = 1;
  31     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  32   } elsif ($is eq 'rwp') {
  33     $spec->{reader} = $name unless exists $spec->{reader};
  34     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  35   } elsif ($is ne 'bare') {
  36     die "Unknown is ${is}";
  37   }
  38   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  39   die "Invalid builder for $into->$name - not a valid method name"
  40     if exists $spec->{builder} and (ref $spec->{builder}
  41       or $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/);
  42   if (($spec->{predicate}||0) eq 1) {
  43     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  44   }
  45   if (($spec->{clearer}||0) eq 1) {
  46     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  47   }
  48   if (($spec->{trigger}||0) eq 1) {
  49     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  50   }
  51
  52   for my $setting (qw( default coerce )) {
  53     next if !exists $spec->{$setting};
  54     my $value = $spec->{$setting};
  55     my $invalid = "Invalid $setting '" . overload::StrVal($value)
  56       . "' for $into->$name - not a coderef";
  57     die "$invalid or code-convertible object"
  58       unless ref $value and (ref $value eq 'CODE' or blessed($value));
  59     die "$invalid and could not be converted to a coderef: $@"
  60       if !eval { \&$value };
  61   }
  62
  63   my %methods;
  64   if (my $reader = $spec->{reader}) {
  65     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  66       $methods{$reader} = $self->_generate_xs(
  67         getters => $into, $reader, $name, $spec
  68       );
  69     } else {
  70       $self->{captures} = {};
  71       $methods{$reader} =
  72         quote_sub "${into}::${reader}"
  73           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  74              .$self->_generate_get($name, $spec)
  75           => delete $self->{captures}
  76         ;
  77     }
  78   }
  79   if (my $accessor = $spec->{accessor}) {
  80     if (
  81       our $CAN_HAZ_XS
  82       && $self->is_simple_get($name, $spec)
  83       && $self->is_simple_set($name, $spec)
  84     ) {
  85       $methods{$accessor} = $self->_generate_xs(
  86         accessors => $into, $accessor, $name, $spec
  87       );
  88     } else {
  89       $self->{captures} = {};
  90       $methods{$accessor} =
  91         quote_sub "${into}::${accessor}"
  92           => $self->_generate_getset($name, $spec)
  93           => delete $self->{captures}
  94         ;
  95     }
  96   }
  97   if (my $writer = $spec->{writer}) {
  98     if (
  99       our $CAN_HAZ_XS
 100       && $self->is_simple_set($name, $spec)
 101     ) {
 102       $methods{$writer} = $self->_generate_xs(
 103         setters => $into, $writer, $name, $spec
 104       );
 105     } else {
 106       $self->{captures} = {};
 107       $methods{$writer} =
 108         quote_sub "${into}::${writer}"
 109           => $self->_generate_set($name, $spec)
 110           => delete $self->{captures}
 111         ;
 112     }
 113   }
 114   if (my $pred = $spec->{predicate}) {
 115     $methods{$pred} =
 116       quote_sub "${into}::${pred}" =>
 117         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 118       ;
 119   }
 120   if (my $cl = $spec->{clearer}) {
 121     $methods{$cl} =
 122       quote_sub "${into}::${cl}" =>
 123         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 124       ;
 125   }
 126   if (my $hspec = $spec->{handles}) {
 127     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 128     my @specs = do {
 129       if (ref($hspec) eq 'ARRAY') {
 130         map [ $_ => $_ ], @$hspec;
 131       } elsif (ref($hspec) eq 'HASH') {
 132         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 133           keys %$hspec;
 134       } elsif (!ref($hspec)) {
 135         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 136       } else {
 137         die "You gave me a handles of ${hspec} and I have no idea why";
 138       }
 139     };
 140     foreach my $spec (@specs) {
 141       my ($proxy, $target, @args) = @$spec;
 142       $self->{captures} = {};
 143       $methods{$proxy} =
 144         quote_sub "${into}::${proxy}" =>
 145           $self->_generate_delegation($asserter, $target, \@args),
 146           delete $self->{captures}
 147         ;
 148     }
 149   }
 150   if (my $asserter = $spec->{asserter}) {
 151     $self->{captures} = {};
 152     $methods{$asserter} =
 153       quote_sub "${into}::${asserter}" =>
 154         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 155         delete $self->{captures}
 156       ;
 157   }
 158   \%methods;
 159 }
 160
 161 sub is_simple_attribute {
 162   my ($self, $name, $spec) = @_;
 163   # clearer doesn't have to be listed because it doesn't
 164   # affect whether defined/exists makes a difference
 165   !grep $spec->{$_},
 166     qw(lazy default builder coerce isa trigger predicate weak_ref);
 167 }
 168
 169 sub is_simple_get {
 170   my ($self, $name, $spec) = @_;
 171   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 172 }
 173
 174 sub is_simple_set {
 175   my ($self, $name, $spec) = @_;
 176   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 177 }
 178
 179 sub has_eager_default {
 180   my ($self, $name, $spec) = @_;
 181   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 182 }
 183
 184 sub _generate_get {
 185   my ($self, $name, $spec) = @_;
 186   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 187   if ($self->is_simple_get($name, $spec)) {
 188     $simple;
 189   } else {
 190     'do { '.$self->_generate_use_default(
 191       '$_[0]', $name, $spec,
 192       $self->_generate_simple_has('$_[0]', $name, $spec),
 193     ).'; '
 194     .($spec->{isa}
 195       ?($self->_generate_isa_check($name, $simple, $spec->{isa}).'; ')
 196       :''
 197     )
 198     .$simple.' }';
 199   }
 200 }
 201
 202 sub _generate_simple_has {
 203   my ($self, $me, $name) = @_;
 204   "exists ${me}->{${\perlstring $name}}";
 205 }
 206
 207 sub _generate_simple_clear {
 208   my ($self, $me, $name) = @_;
 209   "    delete ${me}->{${\perlstring $name}}\n"
 210 }
 211
 212 sub generate_get_default {
 213   my $self = shift;
 214   $self->{captures} = {};
 215   my $code = $self->_generate_get_default(@_);
 216   ($code, delete $self->{captures});
 217 }
 218
 219 sub _generate_use_default {
 220   my ($self, $me, $name, $spec, $test) = @_;
 221   my $get_value = $self->_generate_get_default($me, $name, $spec);
 222   if ($spec->{coerce}) {
 223     $get_value = $self->_generate_coerce(
 224       $name, $get_value,
 225       $spec->{coerce}
 226     )
 227   }
 228   $self->_generate_simple_set(
 229     $me, $name, $spec, $get_value
 230   ).' unless '.$test;
 231 }
 232
 233 sub _generate_get_default {
 234   my ($self, $me, $name, $spec) = @_;
 235   $spec->{default}
 236     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 237     : "${me}->${\$spec->{builder}}"
 238 }
 239
 240 sub generate_simple_get {
 241   my ($self, @args) = @_;
 242   $self->_generate_simple_get(@args);
 243 }
 244
 245 sub _generate_simple_get {
 246   my ($self, $me, $name) = @_;
 247   my $name_str = perlstring $name;
 248   "${me}->{${name_str}}";
 249 }
 250
 251 sub _generate_set {
 252   my ($self, $name, $spec) = @_;
 253   if ($self->is_simple_set($name, $spec)) {
 254     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 255   } else {
 256     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 257     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 258     my $code = "do { my (\$self, \$value) = \@_;\n";
 259     if ($coerce) {
 260       $code .=
 261         "        \$value = "
 262         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 263     }
 264     if ($isa_check) {
 265       $code .=
 266         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 267     }
 268     if ($trigger) {
 269       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 270       $code .=
 271         "        ".$simple.";\n        ".$fire.";\n"
 272         ."        \$value;\n";
 273     } else {
 274       $code .= "        ".$simple.";\n";
 275     }
 276     $code .= "      }";
 277     $code;
 278   }
 279 }
 280
 281 sub generate_coerce {
 282   my $self = shift;
 283   $self->{captures} = {};
 284   my $code = $self->_generate_coerce(@_);
 285   ($code, delete $self->{captures});
 286 }
 287
 288 sub _attr_desc {
 289   my ($name, $init_arg) = @_;
 290   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 291   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 292 }
 293
 294 sub _generate_coerce {
 295   my ($self, $name, $value, $coerce, $init_arg) = @_;
 296   $self->_generate_die_prefix(
 297     "coercion for ${\_attr_desc($name, $init_arg)} failed: ",
 298     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 299   );
 300 }
 301
 302 sub generate_trigger {
 303   my $self = shift;
 304   $self->{captures} = {};
 305   my $code = $self->_generate_trigger(@_);
 306   ($code, delete $self->{captures});
 307 }
 308
 309 sub _generate_trigger {
 310   my ($self, $name, $obj, $value, $trigger) = @_;
 311   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 312 }
 313
 314 sub generate_isa_check {
 315   my ($self, @args) = @_;
 316   $self->{captures} = {};
 317   my $code = $self->_generate_isa_check(@args);
 318   ($code, delete $self->{captures});
 319 }
 320
 321 sub _generate_die_prefix {
 322   my ($self, $prefix, $inside) = @_;
 323   "do {\n"
 324   .'  my $sig_die = $SIG{__DIE__} || sub { die $_[0] };'."\n"
 325   .'  local $SIG{__DIE__} = sub {'."\n"
 326   .'    $sig_die->(ref($_[0]) ? $_[0] : '.perlstring($prefix).'.$_[0]);'."\n"
 327   .'  };'."\n"
 328   .$inside
 329   ."}\n"
 330 }
 331
 332 sub _generate_isa_check {
 333   my ($self, $name, $value, $check, $init_arg) = @_;
 334   $self->_generate_die_prefix(
 335     "isa check for ${\_attr_desc($name, $init_arg)} failed: ",
 336     $self->_generate_call_code($name, 'isa_check', $value, $check)
 337   );
 338 }
 339
 340 sub _generate_call_code {
 341   my ($self, $name, $type, $values, $sub) = @_;
 342   if (my $quoted = quoted_from_sub($sub)) {
 343     my $code = $quoted->[1];
 344     if (my $captures = $quoted->[2]) {
 345       my $cap_name = qq{\$${type}_captures_for_${name}};
 346       $self->{captures}->{$cap_name} = \$captures;
 347       Sub::Quote::inlinify(
 348         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), 1
 349       );
 350     } else {
 351       Sub::Quote::inlinify($code, $values, undef, 1);
 352     }
 353   } else {
 354     my $cap_name = qq{\$${type}_for_${name}};
 355     $self->{captures}->{$cap_name} = \$sub;
 356     "${cap_name}->(${values})";
 357   }
 358 }
 359
 360 sub generate_populate_set {
 361   my $self = shift;
 362   $self->{captures} = {};
 363   my $code = $self->_generate_populate_set(@_);
 364   ($code, delete $self->{captures});
 365 }
 366
 367 sub _generate_populate_set {
 368   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 369   if ($self->has_eager_default($name, $spec)) {
 370     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 371     my $get_default = $self->_generate_get_default(
 372                         '$new', $_, $spec
 373                       );
 374     my $get_value =
 375       defined($spec->{init_arg})
 376         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 377             .$get_default
 378             ."\n${get_indent})"
 379         : $get_default;
 380     if ($spec->{coerce}) {
 381       $get_value = $self->_generate_coerce(
 382         $name, $get_value,
 383         $spec->{coerce}, $init_arg
 384       )
 385     }
 386     ($spec->{isa}
 387       ? "    {\n      my \$value = ".$get_value.";\n      "
 388         .$self->_generate_isa_check(
 389           $name, '$value', $spec->{isa}, $init_arg
 390         ).";\n"
 391         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 392         ."    }\n"
 393       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 394     )
 395     .($spec->{trigger}
 396       ? '    '
 397         .$self->_generate_trigger(
 398           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 399           $spec->{trigger}
 400         )." if ${test};\n"
 401       : ''
 402     );
 403   } else {
 404     "    if (${test}) {\n"
 405       .($spec->{coerce}
 406         ? "      $source = "
 407           .$self->_generate_coerce(
 408             $name, $source,
 409             $spec->{coerce}, $init_arg
 410           ).";\n"
 411         : ""
 412       )
 413       .($spec->{isa}
 414         ? "      "
 415           .$self->_generate_isa_check(
 416             $name, $source, $spec->{isa}, $init_arg
 417           ).";\n"
 418         : ""
 419       )
 420       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 421       .($spec->{trigger}
 422         ? "      "
 423           .$self->_generate_trigger(
 424             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 425             $spec->{trigger}
 426           ).";\n"
 427         : ""
 428       )
 429       ."    }\n";
 430   }
 431 }
 432
 433 sub _generate_core_set {
 434   my ($self, $me, $name, $spec, $value) = @_;
 435   my $name_str = perlstring $name;
 436   "${me}->{${name_str}} = ${value}";
 437 }
 438
 439 sub _generate_simple_set {
 440   my ($self, $me, $name, $spec, $value) = @_;
 441   my $name_str = perlstring $name;
 442
 443   if ($spec->{weak_ref}) {
 444     $value = '$preserve = '.$value;
 445     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 446     require Scalar::Util;
 447
 448     # Perl < 5.8.3 can't weaken refs to readonly vars
 449     # (e.g. string constants). This *can* be solved by:
 450     #
 451     #Internals::SetReadWrite($foo);
 452     #Scalar::Util::weaken ($foo);
 453     #Internals::SetReadOnly($foo);
 454     #
 455     # but requires XS and is just too damn crazy
 456     # so simply throw a better exception
 457     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple}); no warnings 'void'; \$preserve";
 458     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 459
 460       my \$preserve;
 461       eval { Scalar::Util::weaken($simple); 1 }
 462         ? do { no warnings 'void'; \$preserve; }
 463         : do {
 464           if( \$@ =~ /Modification of a read-only value attempted/) {
 465             require Carp;
 466             Carp::croak( sprintf (
 467               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 468               $name_str,
 469             ) );
 470           } else {
 471             die \$@;
 472           }
 473         }
 474 EOC
 475   } else {
 476     $self->_generate_core_set($me, $name, $spec, $value);
 477   }
 478 }
 479
 480 sub _generate_getset {
 481   my ($self, $name, $spec) = @_;
 482   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 483     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 484 }
 485
 486 sub _generate_delegation {
 487   my ($self, $asserter, $target, $args) = @_;
 488   my $arg_string = do {
 489     if (@$args) {
 490       # I could, I reckon, linearise out non-refs here using perlstring
 491       # plus something to check for numbers but I'm unsure if it's worth it
 492       $self->{captures}{'@curries'} = $args;
 493       '@curries, @_';
 494     } else {
 495       '@_';
 496     }
 497   };
 498   "shift->${asserter}->${target}(${arg_string});";
 499 }
 500
 501 sub _generate_xs {
 502   my ($self, $type, $into, $name, $slot) = @_;
 503   Class::XSAccessor->import(
 504     class => $into,
 505     $type => { $name => $slot },
 506     replace => 1,
 507   );
 508   $into->can($name);
 509 }
 510
 511 sub default_construction_string { '{}' }
 512
 513 1;