lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 use Module::Runtime qw(use_module);
  11 BEGIN {
  12   our $CAN_HAZ_XS =
  13     !$ENV{MOO_XS_DISABLE}
  14       &&
  15     _maybe_load_module('Class::XSAccessor')
  16       &&
  17     (eval { Class::XSAccessor->VERSION('1.07') })
  18   ;
  19 }
  20
  21 sub _SIGDIE
  22 {
  23   our ($CurrentAttribute, $OrigSigDie);
  24   $OrigSigDie ||= sub { die $_[0] };
  25   my $attr_desc = _attr_desc(@$CurrentAttribute{qw(name init_arg)});
  26   $OrigSigDie->("$CurrentAttribute->{step} for $attr_desc failed: $_[0]");
  27 }
  28
  29 sub _die_overwrite
  30 {
  31   my ($pkg, $method, $type) = @_;
  32   die "You cannot overwrite a locally defined method ($method) with @{[ $type || 'an accessor' ]}";
  33 }
  34
  35 sub generate_method {
  36   my ($self, $into, $name, $spec, $quote_opts) = @_;
  37   $spec->{allow_overwrite}++ if $name =~ s/^\+//;
  38   die "Must have an is" unless my $is = $spec->{is};
  39   if ($is eq 'ro') {
  40     $spec->{reader} = $name unless exists $spec->{reader};
  41   } elsif ($is eq 'rw') {
  42     $spec->{accessor} = $name unless exists $spec->{accessor}
  43       or ( $spec->{reader} and $spec->{writer} );
  44   } elsif ($is eq 'lazy') {
  45     $spec->{reader} = $name unless exists $spec->{reader};
  46     $spec->{lazy} = 1;
  47     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  48   } elsif ($is eq 'rwp') {
  49     $spec->{reader} = $name unless exists $spec->{reader};
  50     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  51   } elsif ($is ne 'bare') {
  52     die "Unknown is ${is}";
  53   }
  54   if (exists $spec->{builder}) {
  55     if(ref $spec->{builder}) {
  56       die "Invalid builder for $into->$name - not a method name, coderef or"
  57         . " code-convertible object"
  58         unless ref $spec->{builder} eq 'CODE'
  59         or (blessed($spec->{builder}) and eval { \&{$spec->{builder}} });
  60       $spec->{builder_sub} = $spec->{builder};
  61       $spec->{builder} = 1;
  62     }
  63     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  64     die "Invalid builder for $into->$name - not a valid method name"
  65       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  66   }
  67   if (($spec->{predicate}||0) eq 1) {
  68     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  69   }
  70   if (($spec->{clearer}||0) eq 1) {
  71     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  72   }
  73   if (($spec->{trigger}||0) eq 1) {
  74     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  75   }
  76
  77   for my $setting (qw( isa coerce )) {
  78     next if !exists $spec->{$setting};
  79     $self->_validate_codulatable($setting, $spec->{$setting}, "$into->$name");
  80   }
  81
  82   if (exists $spec->{default}) {
  83     if (!defined $spec->{default} || ref $spec->{default}) {
  84       $self->_validate_codulatable('default', $spec->{default}, "$into->$name", 'or a non-ref');
  85     }
  86   }
  87
  88   if (exists $spec->{moosify}) {
  89     if (ref $spec->{moosify} ne 'ARRAY') {
  90       $spec->{moosify} = [$spec->{moosify}];
  91     }
  92
  93     for my $spec (@{$spec->{moosify}}) {
  94       $self->_validate_codulatable('moosify', $spec, "$into->$name");
  95     }
  96   }
  97
  98   my %methods;
  99   if (my $reader = $spec->{reader}) {
 100     _die_overwrite($into, $reader, 'a reader')
 101       if !$spec->{allow_overwrite} && *{_getglob("${into}::${reader}")}{CODE};
 102     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
 103       $methods{$reader} = $self->_generate_xs(
 104         getters => $into, $reader, $name, $spec
 105       );
 106     } else {
 107       $self->{captures} = {};
 108       $methods{$reader} =
 109         quote_sub "${into}::${reader}"
 110           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
 111              .$self->_generate_get($name, $spec)
 112           => delete $self->{captures}
 113         ;
 114     }
 115   }
 116   if (my $accessor = $spec->{accessor}) {
 117     _die_overwrite($into, $accessor, 'an accessor')
 118       if !$spec->{allow_overwrite} && *{_getglob("${into}::${accessor}")}{CODE};
 119     if (
 120       our $CAN_HAZ_XS
 121       && $self->is_simple_get($name, $spec)
 122       && $self->is_simple_set($name, $spec)
 123     ) {
 124       $methods{$accessor} = $self->_generate_xs(
 125         accessors => $into, $accessor, $name, $spec
 126       );
 127     } else {
 128       $self->{captures} = {};
 129       $methods{$accessor} =
 130         quote_sub "${into}::${accessor}"
 131           => $self->_generate_getset($name, $spec)
 132           => delete $self->{captures}
 133         ;
 134     }
 135   }
 136   if (my $writer = $spec->{writer}) {
 137     _die_overwrite($into, $writer, 'a writer')
 138       if !$spec->{allow_overwrite} && *{_getglob("${into}::${writer}")}{CODE};
 139     if (
 140       our $CAN_HAZ_XS
 141       && $self->is_simple_set($name, $spec)
 142     ) {
 143       $methods{$writer} = $self->_generate_xs(
 144         setters => $into, $writer, $name, $spec
 145       );
 146     } else {
 147       $self->{captures} = {};
 148       $methods{$writer} =
 149         quote_sub "${into}::${writer}"
 150           => $self->_generate_set($name, $spec)
 151           => delete $self->{captures}
 152         ;
 153     }
 154   }
 155   if (my $pred = $spec->{predicate}) {
 156     _die_overwrite($into, $pred, 'a predicate')
 157       if !$spec->{allow_overwrite} && *{_getglob("${into}::${pred}")}{CODE};
 158     $methods{$pred} =
 159       quote_sub "${into}::${pred}" =>
 160         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 161       ;
 162   }
 163   if (my $pred = $spec->{builder_sub}) {
 164     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 165   }
 166   if (my $cl = $spec->{clearer}) {
 167     _die_overwrite($into, $cl, 'a clearer')
 168       if !$spec->{allow_overwrite} && *{_getglob("${into}::${cl}")}{CODE};
 169     $methods{$cl} =
 170       quote_sub "${into}::${cl}" =>
 171         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 172       ;
 173   }
 174   if (my $hspec = $spec->{handles}) {
 175     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 176     my @specs = do {
 177       if (ref($hspec) eq 'ARRAY') {
 178         map [ $_ => $_ ], @$hspec;
 179       } elsif (ref($hspec) eq 'HASH') {
 180         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 181           keys %$hspec;
 182       } elsif (!ref($hspec)) {
 183         map [ $_ => $_ ], use_module('Role::Tiny')->methods_provided_by(use_module($hspec))
 184       } else {
 185         die "You gave me a handles of ${hspec} and I have no idea why";
 186       }
 187     };
 188     foreach my $delegation_spec (@specs) {
 189       my ($proxy, $target, @args) = @$delegation_spec;
 190       _die_overwrite($into, $proxy, 'a delegation')
 191         if !$spec->{allow_overwrite} && *{_getglob("${into}::${proxy}")}{CODE};
 192       $self->{captures} = {};
 193       $methods{$proxy} =
 194         quote_sub "${into}::${proxy}" =>
 195           $self->_generate_delegation($asserter, $target, \@args),
 196           delete $self->{captures}
 197         ;
 198     }
 199   }
 200   if (my $asserter = $spec->{asserter}) {
 201     $self->{captures} = {};
 202
 203
 204     $methods{$asserter} =
 205       quote_sub "${into}::${asserter}" => $self->_generate_asserter($name, $spec),
 206         delete $self->{captures}
 207       ;
 208   }
 209   \%methods;
 210 }
 211
 212 sub is_simple_attribute {
 213   my ($self, $name, $spec) = @_;
 214   # clearer doesn't have to be listed because it doesn't
 215   # affect whether defined/exists makes a difference
 216   !grep $spec->{$_},
 217     qw(lazy default builder coerce isa trigger predicate weak_ref);
 218 }
 219
 220 sub is_simple_get {
 221   my ($self, $name, $spec) = @_;
 222   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 223 }
 224
 225 sub is_simple_set {
 226   my ($self, $name, $spec) = @_;
 227   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 228 }
 229
 230 sub has_eager_default {
 231   my ($self, $name, $spec) = @_;
 232   (!$spec->{lazy} and (exists $spec->{default} or $spec->{builder}));
 233 }
 234
 235 sub _generate_get {
 236   my ($self, $name, $spec) = @_;
 237   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 238   if ($self->is_simple_get($name, $spec)) {
 239     $simple;
 240   } else {
 241     $self->_generate_use_default(
 242       '$_[0]', $name, $spec,
 243       $self->_generate_simple_has('$_[0]', $name, $spec),
 244     );
 245   }
 246 }
 247
 248 sub _generate_simple_has {
 249   my ($self, $me, $name) = @_;
 250   "exists ${me}->{${\perlstring $name}}";
 251 }
 252
 253 sub _generate_simple_clear {
 254   my ($self, $me, $name) = @_;
 255   "    delete ${me}->{${\perlstring $name}}\n"
 256 }
 257
 258 sub generate_get_default {
 259   my $self = shift;
 260   $self->{captures} = {};
 261   my $code = $self->_generate_get_default(@_);
 262   ($code, delete $self->{captures});
 263 }
 264
 265 sub _generate_use_default {
 266   my ($self, $me, $name, $spec, $test) = @_;
 267   my $get_value = $self->_generate_get_default($me, $name, $spec);
 268   if ($spec->{coerce}) {
 269     $get_value = $self->_generate_coerce(
 270       $name, $get_value,
 271       $spec->{coerce}
 272     )
 273   }
 274   $test." ? \n"
 275   .$self->_generate_simple_get($me, $name, $spec)."\n:"
 276   .($spec->{isa}
 277     ? "    do {\n      my \$value = ".$get_value.";\n"
 278       ."      ".$self->_generate_isa_check($name, '$value', $spec->{isa}).";\n"
 279       ."      ".$self->_generate_simple_set($me, $name, $spec, '$value')."\n"
 280       ."    }\n"
 281     : '    ('.$self->_generate_simple_set($me, $name, $spec, $get_value).")\n");
 282 }
 283
 284 sub _generate_get_default {
 285   my ($self, $me, $name, $spec) = @_;
 286   if (exists $spec->{default}) {
 287     ref $spec->{default}
 288       ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 289       : perlstring $spec->{default};
 290   }
 291   else {
 292     "${me}->${\$spec->{builder}}"
 293   }
 294 }
 295
 296 sub generate_simple_get {
 297   my ($self, @args) = @_;
 298   $self->_generate_simple_get(@args);
 299 }
 300
 301 sub _generate_simple_get {
 302   my ($self, $me, $name) = @_;
 303   my $name_str = perlstring $name;
 304   "${me}->{${name_str}}";
 305 }
 306
 307 sub _generate_set {
 308   my ($self, $name, $spec) = @_;
 309   if ($self->is_simple_set($name, $spec)) {
 310     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 311   } else {
 312     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 313     my $value_store = '$_[0]';
 314     my $code;
 315     if ($coerce) {
 316       $value_store = '$value';
 317       $code = "do { my (\$self, \$value) = \@_;\n"
 318         ."        \$value = "
 319         .$self->_generate_coerce($name, $value_store, $coerce).";\n";
 320     }
 321     else {
 322       $code = "do { my \$self = shift;\n";
 323     }
 324     if ($isa_check) {
 325       $code .=
 326         "        ".$self->_generate_isa_check($name, $value_store, $isa_check).";\n";
 327     }
 328     my $simple = $self->_generate_simple_set('$self', $name, $spec, $value_store);
 329     if ($trigger) {
 330       my $fire = $self->_generate_trigger($name, '$self', $value_store, $trigger);
 331       $code .=
 332         "        ".$simple.";\n        ".$fire.";\n"
 333         ."        $value_store;\n";
 334     } else {
 335       $code .= "        ".$simple.";\n";
 336     }
 337     $code .= "      }";
 338     $code;
 339   }
 340 }
 341
 342 sub generate_coerce {
 343   my $self = shift;
 344   $self->{captures} = {};
 345   my $code = $self->_generate_coerce(@_);
 346   ($code, delete $self->{captures});
 347 }
 348
 349 sub _attr_desc {
 350   my ($name, $init_arg) = @_;
 351   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 352   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 353 }
 354
 355 sub _generate_coerce {
 356   my ($self, $name, $value, $coerce, $init_arg) = @_;
 357   $self->_generate_die_prefix(
 358     $name,
 359     "coercion",
 360     $init_arg,
 361     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 362   );
 363 }
 364
 365 sub generate_trigger {
 366   my $self = shift;
 367   $self->{captures} = {};
 368   my $code = $self->_generate_trigger(@_);
 369   ($code, delete $self->{captures});
 370 }
 371
 372 sub _generate_trigger {
 373   my ($self, $name, $obj, $value, $trigger) = @_;
 374   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 375 }
 376
 377 sub generate_isa_check {
 378   my ($self, @args) = @_;
 379   $self->{captures} = {};
 380   my $code = $self->_generate_isa_check(@args);
 381   ($code, delete $self->{captures});
 382 }
 383
 384 sub _generate_die_prefix {
 385   my ($self, $name, $prefix, $arg, $inside) = @_;
 386   "do {\n"
 387   .'  local $Method::Generate::Accessor::CurrentAttribute = {'
 388   .'    init_arg => '.(defined $arg ? B::perlstring($arg) : 'undef') . ",\n"
 389   .'    name     => '.B::perlstring($name).",\n"
 390   .'    step     => '.B::perlstring($prefix).",\n"
 391   ."  };\n"
 392   .'  local $Method::Generate::Accessor::OrigSigDie = $SIG{__DIE__};'."\n"
 393   .'  local $SIG{__DIE__} = \&Method::Generate::Accessor::_SIGDIE;'."\n"
 394   .$inside
 395   ."}\n"
 396 }
 397
 398 sub _generate_isa_check {
 399   my ($self, $name, $value, $check, $init_arg) = @_;
 400   $self->_generate_die_prefix(
 401     $name,
 402     "isa check",
 403     $init_arg,
 404     $self->_generate_call_code($name, 'isa_check', $value, $check)
 405   );
 406 }
 407
 408 sub _generate_call_code {
 409   my ($self, $name, $type, $values, $sub) = @_;
 410   $sub = \&{$sub} if blessed($sub);  # coderef if blessed
 411   if (my $quoted = quoted_from_sub($sub)) {
 412     my $local = 1;
 413     if ($values eq '@_' || $values eq '$_[0]') {
 414       $local = 0;
 415       $values = '@_';
 416     }
 417     my $code = $quoted->[1];
 418     if (my $captures = $quoted->[2]) {
 419       my $cap_name = qq{\$${type}_captures_for_${name}};
 420       $self->{captures}->{$cap_name} = \$captures;
 421       Sub::Quote::inlinify(
 422         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), $local
 423       );
 424     } else {
 425       Sub::Quote::inlinify($code, $values, undef, $local);
 426     }
 427   } else {
 428     my $cap_name = qq{\$${type}_for_${name}};
 429     $self->{captures}->{$cap_name} = \$sub;
 430     "${cap_name}->(${values})";
 431   }
 432 }
 433
 434 sub generate_populate_set {
 435   my $self = shift;
 436   $self->{captures} = {};
 437   my $code = $self->_generate_populate_set(@_);
 438   ($code, delete $self->{captures});
 439 }
 440
 441 sub _generate_populate_set {
 442   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 443   if ($self->has_eager_default($name, $spec)) {
 444     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 445     my $get_default = $self->_generate_get_default(
 446                         '$new', $_, $spec
 447                       );
 448     my $get_value =
 449       defined($spec->{init_arg})
 450         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 451             .$get_default
 452             ."\n${get_indent})"
 453         : $get_default;
 454     if ($spec->{coerce}) {
 455       $get_value = $self->_generate_coerce(
 456         $name, $get_value,
 457         $spec->{coerce}, $init_arg
 458       )
 459     }
 460     ($spec->{isa}
 461       ? "    {\n      my \$value = ".$get_value.";\n      "
 462         .$self->_generate_isa_check(
 463           $name, '$value', $spec->{isa}, $init_arg
 464         ).";\n"
 465         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 466         ."    }\n"
 467       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 468     )
 469     .($spec->{trigger}
 470       ? '    '
 471         .$self->_generate_trigger(
 472           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 473           $spec->{trigger}
 474         )." if ${test};\n"
 475       : ''
 476     );
 477   } else {
 478     "    if (${test}) {\n"
 479       .($spec->{coerce}
 480         ? "      $source = "
 481           .$self->_generate_coerce(
 482             $name, $source,
 483             $spec->{coerce}, $init_arg
 484           ).";\n"
 485         : ""
 486       )
 487       .($spec->{isa}
 488         ? "      "
 489           .$self->_generate_isa_check(
 490             $name, $source, $spec->{isa}, $init_arg
 491           ).";\n"
 492         : ""
 493       )
 494       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 495       .($spec->{trigger}
 496         ? "      "
 497           .$self->_generate_trigger(
 498             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 499             $spec->{trigger}
 500           ).";\n"
 501         : ""
 502       )
 503       ."    }\n";
 504   }
 505 }
 506
 507 sub _generate_core_set {
 508   my ($self, $me, $name, $spec, $value) = @_;
 509   my $name_str = perlstring $name;
 510   "${me}->{${name_str}} = ${value}";
 511 }
 512
 513 sub _generate_simple_set {
 514   my ($self, $me, $name, $spec, $value) = @_;
 515   my $name_str = perlstring $name;
 516   my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 517
 518   if ($spec->{weak_ref}) {
 519     require Scalar::Util;
 520     my $get = $self->_generate_simple_get($me, $name, $spec);
 521
 522     # Perl < 5.8.3 can't weaken refs to readonly vars
 523     # (e.g. string constants). This *can* be solved by:
 524     #
 525     #Internals::SetReadWrite($foo);
 526     #Scalar::Util::weaken ($foo);
 527     #Internals::SetReadOnly($foo);
 528     #
 529     # but requires XS and is just too damn crazy
 530     # so simply throw a better exception
 531     my $weak_simple = "do { Scalar::Util::weaken(${simple}); no warnings 'void'; $get }";
 532     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 533       eval { Scalar::Util::weaken($simple); 1 }
 534         ? do { no warnings 'void'; $get }
 535         : do {
 536           if( \$@ =~ /Modification of a read-only value attempted/) {
 537             require Carp;
 538             Carp::croak( sprintf (
 539               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 540               $name_str,
 541             ) );
 542           } else {
 543             die \$@;
 544           }
 545         }
 546 EOC
 547   } else {
 548     $simple;
 549   }
 550 }
 551
 552 sub _generate_getset {
 553   my ($self, $name, $spec) = @_;
 554   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 555     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 556 }
 557
 558 sub _generate_asserter {
 559   my ($self, $name, $spec) = @_;
 560
 561   "do {\n"
 562    ."  my \$val = ".$self->_generate_get($name, $spec).";\n"
 563    ."  unless (".$self->_generate_simple_has('$_[0]', $name, $spec).") {\n"
 564    .qq!    die "Attempted to access '${name}' but it is not set";\n!
 565    ."  }\n"
 566    ."  \$val;\n"
 567    ."}\n";
 568 }
 569 sub _generate_delegation {
 570   my ($self, $asserter, $target, $args) = @_;
 571   my $arg_string = do {
 572     if (@$args) {
 573       # I could, I reckon, linearise out non-refs here using perlstring
 574       # plus something to check for numbers but I'm unsure if it's worth it
 575       $self->{captures}{'@curries'} = $args;
 576       '@curries, @_';
 577     } else {
 578       '@_';
 579     }
 580   };
 581   "shift->${asserter}->${target}(${arg_string});";
 582 }
 583
 584 sub _generate_xs {
 585   my ($self, $type, $into, $name, $slot) = @_;
 586   Class::XSAccessor->import(
 587     class => $into,
 588     $type => { $name => $slot },
 589     replace => 1,
 590   );
 591   $into->can($name);
 592 }
 593
 594 sub default_construction_string { '{}' }
 595
 596 sub _validate_codulatable {
 597   my ($self, $setting, $value, $into, $appended) = @_;
 598   my $invalid = "Invalid $setting '" . overload::StrVal($value)
 599     . "' for $into not a coderef";
 600   $invalid .= " $appended" if $appended;
 601
 602   unless (ref $value and (ref $value eq 'CODE' or blessed($value))) {
 603     die "$invalid or code-convertible object";
 604   }
 605
 606   unless (eval { \&$value }) {
 607     die "$invalid and could not be converted to a coderef: $@";
 608   }
 609
 610   1;
 611 }
 612
 613 1;