lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     !$ENV{MOO_XS_DISABLE}
  11       &&
  12     _maybe_load_module('Class::XSAccessor')
  13       &&
  14     (eval { Class::XSAccessor->VERSION('1.07') })
  15   ;
  16 }
  17
  18 sub generate_method {
  19   my ($self, $into, $name, $spec, $quote_opts) = @_;
  20   $name =~ s/^\+//;
  21   die "Must have an is" unless my $is = $spec->{is};
  22   if ($is eq 'ro') {
  23     $spec->{reader} = $name unless exists $spec->{reader};
  24   } elsif ($is eq 'rw') {
  25     $spec->{accessor} = $name unless exists $spec->{accessor};
  26   } elsif ($is eq 'lazy') {
  27     $spec->{reader} = $name unless exists $spec->{reader};
  28     $spec->{lazy} = 1;
  29     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  30   } elsif ($is eq 'rwp') {
  31     $spec->{reader} = $name unless exists $spec->{reader};
  32     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  33   } elsif ($is ne 'bare') {
  34     die "Unknown is ${is}";
  35   }
  36   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  37   if (($spec->{predicate}||0) eq 1) {
  38     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  39   }
  40   if (($spec->{clearer}||0) eq 1) {
  41     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  42   }
  43   if (($spec->{trigger}||0) eq 1) {
  44     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  45   }
  46   my %methods;
  47   if (my $reader = $spec->{reader}) {
  48     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  49       $methods{$reader} = $self->_generate_xs(
  50         getters => $into, $reader, $name, $spec
  51       );
  52     } else {
  53       $self->{captures} = {};
  54       $methods{$reader} =
  55         quote_sub "${into}::${reader}"
  56           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  57              .$self->_generate_get($name, $spec)
  58           => delete $self->{captures}
  59         ;
  60     }
  61   }
  62   if (my $accessor = $spec->{accessor}) {
  63     if (
  64       our $CAN_HAZ_XS
  65       && $self->is_simple_get($name, $spec)
  66       && $self->is_simple_set($name, $spec)
  67     ) {
  68       $methods{$accessor} = $self->_generate_xs(
  69         accessors => $into, $accessor, $name, $spec
  70       );
  71     } else {
  72       $self->{captures} = {};
  73       $methods{$accessor} =
  74         quote_sub "${into}::${accessor}"
  75           => $self->_generate_getset($name, $spec)
  76           => delete $self->{captures}
  77         ;
  78     }
  79   }
  80   if (my $writer = $spec->{writer}) {
  81     if (
  82       our $CAN_HAZ_XS
  83       && $self->is_simple_set($name, $spec)
  84     ) {
  85       $methods{$writer} = $self->_generate_xs(
  86         setters => $into, $writer, $name, $spec
  87       );
  88     } else {
  89       $self->{captures} = {};
  90       $methods{$writer} =
  91         quote_sub "${into}::${writer}"
  92           => $self->_generate_set($name, $spec)
  93           => delete $self->{captures}
  94         ;
  95     }
  96   }
  97   if (my $pred = $spec->{predicate}) {
  98     $methods{$pred} =
  99       quote_sub "${into}::${pred}" =>
 100         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 101       ;
 102   }
 103   if (my $cl = $spec->{clearer}) {
 104     $methods{$cl} =
 105       quote_sub "${into}::${cl}" =>
 106         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 107       ;
 108   }
 109   if (my $hspec = $spec->{handles}) {
 110     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 111     my @specs = do {
 112       if (ref($hspec) eq 'ARRAY') {
 113         map [ $_ => $_ ], @$hspec;
 114       } elsif (ref($hspec) eq 'HASH') {
 115         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 116           keys %$hspec;
 117       } elsif (!ref($hspec)) {
 118         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 119       } else {
 120         die "You gave me a handles of ${hspec} and I have no idea why";
 121       }
 122     };
 123     foreach my $spec (@specs) {
 124       my ($proxy, $target, @args) = @$spec;
 125       $self->{captures} = {};
 126       $methods{$proxy} =
 127         quote_sub "${into}::${proxy}" =>
 128           $self->_generate_delegation($asserter, $target, \@args),
 129           delete $self->{captures}
 130         ;
 131     }
 132   }
 133   if (my $asserter = $spec->{asserter}) {
 134     $self->{captures} = {};
 135     $methods{$asserter} =
 136       quote_sub "${into}::${asserter}" =>
 137         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 138         delete $self->{captures}
 139       ;
 140   }
 141   \%methods;
 142 }
 143
 144 sub is_simple_attribute {
 145   my ($self, $name, $spec) = @_;
 146   # clearer doesn't have to be listed because it doesn't
 147   # affect whether defined/exists makes a difference
 148   !grep $spec->{$_},
 149     qw(lazy default builder coerce isa trigger predicate weak_ref);
 150 }
 151
 152 sub is_simple_get {
 153   my ($self, $name, $spec) = @_;
 154   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 155 }
 156
 157 sub is_simple_set {
 158   my ($self, $name, $spec) = @_;
 159   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 160 }
 161
 162 sub has_eager_default {
 163   my ($self, $name, $spec) = @_;
 164   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 165 }
 166
 167 sub _generate_get {
 168   my ($self, $name, $spec) = @_;
 169   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 170   if ($self->is_simple_get($name, $spec)) {
 171     $simple;
 172   } else {
 173     'do { '.$self->_generate_use_default(
 174       '$_[0]', $name, $spec,
 175       $self->_generate_simple_has('$_[0]', $name, $spec),
 176     ).'; '.$simple.' }';
 177   }
 178 }
 179
 180 sub _generate_simple_has {
 181   my ($self, $me, $name) = @_;
 182   "exists ${me}->{${\perlstring $name}}";
 183 }
 184
 185 sub _generate_simple_clear {
 186   my ($self, $me, $name) = @_;
 187   "    delete ${me}->{${\perlstring $name}}\n"
 188 }
 189
 190 sub generate_get_default {
 191   my $self = shift;
 192   $self->{captures} = {};
 193   my $code = $self->_generate_get_default(@_);
 194   ($code, delete $self->{captures});
 195 }
 196
 197 sub _generate_use_default {
 198   my ($self, $me, $name, $spec, $test) = @_;
 199   my $get_value = $self->_generate_get_default($me, $name, $spec);
 200   if ($spec->{coerce}) {
 201     $get_value = $self->_generate_coerce(
 202       $name, $get_value,
 203       $spec->{coerce}
 204     )
 205   }
 206   $self->_generate_simple_set(
 207     $me, $name, $spec, $get_value
 208   ).' unless '.$test;
 209 }
 210
 211 sub _generate_get_default {
 212   my ($self, $me, $name, $spec) = @_;
 213   $spec->{default}
 214     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 215     : "${me}->${\$spec->{builder}}"
 216 }
 217
 218 sub generate_simple_get {
 219   my ($self, @args) = @_;
 220   $self->_generate_simple_get(@args);
 221 }
 222
 223 sub _generate_simple_get {
 224   my ($self, $me, $name) = @_;
 225   my $name_str = perlstring $name;
 226   "${me}->{${name_str}}";
 227 }
 228
 229 sub _generate_set {
 230   my ($self, $name, $spec) = @_;
 231   if ($self->is_simple_set($name, $spec)) {
 232     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 233   } else {
 234     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 235     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 236     my $code = "do { my (\$self, \$value) = \@_;\n";
 237     if ($coerce) {
 238       $code .=
 239         "        \$value = "
 240         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 241     }
 242     if ($isa_check) {
 243       $code .=
 244         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 245     }
 246     if ($trigger) {
 247       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 248       $code .=
 249         "        ".$simple.";\n        ".$fire.";\n"
 250         ."        \$value;\n";
 251     } else {
 252       $code .= "        ".$simple.";\n";
 253     }
 254     $code .= "      }";
 255     $code;
 256   }
 257 }
 258
 259 sub generate_coerce {
 260   my $self = shift;
 261   $self->{captures} = {};
 262   my $code = $self->_generate_coerce(@_);
 263   ($code, delete $self->{captures});
 264 }
 265
 266 sub _generate_coerce {
 267   my ($self, $name, $value, $coerce) = @_;
 268   $self->_generate_call_code($name, 'coerce', "${value}", $coerce);
 269 }
 270
 271 sub generate_trigger {
 272   my $self = shift;
 273   $self->{captures} = {};
 274   my $code = $self->_generate_trigger(@_);
 275   ($code, delete $self->{captures});
 276 }
 277
 278 sub _generate_trigger {
 279   my ($self, $name, $obj, $value, $trigger) = @_;
 280   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 281 }
 282
 283 sub generate_isa_check {
 284   my ($self, @args) = @_;
 285   $self->{captures} = {};
 286   my $code = $self->_generate_isa_check(@args);
 287   ($code, delete $self->{captures});
 288 }
 289
 290 sub _generate_isa_check {
 291   my ($self, $name, $value, $check) = @_;
 292   $self->_generate_call_code($name, 'isa_check', $value, $check);
 293 }
 294
 295 sub _generate_call_code {
 296   my ($self, $name, $type, $values, $sub) = @_;
 297   if (my $quoted = quoted_from_sub($sub)) {
 298     my $code = $quoted->[1];
 299     my $at_ = '@_ = ('.$values.');';
 300     if (my $captures = $quoted->[2]) {
 301       my $cap_name = qq{\$${type}_captures_for_${name}};
 302       $self->{captures}->{$cap_name} = \$captures;
 303       Sub::Quote::inlinify(
 304         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 305       );
 306     } else {
 307       Sub::Quote::inlinify($code, $values);
 308     }
 309   } else {
 310     my $cap_name = qq{\$${type}_for_${name}};
 311     $self->{captures}->{$cap_name} = \$sub;
 312     "${cap_name}->(${values})";
 313   }
 314 }
 315
 316 sub generate_populate_set {
 317   my $self = shift;
 318   $self->{captures} = {};
 319   my $code = $self->_generate_populate_set(@_);
 320   ($code, delete $self->{captures});
 321 }
 322
 323 sub _generate_populate_set {
 324   my ($self, $me, $name, $spec, $source, $test) = @_;
 325   if ($self->has_eager_default($name, $spec)) {
 326     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 327     my $get_default = $self->_generate_get_default(
 328                         '$new', $_, $spec
 329                       );
 330     my $get_value =
 331       defined($spec->{init_arg})
 332         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 333             .$get_default
 334             ."\n${get_indent})"
 335         : $get_default;
 336     if ($spec->{coerce}) {
 337       $get_value = $self->_generate_coerce(
 338         $name, $get_value,
 339         $spec->{coerce}
 340       )
 341     }
 342     ($spec->{isa}
 343       ? "    {\n      my \$value = ".$get_value.";\n      "
 344         .$self->_generate_isa_check(
 345           $name, '$value', $spec->{isa}
 346         ).";\n"
 347         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 348         ."    }\n"
 349       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 350     )
 351     .($spec->{trigger}
 352       ? '    '
 353         .$self->_generate_trigger(
 354           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 355           $spec->{trigger}
 356         )." if ${test};\n"
 357       : ''
 358     );
 359   } else {
 360     "    if (${test}) {\n"
 361       .($spec->{coerce}
 362         ? "      $source = "
 363           .$self->_generate_coerce(
 364             $name, $source,
 365             $spec->{coerce}
 366           ).";\n"
 367         : ""
 368       )
 369       .($spec->{isa}
 370         ? "      "
 371           .$self->_generate_isa_check(
 372             $name, $source, $spec->{isa}
 373           ).";\n"
 374         : ""
 375       )
 376       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 377       .($spec->{trigger}
 378         ? "      "
 379           .$self->_generate_trigger(
 380             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 381             $spec->{trigger}
 382           ).";\n"
 383         : ""
 384       )
 385       ."    }\n";
 386   }
 387 }
 388
 389 sub generate_multi_set {
 390   my ($self, $me, $to_set, $from) = @_;
 391   "\@{${me}}{qw(${\join ' ', @$to_set})} = $from";
 392 }
 393
 394 sub _generate_core_set {
 395   my ($self, $me, $name, $spec, $value) = @_;
 396   my $name_str = perlstring $name;
 397   "${me}->{${name_str}} = ${value}";
 398 }
 399
 400 sub _generate_simple_set {
 401   my ($self, $me, $name, $spec, $value) = @_;
 402   my $name_str = perlstring $name;
 403
 404   if ($spec->{weak_ref}) {
 405     $value = '$preserve = '.$value;
 406     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 407     require Scalar::Util;
 408
 409     # Perl < 5.8.3 can't weaken refs to readonly vars
 410     # (e.g. string constants). This *can* be solved by:
 411     #
 412     #Internals::SetReadWrite($foo);
 413     #Scalar::Util::weaken ($foo);
 414     #Internals::SetReadOnly($foo);
 415     #
 416     # but requires XS and is just too damn crazy
 417     # so simply throw a better exception
 418     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple})";
 419     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 420
 421       my \$preserve;
 422       eval { Scalar::Util::weaken($simple); 1 } or do {
 423         if( \$@ =~ /Modification of a read-only value attempted/) {
 424           require Carp;
 425           Carp::croak( sprintf (
 426             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 427             $name_str,
 428           ) );
 429         } else {
 430           die \$@;
 431         }
 432       };
 433 EOC
 434   } else {
 435     $self->_generate_core_set($me, $name, $spec, $value);
 436   }
 437 }
 438
 439 sub _generate_getset {
 440   my ($self, $name, $spec) = @_;
 441   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 442     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 443 }
 444
 445 sub _generate_delegation {
 446   my ($self, $asserter, $target, $args) = @_;
 447   my $arg_string = do {
 448     if (@$args) {
 449       # I could, I reckon, linearise out non-refs here using perlstring
 450       # plus something to check for numbers but I'm unsure if it's worth it
 451       $self->{captures}{'@curries'} = $args;
 452       '@curries, @_';
 453     } else {
 454       '@_';
 455     }
 456   };
 457   "shift->${asserter}->${target}(${arg_string});";
 458 }
 459
 460 sub _generate_xs {
 461   my ($self, $type, $into, $name, $slot) = @_;
 462   Class::XSAccessor->import(
 463     class => $into,
 464     $type => { $name => $slot },
 465     replace => 1,
 466   );
 467   $into->can($name);
 468 }
 469
 470 sub default_construction_string { '{}' }
 471
 472 1;