lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 use Module::Runtime qw(use_module);
  11 BEGIN {
  12   our $CAN_HAZ_XS =
  13     !$ENV{MOO_XS_DISABLE}
  14       &&
  15     _maybe_load_module('Class::XSAccessor')
  16       &&
  17     (eval { Class::XSAccessor->VERSION('1.07') })
  18   ;
  19 }
  20
  21 sub _SIGDIE
  22 {
  23   our ($CurrentAttribute, $OrigSigDie);
  24   $OrigSigDie ||= sub { die $_[0] };
  25
  26   return $OrigSigDie->(@_) if ref($_[0]);
  27
  28   my $attr_desc = _attr_desc(@$CurrentAttribute{qw(name init_arg)});
  29   $OrigSigDie->("$CurrentAttribute->{step} for $attr_desc failed: $_[0]");
  30 }
  31
  32 sub _die_overwrite
  33 {
  34   my ($pkg, $method, $type) = @_;
  35   die "You cannot overwrite a locally defined method ($method) with @{[ $type || 'an accessor' ]}";
  36 }
  37
  38 sub generate_method {
  39   my ($self, $into, $name, $spec, $quote_opts) = @_;
  40   $spec->{allow_overwrite}++ if $name =~ s/^\+//;
  41   die "Must have an is" unless my $is = $spec->{is};
  42   if ($is eq 'ro') {
  43     $spec->{reader} = $name unless exists $spec->{reader};
  44   } elsif ($is eq 'rw') {
  45     $spec->{accessor} = $name unless exists $spec->{accessor}
  46       or ( $spec->{reader} and $spec->{writer} );
  47   } elsif ($is eq 'lazy') {
  48     $spec->{reader} = $name unless exists $spec->{reader};
  49     $spec->{lazy} = 1;
  50     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  51   } elsif ($is eq 'rwp') {
  52     $spec->{reader} = $name unless exists $spec->{reader};
  53     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  54   } elsif ($is ne 'bare') {
  55     die "Unknown is ${is}";
  56   }
  57   if (exists $spec->{builder}) {
  58     if(ref $spec->{builder}) {
  59       $self->_validate_codulatable('builder', $spec->{builder},
  60         "$into->$name", 'or a method name');
  61       $spec->{builder_sub} = $spec->{builder};
  62       $spec->{builder} = 1;
  63     }
  64     $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  65     die "Invalid builder for $into->$name - not a valid method name"
  66       if $spec->{builder} !~ /\A[A-Za-z_][A-Za-z0-9_]*(?:::[A-Za-z_][A-Za-z0-9_]*)*\z/;
  67   }
  68   if (($spec->{predicate}||0) eq 1) {
  69     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  70   }
  71   if (($spec->{clearer}||0) eq 1) {
  72     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  73   }
  74   if (($spec->{trigger}||0) eq 1) {
  75     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  76   }
  77
  78   for my $setting (qw( isa coerce )) {
  79     next if !exists $spec->{$setting};
  80     $self->_validate_codulatable($setting, $spec->{$setting}, "$into->$name");
  81   }
  82
  83   if (exists $spec->{default}) {
  84     if (!defined $spec->{default} || ref $spec->{default}) {
  85       $self->_validate_codulatable('default', $spec->{default}, "$into->$name", 'or a non-ref');
  86     }
  87   }
  88
  89   if (exists $spec->{moosify}) {
  90     if (ref $spec->{moosify} ne 'ARRAY') {
  91       $spec->{moosify} = [$spec->{moosify}];
  92     }
  93
  94     for my $spec (@{$spec->{moosify}}) {
  95       $self->_validate_codulatable('moosify', $spec, "$into->$name");
  96     }
  97   }
  98
  99   my %methods;
 100   if (my $reader = $spec->{reader}) {
 101     _die_overwrite($into, $reader, 'a reader')
 102       if !$spec->{allow_overwrite} && *{_getglob("${into}::${reader}")}{CODE};
 103     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
 104       $methods{$reader} = $self->_generate_xs(
 105         getters => $into, $reader, $name, $spec
 106       );
 107     } else {
 108       $self->{captures} = {};
 109       $methods{$reader} =
 110         quote_sub "${into}::${reader}"
 111           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
 112              .$self->_generate_get($name, $spec)
 113           => delete $self->{captures}
 114         ;
 115     }
 116   }
 117   if (my $accessor = $spec->{accessor}) {
 118     _die_overwrite($into, $accessor, 'an accessor')
 119       if !$spec->{allow_overwrite} && *{_getglob("${into}::${accessor}")}{CODE};
 120     if (
 121       our $CAN_HAZ_XS
 122       && $self->is_simple_get($name, $spec)
 123       && $self->is_simple_set($name, $spec)
 124     ) {
 125       $methods{$accessor} = $self->_generate_xs(
 126         accessors => $into, $accessor, $name, $spec
 127       );
 128     } else {
 129       $self->{captures} = {};
 130       $methods{$accessor} =
 131         quote_sub "${into}::${accessor}"
 132           => $self->_generate_getset($name, $spec)
 133           => delete $self->{captures}
 134         ;
 135     }
 136   }
 137   if (my $writer = $spec->{writer}) {
 138     _die_overwrite($into, $writer, 'a writer')
 139       if !$spec->{allow_overwrite} && *{_getglob("${into}::${writer}")}{CODE};
 140     if (
 141       our $CAN_HAZ_XS
 142       && $self->is_simple_set($name, $spec)
 143     ) {
 144       $methods{$writer} = $self->_generate_xs(
 145         setters => $into, $writer, $name, $spec
 146       );
 147     } else {
 148       $self->{captures} = {};
 149       $methods{$writer} =
 150         quote_sub "${into}::${writer}"
 151           => $self->_generate_set($name, $spec)
 152           => delete $self->{captures}
 153         ;
 154     }
 155   }
 156   if (my $pred = $spec->{predicate}) {
 157     _die_overwrite($into, $pred, 'a predicate')
 158       if !$spec->{allow_overwrite} && *{_getglob("${into}::${pred}")}{CODE};
 159     $methods{$pred} =
 160       quote_sub "${into}::${pred}" =>
 161         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 162       ;
 163   }
 164   if (my $pred = $spec->{builder_sub}) {
 165     _install_coderef( "${into}::$spec->{builder}" => $spec->{builder_sub} );
 166   }
 167   if (my $cl = $spec->{clearer}) {
 168     _die_overwrite($into, $cl, 'a clearer')
 169       if !$spec->{allow_overwrite} && *{_getglob("${into}::${cl}")}{CODE};
 170     $methods{$cl} =
 171       quote_sub "${into}::${cl}" =>
 172         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 173       ;
 174   }
 175   if (my $hspec = $spec->{handles}) {
 176     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 177     my @specs = do {
 178       if (ref($hspec) eq 'ARRAY') {
 179         map [ $_ => $_ ], @$hspec;
 180       } elsif (ref($hspec) eq 'HASH') {
 181         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 182           keys %$hspec;
 183       } elsif (!ref($hspec)) {
 184         map [ $_ => $_ ], use_module('Role::Tiny')->methods_provided_by(use_module($hspec))
 185       } else {
 186         die "You gave me a handles of ${hspec} and I have no idea why";
 187       }
 188     };
 189     foreach my $delegation_spec (@specs) {
 190       my ($proxy, $target, @args) = @$delegation_spec;
 191       _die_overwrite($into, $proxy, 'a delegation')
 192         if !$spec->{allow_overwrite} && *{_getglob("${into}::${proxy}")}{CODE};
 193       $self->{captures} = {};
 194       $methods{$proxy} =
 195         quote_sub "${into}::${proxy}" =>
 196           $self->_generate_delegation($asserter, $target, \@args),
 197           delete $self->{captures}
 198         ;
 199     }
 200   }
 201   if (my $asserter = $spec->{asserter}) {
 202     $self->{captures} = {};
 203
 204
 205     $methods{$asserter} =
 206       quote_sub "${into}::${asserter}" => $self->_generate_asserter($name, $spec),
 207         delete $self->{captures}
 208       ;
 209   }
 210   \%methods;
 211 }
 212
 213 sub is_simple_attribute {
 214   my ($self, $name, $spec) = @_;
 215   # clearer doesn't have to be listed because it doesn't
 216   # affect whether defined/exists makes a difference
 217   !grep $spec->{$_},
 218     qw(lazy default builder coerce isa trigger predicate weak_ref);
 219 }
 220
 221 sub is_simple_get {
 222   my ($self, $name, $spec) = @_;
 223   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 224 }
 225
 226 sub is_simple_set {
 227   my ($self, $name, $spec) = @_;
 228   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 229 }
 230
 231 sub has_eager_default {
 232   my ($self, $name, $spec) = @_;
 233   (!$spec->{lazy} and (exists $spec->{default} or $spec->{builder}));
 234 }
 235
 236 sub _generate_get {
 237   my ($self, $name, $spec) = @_;
 238   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 239   if ($self->is_simple_get($name, $spec)) {
 240     $simple;
 241   } else {
 242     $self->_generate_use_default(
 243       '$_[0]', $name, $spec,
 244       $self->_generate_simple_has('$_[0]', $name, $spec),
 245     );
 246   }
 247 }
 248
 249 sub generate_simple_has {
 250   my $self = shift;
 251   $self->{captures} = {};
 252   my $code = $self->_generate_simple_has(@_);
 253   ($code, delete $self->{captures});
 254 }
 255
 256 sub _generate_simple_has {
 257   my ($self, $me, $name) = @_;
 258   "exists ${me}->{${\perlstring $name}}";
 259 }
 260
 261 sub _generate_simple_clear {
 262   my ($self, $me, $name) = @_;
 263   "    delete ${me}->{${\perlstring $name}}\n"
 264 }
 265
 266 sub generate_get_default {
 267   my $self = shift;
 268   $self->{captures} = {};
 269   my $code = $self->_generate_get_default(@_);
 270   ($code, delete $self->{captures});
 271 }
 272
 273 sub generate_use_default {
 274   my $self = shift;
 275   $self->{captures} = {};
 276   my $code = $self->_generate_use_default(@_);
 277   ($code, delete $self->{captures});
 278 }
 279
 280 sub _generate_use_default {
 281   my ($self, $me, $name, $spec, $test) = @_;
 282   my $get_value = $self->_generate_get_default($me, $name, $spec);
 283   if ($spec->{coerce}) {
 284     $get_value = $self->_generate_coerce(
 285       $name, $get_value,
 286       $spec->{coerce}
 287     )
 288   }
 289   $test." ? \n"
 290   .$self->_generate_simple_get($me, $name, $spec)."\n:"
 291   .($spec->{isa}
 292     ? "    do {\n      my \$value = ".$get_value.";\n"
 293       ."      ".$self->_generate_isa_check($name, '$value', $spec->{isa}).";\n"
 294       ."      ".$self->_generate_simple_set($me, $name, $spec, '$value')."\n"
 295       ."    }\n"
 296     : '    ('.$self->_generate_simple_set($me, $name, $spec, $get_value).")\n");
 297 }
 298
 299 sub _generate_get_default {
 300   my ($self, $me, $name, $spec) = @_;
 301   if (exists $spec->{default}) {
 302     ref $spec->{default}
 303       ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 304       : perlstring $spec->{default};
 305   }
 306   else {
 307     "${me}->${\$spec->{builder}}"
 308   }
 309 }
 310
 311 sub generate_simple_get {
 312   my ($self, @args) = @_;
 313   $self->_generate_simple_get(@args);
 314 }
 315
 316 sub _generate_simple_get {
 317   my ($self, $me, $name) = @_;
 318   my $name_str = perlstring $name;
 319   "${me}->{${name_str}}";
 320 }
 321
 322 sub _generate_set {
 323   my ($self, $name, $spec) = @_;
 324   if ($self->is_simple_set($name, $spec)) {
 325     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 326   } else {
 327     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 328     my $value_store = '$_[0]';
 329     my $code;
 330     if ($coerce) {
 331       $value_store = '$value';
 332       $code = "do { my (\$self, \$value) = \@_;\n"
 333         ."        \$value = "
 334         .$self->_generate_coerce($name, $value_store, $coerce).";\n";
 335     }
 336     else {
 337       $code = "do { my \$self = shift;\n";
 338     }
 339     if ($isa_check) {
 340       $code .=
 341         "        ".$self->_generate_isa_check($name, $value_store, $isa_check).";\n";
 342     }
 343     my $simple = $self->_generate_simple_set('$self', $name, $spec, $value_store);
 344     if ($trigger) {
 345       my $fire = $self->_generate_trigger($name, '$self', $value_store, $trigger);
 346       $code .=
 347         "        ".$simple.";\n        ".$fire.";\n"
 348         ."        $value_store;\n";
 349     } else {
 350       $code .= "        ".$simple.";\n";
 351     }
 352     $code .= "      }";
 353     $code;
 354   }
 355 }
 356
 357 sub generate_coerce {
 358   my $self = shift;
 359   $self->{captures} = {};
 360   my $code = $self->_generate_coerce(@_);
 361   ($code, delete $self->{captures});
 362 }
 363
 364 sub _attr_desc {
 365   my ($name, $init_arg) = @_;
 366   return perlstring($name) if !defined($init_arg) or $init_arg eq $name;
 367   return perlstring($name).' (constructor argument: '.perlstring($init_arg).')';
 368 }
 369
 370 sub _generate_coerce {
 371   my ($self, $name, $value, $coerce, $init_arg) = @_;
 372   $self->_generate_die_prefix(
 373     $name,
 374     "coercion",
 375     $init_arg,
 376     $self->_generate_call_code($name, 'coerce', "${value}", $coerce)
 377   );
 378 }
 379
 380 sub generate_trigger {
 381   my $self = shift;
 382   $self->{captures} = {};
 383   my $code = $self->_generate_trigger(@_);
 384   ($code, delete $self->{captures});
 385 }
 386
 387 sub _generate_trigger {
 388   my ($self, $name, $obj, $value, $trigger) = @_;
 389   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 390 }
 391
 392 sub generate_isa_check {
 393   my ($self, @args) = @_;
 394   $self->{captures} = {};
 395   my $code = $self->_generate_isa_check(@args);
 396   ($code, delete $self->{captures});
 397 }
 398
 399 sub _generate_die_prefix {
 400   my ($self, $name, $prefix, $arg, $inside) = @_;
 401   "do {\n"
 402   .'  local $Method::Generate::Accessor::CurrentAttribute = {'
 403   .'    init_arg => '.(defined $arg ? B::perlstring($arg) : 'undef') . ",\n"
 404   .'    name     => '.B::perlstring($name).",\n"
 405   .'    step     => '.B::perlstring($prefix).",\n"
 406   ."  };\n"
 407   .'  local $Method::Generate::Accessor::OrigSigDie = $SIG{__DIE__};'."\n"
 408   .'  local $SIG{__DIE__} = \&Method::Generate::Accessor::_SIGDIE;'."\n"
 409   .$inside
 410   ."}\n"
 411 }
 412
 413 sub _generate_isa_check {
 414   my ($self, $name, $value, $check, $init_arg) = @_;
 415   $self->_generate_die_prefix(
 416     $name,
 417     "isa check",
 418     $init_arg,
 419     $self->_generate_call_code($name, 'isa_check', $value, $check)
 420   );
 421 }
 422
 423 sub _generate_call_code {
 424   my ($self, $name, $type, $values, $sub) = @_;
 425   $sub = \&{$sub} if blessed($sub);  # coderef if blessed
 426   if (my $quoted = quoted_from_sub($sub)) {
 427     my $local = 1;
 428     if ($values eq '@_' || $values eq '$_[0]') {
 429       $local = 0;
 430       $values = '@_';
 431     }
 432     my $code = $quoted->[1];
 433     if (my $captures = $quoted->[2]) {
 434       my $cap_name = qq{\$${type}_captures_for_${name}};
 435       $self->{captures}->{$cap_name} = \$captures;
 436       Sub::Quote::inlinify(
 437         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6), $local
 438       );
 439     } else {
 440       Sub::Quote::inlinify($code, $values, undef, $local);
 441     }
 442   } else {
 443     my $cap_name = qq{\$${type}_for_${name}};
 444     $self->{captures}->{$cap_name} = \$sub;
 445     "${cap_name}->(${values})";
 446   }
 447 }
 448
 449 sub generate_populate_set {
 450   my $self = shift;
 451   $self->{captures} = {};
 452   my $code = $self->_generate_populate_set(@_);
 453   ($code, delete $self->{captures});
 454 }
 455
 456 sub _generate_populate_set {
 457   my ($self, $me, $name, $spec, $source, $test, $init_arg) = @_;
 458   if ($self->has_eager_default($name, $spec)) {
 459     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 460     my $get_default = $self->_generate_get_default(
 461                         '$new', $_, $spec
 462                       );
 463     my $get_value =
 464       defined($spec->{init_arg})
 465         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 466             .$get_default
 467             ."\n${get_indent})"
 468         : $get_default;
 469     if ($spec->{coerce}) {
 470       $get_value = $self->_generate_coerce(
 471         $name, $get_value,
 472         $spec->{coerce}, $init_arg
 473       )
 474     }
 475     ($spec->{isa}
 476       ? "    {\n      my \$value = ".$get_value.";\n      "
 477         .$self->_generate_isa_check(
 478           $name, '$value', $spec->{isa}, $init_arg
 479         ).";\n"
 480         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 481         ."    }\n"
 482       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 483     )
 484     .($spec->{trigger}
 485       ? '    '
 486         .$self->_generate_trigger(
 487           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 488           $spec->{trigger}
 489         )." if ${test};\n"
 490       : ''
 491     );
 492   } else {
 493     "    if (${test}) {\n"
 494       .($spec->{coerce}
 495         ? "      $source = "
 496           .$self->_generate_coerce(
 497             $name, $source,
 498             $spec->{coerce}, $init_arg
 499           ).";\n"
 500         : ""
 501       )
 502       .($spec->{isa}
 503         ? "      "
 504           .$self->_generate_isa_check(
 505             $name, $source, $spec->{isa}, $init_arg
 506           ).";\n"
 507         : ""
 508       )
 509       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 510       .($spec->{trigger}
 511         ? "      "
 512           .$self->_generate_trigger(
 513             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 514             $spec->{trigger}
 515           ).";\n"
 516         : ""
 517       )
 518       ."    }\n";
 519   }
 520 }
 521
 522 sub _generate_core_set {
 523   my ($self, $me, $name, $spec, $value) = @_;
 524   my $name_str = perlstring $name;
 525   "${me}->{${name_str}} = ${value}";
 526 }
 527
 528 sub _generate_simple_set {
 529   my ($self, $me, $name, $spec, $value) = @_;
 530   my $name_str = perlstring $name;
 531   my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 532
 533   if ($spec->{weak_ref}) {
 534     require Scalar::Util;
 535     my $get = $self->_generate_simple_get($me, $name, $spec);
 536
 537     # Perl < 5.8.3 can't weaken refs to readonly vars
 538     # (e.g. string constants). This *can* be solved by:
 539     #
 540     #Internals::SetReadWrite($foo);
 541     #Scalar::Util::weaken ($foo);
 542     #Internals::SetReadOnly($foo);
 543     #
 544     # but requires XS and is just too damn crazy
 545     # so simply throw a better exception
 546     my $weak_simple = "do { Scalar::Util::weaken(${simple}); no warnings 'void'; $get }";
 547     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 548       eval { Scalar::Util::weaken($simple); 1 }
 549         ? do { no warnings 'void'; $get }
 550         : do {
 551           if( \$@ =~ /Modification of a read-only value attempted/) {
 552             require Carp;
 553             Carp::croak( sprintf (
 554               'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 555               $name_str,
 556             ) );
 557           } else {
 558             die \$@;
 559           }
 560         }
 561 EOC
 562   } else {
 563     $simple;
 564   }
 565 }
 566
 567 sub _generate_getset {
 568   my ($self, $name, $spec) = @_;
 569   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 570     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 571 }
 572
 573 sub _generate_asserter {
 574   my ($self, $name, $spec) = @_;
 575
 576   "do {\n"
 577    ."  my \$val = ".$self->_generate_get($name, $spec).";\n"
 578    ."  unless (".$self->_generate_simple_has('$_[0]', $name, $spec).") {\n"
 579    .qq!    die "Attempted to access '${name}' but it is not set";\n!
 580    ."  }\n"
 581    ."  \$val;\n"
 582    ."}\n";
 583 }
 584 sub _generate_delegation {
 585   my ($self, $asserter, $target, $args) = @_;
 586   my $arg_string = do {
 587     if (@$args) {
 588       # I could, I reckon, linearise out non-refs here using perlstring
 589       # plus something to check for numbers but I'm unsure if it's worth it
 590       $self->{captures}{'@curries'} = $args;
 591       '@curries, @_';
 592     } else {
 593       '@_';
 594     }
 595   };
 596   "shift->${asserter}->${target}(${arg_string});";
 597 }
 598
 599 sub _generate_xs {
 600   my ($self, $type, $into, $name, $slot) = @_;
 601   Class::XSAccessor->import(
 602     class => $into,
 603     $type => { $name => $slot },
 604     replace => 1,
 605   );
 606   $into->can($name);
 607 }
 608
 609 sub default_construction_string { '{}' }
 610
 611 sub _validate_codulatable {
 612   my ($self, $setting, $value, $into, $appended) = @_;
 613   my $invalid = "Invalid $setting '" . overload::StrVal($value)
 614     . "' for $into not a coderef";
 615   $invalid .= " $appended" if $appended;
 616
 617   unless (ref $value and (ref $value eq 'CODE' or blessed($value))) {
 618     die "$invalid or code-convertible object";
 619   }
 620
 621   unless (eval { \&$value }) {
 622     die "$invalid and could not be converted to a coderef: $@";
 623   }
 624
 625   1;
 626 }
 627
 628 1;