lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 use Scalar::Util 'blessed';
   9 use overload ();
  10 BEGIN {
  11   our $CAN_HAZ_XS =
  12     !$ENV{MOO_XS_DISABLE}
  13       &&
  14     _maybe_load_module('Class::XSAccessor')
  15       &&
  16     (eval { Class::XSAccessor->VERSION('1.07') })
  17   ;
  18 }
  19
  20 sub generate_method {
  21   my ($self, $into, $name, $spec, $quote_opts) = @_;
  22   $name =~ s/^\+//;
  23   die "Must have an is" unless my $is = $spec->{is};
  24   if ($is eq 'ro') {
  25     $spec->{reader} = $name unless exists $spec->{reader};
  26   } elsif ($is eq 'rw') {
  27     $spec->{accessor} = $name unless exists $spec->{accessor};
  28   } elsif ($is eq 'lazy') {
  29     $spec->{reader} = $name unless exists $spec->{reader};
  30     $spec->{lazy} = 1;
  31     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  32   } elsif ($is eq 'rwp') {
  33     $spec->{reader} = $name unless exists $spec->{reader};
  34     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  35   } elsif ($is ne 'bare') {
  36     die "Unknown is ${is}";
  37   }
  38   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  39   if (($spec->{predicate}||0) eq 1) {
  40     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  41   }
  42   if (($spec->{clearer}||0) eq 1) {
  43     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  44   }
  45   if (($spec->{trigger}||0) eq 1) {
  46     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  47   }
  48
  49   for my $setting (qw( default coerce )) {
  50     next if !exists $spec->{$setting};
  51     my $value = $spec->{$setting};
  52     my $invalid = "Invalid $setting '" . overload::StrVal($value)
  53       . "' for $into->$name - not a coderef";
  54     die "$invalid or code-convertible object"
  55       unless ref $value and (ref $value eq 'CODE' or blessed($value));
  56     die "$invalid and could not be converted to a coderef: $@"
  57       if !eval { \&$value };
  58   }
  59
  60   my %methods;
  61   if (my $reader = $spec->{reader}) {
  62     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  63       $methods{$reader} = $self->_generate_xs(
  64         getters => $into, $reader, $name, $spec
  65       );
  66     } else {
  67       $self->{captures} = {};
  68       $methods{$reader} =
  69         quote_sub "${into}::${reader}"
  70           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  71              .$self->_generate_get($name, $spec)
  72           => delete $self->{captures}
  73         ;
  74     }
  75   }
  76   if (my $accessor = $spec->{accessor}) {
  77     if (
  78       our $CAN_HAZ_XS
  79       && $self->is_simple_get($name, $spec)
  80       && $self->is_simple_set($name, $spec)
  81     ) {
  82       $methods{$accessor} = $self->_generate_xs(
  83         accessors => $into, $accessor, $name, $spec
  84       );
  85     } else {
  86       $self->{captures} = {};
  87       $methods{$accessor} =
  88         quote_sub "${into}::${accessor}"
  89           => $self->_generate_getset($name, $spec)
  90           => delete $self->{captures}
  91         ;
  92     }
  93   }
  94   if (my $writer = $spec->{writer}) {
  95     if (
  96       our $CAN_HAZ_XS
  97       && $self->is_simple_set($name, $spec)
  98     ) {
  99       $methods{$writer} = $self->_generate_xs(
 100         setters => $into, $writer, $name, $spec
 101       );
 102     } else {
 103       $self->{captures} = {};
 104       $methods{$writer} =
 105         quote_sub "${into}::${writer}"
 106           => $self->_generate_set($name, $spec)
 107           => delete $self->{captures}
 108         ;
 109     }
 110   }
 111   if (my $pred = $spec->{predicate}) {
 112     $methods{$pred} =
 113       quote_sub "${into}::${pred}" =>
 114         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 115       ;
 116   }
 117   if (my $cl = $spec->{clearer}) {
 118     $methods{$cl} =
 119       quote_sub "${into}::${cl}" =>
 120         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 121       ;
 122   }
 123   if (my $hspec = $spec->{handles}) {
 124     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 125     my @specs = do {
 126       if (ref($hspec) eq 'ARRAY') {
 127         map [ $_ => $_ ], @$hspec;
 128       } elsif (ref($hspec) eq 'HASH') {
 129         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 130           keys %$hspec;
 131       } elsif (!ref($hspec)) {
 132         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 133       } else {
 134         die "You gave me a handles of ${hspec} and I have no idea why";
 135       }
 136     };
 137     foreach my $spec (@specs) {
 138       my ($proxy, $target, @args) = @$spec;
 139       $self->{captures} = {};
 140       $methods{$proxy} =
 141         quote_sub "${into}::${proxy}" =>
 142           $self->_generate_delegation($asserter, $target, \@args),
 143           delete $self->{captures}
 144         ;
 145     }
 146   }
 147   if (my $asserter = $spec->{asserter}) {
 148     $self->{captures} = {};
 149     $methods{$asserter} =
 150       quote_sub "${into}::${asserter}" =>
 151         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 152         delete $self->{captures}
 153       ;
 154   }
 155   \%methods;
 156 }
 157
 158 sub is_simple_attribute {
 159   my ($self, $name, $spec) = @_;
 160   # clearer doesn't have to be listed because it doesn't
 161   # affect whether defined/exists makes a difference
 162   !grep $spec->{$_},
 163     qw(lazy default builder coerce isa trigger predicate weak_ref);
 164 }
 165
 166 sub is_simple_get {
 167   my ($self, $name, $spec) = @_;
 168   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 169 }
 170
 171 sub is_simple_set {
 172   my ($self, $name, $spec) = @_;
 173   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 174 }
 175
 176 sub has_eager_default {
 177   my ($self, $name, $spec) = @_;
 178   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 179 }
 180
 181 sub _generate_get {
 182   my ($self, $name, $spec) = @_;
 183   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 184   if ($self->is_simple_get($name, $spec)) {
 185     $simple;
 186   } else {
 187     'do { '.$self->_generate_use_default(
 188       '$_[0]', $name, $spec,
 189       $self->_generate_simple_has('$_[0]', $name, $spec),
 190     ).'; '
 191     .($spec->{isa}
 192       ?($self->_generate_isa_check($name, $simple, $spec->{isa}).'; ')
 193       :''
 194     )
 195     .$simple.' }';
 196   }
 197 }
 198
 199 sub _generate_simple_has {
 200   my ($self, $me, $name) = @_;
 201   "exists ${me}->{${\perlstring $name}}";
 202 }
 203
 204 sub _generate_simple_clear {
 205   my ($self, $me, $name) = @_;
 206   "    delete ${me}->{${\perlstring $name}}\n"
 207 }
 208
 209 sub generate_get_default {
 210   my $self = shift;
 211   $self->{captures} = {};
 212   my $code = $self->_generate_get_default(@_);
 213   ($code, delete $self->{captures});
 214 }
 215
 216 sub _generate_use_default {
 217   my ($self, $me, $name, $spec, $test) = @_;
 218   my $get_value = $self->_generate_get_default($me, $name, $spec);
 219   if ($spec->{coerce}) {
 220     $get_value = $self->_generate_coerce(
 221       $name, $get_value,
 222       $spec->{coerce}
 223     )
 224   }
 225   $self->_generate_simple_set(
 226     $me, $name, $spec, $get_value
 227   ).' unless '.$test;
 228 }
 229
 230 sub _generate_get_default {
 231   my ($self, $me, $name, $spec) = @_;
 232   $spec->{default}
 233     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 234     : "${me}->${\$spec->{builder}}"
 235 }
 236
 237 sub generate_simple_get {
 238   my ($self, @args) = @_;
 239   $self->_generate_simple_get(@args);
 240 }
 241
 242 sub _generate_simple_get {
 243   my ($self, $me, $name) = @_;
 244   my $name_str = perlstring $name;
 245   "${me}->{${name_str}}";
 246 }
 247
 248 sub _generate_set {
 249   my ($self, $name, $spec) = @_;
 250   if ($self->is_simple_set($name, $spec)) {
 251     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 252   } else {
 253     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 254     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 255     my $code = "do { my (\$self, \$value) = \@_;\n";
 256     if ($coerce) {
 257       $code .=
 258         "        \$value = "
 259         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 260     }
 261     if ($isa_check) {
 262       $code .=
 263         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 264     }
 265     if ($trigger) {
 266       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 267       $code .=
 268         "        ".$simple.";\n        ".$fire.";\n"
 269         ."        \$value;\n";
 270     } else {
 271       $code .= "        ".$simple.";\n";
 272     }
 273     $code .= "      }";
 274     $code;
 275   }
 276 }
 277
 278 sub generate_coerce {
 279   my $self = shift;
 280   $self->{captures} = {};
 281   my $code = $self->_generate_coerce(@_);
 282   ($code, delete $self->{captures});
 283 }
 284
 285 sub _generate_coerce {
 286   my ($self, $name, $value, $coerce) = @_;
 287   $self->_generate_call_code($name, 'coerce', "${value}", $coerce);
 288 }
 289
 290 sub generate_trigger {
 291   my $self = shift;
 292   $self->{captures} = {};
 293   my $code = $self->_generate_trigger(@_);
 294   ($code, delete $self->{captures});
 295 }
 296
 297 sub _generate_trigger {
 298   my ($self, $name, $obj, $value, $trigger) = @_;
 299   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 300 }
 301
 302 sub generate_isa_check {
 303   my ($self, @args) = @_;
 304   $self->{captures} = {};
 305   my $code = $self->_generate_isa_check(@args);
 306   ($code, delete $self->{captures});
 307 }
 308
 309 sub _generate_isa_check {
 310   my ($self, $name, $value, $check) = @_;
 311   $self->_generate_call_code($name, 'isa_check', $value, $check);
 312 }
 313
 314 sub _generate_call_code {
 315   my ($self, $name, $type, $values, $sub) = @_;
 316   if (my $quoted = quoted_from_sub($sub)) {
 317     my $code = $quoted->[1];
 318     my $at_ = '@_ = ('.$values.');';
 319     if (my $captures = $quoted->[2]) {
 320       my $cap_name = qq{\$${type}_captures_for_${name}};
 321       $self->{captures}->{$cap_name} = \$captures;
 322       Sub::Quote::inlinify(
 323         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 324       );
 325     } else {
 326       Sub::Quote::inlinify($code, $values);
 327     }
 328   } else {
 329     my $cap_name = qq{\$${type}_for_${name}};
 330     $self->{captures}->{$cap_name} = \$sub;
 331     "${cap_name}->(${values})";
 332   }
 333 }
 334
 335 sub generate_populate_set {
 336   my $self = shift;
 337   $self->{captures} = {};
 338   my $code = $self->_generate_populate_set(@_);
 339   ($code, delete $self->{captures});
 340 }
 341
 342 sub _generate_populate_set {
 343   my ($self, $me, $name, $spec, $source, $test) = @_;
 344   if ($self->has_eager_default($name, $spec)) {
 345     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 346     my $get_default = $self->_generate_get_default(
 347                         '$new', $_, $spec
 348                       );
 349     my $get_value =
 350       defined($spec->{init_arg})
 351         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 352             .$get_default
 353             ."\n${get_indent})"
 354         : $get_default;
 355     if ($spec->{coerce}) {
 356       $get_value = $self->_generate_coerce(
 357         $name, $get_value,
 358         $spec->{coerce}
 359       )
 360     }
 361     ($spec->{isa}
 362       ? "    {\n      my \$value = ".$get_value.";\n      "
 363         .$self->_generate_isa_check(
 364           $name, '$value', $spec->{isa}
 365         ).";\n"
 366         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 367         ."    }\n"
 368       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 369     )
 370     .($spec->{trigger}
 371       ? '    '
 372         .$self->_generate_trigger(
 373           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 374           $spec->{trigger}
 375         )." if ${test};\n"
 376       : ''
 377     );
 378   } else {
 379     "    if (${test}) {\n"
 380       .($spec->{coerce}
 381         ? "      $source = "
 382           .$self->_generate_coerce(
 383             $name, $source,
 384             $spec->{coerce}
 385           ).";\n"
 386         : ""
 387       )
 388       .($spec->{isa}
 389         ? "      "
 390           .$self->_generate_isa_check(
 391             $name, $source, $spec->{isa}
 392           ).";\n"
 393         : ""
 394       )
 395       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 396       .($spec->{trigger}
 397         ? "      "
 398           .$self->_generate_trigger(
 399             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 400             $spec->{trigger}
 401           ).";\n"
 402         : ""
 403       )
 404       ."    }\n";
 405   }
 406 }
 407
 408 sub _generate_core_set {
 409   my ($self, $me, $name, $spec, $value) = @_;
 410   my $name_str = perlstring $name;
 411   "${me}->{${name_str}} = ${value}";
 412 }
 413
 414 sub _generate_simple_set {
 415   my ($self, $me, $name, $spec, $value) = @_;
 416   my $name_str = perlstring $name;
 417
 418   if ($spec->{weak_ref}) {
 419     $value = '$preserve = '.$value;
 420     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 421     require Scalar::Util;
 422
 423     # Perl < 5.8.3 can't weaken refs to readonly vars
 424     # (e.g. string constants). This *can* be solved by:
 425     #
 426     #Internals::SetReadWrite($foo);
 427     #Scalar::Util::weaken ($foo);
 428     #Internals::SetReadOnly($foo);
 429     #
 430     # but requires XS and is just too damn crazy
 431     # so simply throw a better exception
 432     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple})";
 433     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 434
 435       my \$preserve;
 436       eval { Scalar::Util::weaken($simple); 1 } or do {
 437         if( \$@ =~ /Modification of a read-only value attempted/) {
 438           require Carp;
 439           Carp::croak( sprintf (
 440             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 441             $name_str,
 442           ) );
 443         } else {
 444           die \$@;
 445         }
 446       };
 447 EOC
 448   } else {
 449     $self->_generate_core_set($me, $name, $spec, $value);
 450   }
 451 }
 452
 453 sub _generate_getset {
 454   my ($self, $name, $spec) = @_;
 455   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 456     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 457 }
 458
 459 sub _generate_delegation {
 460   my ($self, $asserter, $target, $args) = @_;
 461   my $arg_string = do {
 462     if (@$args) {
 463       # I could, I reckon, linearise out non-refs here using perlstring
 464       # plus something to check for numbers but I'm unsure if it's worth it
 465       $self->{captures}{'@curries'} = $args;
 466       '@curries, @_';
 467     } else {
 468       '@_';
 469     }
 470   };
 471   "shift->${asserter}->${target}(${arg_string});";
 472 }
 473
 474 sub _generate_xs {
 475   my ($self, $type, $into, $name, $slot) = @_;
 476   Class::XSAccessor->import(
 477     class => $into,
 478     $type => { $name => $slot },
 479     replace => 1,
 480   );
 481   $into->can($name);
 482 }
 483
 484 sub default_construction_string { '{}' }
 485
 486 1;