lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     !$ENV{MOO_XS_DISABLE}
  11       &&
  12     _maybe_load_module('Class::XSAccessor')
  13       &&
  14     (eval { Class::XSAccessor->VERSION('1.07') })
  15   ;
  16 }
  17
  18 sub generate_method {
  19   my ($self, $into, $name, $spec, $quote_opts) = @_;
  20   die "Must have an is" unless my $is = $spec->{is};
  21   if ($is eq 'ro') {
  22     $spec->{reader} = $name unless exists $spec->{reader};
  23   } elsif ($is eq 'rw') {
  24     $spec->{accessor} = $name unless exists $spec->{accessor};
  25   } elsif ($is eq 'lazy') {
  26     $spec->{reader} = $name unless exists $spec->{reader};
  27     $spec->{lazy} = 1;
  28     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  29   } elsif ($is eq 'rwp') {
  30     $spec->{reader} = $name unless exists $spec->{reader};
  31     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  32   } elsif ($is ne 'bare') {
  33     die "Unknown is ${is}";
  34   }
  35   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  36   if (($spec->{predicate}||0) eq 1) {
  37     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  38   }
  39   if (($spec->{clearer}||0) eq 1) {
  40     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  41   }
  42   if (($spec->{trigger}||0) eq 1) {
  43     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  44   }
  45   my %methods;
  46   if (my $reader = $spec->{reader}) {
  47     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  48       $methods{$reader} = $self->_generate_xs(
  49         getters => $into, $reader, $name, $spec
  50       );
  51     } else {
  52       $self->{captures} = {};
  53       $methods{$reader} =
  54         quote_sub "${into}::${reader}"
  55           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  56              .$self->_generate_get($name, $spec)
  57           => delete $self->{captures}
  58         ;
  59     }
  60   }
  61   if (my $accessor = $spec->{accessor}) {
  62     if (
  63       our $CAN_HAZ_XS
  64       && $self->is_simple_get($name, $spec)
  65       && $self->is_simple_set($name, $spec)
  66     ) {
  67       $methods{$accessor} = $self->_generate_xs(
  68         accessors => $into, $accessor, $name, $spec
  69       );
  70     } else {
  71       $self->{captures} = {};
  72       $methods{$accessor} =
  73         quote_sub "${into}::${accessor}"
  74           => $self->_generate_getset($name, $spec)
  75           => delete $self->{captures}
  76         ;
  77     }
  78   }
  79   if (my $writer = $spec->{writer}) {
  80     if (
  81       our $CAN_HAZ_XS
  82       && $self->is_simple_set($name, $spec)
  83     ) {
  84       $methods{$writer} = $self->_generate_xs(
  85         setters => $into, $writer, $name, $spec
  86       );
  87     } else {
  88       $self->{captures} = {};
  89       $methods{$writer} =
  90         quote_sub "${into}::${writer}"
  91           => $self->_generate_set($name, $spec)
  92           => delete $self->{captures}
  93         ;
  94     }
  95   }
  96   if (my $pred = $spec->{predicate}) {
  97     $methods{$pred} =
  98       quote_sub "${into}::${pred}" =>
  99         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 100       ;
 101   }
 102   if (my $cl = $spec->{clearer}) {
 103     $methods{$cl} =
 104       quote_sub "${into}::${cl}" =>
 105         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 106       ;
 107   }
 108   if (my $hspec = $spec->{handles}) {
 109     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 110     my @specs = do {
 111       if (ref($hspec) eq 'ARRAY') {
 112         map [ $_ => $_ ], @$hspec;
 113       } elsif (ref($hspec) eq 'HASH') {
 114         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 115           keys %$hspec;
 116       } elsif (!ref($hspec)) {
 117         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 118       } else {
 119         die "You gave me a handles of ${hspec} and I have no idea why";
 120       }
 121     };
 122     foreach my $spec (@specs) {
 123       my ($proxy, $target, @args) = @$spec;
 124       $self->{captures} = {};
 125       $methods{$proxy} =
 126         quote_sub "${into}::${proxy}" =>
 127           $self->_generate_delegation($asserter, $target, \@args),
 128           delete $self->{captures}
 129         ;
 130     }
 131   }
 132   if (my $asserter = $spec->{asserter}) {
 133     $self->{captures} = {};
 134     $methods{$asserter} =
 135       quote_sub "${into}::${asserter}" =>
 136         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 137         delete $self->{captures}
 138       ;
 139   }
 140   \%methods;
 141 }
 142
 143 sub is_simple_attribute {
 144   my ($self, $name, $spec) = @_;
 145   # clearer doesn't have to be listed because it doesn't
 146   # affect whether defined/exists makes a difference
 147   !grep $spec->{$_},
 148     qw(lazy default builder coerce isa trigger predicate weak_ref);
 149 }
 150
 151 sub is_simple_get {
 152   my ($self, $name, $spec) = @_;
 153   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 154 }
 155
 156 sub is_simple_set {
 157   my ($self, $name, $spec) = @_;
 158   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 159 }
 160
 161 sub has_eager_default {
 162   my ($self, $name, $spec) = @_;
 163   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 164 }
 165
 166 sub _generate_get {
 167   my ($self, $name, $spec) = @_;
 168   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 169   if ($self->is_simple_get($name, $spec)) {
 170     $simple;
 171   } else {
 172     'do { '.$self->_generate_use_default(
 173       '$_[0]', $name, $spec,
 174       $self->_generate_simple_has('$_[0]', $name, $spec),
 175     ).'; '.$simple.' }';
 176   }
 177 }
 178
 179 sub _generate_simple_has {
 180   my ($self, $me, $name) = @_;
 181   "exists ${me}->{${\perlstring $name}}";
 182 }
 183
 184 sub _generate_simple_clear {
 185   my ($self, $me, $name) = @_;
 186   "    delete ${me}->{${\perlstring $name}}\n"
 187 }
 188
 189 sub generate_get_default {
 190   my $self = shift;
 191   $self->{captures} = {};
 192   my $code = $self->_generate_get_default(@_);
 193   ($code, delete $self->{captures});
 194 }
 195
 196 sub _generate_use_default {
 197   my ($self, $me, $name, $spec, $test) = @_;
 198   my $get_value = $self->_generate_get_default($me, $name, $spec);
 199   if ($spec->{coerce}) {
 200     $get_value = $self->_generate_coerce(
 201       $name, $get_value,
 202       $spec->{coerce}
 203     )
 204   }
 205   $self->_generate_simple_set(
 206     $me, $name, $spec, $get_value
 207   ).' unless '.$test;
 208 }
 209
 210 sub _generate_get_default {
 211   my ($self, $me, $name, $spec) = @_;
 212   $spec->{default}
 213     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 214     : "${me}->${\$spec->{builder}}"
 215 }
 216
 217 sub generate_simple_get {
 218   my ($self, @args) = @_;
 219   $self->_generate_simple_get(@args);
 220 }
 221
 222 sub _generate_simple_get {
 223   my ($self, $me, $name) = @_;
 224   my $name_str = perlstring $name;
 225   "${me}->{${name_str}}";
 226 }
 227
 228 sub _generate_set {
 229   my ($self, $name, $spec) = @_;
 230   if ($self->is_simple_set($name, $spec)) {
 231     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 232   } else {
 233     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 234     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 235     my $code = "do { my (\$self, \$value) = \@_;\n";
 236     if ($coerce) {
 237       $code .=
 238         "        \$value = "
 239         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 240     }
 241     if ($isa_check) {
 242       $code .=
 243         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 244     }
 245     if ($trigger) {
 246       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 247       $code .=
 248         "        ".$simple.";\n        ".$fire.";\n"
 249         ."        \$value;\n";
 250     } else {
 251       $code .= "        ".$simple.";\n";
 252     }
 253     $code .= "      }";
 254     $code;
 255   }
 256 }
 257
 258 sub generate_coerce {
 259   my $self = shift;
 260   $self->{captures} = {};
 261   my $code = $self->_generate_coerce(@_);
 262   ($code, delete $self->{captures});
 263 }
 264
 265 sub _generate_coerce {
 266   my ($self, $name, $value, $coerce) = @_;
 267   $self->_generate_call_code($name, 'coerce', "${value}", $coerce);
 268 }
 269
 270 sub generate_trigger {
 271   my $self = shift;
 272   $self->{captures} = {};
 273   my $code = $self->_generate_trigger(@_);
 274   ($code, delete $self->{captures});
 275 }
 276
 277 sub _generate_trigger {
 278   my ($self, $name, $obj, $value, $trigger) = @_;
 279   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 280 }
 281
 282 sub generate_isa_check {
 283   my ($self, @args) = @_;
 284   $self->{captures} = {};
 285   my $code = $self->_generate_isa_check(@args);
 286   ($code, delete $self->{captures});
 287 }
 288
 289 sub _generate_isa_check {
 290   my ($self, $name, $value, $check) = @_;
 291   $self->_generate_call_code($name, 'isa_check', $value, $check);
 292 }
 293
 294 sub _generate_call_code {
 295   my ($self, $name, $type, $values, $sub) = @_;
 296   if (my $quoted = quoted_from_sub($sub)) {
 297     my $code = $quoted->[1];
 298     my $at_ = '@_ = ('.$values.');';
 299     if (my $captures = $quoted->[2]) {
 300       my $cap_name = qq{\$${type}_captures_for_${name}};
 301       $self->{captures}->{$cap_name} = \$captures;
 302       Sub::Quote::inlinify(
 303         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 304       );
 305     } else {
 306       Sub::Quote::inlinify($code, $values);
 307     }
 308   } else {
 309     my $cap_name = qq{\$${type}_for_${name}};
 310     $self->{captures}->{$cap_name} = \$sub;
 311     "${cap_name}->(${values})";
 312   }
 313 }
 314
 315 sub generate_populate_set {
 316   my $self = shift;
 317   $self->{captures} = {};
 318   my $code = $self->_generate_populate_set(@_);
 319   ($code, delete $self->{captures});
 320 }
 321
 322 sub _generate_populate_set {
 323   my ($self, $me, $name, $spec, $source, $test) = @_;
 324   if ($self->has_eager_default($name, $spec)) {
 325     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 326     my $get_default = $self->_generate_get_default(
 327                         '$new', $_, $spec
 328                       );
 329     my $get_value =
 330       defined($spec->{init_arg})
 331         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 332             .$get_default
 333             ."\n${get_indent})"
 334         : $get_default;
 335     if ($spec->{coerce}) {
 336       $get_value = $self->_generate_coerce(
 337         $name, $get_value,
 338         $spec->{coerce}
 339       )
 340     }
 341     ($spec->{isa}
 342       ? "    {\n      my \$value = ".$get_value.";\n      "
 343         .$self->_generate_isa_check(
 344           $name, '$value', $spec->{isa}
 345         ).";\n"
 346         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 347         ."    }\n"
 348       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 349     )
 350     .($spec->{trigger}
 351       ? '    '
 352         .$self->_generate_trigger(
 353           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 354           $spec->{trigger}
 355         )." if ${test};\n"
 356       : ''
 357     );
 358   } else {
 359     "    if (${test}) {\n"
 360       .($spec->{coerce}
 361         ? "      $source = "
 362           .$self->_generate_coerce(
 363             $name, $source,
 364             $spec->{coerce}
 365           ).";\n"
 366         : ""
 367       )
 368       .($spec->{isa}
 369         ? "      "
 370           .$self->_generate_isa_check(
 371             $name, $source, $spec->{isa}
 372           ).";\n"
 373         : ""
 374       )
 375       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 376       .($spec->{trigger}
 377         ? "      "
 378           .$self->_generate_trigger(
 379             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 380             $spec->{trigger}
 381           ).";\n"
 382         : ""
 383       )
 384       ."    }\n";
 385   }
 386 }
 387
 388 sub generate_multi_set {
 389   my ($self, $me, $to_set, $from) = @_;
 390   "\@{${me}}{qw(${\join ' ', @$to_set})} = $from";
 391 }
 392
 393 sub _generate_core_set {
 394   my ($self, $me, $name, $spec, $value) = @_;
 395   my $name_str = perlstring $name;
 396   "${me}->{${name_str}} = ${value}";
 397 }
 398
 399 sub _generate_simple_set {
 400   my ($self, $me, $name, $spec, $value) = @_;
 401   my $name_str = perlstring $name;
 402
 403   if ($spec->{weak_ref}) {
 404     $value = '$preserve = '.$value;
 405     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 406     require Scalar::Util;
 407
 408     # Perl < 5.8.3 can't weaken refs to readonly vars
 409     # (e.g. string constants). This *can* be solved by:
 410     #
 411     #Internals::SetReadWrite($foo);
 412     #Scalar::Util::weaken ($foo);
 413     #Internals::SetReadOnly($foo);
 414     #
 415     # but requires XS and is just too damn crazy
 416     # so simply throw a better exception
 417     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple})";
 418     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 419
 420       my \$preserve;
 421       eval { Scalar::Util::weaken($simple); 1 } or do {
 422         if( \$@ =~ /Modification of a read-only value attempted/) {
 423           require Carp;
 424           Carp::croak( sprintf (
 425             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 426             $name_str,
 427           ) );
 428         } else {
 429           die \$@;
 430         }
 431       };
 432 EOC
 433   } else {
 434     $self->_generate_core_set($me, $name, $spec, $value);
 435   }
 436 }
 437
 438 sub _generate_getset {
 439   my ($self, $name, $spec) = @_;
 440   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 441     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 442 }
 443
 444 sub _generate_delegation {
 445   my ($self, $asserter, $target, $args) = @_;
 446   my $arg_string = do {
 447     if (@$args) {
 448       # I could, I reckon, linearise out non-refs here using perlstring
 449       # plus something to check for numbers but I'm unsure if it's worth it
 450       $self->{captures}{'@curries'} = $args;
 451       '@curries, @_';
 452     } else {
 453       '@_';
 454     }
 455   };
 456   "shift->${asserter}->${target}(${arg_string});";
 457 }
 458
 459 sub _generate_xs {
 460   my ($self, $type, $into, $name, $slot) = @_;
 461   Class::XSAccessor->import(
 462     class => $into,
 463     $type => { $name => $slot }
 464   );
 465   $into->can($name);
 466 }
 467
 468 sub default_construction_string { '{}' }
 469
 470 1;