lib/Method/Generate/Accessor.pm

   1 package Method::Generate::Accessor;
   2
   3 use strictures 1;
   4 use Moo::_Utils;
   5 use base qw(Moo::Object);
   6 use Sub::Quote;
   7 use B 'perlstring';
   8 BEGIN {
   9   our $CAN_HAZ_XS =
  10     !$ENV{MOO_XS_DISABLE}
  11       &&
  12     _maybe_load_module('Class::XSAccessor')
  13       &&
  14     (eval { Class::XSAccessor->VERSION('1.07') })
  15   ;
  16 }
  17
  18 sub generate_method {
  19   my ($self, $into, $name, $spec, $quote_opts) = @_;
  20   $name =~ s/^\+//;
  21   die "Must have an is" unless my $is = $spec->{is};
  22   if ($is eq 'ro') {
  23     $spec->{reader} = $name unless exists $spec->{reader};
  24   } elsif ($is eq 'rw') {
  25     $spec->{accessor} = $name unless exists $spec->{accessor};
  26   } elsif ($is eq 'lazy') {
  27     $spec->{reader} = $name unless exists $spec->{reader};
  28     $spec->{lazy} = 1;
  29     $spec->{builder} ||= '_build_'.$name unless $spec->{default};
  30   } elsif ($is eq 'rwp') {
  31     $spec->{reader} = $name unless exists $spec->{reader};
  32     $spec->{writer} = "_set_${name}" unless exists $spec->{writer};
  33   } elsif ($is ne 'bare') {
  34     die "Unknown is ${is}";
  35   }
  36   $spec->{builder} = '_build_'.$name if ($spec->{builder}||0) eq 1;
  37   if (($spec->{predicate}||0) eq 1) {
  38     $spec->{predicate} = $name =~ /^_/ ? "_has${name}" : "has_${name}";
  39   }
  40   if (($spec->{clearer}||0) eq 1) {
  41     $spec->{clearer} = $name =~ /^_/ ? "_clear${name}" : "clear_${name}";
  42   }
  43   if (($spec->{trigger}||0) eq 1) {
  44     $spec->{trigger} = quote_sub('shift->_trigger_'.$name.'(@_)');
  45   }
  46   if (exists $spec->{default}) {
  47     my $default = $spec->{default};
  48     unless (ref $default) {
  49       die "Invalid default $default";
  50     }
  51     if (ref $default ne 'CODE') {
  52       unless (eval { \&$default }) {
  53         die "Invalid default $default";
  54       }
  55     }
  56   }
  57
  58   my %methods;
  59   if (my $reader = $spec->{reader}) {
  60     if (our $CAN_HAZ_XS && $self->is_simple_get($name, $spec)) {
  61       $methods{$reader} = $self->_generate_xs(
  62         getters => $into, $reader, $name, $spec
  63       );
  64     } else {
  65       $self->{captures} = {};
  66       $methods{$reader} =
  67         quote_sub "${into}::${reader}"
  68           => '    die "'.$reader.' is a read-only accessor" if @_ > 1;'."\n"
  69              .$self->_generate_get($name, $spec)
  70           => delete $self->{captures}
  71         ;
  72     }
  73   }
  74   if (my $accessor = $spec->{accessor}) {
  75     if (
  76       our $CAN_HAZ_XS
  77       && $self->is_simple_get($name, $spec)
  78       && $self->is_simple_set($name, $spec)
  79     ) {
  80       $methods{$accessor} = $self->_generate_xs(
  81         accessors => $into, $accessor, $name, $spec
  82       );
  83     } else {
  84       $self->{captures} = {};
  85       $methods{$accessor} =
  86         quote_sub "${into}::${accessor}"
  87           => $self->_generate_getset($name, $spec)
  88           => delete $self->{captures}
  89         ;
  90     }
  91   }
  92   if (my $writer = $spec->{writer}) {
  93     if (
  94       our $CAN_HAZ_XS
  95       && $self->is_simple_set($name, $spec)
  96     ) {
  97       $methods{$writer} = $self->_generate_xs(
  98         setters => $into, $writer, $name, $spec
  99       );
 100     } else {
 101       $self->{captures} = {};
 102       $methods{$writer} =
 103         quote_sub "${into}::${writer}"
 104           => $self->_generate_set($name, $spec)
 105           => delete $self->{captures}
 106         ;
 107     }
 108   }
 109   if (my $pred = $spec->{predicate}) {
 110     $methods{$pred} =
 111       quote_sub "${into}::${pred}" =>
 112         '    '.$self->_generate_simple_has('$_[0]', $name, $spec)."\n"
 113       ;
 114   }
 115   if (my $cl = $spec->{clearer}) {
 116     $methods{$cl} =
 117       quote_sub "${into}::${cl}" =>
 118         $self->_generate_simple_clear('$_[0]', $name, $spec)."\n"
 119       ;
 120   }
 121   if (my $hspec = $spec->{handles}) {
 122     my $asserter = $spec->{asserter} ||= '_assert_'.$name;
 123     my @specs = do {
 124       if (ref($hspec) eq 'ARRAY') {
 125         map [ $_ => $_ ], @$hspec;
 126       } elsif (ref($hspec) eq 'HASH') {
 127         map [ $_ => ref($hspec->{$_}) ? @{$hspec->{$_}} : $hspec->{$_} ],
 128           keys %$hspec;
 129       } elsif (!ref($hspec)) {
 130         map [ $_ => $_ ], Role::Tiny->methods_provided_by($hspec);
 131       } else {
 132         die "You gave me a handles of ${hspec} and I have no idea why";
 133       }
 134     };
 135     foreach my $spec (@specs) {
 136       my ($proxy, $target, @args) = @$spec;
 137       $self->{captures} = {};
 138       $methods{$proxy} =
 139         quote_sub "${into}::${proxy}" =>
 140           $self->_generate_delegation($asserter, $target, \@args),
 141           delete $self->{captures}
 142         ;
 143     }
 144   }
 145   if (my $asserter = $spec->{asserter}) {
 146     $self->{captures} = {};
 147     $methods{$asserter} =
 148       quote_sub "${into}::${asserter}" =>
 149         'do { '.$self->_generate_get($name, $spec).qq! }||die "Attempted to access '${name}' but it is not set"!,
 150         delete $self->{captures}
 151       ;
 152   }
 153   \%methods;
 154 }
 155
 156 sub is_simple_attribute {
 157   my ($self, $name, $spec) = @_;
 158   # clearer doesn't have to be listed because it doesn't
 159   # affect whether defined/exists makes a difference
 160   !grep $spec->{$_},
 161     qw(lazy default builder coerce isa trigger predicate weak_ref);
 162 }
 163
 164 sub is_simple_get {
 165   my ($self, $name, $spec) = @_;
 166   !($spec->{lazy} and ($spec->{default} or $spec->{builder}));
 167 }
 168
 169 sub is_simple_set {
 170   my ($self, $name, $spec) = @_;
 171   !grep $spec->{$_}, qw(coerce isa trigger weak_ref);
 172 }
 173
 174 sub has_eager_default {
 175   my ($self, $name, $spec) = @_;
 176   (!$spec->{lazy} and ($spec->{default} or $spec->{builder}));
 177 }
 178
 179 sub _generate_get {
 180   my ($self, $name, $spec) = @_;
 181   my $simple = $self->_generate_simple_get('$_[0]', $name, $spec);
 182   if ($self->is_simple_get($name, $spec)) {
 183     $simple;
 184   } else {
 185     'do { '.$self->_generate_use_default(
 186       '$_[0]', $name, $spec,
 187       $self->_generate_simple_has('$_[0]', $name, $spec),
 188     ).'; '
 189     .($spec->{isa}
 190       ?($self->_generate_isa_check($name, $simple, $spec->{isa}).'; ')
 191       :''
 192     )
 193     .$simple.' }';
 194   }
 195 }
 196
 197 sub _generate_simple_has {
 198   my ($self, $me, $name) = @_;
 199   "exists ${me}->{${\perlstring $name}}";
 200 }
 201
 202 sub _generate_simple_clear {
 203   my ($self, $me, $name) = @_;
 204   "    delete ${me}->{${\perlstring $name}}\n"
 205 }
 206
 207 sub generate_get_default {
 208   my $self = shift;
 209   $self->{captures} = {};
 210   my $code = $self->_generate_get_default(@_);
 211   ($code, delete $self->{captures});
 212 }
 213
 214 sub _generate_use_default {
 215   my ($self, $me, $name, $spec, $test) = @_;
 216   my $get_value = $self->_generate_get_default($me, $name, $spec);
 217   if ($spec->{coerce}) {
 218     $get_value = $self->_generate_coerce(
 219       $name, $get_value,
 220       $spec->{coerce}
 221     )
 222   }
 223   $self->_generate_simple_set(
 224     $me, $name, $spec, $get_value
 225   ).' unless '.$test;
 226 }
 227
 228 sub _generate_get_default {
 229   my ($self, $me, $name, $spec) = @_;
 230   $spec->{default}
 231     ? $self->_generate_call_code($name, 'default', $me, $spec->{default})
 232     : "${me}->${\$spec->{builder}}"
 233 }
 234
 235 sub generate_simple_get {
 236   my ($self, @args) = @_;
 237   $self->_generate_simple_get(@args);
 238 }
 239
 240 sub _generate_simple_get {
 241   my ($self, $me, $name) = @_;
 242   my $name_str = perlstring $name;
 243   "${me}->{${name_str}}";
 244 }
 245
 246 sub _generate_set {
 247   my ($self, $name, $spec) = @_;
 248   if ($self->is_simple_set($name, $spec)) {
 249     $self->_generate_simple_set('$_[0]', $name, $spec, '$_[1]');
 250   } else {
 251     my ($coerce, $trigger, $isa_check) = @{$spec}{qw(coerce trigger isa)};
 252     my $simple = $self->_generate_simple_set('$self', $name, $spec, '$value');
 253     my $code = "do { my (\$self, \$value) = \@_;\n";
 254     if ($coerce) {
 255       $code .=
 256         "        \$value = "
 257         .$self->_generate_coerce($name, '$value', $coerce).";\n";
 258     }
 259     if ($isa_check) {
 260       $code .=
 261         "        ".$self->_generate_isa_check($name, '$value', $isa_check).";\n";
 262     }
 263     if ($trigger) {
 264       my $fire = $self->_generate_trigger($name, '$self', '$value', $trigger);
 265       $code .=
 266         "        ".$simple.";\n        ".$fire.";\n"
 267         ."        \$value;\n";
 268     } else {
 269       $code .= "        ".$simple.";\n";
 270     }
 271     $code .= "      }";
 272     $code;
 273   }
 274 }
 275
 276 sub generate_coerce {
 277   my $self = shift;
 278   $self->{captures} = {};
 279   my $code = $self->_generate_coerce(@_);
 280   ($code, delete $self->{captures});
 281 }
 282
 283 sub _generate_coerce {
 284   my ($self, $name, $value, $coerce) = @_;
 285   $self->_generate_call_code($name, 'coerce', "${value}", $coerce);
 286 }
 287
 288 sub generate_trigger {
 289   my $self = shift;
 290   $self->{captures} = {};
 291   my $code = $self->_generate_trigger(@_);
 292   ($code, delete $self->{captures});
 293 }
 294
 295 sub _generate_trigger {
 296   my ($self, $name, $obj, $value, $trigger) = @_;
 297   $self->_generate_call_code($name, 'trigger', "${obj}, ${value}", $trigger);
 298 }
 299
 300 sub generate_isa_check {
 301   my ($self, @args) = @_;
 302   $self->{captures} = {};
 303   my $code = $self->_generate_isa_check(@args);
 304   ($code, delete $self->{captures});
 305 }
 306
 307 sub _generate_isa_check {
 308   my ($self, $name, $value, $check) = @_;
 309   $self->_generate_call_code($name, 'isa_check', $value, $check);
 310 }
 311
 312 sub _generate_call_code {
 313   my ($self, $name, $type, $values, $sub) = @_;
 314   if (my $quoted = quoted_from_sub($sub)) {
 315     my $code = $quoted->[1];
 316     my $at_ = '@_ = ('.$values.');';
 317     if (my $captures = $quoted->[2]) {
 318       my $cap_name = qq{\$${type}_captures_for_${name}};
 319       $self->{captures}->{$cap_name} = \$captures;
 320       Sub::Quote::inlinify(
 321         $code, $values, Sub::Quote::capture_unroll($cap_name, $captures, 6)
 322       );
 323     } else {
 324       Sub::Quote::inlinify($code, $values);
 325     }
 326   } else {
 327     my $cap_name = qq{\$${type}_for_${name}};
 328     $self->{captures}->{$cap_name} = \$sub;
 329     "${cap_name}->(${values})";
 330   }
 331 }
 332
 333 sub generate_populate_set {
 334   my $self = shift;
 335   $self->{captures} = {};
 336   my $code = $self->_generate_populate_set(@_);
 337   ($code, delete $self->{captures});
 338 }
 339
 340 sub _generate_populate_set {
 341   my ($self, $me, $name, $spec, $source, $test) = @_;
 342   if ($self->has_eager_default($name, $spec)) {
 343     my $get_indent = ' ' x ($spec->{isa} ? 6 : 4);
 344     my $get_default = $self->_generate_get_default(
 345                         '$new', $_, $spec
 346                       );
 347     my $get_value =
 348       defined($spec->{init_arg})
 349         ? "(\n${get_indent}  ${test}\n${get_indent}   ? ${source}\n${get_indent}   : "
 350             .$get_default
 351             ."\n${get_indent})"
 352         : $get_default;
 353     if ($spec->{coerce}) {
 354       $get_value = $self->_generate_coerce(
 355         $name, $get_value,
 356         $spec->{coerce}
 357       )
 358     }
 359     ($spec->{isa}
 360       ? "    {\n      my \$value = ".$get_value.";\n      "
 361         .$self->_generate_isa_check(
 362           $name, '$value', $spec->{isa}
 363         ).";\n"
 364         .'      '.$self->_generate_simple_set($me, $name, $spec, '$value').";\n"
 365         ."    }\n"
 366       : '    '.$self->_generate_simple_set($me, $name, $spec, $get_value).";\n"
 367     )
 368     .($spec->{trigger}
 369       ? '    '
 370         .$self->_generate_trigger(
 371           $name, $me, $self->_generate_simple_get($me, $name, $spec),
 372           $spec->{trigger}
 373         )." if ${test};\n"
 374       : ''
 375     );
 376   } else {
 377     "    if (${test}) {\n"
 378       .($spec->{coerce}
 379         ? "      $source = "
 380           .$self->_generate_coerce(
 381             $name, $source,
 382             $spec->{coerce}
 383           ).";\n"
 384         : ""
 385       )
 386       .($spec->{isa}
 387         ? "      "
 388           .$self->_generate_isa_check(
 389             $name, $source, $spec->{isa}
 390           ).";\n"
 391         : ""
 392       )
 393       ."      ".$self->_generate_simple_set($me, $name, $spec, $source).";\n"
 394       .($spec->{trigger}
 395         ? "      "
 396           .$self->_generate_trigger(
 397             $name, $me, $self->_generate_simple_get($me, $name, $spec),
 398             $spec->{trigger}
 399           ).";\n"
 400         : ""
 401       )
 402       ."    }\n";
 403   }
 404 }
 405
 406 sub _generate_core_set {
 407   my ($self, $me, $name, $spec, $value) = @_;
 408   my $name_str = perlstring $name;
 409   "${me}->{${name_str}} = ${value}";
 410 }
 411
 412 sub _generate_simple_set {
 413   my ($self, $me, $name, $spec, $value) = @_;
 414   my $name_str = perlstring $name;
 415
 416   if ($spec->{weak_ref}) {
 417     $value = '$preserve = '.$value;
 418     my $simple = $self->_generate_core_set($me, $name, $spec, $value);
 419     require Scalar::Util;
 420
 421     # Perl < 5.8.3 can't weaken refs to readonly vars
 422     # (e.g. string constants). This *can* be solved by:
 423     #
 424     #Internals::SetReadWrite($foo);
 425     #Scalar::Util::weaken ($foo);
 426     #Internals::SetReadOnly($foo);
 427     #
 428     # but requires XS and is just too damn crazy
 429     # so simply throw a better exception
 430     my $weak_simple = "my \$preserve; Scalar::Util::weaken(${simple})";
 431     Moo::_Utils::lt_5_8_3() ? <<"EOC" : $weak_simple;
 432
 433       my \$preserve;
 434       eval { Scalar::Util::weaken($simple); 1 } or do {
 435         if( \$@ =~ /Modification of a read-only value attempted/) {
 436           require Carp;
 437           Carp::croak( sprintf (
 438             'Reference to readonly value in "%s" can not be weakened on Perl < 5.8.3',
 439             $name_str,
 440           ) );
 441         } else {
 442           die \$@;
 443         }
 444       };
 445 EOC
 446   } else {
 447     $self->_generate_core_set($me, $name, $spec, $value);
 448   }
 449 }
 450
 451 sub _generate_getset {
 452   my ($self, $name, $spec) = @_;
 453   q{(@_ > 1}."\n      ? ".$self->_generate_set($name, $spec)
 454     ."\n      : ".$self->_generate_get($name, $spec)."\n    )";
 455 }
 456
 457 sub _generate_delegation {
 458   my ($self, $asserter, $target, $args) = @_;
 459   my $arg_string = do {
 460     if (@$args) {
 461       # I could, I reckon, linearise out non-refs here using perlstring
 462       # plus something to check for numbers but I'm unsure if it's worth it
 463       $self->{captures}{'@curries'} = $args;
 464       '@curries, @_';
 465     } else {
 466       '@_';
 467     }
 468   };
 469   "shift->${asserter}->${target}(${arg_string});";
 470 }
 471
 472 sub _generate_xs {
 473   my ($self, $type, $into, $name, $slot) = @_;
 474   Class::XSAccessor->import(
 475     class => $into,
 476     $type => { $name => $slot },
 477     replace => 1,
 478   );
 479   $into->can($name);
 480 }
 481
 482 sub default_construction_string { '{}' }
 483
 484 1;