t/017_add_method_modifier.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 20;
   7 use Test::Exception;
   8
   9 BEGIN {
  10     use_ok('Class::MOP');
  11 }
  12
  13 {
  14     package BankAccount;
  15
  16     use strict;
  17     use warnings;
  18     use metaclass;
  19
  20     use Carp 'confess';
  21
  22     BankAccount->meta->add_attribute('balance' => (
  23         accessor => 'balance',
  24                 init_arg => 'balance',
  25         default  => 0
  26     ));
  27
  28     sub new { (shift)->meta->new_object(@_) }
  29
  30     sub deposit {
  31         my ($self, $amount) = @_;
  32         $self->balance($self->balance + $amount);
  33     }
  34
  35     sub withdraw {
  36         my ($self, $amount) = @_;
  37         my $current_balance = $self->balance();
  38         ($current_balance >= $amount)
  39             || confess "Account overdrawn";
  40         $self->balance($current_balance - $amount);
  41     }
  42
  43         package CheckingAccount;
  44
  45         use strict;
  46         use warnings;
  47     use metaclass;
  48
  49         use base 'BankAccount';
  50
  51     CheckingAccount->meta->add_attribute('overdraft_account' => (
  52         accessor => 'overdraft_account',
  53                 init_arg => 'overdraft',
  54     ));
  55
  56         CheckingAccount->meta->add_before_method_modifier('withdraw' => sub {
  57                 my ($self, $amount) = @_;
  58                 my $overdraft_amount = $amount - $self->balance();
  59                 if ($overdraft_amount > 0) {
  60                         $self->overdraft_account->withdraw($overdraft_amount);
  61                         $self->deposit($overdraft_amount);
  62                 }
  63         });
  64
  65         ::ok(CheckingAccount->meta->has_method('withdraw'), '... checking account now has a withdraw method');
  66         ::isa_ok(CheckingAccount->meta->get_method('withdraw'), 'Class::MOP::Method::Wrapped');
  67         ::isa_ok(BankAccount->meta->get_method('withdraw'), 'Class::MOP::Method');
  68 }
  69
  70
  71 my $savings_account = BankAccount->new(balance => 250);
  72 isa_ok($savings_account, 'BankAccount');
  73
  74 is($savings_account->balance, 250, '... got the right savings balance');
  75 lives_ok {
  76         $savings_account->withdraw(50);
  77 } '... withdrew from savings successfully';
  78 is($savings_account->balance, 200, '... got the right savings balance after withdrawl');
  79 dies_ok {
  80         $savings_account->withdraw(250);
  81 } '... could not withdraw from savings successfully';
  82
  83
  84 $savings_account->deposit(150);
  85 is($savings_account->balance, 350, '... got the right savings balance after deposit');
  86
  87 my $checking_account = CheckingAccount->new(
  88                                                         balance   => 100,
  89                                                         overdraft => $savings_account
  90                                                 );
  91 isa_ok($checking_account, 'CheckingAccount');
  92 isa_ok($checking_account, 'BankAccount');
  93
  94 is($checking_account->overdraft_account, $savings_account, '... got the right overdraft account');
  95
  96 is($checking_account->balance, 100, '... got the right checkings balance');
  97
  98 lives_ok {
  99         $checking_account->withdraw(50);
 100 } '... withdrew from checking successfully';
 101 is($checking_account->balance, 50, '... got the right checkings balance after withdrawl');
 102 is($savings_account->balance, 350, '... got the right savings balance after checking withdrawl (no overdraft)');
 103
 104 lives_ok {
 105         $checking_account->withdraw(200);
 106 } '... withdrew from checking successfully';
 107 is($checking_account->balance, 0, '... got the right checkings balance after withdrawl');
 108 is($savings_account->balance, 200, '... got the right savings balance after overdraft withdrawl');
 109