t/003_methods.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 40;
   7 use Test::Exception;
   8
   9 BEGIN {
  10     use_ok('Class::MOP');
  11     use_ok('Class::MOP::Class');
  12 }
  13
  14 {   # This package tries to test &has_method
  15     # as exhaustively as possible. More corner
  16     # cases are welcome :)
  17     package Foo;
  18
  19     # import a sub
  20     use Scalar::Util 'blessed';
  21
  22     use constant FOO_CONSTANT => 'Foo-CONSTANT';
  23
  24     # define a sub in package
  25     sub bar { 'Foo::bar' }
  26     *baz = \&bar;
  27
  28     { # method named with Sub::Name inside the package scope
  29         no strict 'refs';
  30         *{'Foo::floob'} = Sub::Name::subname 'floob' => sub { '!floob!' };
  31     }
  32
  33     # We hateses the "used only once" warnings
  34     { my $temp = \&Foo::baz }
  35
  36     package main;
  37
  38     sub Foo::blah { $_[0]->Foo::baz() }
  39
  40     {
  41         no strict 'refs';
  42         *{'Foo::bling'} = sub { '$$Bling$$' };
  43         *{'Foo::bang'} = Sub::Name::subname 'Foo::bang' => sub { '!BANG!' };
  44         *{'Foo::boom'} = Sub::Name::subname 'boom' => sub { '!BOOM!' };
  45
  46         eval "package Foo; sub evaled_foo { 'Foo::evaled_foo' }";
  47     }
  48 }
  49
  50 my $Foo = Class::MOP::Class->initialize('Foo');
  51
  52 my $foo = sub { 'Foo::foo' };
  53
  54 lives_ok {
  55     $Foo->add_method('foo' => $foo);
  56 } '... we added the method successfully';
  57
  58 ok($Foo->has_method('foo'), '... Foo->has_method(foo) (defined with Sub::Name)');
  59
  60 is($Foo->get_method('foo'), $foo, '... Foo->get_method(foo) == \&foo');
  61 is(Foo->foo(), 'Foo::foo', '... Foo->foo() returns "Foo::foo"');
  62
  63 # now check all our other items ...
  64
  65 ok($Foo->has_method('FOO_CONSTANT'), '... Foo->has_method(FOO_CONSTANT) (defined w/ use constant)');
  66 ok($Foo->has_method('bar'), '... Foo->has_method(bar) (defined in Foo)');
  67 ok($Foo->has_method('baz'), '... Foo->has_method(baz) (typeglob aliased within Foo)');
  68 ok($Foo->has_method('floob'), '... Foo->has_method(floob) (defined in Foo:: using symbol tables and Sub::Name w/out package name)');
  69 ok($Foo->has_method('blah'), '... Foo->has_method(blah) (defined in main:: using fully qualified package name)');
  70 ok($Foo->has_method('bling'), '... Foo->has_method(bling) (defined in main:: using symbol tables (no Sub::Name))');
  71 ok($Foo->has_method('bang'), '... Foo->has_method(bang) (defined in main:: using symbol tables and Sub::Name)');
  72 ok($Foo->has_method('evaled_foo'), '... Foo->has_method(evaled_foo) (evaled in main::)');
  73
  74 {
  75     package Foo::Aliasing;
  76     use metaclass;
  77     sub alias_me { '...' }
  78 }
  79
  80 $Foo->alias_method('alias_me' => Foo::Aliasing->meta->get_method('alias_me'));
  81
  82 ok(!$Foo->has_method('alias_me'), '... !Foo->has_method(alias_me) (aliased from Foo::Aliasing)');
  83 ok(defined &Foo::alias_me, '... Foo does have a symbol table slow for alias_me though');
  84
  85 ok(!$Foo->has_method('blessed'), '... !Foo->has_method(blessed) (imported into Foo)');
  86 ok(!$Foo->has_method('boom'), '... !Foo->has_method(boom) (defined in main:: using symbol tables and Sub::Name w/out package name)');
  87
  88 ok(!$Foo->has_method('not_a_real_method'), '... !Foo->has_method(not_a_real_method) (does not exist)');
  89 is($Foo->get_method('not_a_real_method'), undef, '... Foo->get_method(not_a_real_method) == undef');
  90
  91 is_deeply(
  92     [ sort $Foo->get_method_list ],
  93     [ qw(FOO_CONSTANT bang bar baz blah bling evaled_foo floob foo) ],
  94     '... got the right method list for Foo');
  95
  96 is_deeply(
  97     [ sort { $a->{name} cmp $b->{name} } $Foo->compute_all_applicable_methods() ],
  98     [
  99         map {
 100             {
 101             name  => $_,
 102             class => 'Foo',
 103             code  => $Foo->get_method($_)
 104             }
 105         } qw(
 106             FOO_CONSTANT
 107             bang
 108             bar
 109             baz
 110             blah
 111             bling
 112             evaled_foo
 113             floob
 114             foo
 115         )
 116     ],
 117     '... got the right list of applicable methods for Foo');
 118
 119 is($Foo->remove_method('foo'), $foo, '... removed the foo method');
 120 ok(!$Foo->has_method('foo'), '... !Foo->has_method(foo) we just removed it');
 121 dies_ok { Foo->foo } '... cannot call Foo->foo because it is not there';
 122
 123 is_deeply(
 124     [ sort $Foo->get_method_list ],
 125     [ qw(FOO_CONSTANT bang bar baz blah bling evaled_foo floob) ],
 126     '... got the right method list for Foo');
 127
 128 ok($Foo->remove_method('FOO_CONSTANT'), '... removed the FOO_CONSTANT method');
 129 ok(!$Foo->has_method('FOO_CONSTANT'), '... !Foo->has_method(FOO_CONSTANT) we just removed it');
 130 dies_ok { Foo->FOO_CONSTANT } '... cannot call Foo->FOO_CONSTANT because it is not there';
 131
 132 is_deeply(
 133     [ sort $Foo->get_method_list ],
 134     [ qw(bang bar baz blah bling evaled_foo floob) ],
 135     '... got the right method list for Foo');
 136
 137 # ... test our class creator
 138
 139 my $Bar = Class::MOP::Class->create(
 140             'Bar' => '0.10' => (
 141                 superclasses => [ 'Foo' ],
 142                 methods => {
 143                     foo => sub { 'Bar::foo' },
 144                     bar => sub { 'Bar::bar' },
 145                 }
 146             ));
 147 isa_ok($Bar, 'Class::MOP::Class');
 148
 149 ok($Bar->has_method('foo'), '... Bar->has_method(foo)');
 150 ok($Bar->has_method('bar'), '... Bar->has_method(bar)');
 151
 152 is(Bar->foo, 'Bar::foo', '... Bar->foo == Bar::foo');
 153 is(Bar->bar, 'Bar::bar', '... Bar->bar == Bar::bar');
 154
 155 lives_ok {
 156     $Bar->add_method('foo' => sub { 'Bar::foo v2' });
 157 } '... overwriting a method is fine';
 158
 159 ok($Bar->has_method('foo'), '... Bar-> (still) has_method(foo)');
 160 is(Bar->foo, 'Bar::foo v2', '... Bar->foo == "Bar::foo v2"');
 161
 162 is_deeply(
 163     [ sort $Bar->get_method_list ],
 164     [ qw(bar foo meta) ],
 165     '... got the right method list for Bar');
 166
 167 is_deeply(
 168     [ sort { $a->{name} cmp $b->{name} } $Bar->compute_all_applicable_methods() ],
 169     [
 170         {
 171             name  => 'bang',
 172             class => 'Foo',
 173             code  => $Foo->get_method('bang')
 174         },
 175         {
 176             name  => 'bar',
 177             class => 'Bar',
 178             code  => $Bar->get_method('bar')
 179         },
 180         (map {
 181             {
 182                 name  => $_,
 183                 class => 'Foo',
 184                 code  => $Foo->get_method($_)
 185             }
 186         } qw(
 187             baz
 188             blah
 189             bling
 190             evaled_foo
 191             floob
 192         )),
 193         {
 194             name  => 'foo',
 195             class => 'Bar',
 196             code  => $Bar->get_method('foo')
 197         },
 198         {
 199             name  => 'meta',
 200             class => 'Bar',
 201             code  => $Bar->get_method('meta')
 202         }
 203     ],
 204     '... got the right list of applicable methods for Bar');
 205
 206