lib/Class/MOP/Method/Constructor.pm

   1
   2 package Class::MOP::Method::Constructor;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'blessed', 'weaken';
   9 use Try::Tiny;
  10
  11 our $VERSION   = '1.11';
  12 $VERSION = eval $VERSION;
  13 our $AUTHORITY = 'cpan:STEVAN';
  14
  15 use base 'Class::MOP::Method::Inlined';
  16
  17 sub new {
  18     my $class   = shift;
  19     my %options = @_;
  20
  21     (blessed $options{metaclass} && $options{metaclass}->isa('Class::MOP::Class'))
  22         || confess "You must pass a metaclass instance if you want to inline"
  23             if $options{is_inline};
  24
  25     ($options{package_name} && $options{name})
  26         || confess "You must supply the package_name and name parameters $Class::MOP::Method::UPGRADE_ERROR_TEXT";
  27
  28     my $self = $class->_new(\%options);
  29
  30     # we don't want this creating
  31     # a cycle in the code, if not
  32     # needed
  33     weaken($self->{'associated_metaclass'});
  34
  35     $self->_initialize_body;
  36
  37     return $self;
  38 }
  39
  40 sub _new {
  41     my $class = shift;
  42
  43     return Class::MOP::Class->initialize($class)->new_object(@_)
  44         if $class ne __PACKAGE__;
  45
  46     my $params = @_ == 1 ? $_[0] : {@_};
  47
  48     return bless {
  49         # inherited from Class::MOP::Method
  50         body                 => $params->{body},
  51         # associated_metaclass => $params->{associated_metaclass}, # overriden
  52         package_name         => $params->{package_name},
  53         name                 => $params->{name},
  54         original_method      => $params->{original_method},
  55
  56         # inherited from Class::MOP::Generated
  57         is_inline            => $params->{is_inline} || 0,
  58         definition_context   => $params->{definition_context},
  59
  60         # inherited from Class::MOP::Inlined
  61         _expected_method_class => $params->{_expected_method_class},
  62
  63         # defined in this subclass
  64         options              => $params->{options} || {},
  65         associated_metaclass => $params->{metaclass},
  66     }, $class;
  67 }
  68
  69 ## accessors
  70
  71 sub options              { (shift)->{'options'}              }
  72 sub associated_metaclass { (shift)->{'associated_metaclass'} }
  73
  74 ## cached values ...
  75
  76 sub _attributes {
  77     my $self = shift;
  78     $self->{'attributes'} ||= [ $self->associated_metaclass->get_all_attributes ]
  79 }
  80
  81 ## method
  82
  83 sub _initialize_body {
  84     my $self        = shift;
  85     my $method_name = '_generate_constructor_method';
  86
  87     $method_name .= '_inline' if $self->is_inline;
  88
  89     $self->{'body'} = $self->$method_name;
  90 }
  91
  92 sub _eval_environment {
  93     my $self = shift;
  94     my $defaults = [map { $_->default } @{ $self->_attributes }];
  95     return {
  96         '$defaults' => \$defaults,
  97     };
  98 }
  99
 100 sub _generate_constructor_method {
 101     return sub { Class::MOP::Class->initialize(shift)->new_object(@_) }
 102 }
 103
 104 sub _generate_constructor_method_inline {
 105     my $self = shift;
 106
 107     my $meta = $self->associated_metaclass;
 108
 109     my @source = (
 110         'sub {',
 111             $meta->_inline_new_object,
 112         '}',
 113     );
 114
 115     warn join("\n", @source) if $self->options->{debug};
 116
 117     my $code = try {
 118         $self->_compile_code(\@source);
 119     }
 120     catch {
 121         my $source = join("\n", @source);
 122         confess "Could not eval the constructor :\n\n$source\n\nbecause :\n\n$_";
 123     };
 124
 125     return $code;
 126 }
 127
 128 1;
 129
 130 __END__
 131
 132 =pod
 133
 134 =head1 NAME
 135
 136 Class::MOP::Method::Constructor - Method Meta Object for constructors
 137
 138 =head1 SYNOPSIS
 139
 140   use Class::MOP::Method::Constructor;
 141
 142   my $constructor = Class::MOP::Method::Constructor->new(
 143       metaclass => $metaclass,
 144       options   => {
 145           debug => 1, # this is all for now
 146       },
 147   );
 148
 149   # calling the constructor ...
 150   $constructor->body->execute($metaclass->name, %params);
 151
 152 =head1 DESCRIPTION
 153
 154 This is a subclass of C<Class::MOP::Method> which generates
 155 constructor methods.
 156
 157 =head1 METHODS
 158
 159 =over 4
 160
 161 =item B<< Class::MOP::Method::Constructor->new(%options) >>
 162
 163 This creates a new constructor object. It accepts a hash reference of
 164 options.
 165
 166 =over 8
 167
 168 =item * metaclass
 169
 170 This should be a L<Class::MOP::Class> object. It is required.
 171
 172 =item * name
 173
 174 The method name (without a package name). This is required.
 175
 176 =item * package_name
 177
 178 The package name for the method. This is required.
 179
 180 =item * is_inline
 181
 182 This indicates whether or not the constructor should be inlined. This
 183 defaults to false.
 184
 185 =back
 186
 187 =item B<< $metamethod->is_inline >>
 188
 189 Returns a boolean indicating whether or not the constructor is
 190 inlined.
 191
 192 =item B<< $metamethod->associated_metaclass >>
 193
 194 This returns the L<Class::MOP::Class> object for the method.
 195
 196 =back
 197
 198 =head1 AUTHORS
 199
 200 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 201
 202 =head1 COPYRIGHT AND LICENSE
 203
 204 Copyright 2006-2010 by Infinity Interactive, Inc.
 205
 206 L<http://www.iinteractive.com>
 207
 208 This library is free software; you can redistribute it and/or modify
 209 it under the same terms as Perl itself.
 210
 211 =cut
 212