lib/Class/MOP/Method.pm

   1
   2 package Class::MOP::Method;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'weaken';
   9
  10 our $VERSION   = '0.64_02';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Class::MOP::Object';
  15
  16 # NOTE:
  17 # if poked in the right way,
  18 # they should act like CODE refs.
  19 use overload '&{}' => sub { $_[0]->body }, fallback => 1;
  20
  21 our $UPGRADE_ERROR_TEXT = q{
  22 ---------------------------------------------------------
  23 NOTE: this error is likely not an error, but a regression
  24 caused by the latest upgrade to Moose/Class::MOP. Consider
  25 upgrading any MooseX::* modules to their latest versions
  26 before spending too much time chasing this one down.
  27 ---------------------------------------------------------
  28 };
  29
  30 # construction
  31
  32 sub wrap {
  33     my ( $class, @args ) = @_;
  34
  35     unshift @args, 'body' if @args % 2 == 1;
  36
  37     my %params = @args;
  38     my $code = $params{body};
  39
  40     ('CODE' eq ref($code))
  41         || confess "You must supply a CODE reference to bless, not (" . ($code || 'undef') . ")";
  42
  43     ($params{package_name} && $params{name})
  44         || confess "You must supply the package_name and name parameters $UPGRADE_ERROR_TEXT";
  45
  46     my $self = (ref($class) || $class)->_new(\%params);
  47
  48     weaken($self->{associated_metaclass}) if $self->{associated_metaclass};
  49
  50     return $self;
  51 }
  52
  53 sub _new {
  54     my $class = shift;
  55     my $params = @_ == 1 ? $_[0] : {@_};
  56
  57     my $self = bless {
  58         'body'                 => $params->{body},
  59         'associated_metaclass' => $params->{associated_metaclass},
  60         'package_name'         => $params->{package_name},
  61         'name'                 => $params->{name},
  62     } => $class;
  63 }
  64
  65 ## accessors
  66
  67 sub body { (shift)->{'body'} }
  68
  69 sub associated_metaclass { shift->{'associated_metaclass'} }
  70
  71 sub attach_to_class {
  72     my ( $self, $class ) = @_;
  73     $self->{associated_metaclass} = $class;
  74     weaken($self->{associated_metaclass});
  75 }
  76
  77 sub detach_from_class {
  78     my $self = shift;
  79     delete $self->{associated_metaclass};
  80 }
  81
  82 sub package_name {
  83     my $self = shift;
  84     $self->{'package_name'} ||= (Class::MOP::get_code_info($self->body))[0];
  85 }
  86
  87 sub name {
  88     my $self = shift;
  89     $self->{'name'} ||= (Class::MOP::get_code_info($self->body))[1];
  90 }
  91
  92 sub fully_qualified_name {
  93     my $code = shift;
  94     $code->package_name . '::' . $code->name;
  95 }
  96
  97 # NOTE:
  98 # the Class::MOP bootstrap
  99 # will create this for us
 100 # - SL
 101 # sub clone { ... }
 102
 103 1;
 104
 105 __END__
 106
 107 =pod
 108
 109 =head1 NAME
 110
 111 Class::MOP::Method - Method Meta Object
 112
 113 =head1 DESCRIPTION
 114
 115 The Method Protocol is very small, since methods in Perl 5 are just
 116 subroutines within the particular package. We provide a very basic
 117 introspection interface.
 118
 119 =head1 METHODS
 120
 121 =head2 Introspection
 122
 123 =over 4
 124
 125 =item B<meta>
 126
 127 This will return a B<Class::MOP::Class> instance which is related
 128 to this class.
 129
 130 =back
 131
 132 =head2 Construction
 133
 134 =over 4
 135
 136 =item B<wrap ($code, %params)>
 137
 138 This is the basic constructor, it returns a B<Class::MOP::Method>
 139 instance which wraps the given C<$code> reference. You can also
 140 set the C<package_name> and C<name> attributes using the C<%params>.
 141 If these are not set, then thier accessors will attempt to figure
 142 it out using the C<Class::MOP::get_code_info> function.
 143
 144 =item B<clone (%params)>
 145
 146 This will make a copy of the object, allowing you to override
 147 any values by stuffing them in C<%params>.
 148
 149 =back
 150
 151 =head2 Informational
 152
 153 =over 4
 154
 155 =item B<body>
 156
 157 This returns the actual CODE reference of the particular instance.
 158
 159 =item B<name>
 160
 161 This returns the name of the CODE reference.
 162
 163 =item B<associated_metaclass>
 164
 165 The metaclass of the method
 166
 167 =item B<package_name>
 168
 169 This returns the package name that the CODE reference is attached to.
 170
 171 =item B<fully_qualified_name>
 172
 173 This returns the fully qualified name of the CODE reference.
 174
 175 =back
 176
 177 =head2 Metaclass
 178
 179 =over 4
 180
 181 =item B<attach_to_class>
 182
 183 Sets the associated metaclass
 184
 185 =item B<detach_from_class>
 186
 187 Disassociates the method from the metaclass
 188
 189 =back
 190
 191 =head1 AUTHORS
 192
 193 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 194
 195 =head1 COPYRIGHT AND LICENSE
 196
 197 Copyright 2006-2008 by Infinity Interactive, Inc.
 198
 199 L<http://www.iinteractive.com>
 200
 201 This library is free software; you can redistribute it and/or modify
 202 it under the same terms as Perl itself.
 203
 204 =cut
 205