lib/Class/MOP/Method.pm

   1
   2 package Class::MOP::Method;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Carp         'confess';
   8 use Scalar::Util 'weaken';
   9
  10 our $VERSION   = '0.75';
  11 $VERSION = eval $VERSION;
  12 our $AUTHORITY = 'cpan:STEVAN';
  13
  14 use base 'Class::MOP::Object';
  15
  16 # NOTE:
  17 # if poked in the right way,
  18 # they should act like CODE refs.
  19 use overload '&{}' => sub { $_[0]->body }, fallback => 1;
  20
  21 our $UPGRADE_ERROR_TEXT = q{
  22 ---------------------------------------------------------
  23 NOTE: this error is likely not an error, but a regression
  24 caused by the latest upgrade to Moose/Class::MOP. Consider
  25 upgrading any MooseX::* modules to their latest versions
  26 before spending too much time chasing this one down.
  27 ---------------------------------------------------------
  28 };
  29
  30 # construction
  31
  32 sub wrap {
  33     my ( $class, @args ) = @_;
  34
  35     unshift @args, 'body' if @args % 2 == 1;
  36
  37     my %params = @args;
  38     my $code = $params{body};
  39
  40     ('CODE' eq ref($code))
  41         || confess "You must supply a CODE reference to bless, not (" . ($code || 'undef') . ")";
  42
  43     ($params{package_name} && $params{name})
  44         || confess "You must supply the package_name and name parameters $UPGRADE_ERROR_TEXT";
  45
  46     my $self = $class->_new(\%params);
  47
  48     weaken($self->{associated_metaclass}) if $self->{associated_metaclass};
  49
  50     return $self;
  51 }
  52
  53 sub _new {
  54     my $class = shift;
  55     my $params = @_ == 1 ? $_[0] : {@_};
  56
  57     my $self = bless {
  58         'body'                 => $params->{body},
  59         'associated_metaclass' => $params->{associated_metaclass},
  60         'package_name'         => $params->{package_name},
  61         'name'                 => $params->{name},
  62     } => $class;
  63 }
  64
  65 ## accessors
  66
  67 sub body { (shift)->{'body'} }
  68
  69 sub associated_metaclass { shift->{'associated_metaclass'} }
  70
  71 sub attach_to_class {
  72     my ( $self, $class ) = @_;
  73     $self->{associated_metaclass} = $class;
  74     weaken($self->{associated_metaclass});
  75 }
  76
  77 sub detach_from_class {
  78     my $self = shift;
  79     delete $self->{associated_metaclass};
  80 }
  81
  82 sub package_name { (shift)->{'package_name'} }
  83
  84 sub name { (shift)->{'name'} }
  85
  86 sub fully_qualified_name {
  87     my $self = shift;
  88     $self->package_name . '::' . $self->name;
  89 }
  90
  91 sub original_method { (shift)->{'original_method'} }
  92
  93 sub _set_original_method { $_[0]->{'original_method'} = $_[1] }
  94
  95 # It's possible that this could cause a loop if there is a circular
  96 # reference in here. That shouldn't ever happen in normal
  97 # circumstances, since original method only gets set when clone is
  98 # called. We _could_ check for such a loop, but it'd involve some sort
  99 # of package-lexical variable, and wouldn't be terribly subclassable.
 100 sub original_package_name {
 101     my $self = shift;
 102
 103     $self->original_method
 104         ? $self->original_method->original_package_name
 105         : $self->package_name;
 106 }
 107
 108 sub original_name {
 109     my $self = shift;
 110
 111     $self->original_method
 112         ? $self->original_method->original_name
 113         : $self->name;
 114 }
 115
 116 sub original_fully_qualified_name {
 117     my $self = shift;
 118
 119     $self->original_method
 120         ? $self->original_method->original_fully_qualified_name
 121         : $self->fully_qualified_name;
 122 }
 123
 124 sub execute {
 125     my $self = shift;
 126     $self->body->(@_);
 127 }
 128
 129 # NOTE:
 130 # the Class::MOP bootstrap
 131 # will create this for us
 132 # - SL
 133 # sub clone { ... }
 134
 135 1;
 136
 137 __END__
 138
 139 =pod
 140
 141 =head1 NAME
 142
 143 Class::MOP::Method - Method Meta Object
 144
 145 =head1 DESCRIPTION
 146
 147 The Method Protocol is very small, since methods in Perl 5 are just
 148 subroutines within the particular package. We provide a very basic
 149 introspection interface.
 150
 151 =head1 METHODS
 152
 153 =head2 Introspection
 154
 155 =over 4
 156
 157 =item B<meta>
 158
 159 This will return a B<Class::MOP::Class> instance which is related
 160 to this class.
 161
 162 =back
 163
 164 =head2 Construction
 165
 166 =over 4
 167
 168 =item B<wrap ($code, %params)>
 169
 170 This is the basic constructor, it returns a B<Class::MOP::Method>
 171 instance which wraps the given C<$code> reference. You must also set
 172 the C<package_name> and C<name> attributes in C<%params>.
 173
 174 =item B<clone (%params)>
 175
 176 This will make a copy of the object, allowing you to override
 177 any values by stuffing them in C<%params>.
 178
 179 =back
 180
 181 =head2 Informational
 182
 183 =over 4
 184
 185 =item B<body>
 186
 187 This returns the actual CODE reference of the particular instance.
 188
 189 =item B<name>
 190
 191 This returns the name of the CODE reference.
 192
 193 =item B<associated_metaclass>
 194
 195 The metaclass of the method
 196
 197 =item B<package_name>
 198
 199 This returns the package name that the CODE reference is attached to.
 200
 201 =item B<fully_qualified_name>
 202
 203 This returns the fully qualified name of the CODE reference.
 204
 205 =item B<original_method>
 206
 207 If this method object was created as a clone of some other method
 208 object, this returns the object that was cloned.
 209
 210 =item B<original_name>
 211
 212 This returns the original name of the CODE reference, wherever it was
 213 first defined.
 214
 215 If this method is a clone of a clone (of a clone, etc.), this method
 216 returns the name from the I<first> method in the chain of clones.
 217
 218 =item B<original_package_name>
 219
 220 This returns the original package name that the CODE reference is
 221 attached to, wherever it was first defined.
 222
 223 If this method is a clone of a clone (of a clone, etc.), this method
 224 returns the package name from the I<first> method in the chain of
 225 clones.
 226
 227 =item B<original_fully_qualified_name>
 228
 229 This returns the original fully qualified name of the CODE reference,
 230 wherever it was first defined.
 231
 232 If this method is a clone of a clone (of a clone, etc.), this method
 233 returns the fully qualified name from the I<first> method in the chain
 234 of clones.
 235
 236 =back
 237
 238 =head2 Metaclass
 239
 240 =over 4
 241
 242 =item B<attach_to_class>
 243
 244 Sets the associated metaclass
 245
 246 =item B<detach_from_class>
 247
 248 Disassociates the method from the metaclass
 249
 250 =back
 251
 252 =head2 Miscellaneous
 253
 254 =over 4
 255
 256 =item B<execute>
 257
 258 Executes the method. Be sure to pass in the instance, since the
 259 method expects it.
 260
 261 =back
 262
 263 =head1 AUTHORS
 264
 265 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 266
 267 =head1 COPYRIGHT AND LICENSE
 268
 269 Copyright 2006-2008 by Infinity Interactive, Inc.
 270
 271 L<http://www.iinteractive.com>
 272
 273 This library is free software; you can redistribute it and/or modify
 274 it under the same terms as Perl itself.
 275
 276 =cut
 277