lib/Class/MOP.pm

   1
   2 package Class::MOP;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed';
   8 use Carp         'confess';
   9
  10 use Class::MOP::Class;
  11 use Class::MOP::Attribute;
  12 use Class::MOP::Method;
  13
  14 our $VERSION = '0.01';
  15
  16 sub import {
  17     shift;
  18     return unless @_;
  19     if ($_[0] eq ':universal') {
  20         *UNIVERSAL::meta = sub {
  21             Class::MOP::Class->initialize(blessed($_[0]) || $_[0])
  22         };
  23     }
  24     else {
  25         my $pkg = caller();
  26         no strict 'refs';
  27         *{$pkg . '::' . $_[0]} = sub {
  28             Class::MOP::Class->initialize(blessed($_[0]) || $_[0])
  29         };
  30     }
  31 }
  32
  33 ## ----------------------------------------------------------------------------
  34 ## Bootstrapping
  35 ## ----------------------------------------------------------------------------
  36 ## The code below here is to bootstrap our MOP with itself. This is also
  37 ## sometimes called "tying the knot". By doing this, we make it much easier
  38 ## to extend the MOP through subclassing and such since now you can use the
  39 ## MOP itself to extend itself.
  40 ##
  41 ## Yes, I know, thats weird and insane, but it's a good thing, trust me :)
  42 ## ----------------------------------------------------------------------------
  43
  44 # We need to add in the meta-attributes here so that
  45 # any subclass of Class::MOP::* will be able to
  46 # inherit them using &construct_instance
  47
  48 ## Class::MOP::Class
  49
  50 Class::MOP::Class->meta->add_attribute(
  51     Class::MOP::Attribute->new('$:pkg' => (
  52         init_arg => ':pkg'
  53     ))
  54 );
  55
  56 Class::MOP::Class->meta->add_attribute(
  57     Class::MOP::Attribute->new('%:attrs' => (
  58         init_arg => ':attrs',
  59         default  => sub { {} }
  60     ))
  61 );
  62
  63 ## Class::MOP::Attribute
  64
  65 Class::MOP::Attribute->meta->add_attribute(Class::MOP::Attribute->new('name'));
  66 Class::MOP::Attribute->meta->add_attribute(Class::MOP::Attribute->new('accessor'));
  67 Class::MOP::Attribute->meta->add_attribute(Class::MOP::Attribute->new('reader'));
  68 Class::MOP::Attribute->meta->add_attribute(Class::MOP::Attribute->new('writer'));
  69 Class::MOP::Attribute->meta->add_attribute(Class::MOP::Attribute->new('predicate'));
  70 Class::MOP::Attribute->meta->add_attribute(Class::MOP::Attribute->new('init_arg'));
  71 Class::MOP::Attribute->meta->add_attribute(Class::MOP::Attribute->new('default'));
  72
  73 # NOTE: (meta-circularity)
  74 # This should be one of the last things done
  75 # it will "tie the knot" with Class::MOP::Attribute
  76 # so that it uses the attributes meta-objects
  77 # to construct itself.
  78 Class::MOP::Attribute->meta->add_method('new' => sub {
  79     my $class   = shift;
  80     my $name    = shift;
  81     my %options = @_;
  82
  83     (defined $name && $name)
  84         || confess "You must provide a name for the attribute";
  85     (!exists $options{reader} && !exists $options{writer})
  86         || confess "You cannot declare an accessor and reader and/or writer functions"
  87             if exists $options{accessor};
  88
  89     bless $class->meta->construct_instance(name => $name, %options) => $class;
  90 });
  91
  92 1;
  93
  94 __END__
  95
  96 =pod
  97
  98 =head1 NAME
  99
 100 Class::MOP - A Meta Object Protocol for Perl 5
 101
 102 =head1 SYNOPSIS
 103
 104   # ... This will come later, for now see
 105   # the other SYNOPSIS for more information
 106
 107 =head1 DESCRIPTON
 108
 109 This module is an attempt to create a meta object protocol for the
 110 Perl 5 object system. It makes no attempt to change the behavior or
 111 characteristics of the Perl 5 object system, only to create a
 112 protocol for its manipulation and introspection.
 113
 114 That said, it does attempt to create the tools for building a rich
 115 set of extensions to the Perl 5 object system. Every attempt has been
 116 made for these tools to keep to the spirit of the Perl 5 object
 117 system that we all know and love.
 118
 119 =head2 What is a Meta Object Protocol?
 120
 121 A meta object protocol is an API to an object system.
 122
 123 To be more specific, it is a set of abstractions of the components of
 124 an object system (typically things like; classes, object, methods,
 125 object attributes, etc.). These abstractions can then be used to both
 126 inspect and manipulate the object system which they describe.
 127
 128 It can be said that there are two MOPs for any object system; the
 129 implicit MOP, and the explicit MOP. The implicit MOP handles things
 130 like method dispatch or inheritance, which happen automatically as
 131 part of how the object system works. The explicit MOP typically
 132 handles the introspection/reflection features of the object system.
 133 All object systems have implicit MOPs, without one, they would not
 134 work. Explict MOPs however as less common, and depending on the
 135 language can vary from restrictive (Reflection in Java or C#) to
 136 wide open (CLOS is a perfect example).
 137
 138 =head2 Yet Another Class Builder!! Why?
 139
 140 This is B<not> a class builder so much as it is a I<class builder
 141 B<builder>>. My intent is that an end user does not use this module
 142 directly, but instead this module is used by module authors to
 143 build extensions and features onto the Perl 5 object system.
 144
 145 =head2 Who is this module for?
 146
 147 This module is specifically for anyone who has ever created or
 148 wanted to create a module for the Class:: namespace. The tools which
 149 this module will provide will hopefully make it easier to do more
 150 complex things with Perl 5 classes by removing such barriers as
 151 the need to hack the symbol tables, or understand the fine details
 152 of method dispatch.
 153
 154 =head2 What changes do I have to make to use this module?
 155
 156 This module was designed to be as unintrusive as possible. Many of
 157 it's features are accessible without B<any> change to your existsing
 158 code at all. It is meant to be a compliment to your existing code and
 159 not an intrusion on your code base. Unlike many other B<Class::>
 160 modules, this module B<does not> require you subclass it, or even that
 161 you C<use> it in within your module's package.
 162
 163 The only features which requires additions to your code are the
 164 attribute handling and instance construction features, and these are
 165 both completely optional features. The only reason for this is because
 166 Perl 5's object system does not actually have these features built
 167 in. More information about this feature can be found below.
 168
 169 =head2 A Note about Performance?
 170
 171 It is a common misconception that explict MOPs are performance drains.
 172 But this is not a universal truth at all, it is an side-effect of
 173 specific implementations. For instance, using Java reflection is much
 174 slower because the JVM cannot take advantage of any compiler
 175 optimizations, and the JVM has to deal with much more runtime type
 176 information as well. Reflection in C# is marginally better as it was
 177 designed into the language and runtime (the CLR). In contrast, CLOS
 178 (the Common Lisp Object System) was built to support an explicit MOP,
 179 and so performance is tuned for it.
 180
 181 This library in particular does it's absolute best to avoid putting
 182 B<any> drain at all upon your code's performance. In fact, by itself
 183 it does nothing to affect your existing code. So you only pay for
 184 what you actually use.
 185
 186 =head1 PROTOCOLS
 187
 188 The protocol is divided into 3 main sub-protocols:
 189
 190 =over 4
 191
 192 =item The Class protocol
 193
 194 This provides a means of manipulating and introspecting a Perl 5
 195 class. It handles all of symbol table hacking for you, and provides
 196 a rich set of methods that go beyond simple package introspection.
 197
 198 See L<Class::MOP::Class> for more details.
 199
 200 =item The Attribute protocol
 201
 202 This provides a consistent represenation for an attribute of a
 203 Perl 5 class. Since there are so many ways to create and handle
 204 atttributes in Perl 5 OO, this attempts to provide as much of a
 205 unified approach as possible, while giving the freedom and
 206 flexibility to subclass for specialization.
 207
 208 See L<Class::MOP::Attribute> for more details.
 209
 210 =item The Method protocol
 211
 212 This provides a means of manipulating and introspecting methods in
 213 the Perl 5 object system. As with attributes, there are many ways to
 214 approach this topic, so we try to keep it pretty basic, while still
 215 making it possible to extend the system in many ways.
 216
 217 See L<Class::MOP::Method> for more details.
 218
 219 =back
 220
 221 =head1 SEE ALSO
 222
 223 =head2 Books
 224
 225 There are very few books out on Meta Object Protocols and Metaclasses
 226 because it is such an esoteric topic. The following books are really
 227 the only ones I have found. If you know of any more, B<I<please>>
 228 email me and let me know, I would love to hear about them.
 229
 230 =over 4
 231
 232 =item "The Art of the Meta Object Protocol"
 233
 234 =item "Advances in Object-Oriented Metalevel Architecture and Reflection"
 235
 236 =item "Putting MetaClasses to Work"
 237
 238 =item "Smalltalk: The Language"
 239
 240 =back
 241
 242 =head2 Prior Art
 243
 244 =over 4
 245
 246 =item The Perl 6 MetaModel work in the Pugs project
 247
 248 =over 4
 249
 250 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-MetaModel>
 251
 252 =item L<http://svn.openfoundry.org/pugs/perl5/Perl6-ObjectSpace>
 253
 254 =back
 255
 256 =back
 257
 258 =head1 SIMILAR MODULES
 259
 260 As I have said above, this module is a class-builder-builder, so it is
 261 not the same thing as modules like L<Class::Accessor> and
 262 L<Class::MethodMaker>. That being said there are very few modules on CPAN
 263 with similar goals to this module. The one I have found which is most
 264 like this module is L<Class::Meta>, although it's philosophy is very
 265 different from this module.
 266
 267 To start with, it provides wrappers around common Perl data types, and even
 268 extends those types with more specific subtypes. This module does not
 269 go into that area at all.
 270
 271 L<Class::Meta> also seems to create it's own custom meta-object protocol,
 272 which is both more restrictive and more featureful than the vanilla
 273 Perl 5 one. This module attempts to model the existing Perl 5 MOP as it is.
 274
 275 It's introspection capabilities also seem to be heavily rooted in this
 276 custom MOP, so that you can only introspect classes which are already
 277 created with L<Class::Meta>. This module does not make such restictions.
 278
 279 Now, all this said, L<Class::Meta> is much more featureful than B<Class::MOP>
 280 would ever try to be. But B<Class::MOP> has some features which L<Class::Meta>
 281 could not easily implement. It would be very possible to completely re-implement
 282 L<Class::Meta> using B<Class::MOP> and bring some of these features to
 283 L<Class::Meta> though.
 284
 285 But in the end, this module's admitedly ambitious goals have no direct equal
 286 on CPAN since surely no one has been crazy enough to try something as silly
 287 as this ;) until now.
 288
 289 =head1 BUGS
 290
 291 All complex software has bugs lurking in it, and this module is no
 292 exception. If you find a bug please either email me, or add the bug
 293 to cpan-RT.
 294
 295 =head1 ACKNOWLEDGEMENTS
 296
 297 =over 4
 298
 299 =item Rob Kinyon E<lt>rob@iinteractive.comE<gt>
 300
 301 Thanks to Rob for actually getting the development of this module kick-started.
 302
 303 =back
 304
 305 =head1 AUTHOR
 306
 307 Stevan Little E<lt>stevan@iinteractive.comE<gt>
 308
 309 =head1 COPYRIGHT AND LICENSE
 310
 311 Copyright 2006 by Infinity Interactive, Inc.
 312
 313 L<http://www.iinteractive.com>
 314
 315 This library is free software; you can redistribute it and/or modify
 316 it under the same terms as Perl itself.
 317
 318 =cut