Makefile.PL

   1 use strict;
   2 use warnings;
   3 use inc::Module::Install;
   4 use 5.008001;
   5
   6 check_conflicts();
   7
   8 name 'Class-MOP';
   9 perl_version '5.008001';
  10 all_from 'lib/Class/MOP.pm';
  11 license 'perl';
  12
  13 require Config;
  14 my $ccflags = ( $Config::Config{ccflags} || '' ) . ' -I.';
  15
  16 if ( -d '.git' || $ENV{MAINTAINER_MODE} ) {
  17     $ccflags .= ' -Wall -Wdeclaration-after-statement';
  18 }
  19
  20 requires 'Carp';
  21 requires 'Data::OptList';
  22 requires 'Devel::GlobalDestruction';
  23 requires 'MRO::Compat'  => '0.05';
  24 requires 'Scalar::Util' => '1.18';
  25 requires 'Sub::Name'    => '0.04';
  26 requires 'Try::Tiny'    => '0.02';
  27 requires 'Task::Weaken';
  28
  29 test_requires 'File::Spec';
  30 test_requires 'Test::More'      => '0.88';
  31 test_requires 'Test::Exception' => '0.27';
  32
  33 repository 'git://git.moose.perl.org/Class-MOP.git';
  34
  35 extra_tests();
  36
  37 makemaker_args( CCFLAGS => $ccflags );
  38
  39 {
  40     my (@clean, @OBJECT, %XS);
  41
  42     for my $xs (<xs/*.xs>) {
  43         (my $c = $xs) =~ s/\.xs$/.c/i;
  44         (my $o = $xs) =~ s/\.xs$/\$(OBJ_EXT)/i;
  45
  46         $XS{$xs} = $c;
  47         push @OBJECT, $o;
  48         push @clean, $o;
  49     }
  50
  51     for my $c (<*.c>) {
  52         (my $o = $c) =~ s/\.c$/\$(OBJ_EXT)/i;
  53         push @OBJECT, $o;
  54         push @clean, $o;
  55     }
  56
  57     makemaker_args(
  58         clean  => { FILES => join(q{ }, @clean) },
  59         OBJECT => join (q{ }, @OBJECT),
  60         XS     => \%XS,
  61     );
  62 }
  63
  64 postamble(<<'EOM');
  65 $(OBJECT) : mop.h
  66 EOM
  67
  68 WriteAll();
  69
  70 # Use the cpan-smolder-stable script in the Moose svn root to figure
  71 # out what on CPAN will break with the latest Moose, then update this
  72 # before a release.
  73 sub check_conflicts {
  74     my %conflicts = (
  75         'Moose' => '0.85',
  76     );
  77
  78     my $found = 0;
  79     for my $mod ( sort keys %conflicts ) {
  80         eval "require $mod";
  81         next if $@;
  82
  83         my $installed = $mod->VERSION();
  84         if ( $installed le $conflicts{$mod} ) {
  85
  86             print <<"EOF";
  87
  88 ***
  89     This version of Class::MOP conflicts with the version of
  90     $mod ($installed) you have installed.
  91
  92     You will need to upgrade $mod after installing
  93     this version of Class::MOP.
  94 ***
  95
  96 EOF
  97
  98             $found = 1;
  99         }
 100     }
 101
 102     return unless $found;
 103
 104     # More or less copied from Module::Build
 105     return if $ENV{PERL_MM_USE_DEFAULT};
 106     return unless -t STDIN && ( -t STDOUT || !( -f STDOUT || -c STDOUT ) );
 107
 108     sleep 4;
 109 }
 110
 111 package MY;
 112
 113 use Config;
 114
 115 sub const_cccmd {
 116     my $ret = shift->SUPER::const_cccmd(@_);
 117     return q{} unless $ret;
 118
 119     if ($Config{cc} =~ /^cl\b/i) {
 120         warn 'you are using MSVC... my condolences.';
 121         $ret .= ' /Fo$@';
 122     }
 123     else {
 124         $ret .= ' -o $@';
 125     }
 126
 127     return $ret;
 128 }