lib/SQL/Translator/Schema/Trigger.pm

   1 package SQL::Translator::Schema::Trigger;
   2
   3 =pod
   4
   5 =head1 NAME
   6
   7 SQL::Translator::Schema::Trigger - SQL::Translator trigger object
   8
   9 =head1 SYNOPSIS
  10
  11   use SQL::Translator::Schema::Trigger;
  12   my $trigger = SQL::Translator::Schema::Trigger->new(
  13     name                => 'foo',
  14     perform_action_when => 'before', # or after
  15     database_events     => [qw/update insert/], # also update, update_on, delete
  16     fields              => [],       # if event is "update"
  17     on_table            => 'foo',    # table name
  18     action              => '...',    # text of trigger
  19     schema              => $schema,  # Schema object
  20     scope               => 'row',    # or statement
  21   );
  22
  23 =head1 DESCRIPTION
  24
  25 C<SQL::Translator::Schema::Trigger> is the trigger object.
  26
  27 =head1 METHODS
  28
  29 =cut
  30
  31 use strict;
  32 use warnings;
  33 use SQL::Translator::Utils 'parse_list_arg';
  34
  35 use base 'SQL::Translator::Schema::Object';
  36
  37 use Carp;
  38
  39 our ( $TABLE_COUNT, $VIEW_COUNT );
  40
  41 our $VERSION = '1.59';
  42
  43 __PACKAGE__->_attributes( qw/
  44     name schema perform_action_when database_events database_event
  45     fields table on_table action order scope
  46 /);
  47
  48 =pod
  49
  50 =head2 new
  51
  52 Object constructor.
  53
  54   my $schema = SQL::Translator::Schema::Trigger->new;
  55
  56 =cut
  57
  58 sub perform_action_when {
  59
  60 =pod
  61
  62 =head2 perform_action_when
  63
  64 Gets or sets whether the event happens "before" or "after" the
  65 C<database_event>.
  66
  67   $trigger->perform_action_when('after');
  68
  69 =cut
  70
  71     my $self = shift;
  72
  73     if ( my $arg = shift ) {
  74         $arg =  lc $arg;
  75         $arg =~ s/\s+/ /g;
  76         if ( $arg =~ m/^(before|after)$/i ) {
  77             $self->{'perform_action_when'} = $arg;
  78         }
  79         else {
  80             return
  81                 $self->error("Invalid argument '$arg' to perform_action_when");
  82         }
  83     }
  84
  85     return $self->{'perform_action_when'};
  86 }
  87
  88 sub database_event {
  89
  90 =pod
  91
  92 =head2 database_event
  93
  94 Obsolete please use database_events!
  95
  96 =cut
  97
  98     my $self = shift;
  99
 100     return $self->database_events( @_ );
 101 }
 102
 103 sub database_events {
 104
 105 =pod
 106
 107 =head2 database_events
 108
 109 Gets or sets the events that triggers the trigger.
 110
 111   my $ok = $trigger->database_events('insert');
 112
 113 =cut
 114
 115     my $self = shift;
 116     my @args = ref $_[0] eq 'ARRAY' ? @{ $_[0] } : @_;
 117
 118     if ( @args ) {
 119         @args       = map { s/\s+/ /g; lc $_ } @args;
 120         my %valid   = map { $_, 1 } qw[ insert update update_on delete ];
 121         my @invalid = grep { !defined $valid{ $_ } } @args;
 122
 123         if ( @invalid ) {
 124             return $self->error(
 125                 sprintf("Invalid events '%s' in database_events",
 126                     join(', ', @invalid)
 127                 )
 128             );
 129         }
 130
 131         $self->{'database_events'} = [ @args ];
 132     }
 133
 134     return wantarray
 135         ? @{ $self->{'database_events'} || [] }
 136         : $self->{'database_events'};
 137 }
 138
 139 sub fields {
 140
 141 =pod
 142
 143 =head2 fields
 144
 145 Gets and set which fields to monitor for C<database_event>.
 146
 147   $view->fields('id');
 148   $view->fields('id', 'name');
 149   $view->fields( 'id, name' );
 150   $view->fields( [ 'id', 'name' ] );
 151   $view->fields( qw[ id name ] );
 152
 153   my @fields = $view->fields;
 154
 155 =cut
 156
 157     my $self = shift;
 158     my $fields = parse_list_arg( @_ );
 159
 160     if ( @$fields ) {
 161         my ( %unique, @unique );
 162         for my $f ( @$fields ) {
 163             next if $unique{ $f };
 164             $unique{ $f } = 1;
 165             push @unique, $f;
 166         }
 167
 168         $self->{'fields'} = \@unique;
 169     }
 170
 171     return wantarray ? @{ $self->{'fields'} || [] } : $self->{'fields'};
 172 }
 173
 174 sub table {
 175
 176 =pod
 177
 178 =head2 table
 179
 180 Gets or set the table on which the trigger works, as a L<SQL::Translator::Schema::Table> object.
 181   $trigger->table($triggered_table);
 182
 183 =cut
 184
 185     my ($self, $arg) = @_;
 186     if ( @_ == 2 ) {
 187         $self->error("Table attribute of a ".__PACKAGE__.
 188                      " must be a SQL::Translator::Schema::Table")
 189             unless ref $arg and $arg->isa('SQL::Translator::Schema::Table');
 190         $self->{table} = $arg;
 191     }
 192     return $self->{table};
 193 }
 194
 195 sub on_table {
 196
 197 =pod
 198
 199 =head2 on_table
 200
 201 Gets or set the table name on which the trigger works, as a string.
 202   $trigger->on_table('foo');
 203
 204 =cut
 205
 206     my ($self, $arg) = @_;
 207     if ( @_ == 2 ) {
 208         my $table = $self->schema->get_table($arg);
 209         die "Table named $arg doesn't exist"
 210             if !$table;
 211         $self->table($table);
 212     }
 213     return $self->table->name;
 214 }
 215
 216 sub action {
 217
 218 =pod
 219
 220 =head2 action
 221
 222 Gets or set the action of the trigger.
 223
 224   $trigger->action(
 225       q[
 226         BEGIN
 227           select ...;
 228           update ...;
 229         END
 230       ]
 231   );
 232
 233 =cut
 234
 235     my $self = shift;
 236     my $arg  = shift || '';
 237     $self->{'action'} = $arg if $arg;
 238     return $self->{'action'};
 239 }
 240
 241 sub is_valid {
 242
 243 =pod
 244
 245 =head2 is_valid
 246
 247 Determine whether the trigger is valid or not.
 248
 249   my $ok = $trigger->is_valid;
 250
 251 =cut
 252
 253     my $self = shift;
 254
 255     for my $attr (
 256         qw[ name perform_action_when database_events on_table action ]
 257     ) {
 258         return $self->error("Invalid: missing '$attr'") unless $self->$attr();
 259     }
 260
 261     return $self->error("Missing fields for UPDATE ON") if
 262         $self->database_event eq 'update_on' && !$self->fields;
 263
 264     return 1;
 265 }
 266
 267 sub name {
 268
 269 =pod
 270
 271 =head2 name
 272
 273 Get or set the trigger's name.
 274
 275   my $name = $trigger->name('foo');
 276
 277 =cut
 278
 279     my $self        = shift;
 280     $self->{'name'} = shift if @_;
 281     return $self->{'name'} || '';
 282 }
 283
 284 sub order {
 285
 286 =pod
 287
 288 =head2 order
 289
 290 Get or set the trigger's order.
 291
 292   my $order = $trigger->order(3);
 293
 294 =cut
 295
 296     my ( $self, $arg ) = @_;
 297
 298     if ( defined $arg && $arg =~ /^\d+$/ ) {
 299         $self->{'order'} = $arg;
 300     }
 301
 302     return $self->{'order'} || 0;
 303 }
 304
 305
 306 sub scope {
 307
 308 =pod
 309
 310 =head2 scope
 311
 312 Get or set the trigger's scope (row or statement).
 313
 314     my $scope = $trigger->scope('statement');
 315
 316 =cut
 317
 318     my ( $self, $arg ) = @_;
 319
 320     if ( defined $arg ) {
 321         return $self->error( "Invalid scope '$arg'" )
 322             unless $arg =~ /^(row|statement)$/i;
 323
 324         $self->{scope} = $arg;
 325     }
 326
 327     return $self->{scope} || '';
 328 }
 329
 330 sub schema {
 331
 332 =pod
 333
 334 =head2 schema
 335
 336 Get or set the trigger's schema object.
 337
 338   $trigger->schema( $schema );
 339   my $schema = $trigger->schema;
 340
 341 =cut
 342
 343     my $self = shift;
 344     if ( my $arg = shift ) {
 345         return $self->error('Not a schema object') unless
 346             UNIVERSAL::isa( $arg, 'SQL::Translator::Schema' );
 347         $self->{'schema'} = $arg;
 348     }
 349
 350     return $self->{'schema'};
 351 }
 352
 353 sub compare_arrays {
 354
 355 =pod
 356
 357 =head2 compare_arrays
 358
 359 Compare two arrays.
 360
 361 =cut
 362
 363     my ($first, $second) = @_;
 364     no warnings;  # silence spurious -w undef complaints
 365
 366     return 0 unless (ref $first eq 'ARRAY' and ref $second eq 'ARRAY' ) ;
 367
 368     return 0 unless @$first == @$second;
 369
 370     my @first = sort @$first;
 371
 372     my @second = sort @$second;
 373
 374     for (my $i = 0; $i < scalar @first; $i++) {
 375         return 0 if @first[$i] ne @second[$i];
 376     }
 377
 378     return 1;
 379 }
 380
 381 sub equals {
 382
 383 =pod
 384
 385 =head2 equals
 386
 387 Determines if this trigger is the same as another
 388
 389   my $is_identical = $trigger1->equals( $trigger2 );
 390
 391 =cut
 392
 393     my $self             = shift;
 394     my $other            = shift;
 395     my $case_insensitive = shift;
 396
 397     return 0 unless $self->SUPER::equals($other);
 398
 399     my %names;
 400     for my $name ( $self->name, $other->name ) {
 401         $name = lc $name if $case_insensitive;
 402         $names{ $name }++;
 403     }
 404
 405     if ( keys %names > 1 ) {
 406         return $self->error('Names not equal');
 407     }
 408
 409     if ( !$self->perform_action_when eq $other->perform_action_when ) {
 410         return $self->error('perform_action_when differs');
 411     }
 412
 413     if (
 414         !compare_arrays( [$self->database_events], [$other->database_events] )
 415     ) {
 416         return $self->error('database_events differ');
 417     }
 418
 419     if ( $self->on_table ne $other->on_table ) {
 420         return $self->error('on_table differs');
 421     }
 422
 423     if ( $self->action ne $other->action ) {
 424         return $self->error('action differs');
 425     }
 426
 427     if (
 428         !$self->_compare_objects( scalar $self->extra, scalar $other->extra )
 429     ) {
 430         return $self->error('extras differ');
 431     }
 432
 433     return 1;
 434 }
 435
 436 sub DESTROY {
 437     my $self = shift;
 438     undef $self->{'schema'}; # destroy cyclical reference
 439 }
 440
 441 1;
 442
 443 =pod
 444
 445 =head1 AUTHORS
 446
 447 Anonymous,
 448 Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>.
 449
 450 =cut