lib/SQL/Translator/Schema/Trigger.pm

   1 package SQL::Translator::Schema::Trigger;
   2
   3 =pod
   4
   5 =head1 NAME
   6
   7 SQL::Translator::Schema::Trigger - SQL::Translator trigger object
   8
   9 =head1 SYNOPSIS
  10
  11   use SQL::Translator::Schema::Trigger;
  12   my $trigger = SQL::Translator::Schema::Trigger->new(
  13     name                => 'foo',
  14     perform_action_when => 'before', # or after
  15     database_events     => [qw/update insert/], # also update, update_on, delete
  16     fields              => [],       # if event is "update"
  17     on_table            => 'foo',    # table name
  18     action              => '...',    # text of trigger
  19     schema              => $schema,  # Schema object
  20   );
  21
  22 =head1 DESCRIPTION
  23
  24 C<SQL::Translator::Schema::Trigger> is the trigger object.
  25
  26 =head1 METHODS
  27
  28 =cut
  29
  30 use strict;
  31 use warnings;
  32 use SQL::Translator::Utils 'parse_list_arg';
  33
  34 use base 'SQL::Translator::Schema::Object';
  35
  36 use Carp;
  37
  38 our ( $TABLE_COUNT, $VIEW_COUNT );
  39
  40 our $VERSION = '1.59';
  41
  42 __PACKAGE__->_attributes( qw/
  43     name schema perform_action_when database_events database_event
  44     fields table on_table action order
  45 /);
  46
  47 =pod
  48
  49 =head2 new
  50
  51 Object constructor.
  52
  53   my $schema = SQL::Translator::Schema::Trigger->new;
  54
  55 =cut
  56
  57 sub perform_action_when {
  58
  59 =pod
  60
  61 =head2 perform_action_when
  62
  63 Gets or sets whether the event happens "before" or "after" the
  64 C<database_event>.
  65
  66   $trigger->perform_action_when('after');
  67
  68 =cut
  69
  70     my $self = shift;
  71
  72     if ( my $arg = shift ) {
  73         $arg =  lc $arg;
  74         $arg =~ s/\s+/ /g;
  75         if ( $arg =~ m/^(before|after)$/i ) {
  76             $self->{'perform_action_when'} = $arg;
  77         }
  78         else {
  79             return
  80                 $self->error("Invalid argument '$arg' to perform_action_when");
  81         }
  82     }
  83
  84     return $self->{'perform_action_when'};
  85 }
  86
  87 sub database_event {
  88
  89 =pod
  90
  91 =head2 database_event
  92
  93 Obsolete please use database_events!
  94
  95 =cut
  96
  97     my $self = shift;
  98
  99     return $self->database_events( @_ );
 100 }
 101
 102 sub database_events {
 103
 104 =pod
 105
 106 =head2 database_events
 107
 108 Gets or sets the events that triggers the trigger.
 109
 110   my $ok = $trigger->database_events('insert');
 111
 112 =cut
 113
 114     my $self = shift;
 115     my @args = ref $_[0] eq 'ARRAY' ? @{ $_[0] } : @_;
 116
 117     if ( @args ) {
 118         @args       = map { s/\s+/ /g; lc $_ } @args;
 119         my %valid   = map { $_, 1 } qw[ insert update update_on delete ];
 120         my @invalid = grep { !defined $valid{ $_ } } @args;
 121
 122         if ( @invalid ) {
 123             return $self->error(
 124                 sprintf("Invalid events '%s' in database_events",
 125                     join(', ', @invalid)
 126                 )
 127             );
 128         }
 129
 130         $self->{'database_events'} = [ @args ];
 131     }
 132
 133     return wantarray
 134         ? @{ $self->{'database_events'} || [] }
 135         : $self->{'database_events'};
 136 }
 137
 138 sub fields {
 139
 140 =pod
 141
 142 =head2 fields
 143
 144 Gets and set which fields to monitor for C<database_event>.
 145
 146   $view->fields('id');
 147   $view->fields('id', 'name');
 148   $view->fields( 'id, name' );
 149   $view->fields( [ 'id', 'name' ] );
 150   $view->fields( qw[ id name ] );
 151
 152   my @fields = $view->fields;
 153
 154 =cut
 155
 156     my $self = shift;
 157     my $fields = parse_list_arg( @_ );
 158
 159     if ( @$fields ) {
 160         my ( %unique, @unique );
 161         for my $f ( @$fields ) {
 162             next if $unique{ $f };
 163             $unique{ $f } = 1;
 164             push @unique, $f;
 165         }
 166
 167         $self->{'fields'} = \@unique;
 168     }
 169
 170     return wantarray ? @{ $self->{'fields'} || [] } : $self->{'fields'};
 171 }
 172
 173 sub table {
 174
 175 =pod
 176
 177 =head2 table
 178
 179 Gets or set the table on which the trigger works, as a L<SQL::Translator::Schema::Table> object.
 180   $trigger->table($triggered_table);
 181
 182 =cut
 183
 184     my ($self, $arg) = @_;
 185     if ( @_ == 2 ) {
 186         $self->error("Table attribute of a ".__PACKAGE__.
 187                      " must be a SQL::Translator::Schema::Table")
 188             unless ref $arg and $arg->isa('SQL::Translator::Schema::Table');
 189         $self->{table} = $arg;
 190     }
 191     return $self->{table};
 192 }
 193
 194 sub on_table {
 195
 196 =pod
 197
 198 =head2 on_table
 199
 200 Gets or set the table name on which the trigger works, as a string.
 201   $trigger->on_table('foo');
 202
 203 =cut
 204
 205     my ($self, $arg) = @_;
 206     if ( @_ == 2 ) {
 207         my $table = $self->schema->get_table($arg);
 208         die "Table named $arg doesn't exist"
 209             if !$table;
 210         $self->table($table);
 211     }
 212     return $self->table->name;
 213 }
 214
 215 sub action {
 216
 217 =pod
 218
 219 =head2 action
 220
 221 Gets or set the action of the trigger.
 222
 223   $trigger->action(
 224       q[
 225         BEGIN
 226           select ...;
 227           update ...;
 228         END
 229       ]
 230   );
 231
 232 =cut
 233
 234     my $self = shift;
 235     my $arg  = shift || '';
 236     $self->{'action'} = $arg if $arg;
 237     return $self->{'action'};
 238 }
 239
 240 sub is_valid {
 241
 242 =pod
 243
 244 =head2 is_valid
 245
 246 Determine whether the trigger is valid or not.
 247
 248   my $ok = $trigger->is_valid;
 249
 250 =cut
 251
 252     my $self = shift;
 253
 254     for my $attr (
 255         qw[ name perform_action_when database_events on_table action ]
 256     ) {
 257         return $self->error("Invalid: missing '$attr'") unless $self->$attr();
 258     }
 259
 260     return $self->error("Missing fields for UPDATE ON") if
 261         $self->database_event eq 'update_on' && !$self->fields;
 262
 263     return 1;
 264 }
 265
 266 sub name {
 267
 268 =pod
 269
 270 =head2 name
 271
 272 Get or set the trigger's name.
 273
 274   my $name = $trigger->name('foo');
 275
 276 =cut
 277
 278     my $self        = shift;
 279     $self->{'name'} = shift if @_;
 280     return $self->{'name'} || '';
 281 }
 282
 283 sub order {
 284
 285 =pod
 286
 287 =head2 order
 288
 289 Get or set the trigger's order.
 290
 291   my $order = $trigger->order(3);
 292
 293 =cut
 294
 295     my ( $self, $arg ) = @_;
 296
 297     if ( defined $arg && $arg =~ /^\d+$/ ) {
 298         $self->{'order'} = $arg;
 299     }
 300
 301     return $self->{'order'} || 0;
 302 }
 303
 304 sub schema {
 305
 306 =pod
 307
 308 =head2 schema
 309
 310 Get or set the trigger's schema object.
 311
 312   $trigger->schema( $schema );
 313   my $schema = $trigger->schema;
 314
 315 =cut
 316
 317     my $self = shift;
 318     if ( my $arg = shift ) {
 319         return $self->error('Not a schema object') unless
 320             UNIVERSAL::isa( $arg, 'SQL::Translator::Schema' );
 321         $self->{'schema'} = $arg;
 322     }
 323
 324     return $self->{'schema'};
 325 }
 326
 327 sub compare_arrays {
 328
 329 =pod
 330
 331 =head2 compare_arrays
 332
 333 Compare two arrays.
 334
 335 =cut
 336
 337     my ($first, $second) = @_;
 338     no warnings;  # silence spurious -w undef complaints
 339
 340     return 0 unless (ref $first eq 'ARRAY' and ref $second eq 'ARRAY' ) ;
 341
 342     return 0 unless @$first == @$second;
 343
 344     my @first = sort @$first;
 345
 346     my @second = sort @$second;
 347
 348     for (my $i = 0; $i < scalar @first; $i++) {
 349         return 0 if @first[$i] ne @second[$i];
 350     }
 351
 352     return 1;
 353 }
 354
 355 sub equals {
 356
 357 =pod
 358
 359 =head2 equals
 360
 361 Determines if this trigger is the same as another
 362
 363   my $is_identical = $trigger1->equals( $trigger2 );
 364
 365 =cut
 366
 367     my $self             = shift;
 368     my $other            = shift;
 369     my $case_insensitive = shift;
 370
 371     return 0 unless $self->SUPER::equals($other);
 372
 373     my %names;
 374     for my $name ( $self->name, $other->name ) {
 375         $name = lc $name if $case_insensitive;
 376         $names{ $name }++;
 377     }
 378
 379     if ( keys %names > 1 ) {
 380         return $self->error('Names not equal');
 381     }
 382
 383     if ( !$self->perform_action_when eq $other->perform_action_when ) {
 384         return $self->error('perform_action_when differs');
 385     }
 386
 387     if (
 388         !compare_arrays( [$self->database_events], [$other->database_events] )
 389     ) {
 390         return $self->error('database_events differ');
 391     }
 392
 393     if ( $self->on_table ne $other->on_table ) {
 394         return $self->error('on_table differs');
 395     }
 396
 397     if ( $self->action ne $other->action ) {
 398         return $self->error('action differs');
 399     }
 400
 401     if (
 402         !$self->_compare_objects( scalar $self->extra, scalar $other->extra )
 403     ) {
 404         return $self->error('extras differ');
 405     }
 406
 407     return 1;
 408 }
 409
 410 sub DESTROY {
 411     my $self = shift;
 412     undef $self->{'schema'}; # destroy cyclical reference
 413 }
 414
 415 1;
 416
 417 =pod
 418
 419 =head1 AUTHORS
 420
 421 Anonymous,
 422 Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>.
 423
 424 =cut