lib/SQL/Translator/Schema/Table.pm

   1 package SQL::Translator::Schema::Table;
   2
   3 # ----------------------------------------------------------------------
   4 # $Id: Table.pm,v 1.7 2003-06-06 22:36:09 kycl4rk Exp $
   5 # ----------------------------------------------------------------------
   6 # Copyright (C) 2003 Ken Y. Clark <kclark@cpan.org>
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =pod
  24
  25 =head1 NAME
  26
  27 SQL::Translator::Schema::Table - SQL::Translator table object
  28
  29 =head1 SYNOPSIS
  30
  31   use SQL::Translator::Schema::Table;
  32   my $table = SQL::Translator::Schema::Table->new( name => 'foo' );
  33
  34 =head1 DESCSIPTION
  35
  36 C<SQL::Translator::Schema::Table> is the table object.
  37
  38 =head1 METHODS
  39
  40 =cut
  41
  42 use strict;
  43 use Class::Base;
  44 use SQL::Translator::Utils 'parse_list_arg';
  45 use SQL::Translator::Schema::Constants;
  46 use SQL::Translator::Schema::Constraint;
  47 use SQL::Translator::Schema::Field;
  48 use SQL::Translator::Schema::Index;
  49
  50 use base 'Class::Base';
  51 use vars qw( $VERSION $FIELD_ORDER );
  52
  53 $VERSION = 1.00;
  54
  55 # ----------------------------------------------------------------------
  56 sub init {
  57
  58 =pod
  59
  60 =head2 new
  61
  62 Object constructor.
  63
  64   my $table  =  SQL::Translator::Schema::Table->new(
  65       schema => $schema,
  66       name   => 'foo',
  67   );
  68
  69 =cut
  70
  71     my ( $self, $config ) = @_;
  72
  73     for my $arg ( qw[ schema name comments ] ) {
  74         next unless defined $config->{ $arg };
  75         defined $self->$arg( $config->{ $arg } ) or return;
  76     }
  77
  78     return $self;
  79 }
  80
  81 # ----------------------------------------------------------------------
  82 sub add_constraint {
  83
  84 =pod
  85
  86 =head2 add_constraint
  87
  88 Add a constraint to the table.  Returns the newly created
  89 C<SQL::Translator::Schema::Constraint> object.
  90
  91   my $c1 = $table->add_constraint(
  92       name        => 'pk',
  93       type        => PRIMARY_KEY,
  94       fields      => [ 'foo_id' ],
  95   );
  96
  97   my $c2 = SQL::Translator::Schema::Constraint->new( name => 'uniq' );
  98   $c2    = $table->add_constraint( $constraint );
  99
 100 =cut
 101
 102     my $self             = shift;
 103     my $constraint_class = 'SQL::Translator::Schema::Constraint';
 104     my $constraint;
 105
 106     if ( UNIVERSAL::isa( $_[0], $constraint_class ) ) {
 107         $constraint = shift;
 108         $constraint->table( $self );
 109     }
 110     else {
 111         my %args = @_;
 112         $args{'table'} = $self;
 113         $constraint = $constraint_class->new( \%args ) or
 114             return $self->error( $constraint_class->error );
 115     }
 116
 117     #
 118     # If we're trying to add a PK when one is already defined,
 119     # then just add the fields to the existing definition.
 120     #
 121     my $ok = 0;
 122     my $pk = $self->primary_key;
 123     if ( $pk && $constraint->type eq PRIMARY_KEY ) {
 124         $self->primary_key( $constraint->fields );
 125         $constraint = $pk;
 126     }
 127     else {
 128         my @field_names = $constraint->fields;
 129         $ok = 1;
 130
 131         for my $c (
 132             grep { $_->type eq $constraint->type }
 133             $self->get_constraints
 134         ) {
 135             my %fields = map { $_, 1 } $c->fields;
 136             for my $field_name ( @field_names ) {
 137                 if ( $fields{ $field_name } ) {
 138                     $constraint = $c;
 139                     $ok = 0;
 140                     last;
 141                 }
 142             }
 143             last unless $ok;
 144         }
 145     }
 146
 147     if ( $ok ) {
 148         push @{ $self->{'constraints'} }, $constraint;
 149     }
 150
 151     return $constraint;
 152 }
 153
 154 # ----------------------------------------------------------------------
 155 sub add_index {
 156
 157 =pod
 158
 159 =head2 add_index
 160
 161 Add an index to the table.  Returns the newly created
 162 C<SQL::Translator::Schema::Index> object.
 163
 164   my $i1 = $table->add_index(
 165       name   => 'name',
 166       fields => [ 'name' ],
 167       type   => 'normal',
 168   );
 169
 170   my $i2 = SQL::Translator::Schema::Index->new( name => 'id' );
 171   $i2    = $table->add_index( $index );
 172
 173 =cut
 174
 175     my $self        = shift;
 176     my $index_class = 'SQL::Translator::Schema::Index';
 177     my $index;
 178
 179     if ( UNIVERSAL::isa( $_[0], $index_class ) ) {
 180         $index = shift;
 181         $index->table( $self );
 182     }
 183     else {
 184         my %args = @_;
 185         $args{'table'} = $self;
 186         $index = $index_class->new( \%args ) or return
 187             $self->error( $index_class->error );
 188     }
 189
 190     push @{ $self->{'indices'} }, $index;
 191     return $index;
 192 }
 193
 194 # ----------------------------------------------------------------------
 195 sub add_field {
 196
 197 =pod
 198
 199 =head2 add_field
 200
 201 Add an field to the table.  Returns the newly created
 202 C<SQL::Translator::Schema::Field> object.  The "name" parameter is
 203 required.  If you try to create a field with the same name as an
 204 existing field, you will get an error and the field will not be created.
 205
 206   my $f1    =  $table->add_field(
 207       name      => 'foo_id',
 208       data_type => 'integer',
 209       size      => 11,
 210   );
 211
 212   my $f2 =  SQL::Translator::Schema::Field->new(
 213       name   => 'name',
 214       table  => $table,
 215   );
 216   $f2    = $table->add_field( $field2 ) or die $table->error;
 217
 218 =cut
 219
 220     my $self        = shift;
 221     my $field_class = 'SQL::Translator::Schema::Field';
 222     my $field;
 223
 224     if ( UNIVERSAL::isa( $_[0], $field_class ) ) {
 225         $field = shift;
 226         $field->table( $self );
 227     }
 228     else {
 229         my %args = @_;
 230         $args{'table'} = $self;
 231         $field = $field_class->new( \%args ) or return
 232             $self->error( $field_class->error );
 233     }
 234
 235     $field->order( ++$FIELD_ORDER );
 236     my $field_name = $field->name or return $self->error('No name');
 237
 238     if ( exists $self->{'fields'}{ $field_name } ) {
 239         return $self->error(qq[Can't create field: "$field_name" exists]);
 240     }
 241     else {
 242         $self->{'fields'}{ $field_name } = $field;
 243     }
 244
 245     return $field;
 246 }
 247
 248 # ----------------------------------------------------------------------
 249 sub comments {
 250
 251 =pod
 252
 253 =head2 comments
 254
 255 Get or set the comments on a table.  May be called several times to
 256 set and it will accumulate the comments.  Called in an array context,
 257 returns each comment individually; called in a scalar context, returns
 258 all the comments joined on newlines.
 259
 260   $table->comments('foo');
 261   $table->comments('bar');
 262   print join( ', ', $table->comments ); # prints "foo, bar"
 263
 264 =cut
 265
 266     my $self = shift;
 267     push @{ $self->{'comments'} }, @_ if @_;
 268
 269     return wantarray
 270         ? @{ $self->{'comments'} || [] }
 271         : join( "\n", @{ $self->{'comments'} || [] } );
 272 }
 273
 274 # ----------------------------------------------------------------------
 275 sub get_constraints {
 276
 277 =pod
 278
 279 =head2 get_constraints
 280
 281 Returns all the constraint objects as an array or array reference.
 282
 283   my @constraints = $table->get_constraints;
 284
 285 =cut
 286
 287     my $self = shift;
 288
 289     if ( ref $self->{'constraints'} ) {
 290         return wantarray
 291             ? @{ $self->{'constraints'} } : $self->{'constraints'};
 292     }
 293     else {
 294         $self->error('No constraints');
 295         return wantarray ? () : undef;
 296     }
 297 }
 298
 299 # ----------------------------------------------------------------------
 300 sub get_indices {
 301
 302 =pod
 303
 304 =head2 get_indices
 305
 306 Returns all the index objects as an array or array reference.
 307
 308   my @indices = $table->get_indices;
 309
 310 =cut
 311
 312     my $self = shift;
 313
 314     if ( ref $self->{'indices'} ) {
 315         return wantarray
 316             ? @{ $self->{'indices'} }
 317             : $self->{'indices'};
 318     }
 319     else {
 320         $self->error('No indices');
 321         return wantarray ? () : undef;
 322     }
 323 }
 324
 325 # ----------------------------------------------------------------------
 326 sub get_field {
 327
 328 =pod
 329
 330 =head2 get_field
 331
 332 Returns a field by the name provided.
 333
 334   my $field = $table->get_field('foo');
 335
 336 =cut
 337
 338     my $self       = shift;
 339     my $field_name = shift or return $self->error('No field name');
 340     return $self->error( qq[Field "$field_name" does not exist] ) unless
 341         exists $self->{'fields'}{ $field_name };
 342     return $self->{'fields'}{ $field_name };
 343 }
 344
 345 # ----------------------------------------------------------------------
 346 sub get_fields {
 347
 348 =pod
 349
 350 =head2 get_fields
 351
 352 Returns all the field objects as an array or array reference.
 353
 354   my @fields = $table->get_fields;
 355
 356 =cut
 357
 358     my $self = shift;
 359     my @fields =
 360         map  { $_->[1] }
 361         sort { $a->[0] <=> $b->[0] }
 362         map  { [ $_->order, $_ ] }
 363         values %{ $self->{'fields'} || {} };
 364
 365     if ( @fields ) {
 366         return wantarray ? @fields : \@fields;
 367     }
 368     else {
 369         $self->error('No fields');
 370         return wantarray ? () : undef;
 371     }
 372 }
 373
 374 # ----------------------------------------------------------------------
 375 sub is_valid {
 376
 377 =pod
 378
 379 =head2 is_valid
 380
 381 Determine whether the view is valid or not.
 382
 383   my $ok = $view->is_valid;
 384
 385 =cut
 386
 387     my $self = shift;
 388     return $self->error('No name')   unless $self->name;
 389     return $self->error('No fields') unless $self->get_fields;
 390
 391     for my $object (
 392         $self->get_fields, $self->get_indices, $self->get_constraints
 393     ) {
 394         return $object->error unless $object->is_valid;
 395     }
 396
 397     return 1;
 398 }
 399
 400 # ----------------------------------------------------------------------
 401 sub name {
 402
 403 =pod
 404
 405 =head2 name
 406
 407 Get or set the table's name.
 408
 409 If provided an argument, checks the schema object for a table of
 410 that name and disallows the change if one exists.
 411
 412   my $table_name = $table->name('foo');
 413
 414 =cut
 415
 416     my $self = shift;
 417
 418     if ( my $arg = shift ) {
 419         if ( my $schema = $self->schema ) {
 420             return $self->error( qq[Can't use table name "$arg": table exists] )
 421                 if $schema->get_table( $arg );
 422         }
 423         $self->{'name'} = $arg;
 424     }
 425
 426     return $self->{'name'} || '';
 427 }
 428
 429 # ----------------------------------------------------------------------
 430 sub schema {
 431
 432 =pod
 433
 434 =head2 schema
 435
 436 Get or set the table's schema object.
 437
 438   my $schema = $table->schema;
 439
 440 =cut
 441
 442     my $self = shift;
 443     if ( my $arg = shift ) {
 444         return $self->error('Not a schema object') unless
 445             UNIVERSAL::isa( $arg, 'SQL::Translator::Schema' );
 446         $self->{'schema'} = $arg;
 447     }
 448
 449     return $self->{'schema'};
 450 }
 451
 452 # ----------------------------------------------------------------------
 453 sub primary_key {
 454
 455 =pod
 456
 457 =head2 options
 458
 459 Gets or sets the table's primary key(s).  Takes one or more field
 460 names (as a string, list or array[ref]) as an argument.  If the field
 461 names are present, it will create a new PK if none exists, or it will
 462 add to the fields of an existing PK (and will unique the field names).
 463 Returns the C<SQL::Translator::Schema::Constraint> object representing
 464 the primary key.
 465
 466 These are eqivalent:
 467
 468   $table->primary_key('id');
 469   $table->primary_key(['name']);
 470   $table->primary_key('id','name']);
 471   $table->primary_key(['id','name']);
 472   $table->primary_key('id,name');
 473   $table->primary_key(qw[ id name ]);
 474
 475   my $pk = $table->primary_key;
 476
 477 =cut
 478
 479     my $self   = shift;
 480     my $fields = parse_list_arg( @_ );
 481
 482     my $constraint;
 483     if ( @$fields ) {
 484         for my $f ( @$fields ) {
 485             return $self->error(qq[Invalid field "$f"]) unless
 486                 $self->get_field($f);
 487         }
 488
 489         my $has_pk;
 490         for my $c ( $self->get_constraints ) {
 491             if ( $c->type eq PRIMARY_KEY ) {
 492                 $has_pk = 1;
 493                 $c->fields( @{ $c->fields }, @$fields );
 494                 $constraint = $c;
 495             }
 496         }
 497
 498         unless ( $has_pk ) {
 499             $constraint = $self->add_constraint(
 500                 type   => PRIMARY_KEY,
 501                 fields => $fields,
 502             ) or return;
 503         }
 504     }
 505
 506     if ( $constraint ) {
 507         return $constraint;
 508     }
 509     else {
 510         for my $c ( $self->get_constraints ) {
 511             return $c if $c->type eq PRIMARY_KEY;
 512         }
 513     }
 514
 515     return;
 516 }
 517
 518 # ----------------------------------------------------------------------
 519 sub options {
 520
 521 =pod
 522
 523 =head2 options
 524
 525 Get or set the table's options (e.g., table types for MySQL).  Returns
 526 an array or array reference.
 527
 528   my @options = $table->options;
 529
 530 =cut
 531
 532     my $self    = shift;
 533     my $options = parse_list_arg( @_ );
 534
 535     push @{ $self->{'options'} }, @$options;
 536
 537     if ( ref $self->{'options'} ) {
 538         return wantarray ? @{ $self->{'options'} || [] } : $self->{'options'};
 539     }
 540     else {
 541         return wantarray ? () : [];
 542     }
 543 }
 544
 545 # ----------------------------------------------------------------------
 546 sub order {
 547
 548 =pod
 549
 550 =head2 order
 551
 552 Get or set the table's order.
 553
 554   my $order = $table->order(3);
 555
 556 =cut
 557
 558     my ( $self, $arg ) = @_;
 559
 560     if ( defined $arg && $arg =~ /^\d+$/ ) {
 561         $self->{'order'} = $arg;
 562     }
 563
 564     return $self->{'order'} || 0;
 565 }
 566
 567 # ----------------------------------------------------------------------
 568 sub DESTROY {
 569     my $self = shift;
 570     undef $self->{'schema'}; # destroy cyclical reference
 571     undef $_ for @{ $self->{'constraints'} };
 572     undef $_ for @{ $self->{'indices'} };
 573     undef $_ for values %{ $self->{'fields'} };
 574 }
 575
 576 1;
 577
 578 # ----------------------------------------------------------------------
 579
 580 =pod
 581
 582 =head1 AUTHOR
 583
 584 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>
 585
 586 =cut