lib/SQL/Translator/Producer/YAML.pm

   1 package SQL::Translator::Producer::YAML;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::YAML - A YAML producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $translator = SQL::Translator->new(producer => 'YAML');
  30
  31 =head1 DESCRIPTION
  32
  33 This module uses YAML to serialize a schema to a string so that it
  34 can be saved to disk.  Serializing a schema and then calling producers
  35 on the stored can realize significant performance gains when parsing
  36 takes a long time.
  37
  38 =cut
  39
  40 use strict;
  41 use vars qw($VERSION);
  42 $VERSION = '1.59';
  43
  44 use YAML qw(Dump);
  45
  46 # -------------------------------------------------------------------
  47 sub produce {
  48     my $translator = shift;
  49     my $schema     = $translator->schema;
  50
  51     return Dump({
  52         schema => {
  53             tables => {
  54                 map { ($_->name => view_table($_)) }
  55                     $schema->get_tables,
  56             },
  57             views => {
  58                 map { ($_->name => view_view($_)) }
  59                     $schema->get_views,
  60             },
  61             triggers => {
  62                 map { ($_->name => view_trigger($_)) }
  63                     $schema->get_triggers,
  64             },
  65             procedures => {
  66                 map { ($_->name => view_procedure($_)) }
  67                     $schema->get_procedures,
  68             },
  69         },
  70         translator => {
  71             add_drop_table => $translator->add_drop_table,
  72             filename       => $translator->filename,
  73             no_comments    => $translator->no_comments,
  74             parser_args    => $translator->parser_args,
  75             producer_args  => $translator->producer_args,
  76             parser_type    => $translator->parser_type,
  77             producer_type  => $translator->producer_type,
  78             show_warnings  => $translator->show_warnings,
  79             trace          => $translator->trace,
  80             version        => $translator->version,
  81         },
  82         keys %{$schema->extra} ? ('extra' => { $schema->extra } ) : (),
  83     });
  84 }
  85
  86 # -------------------------------------------------------------------
  87 sub view_table {
  88     my $table = shift;
  89
  90     return {
  91         'name'        => $table->name,
  92         'order'       => $table->order,
  93         'options'     => $table->options  || [],
  94         $table->comments ? ('comments'    => $table->comments ) : (),
  95         'constraints' => [
  96             map { view_constraint($_) } $table->get_constraints
  97         ],
  98         'indices'     => [
  99             map { view_index($_) } $table->get_indices
 100         ],
 101         'fields'      => {
 102             map { ($_->name => view_field($_)) }
 103                 $table->get_fields
 104         },
 105         keys %{$table->extra} ? ('extra' => { $table->extra } ) : (),
 106     };
 107 }
 108
 109 # -------------------------------------------------------------------
 110 sub view_constraint {
 111     my $constraint = shift;
 112
 113     return {
 114         'deferrable'       => scalar $constraint->deferrable,
 115         'expression'       => scalar $constraint->expression,
 116         'fields'           => [ map { ref $_ ? $_->name : $_ } $constraint->field_names ],
 117         'match_type'       => scalar $constraint->match_type,
 118         'name'             => scalar $constraint->name,
 119         'options'          => scalar $constraint->options,
 120         'on_delete'        => scalar $constraint->on_delete,
 121         'on_update'        => scalar $constraint->on_update,
 122         'reference_fields' => [ map { ref $_ ? $_->name : $_ } $constraint->reference_fields ],
 123         'reference_table'  => scalar $constraint->reference_table,
 124         'type'             => scalar $constraint->type,
 125         keys %{$constraint->extra} ? ('extra' => { $constraint->extra } ) : (),
 126     };
 127 }
 128
 129 # -------------------------------------------------------------------
 130 sub view_field {
 131     my $field = shift;
 132
 133     return {
 134         'order'             => scalar $field->order,
 135         'name'              => scalar $field->name,
 136         'data_type'         => scalar $field->data_type,
 137         'size'              => [ $field->size ],
 138         'default_value'     => scalar $field->default_value,
 139         'is_nullable'       => scalar $field->is_nullable,
 140         'is_primary_key'    => scalar $field->is_primary_key,
 141         'is_unique'         => scalar $field->is_unique,
 142         $field->is_auto_increment ? ('is_auto_increment' => 1) : (),
 143         $field->comments ? ('comments' => $field->comments) : (),
 144         keys %{$field->extra} ? ('extra' => { $field->extra } ) : (),
 145     };
 146 }
 147
 148 # -------------------------------------------------------------------
 149 sub view_procedure {
 150     my $procedure = shift;
 151
 152     return {
 153         'order'      => scalar $procedure->order,
 154         'name'       => scalar $procedure->name,
 155         'sql'        => scalar $procedure->sql,
 156         'parameters' => scalar $procedure->parameters,
 157         'owner'      => scalar $procedure->owner,
 158         'comments'   => scalar $procedure->comments,
 159         keys %{$procedure->extra} ? ('extra' => { $procedure->extra } ) : (),
 160     };
 161 }
 162
 163 # -------------------------------------------------------------------
 164 sub view_trigger {
 165     my $trigger = shift;
 166
 167     return {
 168         'order'               => scalar $trigger->order,
 169         'name'                => scalar $trigger->name,
 170         'perform_action_when' => scalar $trigger->perform_action_when,
 171         'database_events'     => scalar $trigger->database_events,
 172         'fields'              => scalar $trigger->fields,
 173         'on_table'            => scalar $trigger->on_table,
 174         'action'              => scalar $trigger->action,
 175         keys %{$trigger->extra} ? ('extra' => { $trigger->extra } ) : (),
 176     };
 177 }
 178
 179 # -------------------------------------------------------------------
 180 sub view_view {
 181     my $view = shift;
 182
 183     return {
 184         'order'  => scalar $view->order,
 185         'name'   => scalar $view->name,
 186         'sql'    => scalar $view->sql,
 187         'fields' => scalar $view->fields,
 188         keys %{$view->extra} ? ('extra' => { $view->extra } ) : (),
 189     };
 190 }
 191
 192 # -------------------------------------------------------------------
 193 sub view_index {
 194     my $index = shift;
 195
 196     return {
 197         'name'      => scalar $index->name,
 198         'type'      => scalar $index->type,
 199         'fields'    => scalar $index->fields,
 200         'options'   => scalar $index->options,
 201         keys %{$index->extra} ? ('extra' => { $index->extra } ) : (),
 202     };
 203 }
 204
 205 1;
 206
 207 # -------------------------------------------------------------------
 208
 209 =head1 SEE ALSO
 210
 211 SQL::Translator, YAML, http://www.yaml.org/.
 212
 213 =head1 AUTHORS
 214
 215 darren chamberlain E<lt>darren@cpan.orgE<gt>,
 216 Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>.
 217
 218 =cut