lib/SQL/Translator/Producer/YAML.pm

   1 package SQL::Translator::Producer::YAML;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: YAML.pm,v 1.6 2003-10-17 19:48:38 dlc Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2003 darren chamberlain <darren@cpan.org>,
   7 #   Ken Y. Clark <kclark@cpan.org>.
   8 #
   9 # This program is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU General Public License as
  11 # published by the Free Software Foundation; version 2.
  12 #
  13 # This program is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  21 # 02111-1307  USA
  22 # -------------------------------------------------------------------
  23
  24 =head1 NAME
  25
  26 SQL::Translator::Producer::YAML - A YAML producer for SQL::Translator
  27
  28 =head1 SYNOPSIS
  29
  30   use SQL::Translator;
  31
  32   my $translator = SQL::Translator->new(producer => 'YAML');
  33
  34 =head1 DESCRIPTION
  35
  36 This module uses YAML to serialize a schema to a string so that it
  37 can be saved to disk.  Serializing a schema and then calling producers
  38 on the stored can realize significant performance gains when parsing
  39 takes a long time.
  40
  41 =cut
  42
  43 use strict;
  44 use vars qw($VERSION);
  45 $VERSION = sprintf "%d.%02d", q$Revision: 1.6 $ =~ /(\d+)\.(\d+)/;
  46
  47 use YAML qw(Dump);
  48
  49 # -------------------------------------------------------------------
  50 sub produce {
  51     my $translator  = shift;
  52     my $schema      = $translator->schema;
  53
  54     return Dump({
  55         schema => {
  56             tables => {
  57                 map { ($_->name => view_table($_)) }
  58                     $schema->get_tables,
  59             },
  60             views => {
  61                 map { ($_->name => view_view($_)) }
  62                     $schema->get_views,
  63             },
  64             triggers => {
  65                 map { ($_->name => view_trigger($_)) }
  66                     $schema->get_triggers,
  67             },
  68             procedures => {
  69                 map { ($_->name => view_procedure($_)) }
  70                     $schema->get_procedures,
  71             },
  72         }
  73     });
  74 }
  75
  76 # -------------------------------------------------------------------
  77 sub view_table {
  78     my $table = shift;
  79
  80     return {
  81         'name'     => $table->name,
  82         'order'    => $table->order,
  83         'options'  => $table->options  || [],
  84         'comments' => $table->comments || '',
  85         'indices'  => {
  86             map { ($_->name => view_index($_)) }
  87                 $table->get_indices
  88         },
  89         'fields'   => {
  90             map { ($_->name => view_field($_)) }
  91                 $table->get_fields
  92         },
  93     };
  94 }
  95
  96 # -------------------------------------------------------------------
  97 sub view_field {
  98     my $field = shift;
  99
 100     return {
 101         'order'          => scalar $field->order,
 102         'name'           => scalar $field->name,
 103         'data_type'      => scalar $field->data_type,
 104         'size'           => [ $field->size ],
 105         'default_value'  => scalar $field->default_value,
 106         'is_nullable'    => scalar $field->is_nullable,
 107         'is_primary_key' => scalar $field->is_primary_key,
 108         'is_unique'      => scalar $field->is_unique,
 109         'extra'          => { $field->extra },
 110     };
 111 }
 112
 113 # -------------------------------------------------------------------
 114 sub view_procedure {
 115     my $procedure = shift;
 116
 117     return {
 118         'order'      => scalar $procedure->order,
 119         'name'       => scalar $procedure->name,
 120         'sql'        => scalar $procedure->sql,
 121         'parameters' => scalar $procedure->parameters,
 122         'owner'      => scalar $procedure->owner,
 123         'comments'   => scalar $procedure->comments,
 124     };
 125 }
 126
 127 # -------------------------------------------------------------------
 128 sub view_trigger {
 129     my $trigger = shift;
 130
 131     return {
 132         'order'               => scalar $trigger->order,
 133         'name'                => scalar $trigger->name,
 134         'perform_action_when' => scalar $trigger->perform_action_when,
 135         'database_event'      => scalar $trigger->database_event,
 136         'fields'              => scalar $trigger->fields,
 137         'on_table'            => scalar $trigger->on_table,
 138         'action'              => scalar $trigger->action,
 139     };
 140 }
 141
 142 # -------------------------------------------------------------------
 143 sub view_view {
 144     my $view = shift;
 145
 146     return {
 147         'order'  => scalar $view->order,
 148         'name'   => scalar $view->name,
 149         'sql'    => scalar $view->sql,
 150         'fields' => scalar $view->fields,
 151     };
 152 }
 153
 154 # -------------------------------------------------------------------
 155 sub view_index {
 156     my $index = shift;
 157
 158     return {
 159         'name'      => scalar $index->name,
 160         'type'      => scalar $index->type,
 161         'fields'    => scalar $index->fields,
 162         'options'   => scalar $index->options,
 163     };
 164 }
 165
 166 1;
 167
 168 # -------------------------------------------------------------------
 169
 170 =head1 SEE ALSO
 171
 172 SQL::Translator, YAML, http://www.yaml.org/.
 173
 174 =head1 AUTHORS
 175
 176 darren chamberlain E<lt>darren@cpan.orgE<gt>,
 177 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 178
 179 =cut