lib/SQL/Translator/Producer/YAML.pm

   1 package SQL::Translator::Producer::YAML;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: YAML.pm,v 1.12 2005-06-15 18:00:31 kycl4rk Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =head1 NAME
  24
  25 SQL::Translator::Producer::YAML - A YAML producer for SQL::Translator
  26
  27 =head1 SYNOPSIS
  28
  29   use SQL::Translator;
  30
  31   my $translator = SQL::Translator->new(producer => 'YAML');
  32
  33 =head1 DESCRIPTION
  34
  35 This module uses YAML to serialize a schema to a string so that it
  36 can be saved to disk.  Serializing a schema and then calling producers
  37 on the stored can realize significant performance gains when parsing
  38 takes a long time.
  39
  40 =cut
  41
  42 use strict;
  43 use vars qw($VERSION);
  44 $VERSION = sprintf "%d.%02d", q$Revision: 1.12 $ =~ /(\d+)\.(\d+)/;
  45
  46 use YAML qw(Dump);
  47
  48 # -------------------------------------------------------------------
  49 sub produce {
  50     my $translator = shift;
  51     my $schema     = $translator->schema;
  52
  53     return Dump({
  54         schema => {
  55             tables => {
  56                 map { ($_->name => view_table($_)) }
  57                     $schema->get_tables,
  58             },
  59             views => {
  60                 map { ($_->name => view_view($_)) }
  61                     $schema->get_views,
  62             },
  63             triggers => {
  64                 map { ($_->name => view_trigger($_)) }
  65                     $schema->get_triggers,
  66             },
  67             procedures => {
  68                 map { ($_->name => view_procedure($_)) }
  69                     $schema->get_procedures,
  70             },
  71         },
  72         translator => {
  73             add_drop_table => $translator->add_drop_table,
  74             filename       => $translator->filename,
  75             no_comments    => $translator->no_comments,
  76             parser_args    => $translator->parser_args,
  77             producer_args  => $translator->producer_args,
  78             parser_type    => $translator->parser_type,
  79             producer_type  => $translator->producer_type,
  80             show_warnings  => $translator->show_warnings,
  81             trace          => $translator->trace,
  82             version        => $translator->version,
  83         }
  84     });
  85 }
  86
  87 # -------------------------------------------------------------------
  88 sub view_table {
  89     my $table = shift;
  90
  91     return {
  92         'name'        => $table->name,
  93         'order'       => $table->order,
  94         'options'     => $table->options  || [],
  95         'comments'    => $table->comments || '',
  96         'constraints' => [
  97             map { view_constraint($_) } $table->get_constraints
  98         ],
  99         'indices'     => [
 100             map { view_index($_) } $table->get_indices
 101         ],
 102         'fields'      => {
 103             map { ($_->name => view_field($_)) }
 104                 $table->get_fields
 105         },
 106     };
 107 }
 108
 109 # -------------------------------------------------------------------
 110 sub view_constraint {
 111     my $constraint = shift;
 112
 113     return {
 114         'deferrable'       => scalar $constraint->deferrable,
 115         'expression'       => scalar $constraint->expression,
 116         'fields'           => scalar $constraint->field_names,
 117         'match_type'       => scalar $constraint->match_type,
 118         'name'             => scalar $constraint->name,
 119         'options'          => scalar $constraint->options,
 120         'on_delete'        => scalar $constraint->on_delete,
 121         'on_update'        => scalar $constraint->on_update,
 122         'reference_fields' => scalar $constraint->reference_fields,
 123         'reference_table'  => scalar $constraint->reference_table,
 124         'type'             => scalar $constraint->type,
 125     };
 126 }
 127
 128 # -------------------------------------------------------------------
 129 sub view_field {
 130     my $field = shift;
 131
 132     return {
 133         'order'          => scalar $field->order,
 134         'name'           => scalar $field->name,
 135         'data_type'      => scalar $field->data_type,
 136         'size'           => [ $field->size ],
 137         'default_value'  => scalar $field->default_value,
 138         'is_nullable'    => scalar $field->is_nullable,
 139         'is_primary_key' => scalar $field->is_primary_key,
 140         'is_unique'      => scalar $field->is_unique,
 141         'comments'       => $field->comments || '',
 142         'extra'          => { $field->extra },
 143     };
 144 }
 145
 146 # -------------------------------------------------------------------
 147 sub view_procedure {
 148     my $procedure = shift;
 149
 150     return {
 151         'order'      => scalar $procedure->order,
 152         'name'       => scalar $procedure->name,
 153         'sql'        => scalar $procedure->sql,
 154         'parameters' => scalar $procedure->parameters,
 155         'owner'      => scalar $procedure->owner,
 156         'comments'   => scalar $procedure->comments,
 157     };
 158 }
 159
 160 # -------------------------------------------------------------------
 161 sub view_trigger {
 162     my $trigger = shift;
 163
 164     return {
 165         'order'               => scalar $trigger->order,
 166         'name'                => scalar $trigger->name,
 167         'perform_action_when' => scalar $trigger->perform_action_when,
 168         'database_event'      => scalar $trigger->database_event,
 169         'fields'              => scalar $trigger->fields,
 170         'on_table'            => scalar $trigger->on_table,
 171         'action'              => scalar $trigger->action,
 172     };
 173 }
 174
 175 # -------------------------------------------------------------------
 176 sub view_view {
 177     my $view = shift;
 178
 179     return {
 180         'order'  => scalar $view->order,
 181         'name'   => scalar $view->name,
 182         'sql'    => scalar $view->sql,
 183         'fields' => scalar $view->fields,
 184     };
 185 }
 186
 187 # -------------------------------------------------------------------
 188 sub view_index {
 189     my $index = shift;
 190
 191     return {
 192         'name'      => scalar $index->name,
 193         'type'      => scalar $index->type,
 194         'fields'    => scalar $index->fields,
 195         'options'   => scalar $index->options,
 196     };
 197 }
 198
 199 1;
 200
 201 # -------------------------------------------------------------------
 202
 203 =head1 SEE ALSO
 204
 205 SQL::Translator, YAML, http://www.yaml.org/.
 206
 207 =head1 AUTHORS
 208
 209 darren chamberlain E<lt>darren@cpan.orgE<gt>,
 210 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 211
 212 =cut