lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  30   $t->translate;
  31
  32 =head1 DESCRIPTION
  33
  34 This module will produce text output of the schema suitable for SQLite.
  35
  36 =cut
  37
  38 use strict;
  39 use warnings;
  40 use Data::Dumper;
  41 use SQL::Translator::Schema::Constants;
  42 use SQL::Translator::Utils qw(debug header_comment parse_dbms_version);
  43
  44 use vars qw[ $VERSION $DEBUG $WARN ];
  45
  46 $VERSION = '1.59';
  47 $DEBUG = 0 unless defined $DEBUG;
  48 $WARN = 0 unless defined $WARN;
  49
  50 our $max_id_length    = 30;
  51 my %global_names;
  52
  53 sub produce {
  54     my $translator     = shift;
  55     local $DEBUG       = $translator->debug;
  56     local $WARN        = $translator->show_warnings;
  57     my $no_comments    = $translator->no_comments;
  58     my $add_drop_table = $translator->add_drop_table;
  59     my $schema         = $translator->schema;
  60     my $producer_args  = $translator->producer_args;
  61     my $sqlite_version = parse_dbms_version(
  62         $producer_args->{sqlite_version}, 'perl'
  63     );
  64     my $no_txn         = $producer_args->{no_transaction};
  65
  66     debug("PKG: Beginning production\n");
  67
  68     %global_names = ();   #reset
  69
  70
  71     my $head = (header_comment() . "\n") unless $no_comments;
  72
  73     my @create = ();
  74
  75     push @create, "BEGIN TRANSACTION" unless $no_txn;
  76
  77     for my $table ( $schema->get_tables ) {
  78         push @create, create_table($table, { no_comments => $no_comments,
  79                                              sqlite_version => $sqlite_version,
  80                                           add_drop_table => $add_drop_table,});
  81     }
  82
  83     for my $view ( $schema->get_views ) {
  84       push @create, create_view($view, {
  85         add_drop_view => $add_drop_table,
  86         no_comments   => $no_comments,
  87       });
  88     }
  89
  90     for my $trigger ( $schema->get_triggers ) {
  91       push @create, create_trigger($trigger, {
  92         add_drop_trigger => $add_drop_table,
  93         no_comments   => $no_comments,
  94       });
  95     }
  96
  97     push @create, "COMMIT" unless $no_txn;
  98
  99     if (wantarray) {
 100       return ($head||(), @create);
 101     } else {
 102       return join ('',
 103         $head||(),
 104         join(";\n\n", @create ),
 105         ";\n",
 106       );
 107     }
 108 }
 109
 110 # -------------------------------------------------------------------
 111 sub mk_name {
 112     my ($name, $scope, $critical) = @_;
 113
 114     $scope ||= \%global_names;
 115     if ( my $prev = $scope->{ $name } ) {
 116         my $name_orig = $name;
 117         $name        .= sprintf( "%02d", ++$prev );
 118         substr($name, $max_id_length - 3) = "00"
 119             if length( $name ) > $max_id_length;
 120
 121         warn "The name '$name_orig' has been changed to ",
 122              "'$name' to make it unique.\n" if $WARN;
 123
 124         $scope->{ $name_orig }++;
 125     }
 126
 127     $scope->{ $name }++;
 128     return $name;
 129 }
 130
 131 sub create_view {
 132     my ($view, $options) = @_;
 133     my $add_drop_view = $options->{add_drop_view};
 134
 135     my $view_name = $view->name;
 136     debug("PKG: Looking at view '${view_name}'\n");
 137
 138     # Header.  Should this look like what mysqldump produces?
 139     my $extra = $view->extra;
 140     my @create;
 141     push @create, "DROP VIEW IF EXISTS $view_name" if $add_drop_view;
 142
 143     my $create_view = 'CREATE';
 144     $create_view .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 145     $create_view .= ' VIEW';
 146     $create_view .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 147     $create_view .= " ${view_name}";
 148
 149     if( my $sql = $view->sql ){
 150       $create_view .= " AS\n    ${sql}";
 151     }
 152     push @create, $create_view;
 153
 154     # Tack the comment onto the first statement.
 155     unless ($options->{no_comments}) {
 156       $create[0] = "--\n-- View: ${view_name}\n--\n" . $create[0];
 157     }
 158
 159     return @create;
 160 }
 161
 162
 163 sub create_table
 164 {
 165     my ($table, $options) = @_;
 166
 167     my $table_name = $table->name;
 168     my $no_comments = $options->{no_comments};
 169     my $add_drop_table = $options->{add_drop_table};
 170     my $sqlite_version = $options->{sqlite_version} || 0;
 171
 172     debug("PKG: Looking at table '$table_name'\n");
 173
 174     my ( @index_defs, @constraint_defs );
 175     my @fields = $table->get_fields or die "No fields in $table_name";
 176
 177     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 178     #
 179     # Header.
 180     #
 181     my $exists = ($sqlite_version >= 3.003) ? ' IF EXISTS' : '';
 182     my @create;
 183     my ($comment, $create_table) = "";
 184     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 185     if ($add_drop_table) {
 186       push @create, $comment . qq[DROP TABLE$exists $table_name];
 187     } else {
 188       $create_table = $comment;
 189     }
 190
 191     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 192
 193     #
 194     # Comments
 195     #
 196     if ( $table->comments and !$no_comments ){
 197         $create_table .= "-- Comments: \n-- ";
 198         $create_table .= join "\n-- ",  $table->comments;
 199         $create_table .= "\n--\n\n";
 200     }
 201
 202     #
 203     # How many fields in PK?
 204     #
 205     my $pk        = $table->primary_key;
 206     my @pk_fields = $pk ? $pk->fields : ();
 207
 208     #
 209     # Fields
 210     #
 211     my ( @field_defs, $pk_set );
 212     for my $field ( @fields ) {
 213         push @field_defs, create_field($field);
 214     }
 215
 216     if (
 217          scalar @pk_fields > 1
 218          ||
 219          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 220          ) {
 221         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 222     }
 223
 224     #
 225     # Indices
 226     #
 227     my $idx_name_default = 'A';
 228     for my $index ( $table->get_indices ) {
 229         push @index_defs, create_index($index);
 230     }
 231
 232     #
 233     # Constraints
 234     #
 235     my $c_name_default = 'A';
 236     for my $c ( $table->get_constraints ) {
 237         next unless $c->type eq UNIQUE;
 238         push @constraint_defs, create_constraint($c);
 239     }
 240
 241     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 242
 243     return (@create, $create_table, @index_defs, @constraint_defs );
 244 }
 245
 246 sub create_field
 247 {
 248     my ($field, $options) = @_;
 249
 250     my $field_name = $field->name;
 251     debug("PKG: Looking at field '$field_name'\n");
 252     my $field_comments = $field->comments
 253         ? "-- " . $field->comments . "\n  "
 254         : '';
 255
 256     my $field_def = $field_comments.$field_name;
 257
 258     # data type and size
 259     my $size      = $field->size;
 260     my $data_type = $field->data_type;
 261     $data_type    = 'varchar' if lc $data_type eq 'set';
 262     $data_type  = 'blob' if lc $data_type eq 'bytea';
 263
 264     if ( lc $data_type =~ /(text|blob)/i ) {
 265         $size = undef;
 266     }
 267
 268 #             if ( $data_type =~ /timestamp/i ) {
 269 #                 push @trigger_defs,
 270 #                     "CREATE TRIGGER ts_${table_name} ".
 271 #                     "after insert on $table_name\n".
 272 #                     "begin\n".
 273 #                     "  update $table_name set $field_name=timestamp() ".
 274 #                        "where id=new.id;\n".
 275 #                     "end;\n"
 276 #                 ;
 277 #
 278 #            }
 279
 280     #
 281     # SQLite is generally typeless, but newer versions will
 282     # make a field autoincrement if it is declared as (and
 283     # *only* as) INTEGER PRIMARY KEY
 284     #
 285     my $pk        = $field->table->primary_key;
 286     my @pk_fields = $pk ? $pk->fields : ();
 287
 288     if (
 289          $field->is_primary_key &&
 290          scalar @pk_fields == 1 &&
 291          (
 292           $data_type =~ /int(eger)?$/i
 293           ||
 294           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 295           )
 296          ) {
 297         $data_type = 'INTEGER PRIMARY KEY';
 298         $size      = undef;
 299 #        $pk_set    = 1;
 300     }
 301
 302     $field_def .= sprintf " %s%s", $data_type,
 303     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 304
 305     # Null?
 306     $field_def .= ' NOT NULL' unless $field->is_nullable;
 307
 308     # Default?
 309     SQL::Translator::Producer->_apply_default_value(
 310         $field,
 311         \$field_def,
 312         [
 313          'NULL'              => \'NULL',
 314          'now()'             => 'now()',
 315          'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 316         ],
 317     );
 318
 319     return $field_def;
 320
 321 }
 322
 323 sub create_index
 324 {
 325     my ($index, $options) = @_;
 326
 327     my $name   = $index->name;
 328     $name      = mk_name($name);
 329
 330     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 331
 332     # strip any field size qualifiers as SQLite doesn't like these
 333     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 334     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 335     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 336     my $index_def =
 337     "CREATE ${type}INDEX $name ON " . $index_table_name .
 338         ' (' . join( ', ', @fields ) . ')';
 339
 340     return $index_def;
 341 }
 342
 343 sub create_constraint
 344 {
 345     my ($c, $options) = @_;
 346
 347     my $name   = $c->name;
 348     $name      = mk_name($name);
 349     my @fields = $c->fields;
 350     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 351     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 352
 353     my $c_def =
 354     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 355         ' (' . join( ', ', @fields ) . ')';
 356
 357     return $c_def;
 358 }
 359
 360 sub create_trigger {
 361   my ($trigger, $options) = @_;
 362   my $add_drop = $options->{add_drop_trigger};
 363
 364   my @statements;
 365
 366   my $trigger_name = $trigger->name;
 367   my $events = $trigger->database_events;
 368   for my $evt ( @$events ) {
 369
 370     my $trig_name = $trigger_name;
 371     if (@$events > 1) {
 372       $trig_name .= "_$evt";
 373
 374       warn "Multiple database events supplied for trigger '$trigger_name', ",
 375         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 376     }
 377
 378     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 379
 380
 381     $DB::single = 1;
 382     my $action = "";
 383     if (not ref $trigger->action) {
 384       $action .= "BEGIN " . $trigger->action . " END";
 385     }
 386     else {
 387       $action = $trigger->action->{for_each} . " "
 388         if $trigger->action->{for_each};
 389
 390       $action = $trigger->action->{when} . " "
 391         if $trigger->action->{when};
 392
 393       my $steps = $trigger->action->{steps} || [];
 394
 395       $action .= "BEGIN ";
 396       $action .= $_ . "; " for (@$steps);
 397       $action .= "END";
 398     }
 399
 400     push @statements, sprintf (
 401       'CREATE TRIGGER %s %s %s on %s %s',
 402       $trig_name,
 403       $trigger->perform_action_when,
 404       $evt,
 405       $trigger->on_table,
 406       $action
 407     );
 408   }
 409
 410   return @statements;
 411 }
 412
 413 sub alter_table { } # Noop
 414
 415 sub add_field {
 416   my ($field) = @_;
 417
 418   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 419       $field->table->name, create_field($field))
 420 }
 421
 422 sub alter_create_index {
 423   my ($index) = @_;
 424
 425   # This might cause name collisions
 426   return create_index($index);
 427 }
 428
 429 sub alter_create_constraint {
 430   my ($constraint) = @_;
 431
 432   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 433 }
 434
 435 sub alter_drop_constraint { alter_drop_index(@_) }
 436
 437 sub alter_drop_index {
 438   my ($constraint) = @_;
 439
 440   return sprintf("DROP INDEX %s",
 441       $constraint->name);
 442 }
 443
 444 sub batch_alter_table {
 445   my ($table, $diffs) = @_;
 446
 447   # If we have any of the following
 448   #
 449   #  rename_field
 450   #  alter_field
 451   #  drop_field
 452   #
 453   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 454   #
 455   # BEGIN TRANSACTION;
 456   # CREATE TEMPORARY TABLE t1_backup(a,b);
 457   # INSERT INTO t1_backup SELECT a,b FROM t1;
 458   # DROP TABLE t1;
 459   # CREATE TABLE t1(a,b);
 460   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 461   # DROP TABLE t1_backup;
 462   # COMMIT;
 463   #
 464   # Fun, eh?
 465   #
 466   # If we have rename_field we do similarly.
 467
 468   my $table_name = $table->name;
 469   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 470
 471   if ( @{$diffs->{rename_field}} == 0 &&
 472        @{$diffs->{alter_field}}  == 0 &&
 473        @{$diffs->{drop_field}}   == 0
 474        ) {
 475 #    return join("\n", map {
 476     return map {
 477         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 478         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 479
 480       } grep { @{$diffs->{$_}} }
 481     qw/rename_table
 482        alter_drop_constraint
 483        alter_drop_index
 484        drop_field
 485        add_field
 486        alter_field
 487        rename_field
 488        alter_create_index
 489        alter_create_constraint
 490        alter_table/;
 491   }
 492
 493
 494   my @sql;
 495   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 496
 497   do {
 498     local $table->{name} = $table_name . '_temp_alter';
 499     # We only want the table - dont care about indexes on tmp table
 500     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 501     push @sql,$table_sql;
 502   };
 503
 504   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 505              "DROP TABLE @{[$old_table]}",
 506              create_table($table, { no_comments => 1 }),
 507              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 508              "DROP TABLE @{[$table_name]}_temp_alter";
 509
 510   return @sql;
 511 #  return join("", @sql, "");
 512 }
 513
 514 sub drop_table {
 515   my ($table) = @_;
 516   return "DROP TABLE $table";
 517 }
 518
 519 sub rename_table {
 520   my ($old_table, $new_table, $options) = @_;
 521
 522   my $qt = $options->{quote_table_names} || '';
 523
 524   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 525
 526 }
 527
 528 # No-op. Just here to signify that we are a new style parser.
 529 sub preproces_schema { }
 530
 531 1;
 532
 533 =pod
 534
 535 =head1 SEE ALSO
 536
 537 SQL::Translator, http://www.sqlite.org/.
 538
 539 =head1 AUTHOR
 540
 541 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 542
 543 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 544
 545 =cut