lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  30   $t->translate;
  31
  32 =head1 DESCRIPTION
  33
  34 This module will produce text output of the schema suitable for SQLite.
  35
  36 =cut
  37
  38 use strict;
  39 use warnings;
  40 use Data::Dumper;
  41 use SQL::Translator::Schema::Constants;
  42 use SQL::Translator::Utils qw(debug header_comment);
  43 use Readonly;
  44
  45 use vars qw[ $VERSION $DEBUG $WARN ];
  46
  47 $VERSION = '1.60';
  48 $DEBUG   = 0 if !defined $DEBUG;
  49 $WARN    = 0 if !defined $WARN;
  50
  51 Readonly my $MAX_ID_LENGTH => 30;
  52 my %global_names;
  53
  54 sub produce {
  55     my $translator     = shift;
  56     local $DEBUG       = $translator->debug;
  57     local $WARN        = $translator->show_warnings;
  58     my $no_comments    = $translator->no_comments;
  59     my $add_drop_table = $translator->add_drop_table;
  60     my $schema         = $translator->schema;
  61     my $producer_args  = $translator->producer_args;
  62     my $sqlite_version = $producer_args->{sqlite_version} || 0;
  63     my $no_txn         = $producer_args->{no_transaction};
  64
  65     debug("PKG: Beginning production\n");
  66
  67     %global_names = ();   #reset
  68
  69     my @create = ();
  70     push @create, header_comment unless ($no_comments);
  71     $create[0] .= "\n\nBEGIN TRANSACTION" unless $no_txn;
  72
  73     for my $table ( $schema->get_tables ) {
  74         push @create, create_table($table, { no_comments => $no_comments,
  75                                              sqlite_version => $sqlite_version,
  76                                           add_drop_table => $add_drop_table,});
  77     }
  78
  79     for my $view ( $schema->get_views ) {
  80       push @create, create_view($view, {
  81         add_drop_view => $add_drop_table,
  82         no_comments   => $no_comments,
  83       });
  84     }
  85
  86     for my $trigger ( $schema->get_triggers ) {
  87       push @create, create_trigger($trigger, {
  88         add_drop_trigger => $add_drop_table,
  89         no_comments   => $no_comments,
  90       });
  91     }
  92
  93     if (wantarray) {
  94       push @create, "COMMIT" unless $no_txn;
  95       return @create;
  96     } else {
  97       push @create, "COMMIT;\n" unless $no_txn;
  98       return join(";\n\n", @create );
  99     }
 100 }
 101
 102 # -------------------------------------------------------------------
 103 sub mk_name {
 104     my ($name, $scope, $critical) = @_;
 105
 106     $scope ||= \%global_names;
 107     if ( my $prev = $scope->{ $name } ) {
 108         my $name_orig = $name;
 109         $name        .= sprintf( "%02d", ++$prev );
 110         substr($name, $MAX_ID_LENGTH - 3) = "00"
 111             if length( $name ) > $MAX_ID_LENGTH;
 112
 113         warn "The name '$name_orig' has been changed to ",
 114              "'$name' to make it unique.\n" if $WARN;
 115
 116         $scope->{ $name_orig }++;
 117     }
 118
 119     $scope->{ $name }++;
 120     return $name;
 121 }
 122
 123 sub create_view {
 124     my ($view, $options) = @_;
 125     my $add_drop_view = $options->{add_drop_view};
 126
 127     my $view_name = $view->name;
 128     debug("PKG: Looking at view '${view_name}'\n");
 129
 130     # Header.  Should this look like what mysqldump produces?
 131     my $extra = $view->extra;
 132     my $create = '';
 133     $create .= "--\n-- View: ${view_name}\n--\n" unless $options->{no_comments};
 134     $create .= "DROP VIEW IF EXISTS $view_name;\n" if $add_drop_view;
 135     $create .= 'CREATE';
 136     $create .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 137     $create .= ' VIEW';
 138     $create .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 139     $create .= " ${view_name}";
 140
 141     if( my $sql = $view->sql ){
 142       $create .= " AS\n    ${sql}";
 143     }
 144     return $create;
 145 }
 146
 147
 148 sub create_table
 149 {
 150     my ($table, $options) = @_;
 151
 152     my $table_name = $table->name;
 153     my $no_comments = $options->{no_comments};
 154     my $add_drop_table = $options->{add_drop_table};
 155     my $sqlite_version = $options->{sqlite_version} || 0;
 156
 157     debug("PKG: Looking at table '$table_name'\n");
 158
 159     my ( @index_defs, @constraint_defs );
 160     my @fields = $table->get_fields or die "No fields in $table_name";
 161
 162     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 163     #
 164     # Header.
 165     #
 166     my $exists = ($sqlite_version >= 3.3) ? ' IF EXISTS' : '';
 167     my @create;
 168     my ($comment, $create_table) = "";
 169     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 170     if ($add_drop_table) {
 171       push @create, $comment . qq[DROP TABLE$exists $table_name];
 172     } else {
 173       $create_table = $comment;
 174     }
 175
 176     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 177
 178     #
 179     # Comments
 180     #
 181     if ( $table->comments and !$no_comments ){
 182         $create_table .= "-- Comments: \n-- ";
 183         $create_table .= join "\n-- ",  $table->comments;
 184         $create_table .= "\n--\n\n";
 185     }
 186
 187     #
 188     # How many fields in PK?
 189     #
 190     my $pk        = $table->primary_key;
 191     my @pk_fields = $pk ? $pk->fields : ();
 192
 193     #
 194     # Fields
 195     #
 196     my ( @field_defs, $pk_set );
 197     for my $field ( @fields ) {
 198         push @field_defs, create_field($field);
 199     }
 200
 201     if (
 202          scalar @pk_fields > 1
 203          ||
 204          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 205          ) {
 206         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 207     }
 208
 209     #
 210     # Indices
 211     #
 212     my $idx_name_default = 'A';
 213     for my $index ( $table->get_indices ) {
 214         push @index_defs, create_index($index);
 215     }
 216
 217     #
 218     # Constraints
 219     #
 220     my $c_name_default = 'A';
 221     for my $c ( $table->get_constraints ) {
 222         next unless $c->type eq UNIQUE;
 223         push @constraint_defs, create_constraint($c);
 224     }
 225
 226     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 227
 228     return (@create, $create_table, @index_defs, @constraint_defs );
 229 }
 230
 231 sub create_field
 232 {
 233     my ($field, $options) = @_;
 234
 235     my $field_name = $field->name;
 236     debug("PKG: Looking at field '$field_name'\n");
 237     my $field_comments = $field->comments
 238         ? "-- " . $field->comments . "\n  "
 239         : '';
 240
 241     my $field_def = $field_comments.$field_name;
 242
 243     # data type and size
 244     my $size      = $field->size;
 245     my $data_type = $field->data_type;
 246     $data_type    = 'varchar' if lc $data_type eq 'set';
 247     $data_type  = 'blob' if lc $data_type eq 'bytea';
 248
 249     if ( lc $data_type =~ /(text|blob)/i ) {
 250         $size = undef;
 251     }
 252
 253 #             if ( $data_type =~ /timestamp/i ) {
 254 #                 push @trigger_defs,
 255 #                     "CREATE TRIGGER ts_${table_name} ".
 256 #                     "after insert on $table_name\n".
 257 #                     "begin\n".
 258 #                     "  update $table_name set $field_name=timestamp() ".
 259 #                        "where id=new.id;\n".
 260 #                     "end;\n"
 261 #                 ;
 262 #
 263 #            }
 264
 265     #
 266     # SQLite is generally typeless, but newer versions will
 267     # make a field autoincrement if it is declared as (and
 268     # *only* as) INTEGER PRIMARY KEY
 269     #
 270     my $pk        = $field->table->primary_key;
 271     my @pk_fields = $pk ? $pk->fields : ();
 272
 273     if (
 274          $field->is_primary_key &&
 275          scalar @pk_fields == 1 &&
 276          (
 277           $data_type =~ /int(eger)?$/i
 278           ||
 279           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 280           )
 281          ) {
 282         $data_type = 'INTEGER PRIMARY KEY';
 283         $size      = undef;
 284 #        $pk_set    = 1;
 285     }
 286
 287     $field_def .= sprintf " %s%s", $data_type,
 288     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 289
 290     # Null?
 291     $field_def .= ' NOT NULL' unless $field->is_nullable;
 292
 293     # Default?  XXX Need better quoting!
 294     my $default = $field->default_value;
 295     if (defined $default) {
 296         SQL::Translator::Producer->_apply_default_value(
 297             \$field_def,
 298             $default,
 299             [
 300              'NULL'              => \'NULL',
 301              'now()'             => 'now()',
 302              'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 303             ],
 304         );
 305     }
 306
 307     return $field_def;
 308
 309 }
 310
 311 sub create_index
 312 {
 313     my ($index, $options) = @_;
 314
 315     my $name   = $index->name;
 316     $name      = mk_name($name);
 317
 318     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 319
 320     # strip any field size qualifiers as SQLite doesn't like these
 321     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 322     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 323     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 324     my $index_def =
 325     "CREATE ${type}INDEX $name ON " . $index_table_name .
 326         ' (' . join( ', ', @fields ) . ')';
 327
 328     return $index_def;
 329 }
 330
 331 sub create_constraint
 332 {
 333     my ($c, $options) = @_;
 334
 335     my $name   = $c->name;
 336     $name      = mk_name($name);
 337     my @fields = $c->fields;
 338     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 339     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 340
 341     my $c_def =
 342     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 343         ' (' . join( ', ', @fields ) . ')';
 344
 345     return $c_def;
 346 }
 347
 348 sub create_trigger {
 349   my ($trigger, $options) = @_;
 350   my $add_drop = $options->{add_drop_trigger};
 351
 352   my @statements;
 353
 354   my $trigger_name = $trigger->name;
 355   my $events = $trigger->database_events;
 356   for my $evt ( @$events ) {
 357
 358     my $trig_name = $trigger_name;
 359     if (@$events > 1) {
 360       $trig_name .= "_$evt";
 361
 362       warn "Multiple database events supplied for trigger '$trigger_name', ",
 363         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 364     }
 365
 366     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 367
 368
 369     $DB::single = 1;
 370     my $action = "";
 371     if (not ref $trigger->action) {
 372       $action .= "BEGIN " . $trigger->action . " END";
 373     }
 374     else {
 375       $action = $trigger->action->{for_each} . " "
 376         if $trigger->action->{for_each};
 377
 378       $action = $trigger->action->{when} . " "
 379         if $trigger->action->{when};
 380
 381       my $steps = $trigger->action->{steps} || [];
 382
 383       $action .= "BEGIN ";
 384       $action .= $_ . "; " for (@$steps);
 385       $action .= "END";
 386     }
 387
 388     push @statements, sprintf (
 389       'CREATE TRIGGER %s %s %s on %s %s',
 390       $trig_name,
 391       $trigger->perform_action_when,
 392       $evt,
 393       $trigger->on_table,
 394       $action
 395     );
 396   }
 397
 398   return @statements;
 399 }
 400
 401 sub alter_table { } # Noop
 402
 403 sub add_field {
 404   my ($field) = @_;
 405
 406   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 407       $field->table->name, create_field($field))
 408 }
 409
 410 sub alter_create_index {
 411   my ($index) = @_;
 412
 413   # This might cause name collisions
 414   return create_index($index);
 415 }
 416
 417 sub alter_create_constraint {
 418   my ($constraint) = @_;
 419
 420   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 421 }
 422
 423 sub alter_drop_constraint { alter_drop_index(@_) }
 424
 425 sub alter_drop_index {
 426   my ($constraint) = @_;
 427
 428   return sprintf("DROP INDEX %s",
 429       $constraint->name);
 430 }
 431
 432 sub batch_alter_table {
 433   my ($table, $diffs) = @_;
 434
 435   # If we have any of the following
 436   #
 437   #  rename_field
 438   #  alter_field
 439   #  drop_field
 440   #
 441   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 442   #
 443   # BEGIN TRANSACTION;
 444   # CREATE TEMPORARY TABLE t1_backup(a,b);
 445   # INSERT INTO t1_backup SELECT a,b FROM t1;
 446   # DROP TABLE t1;
 447   # CREATE TABLE t1(a,b);
 448   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 449   # DROP TABLE t1_backup;
 450   # COMMIT;
 451   #
 452   # Fun, eh?
 453   #
 454   # If we have rename_field we do similarly.
 455
 456   my $table_name = $table->name;
 457   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 458
 459   if ( @{$diffs->{rename_field}} == 0 &&
 460        @{$diffs->{alter_field}}  == 0 &&
 461        @{$diffs->{drop_field}}   == 0
 462        ) {
 463 #    return join("\n", map {
 464     return map {
 465         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 466         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 467
 468       } grep { @{$diffs->{$_}} }
 469     qw/rename_table
 470        alter_drop_constraint
 471        alter_drop_index
 472        drop_field
 473        add_field
 474        alter_field
 475        rename_field
 476        alter_create_index
 477        alter_create_constraint
 478        alter_table/;
 479   }
 480
 481
 482   my @sql;
 483   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 484
 485   do {
 486     local $table->{name} = $table_name . '_temp_alter';
 487     # We only want the table - dont care about indexes on tmp table
 488     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 489     push @sql,$table_sql;
 490   };
 491
 492   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 493              "DROP TABLE @{[$old_table]}",
 494              create_table($table, { no_comments => 1 }),
 495              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 496              "DROP TABLE @{[$table_name]}_temp_alter";
 497
 498   return @sql;
 499 #  return join("", @sql, "");
 500 }
 501
 502 sub drop_table {
 503   my ($table) = @_;
 504   return "DROP TABLE $table";
 505 }
 506
 507 sub rename_table {
 508   my ($old_table, $new_table, $options) = @_;
 509
 510   my $qt = $options->{quote_table_names} || '';
 511
 512   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 513
 514 }
 515
 516 # No-op. Just here to signify that we are a new style parser.
 517 sub preproces_schema { }
 518
 519 1;
 520
 521 =pod
 522
 523 =head1 SEE ALSO
 524
 525 SQL::Translator, http://www.sqlite.org/.
 526
 527 =head1 AUTHOR
 528
 529 Ken Youens-Clark E<lt>kclark@cpan.orgE<gt>.
 530
 531 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 532
 533 =cut