lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  30   $t->translate;
  31
  32 =head1 DESCRIPTION
  33
  34 This module will produce text output of the schema suitable for SQLite.
  35
  36 =cut
  37
  38 use strict;
  39 use warnings;
  40 use Data::Dumper;
  41 use SQL::Translator::Schema::Constants;
  42 use SQL::Translator::Utils qw(debug header_comment parse_dbms_version);
  43
  44 use vars qw[ $VERSION $DEBUG $WARN ];
  45
  46 $VERSION = '1.59';
  47 $DEBUG = 0 unless defined $DEBUG;
  48 $WARN = 0 unless defined $WARN;
  49
  50 our $max_id_length    = 30;
  51 my %global_names;
  52
  53 sub produce {
  54     my $translator     = shift;
  55     local $DEBUG       = $translator->debug;
  56     local $WARN        = $translator->show_warnings;
  57     my $no_comments    = $translator->no_comments;
  58     my $add_drop_table = $translator->add_drop_table;
  59     my $schema         = $translator->schema;
  60     my $producer_args  = $translator->producer_args;
  61     my $sqlite_version = parse_dbms_version(
  62         $producer_args->{sqlite_version}, 'perl'
  63     );
  64     my $no_txn         = $producer_args->{no_transaction};
  65
  66     debug("PKG: Beginning production\n");
  67
  68     %global_names = ();   #reset
  69
  70
  71     my $head = (header_comment() . "\n") unless $no_comments;
  72
  73     my @create = ();
  74
  75     push @create, "BEGIN TRANSACTION" unless $no_txn;
  76
  77     for my $table ( $schema->get_tables ) {
  78         push @create, create_table($table, { no_comments => $no_comments,
  79                                              sqlite_version => $sqlite_version,
  80                                           add_drop_table => $add_drop_table,});
  81     }
  82
  83     for my $view ( $schema->get_views ) {
  84       push @create, create_view($view, {
  85         add_drop_view => $add_drop_table,
  86         no_comments   => $no_comments,
  87       });
  88     }
  89
  90     for my $trigger ( $schema->get_triggers ) {
  91       push @create, create_trigger($trigger, {
  92         add_drop_trigger => $add_drop_table,
  93         no_comments   => $no_comments,
  94       });
  95     }
  96
  97     push @create, "COMMIT" unless $no_txn;
  98
  99     if (wantarray) {
 100       return ($head||(), @create);
 101     } else {
 102       return join ('',
 103         $head||(),
 104         join(";\n\n", @create ),
 105         ";\n",
 106       );
 107     }
 108 }
 109
 110 # -------------------------------------------------------------------
 111 sub mk_name {
 112     my ($name, $scope, $critical) = @_;
 113
 114     $scope ||= \%global_names;
 115     if ( my $prev = $scope->{ $name } ) {
 116         my $name_orig = $name;
 117         $name        .= sprintf( "%02d", ++$prev );
 118         substr($name, $max_id_length - 3) = "00"
 119             if length( $name ) > $max_id_length;
 120
 121         warn "The name '$name_orig' has been changed to ",
 122              "'$name' to make it unique.\n" if $WARN;
 123
 124         $scope->{ $name_orig }++;
 125     }
 126
 127     $scope->{ $name }++;
 128     return $name;
 129 }
 130
 131 sub create_view {
 132     my ($view, $options) = @_;
 133     my $add_drop_view = $options->{add_drop_view};
 134
 135     my $view_name = $view->name;
 136     debug("PKG: Looking at view '${view_name}'\n");
 137
 138     # Header.  Should this look like what mysqldump produces?
 139     my $extra = $view->extra;
 140     my @create;
 141     push @create, "DROP VIEW IF EXISTS $view_name" if $add_drop_view;
 142
 143     my $create_view = 'CREATE';
 144     $create_view .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 145     $create_view .= ' VIEW';
 146     $create_view .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 147     $create_view .= " ${view_name}";
 148
 149     if( my $sql = $view->sql ){
 150       $create_view .= " AS\n    ${sql}";
 151     }
 152     push @create, $create_view;
 153
 154     # Tack the comment onto the first statement.
 155     unless ($options->{no_comments}) {
 156       $create[0] = "--\n-- View: ${view_name}\n--\n" . $create[0];
 157     }
 158
 159     return @create;
 160 }
 161
 162
 163 sub create_table
 164 {
 165     my ($table, $options) = @_;
 166
 167     my $table_name = $table->name;
 168     my $no_comments = $options->{no_comments};
 169     my $add_drop_table = $options->{add_drop_table};
 170     my $sqlite_version = $options->{sqlite_version} || 0;
 171
 172     debug("PKG: Looking at table '$table_name'\n");
 173
 174     my ( @index_defs, @constraint_defs );
 175     my @fields = $table->get_fields or die "No fields in $table_name";
 176
 177     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 178     #
 179     # Header.
 180     #
 181     my $exists = ($sqlite_version >= 3.003) ? ' IF EXISTS' : '';
 182     my @create;
 183     my ($comment, $create_table) = "";
 184     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 185     if ($add_drop_table) {
 186       push @create, $comment . qq[DROP TABLE$exists $table_name];
 187     } else {
 188       $create_table = $comment;
 189     }
 190
 191     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 192
 193     #
 194     # Comments
 195     #
 196     if ( $table->comments and !$no_comments ){
 197         $create_table .= "-- Comments: \n-- ";
 198         $create_table .= join "\n-- ",  $table->comments;
 199         $create_table .= "\n--\n\n";
 200     }
 201
 202     #
 203     # How many fields in PK?
 204     #
 205     my $pk        = $table->primary_key;
 206     my @pk_fields = $pk ? $pk->fields : ();
 207
 208     #
 209     # Fields
 210     #
 211     my ( @field_defs, $pk_set );
 212     for my $field ( @fields ) {
 213         push @field_defs, create_field($field);
 214     }
 215
 216     if (
 217          scalar @pk_fields > 1
 218          ||
 219          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 220          ) {
 221         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 222     }
 223
 224     #
 225     # Indices
 226     #
 227     my $idx_name_default = 'A';
 228     for my $index ( $table->get_indices ) {
 229         push @index_defs, create_index($index);
 230     }
 231
 232     #
 233     # Constraints
 234     #
 235     my $c_name_default = 'A';
 236     for my $c ( $table->get_constraints ) {
 237         next unless $c->type eq UNIQUE;
 238         push @constraint_defs, create_constraint($c);
 239     }
 240
 241     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 242
 243     return (@create, $create_table, @index_defs, @constraint_defs );
 244 }
 245
 246 sub create_field
 247 {
 248     my ($field, $options) = @_;
 249
 250     my $field_name = $field->name;
 251     debug("PKG: Looking at field '$field_name'\n");
 252     my $field_comments = $field->comments
 253         ? "-- " . $field->comments . "\n  "
 254         : '';
 255
 256     my $field_def = $field_comments.$field_name;
 257
 258     # data type and size
 259     my $size      = $field->size;
 260     my $data_type = $field->data_type;
 261     $data_type    = 'varchar' if lc $data_type eq 'set';
 262     $data_type  = 'blob' if lc $data_type eq 'bytea';
 263
 264     if ( lc $data_type =~ /(text|blob)/i ) {
 265         $size = undef;
 266     }
 267
 268 #             if ( $data_type =~ /timestamp/i ) {
 269 #                 push @trigger_defs,
 270 #                     "CREATE TRIGGER ts_${table_name} ".
 271 #                     "after insert on $table_name\n".
 272 #                     "begin\n".
 273 #                     "  update $table_name set $field_name=timestamp() ".
 274 #                        "where id=new.id;\n".
 275 #                     "end;\n"
 276 #                 ;
 277 #
 278 #            }
 279
 280     #
 281     # SQLite is generally typeless, but newer versions will
 282     # make a field autoincrement if it is declared as (and
 283     # *only* as) INTEGER PRIMARY KEY
 284     #
 285     my $pk        = $field->table->primary_key;
 286     my @pk_fields = $pk ? $pk->fields : ();
 287
 288     if (
 289          $field->is_primary_key &&
 290          scalar @pk_fields == 1 &&
 291          (
 292           $data_type =~ /int(eger)?$/i
 293           ||
 294           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 295           )
 296          ) {
 297         $data_type = 'INTEGER PRIMARY KEY';
 298         $size      = undef;
 299 #        $pk_set    = 1;
 300     }
 301
 302     $field_def .= sprintf " %s%s", $data_type,
 303     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 304
 305     # Null?
 306     $field_def .= ' NOT NULL' unless $field->is_nullable;
 307
 308     # Default?  XXX Need better quoting!
 309     my $default = $field->default_value;
 310     if (defined $default) {
 311         SQL::Translator::Producer->_apply_default_value(
 312             \$field_def,
 313             $default,
 314             [
 315              'NULL'              => \'NULL',
 316              'now()'             => 'now()',
 317              'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 318             ],
 319         );
 320     }
 321
 322     return $field_def;
 323
 324 }
 325
 326 sub create_index
 327 {
 328     my ($index, $options) = @_;
 329
 330     my $name   = $index->name;
 331     $name      = mk_name($name);
 332
 333     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 334
 335     # strip any field size qualifiers as SQLite doesn't like these
 336     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 337     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 338     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 339     my $index_def =
 340     "CREATE ${type}INDEX $name ON " . $index_table_name .
 341         ' (' . join( ', ', @fields ) . ')';
 342
 343     return $index_def;
 344 }
 345
 346 sub create_constraint
 347 {
 348     my ($c, $options) = @_;
 349
 350     my $name   = $c->name;
 351     $name      = mk_name($name);
 352     my @fields = $c->fields;
 353     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 354     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 355
 356     my $c_def =
 357     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 358         ' (' . join( ', ', @fields ) . ')';
 359
 360     return $c_def;
 361 }
 362
 363 sub create_trigger {
 364   my ($trigger, $options) = @_;
 365   my $add_drop = $options->{add_drop_trigger};
 366
 367   my @statements;
 368
 369   my $trigger_name = $trigger->name;
 370   my $events = $trigger->database_events;
 371   for my $evt ( @$events ) {
 372
 373     my $trig_name = $trigger_name;
 374     if (@$events > 1) {
 375       $trig_name .= "_$evt";
 376
 377       warn "Multiple database events supplied for trigger '$trigger_name', ",
 378         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 379     }
 380
 381     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 382
 383
 384     $DB::single = 1;
 385     my $action = "";
 386     if (not ref $trigger->action) {
 387       $action .= "BEGIN " . $trigger->action . " END";
 388     }
 389     else {
 390       $action = $trigger->action->{for_each} . " "
 391         if $trigger->action->{for_each};
 392
 393       $action = $trigger->action->{when} . " "
 394         if $trigger->action->{when};
 395
 396       my $steps = $trigger->action->{steps} || [];
 397
 398       $action .= "BEGIN ";
 399       $action .= $_ . "; " for (@$steps);
 400       $action .= "END";
 401     }
 402
 403     push @statements, sprintf (
 404       'CREATE TRIGGER %s %s %s on %s %s',
 405       $trig_name,
 406       $trigger->perform_action_when,
 407       $evt,
 408       $trigger->on_table,
 409       $action
 410     );
 411   }
 412
 413   return @statements;
 414 }
 415
 416 sub alter_table { } # Noop
 417
 418 sub add_field {
 419   my ($field) = @_;
 420
 421   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 422       $field->table->name, create_field($field))
 423 }
 424
 425 sub alter_create_index {
 426   my ($index) = @_;
 427
 428   # This might cause name collisions
 429   return create_index($index);
 430 }
 431
 432 sub alter_create_constraint {
 433   my ($constraint) = @_;
 434
 435   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 436 }
 437
 438 sub alter_drop_constraint { alter_drop_index(@_) }
 439
 440 sub alter_drop_index {
 441   my ($constraint) = @_;
 442
 443   return sprintf("DROP INDEX %s",
 444       $constraint->name);
 445 }
 446
 447 sub batch_alter_table {
 448   my ($table, $diffs) = @_;
 449
 450   # If we have any of the following
 451   #
 452   #  rename_field
 453   #  alter_field
 454   #  drop_field
 455   #
 456   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 457   #
 458   # BEGIN TRANSACTION;
 459   # CREATE TEMPORARY TABLE t1_backup(a,b);
 460   # INSERT INTO t1_backup SELECT a,b FROM t1;
 461   # DROP TABLE t1;
 462   # CREATE TABLE t1(a,b);
 463   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 464   # DROP TABLE t1_backup;
 465   # COMMIT;
 466   #
 467   # Fun, eh?
 468   #
 469   # If we have rename_field we do similarly.
 470
 471   my $table_name = $table->name;
 472   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 473
 474   if ( @{$diffs->{rename_field}} == 0 &&
 475        @{$diffs->{alter_field}}  == 0 &&
 476        @{$diffs->{drop_field}}   == 0
 477        ) {
 478 #    return join("\n", map {
 479     return map {
 480         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 481         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 482
 483       } grep { @{$diffs->{$_}} }
 484     qw/rename_table
 485        alter_drop_constraint
 486        alter_drop_index
 487        drop_field
 488        add_field
 489        alter_field
 490        rename_field
 491        alter_create_index
 492        alter_create_constraint
 493        alter_table/;
 494   }
 495
 496
 497   my @sql;
 498   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 499
 500   do {
 501     local $table->{name} = $table_name . '_temp_alter';
 502     # We only want the table - dont care about indexes on tmp table
 503     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 504     push @sql,$table_sql;
 505   };
 506
 507   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 508              "DROP TABLE @{[$old_table]}",
 509              create_table($table, { no_comments => 1 }),
 510              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 511              "DROP TABLE @{[$table_name]}_temp_alter";
 512
 513   return @sql;
 514 #  return join("", @sql, "");
 515 }
 516
 517 sub drop_table {
 518   my ($table) = @_;
 519   return "DROP TABLE $table";
 520 }
 521
 522 sub rename_table {
 523   my ($old_table, $new_table, $options) = @_;
 524
 525   my $qt = $options->{quote_table_names} || '';
 526
 527   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 528
 529 }
 530
 531 # No-op. Just here to signify that we are a new style parser.
 532 sub preproces_schema { }
 533
 534 1;
 535
 536 =pod
 537
 538 =head1 SEE ALSO
 539
 540 SQL::Translator, http://www.sqlite.org/.
 541
 542 =head1 AUTHOR
 543
 544 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 545
 546 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 547
 548 =cut