lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 =head1 NAME
   4
   5 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
   6
   7 =head1 SYNOPSIS
   8
   9   use SQL::Translator;
  10
  11   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  12   $t->translate;
  13
  14 =head1 DESCRIPTION
  15
  16 This module will produce text output of the schema suitable for SQLite.
  17
  18 =cut
  19
  20 use strict;
  21 use warnings;
  22 use Data::Dumper;
  23 use SQL::Translator::Schema::Constants;
  24 use SQL::Translator::Utils qw(debug header_comment parse_dbms_version);
  25
  26 use vars qw[ $VERSION $DEBUG $WARN ];
  27
  28 $VERSION = '1.59';
  29 $DEBUG = 0 unless defined $DEBUG;
  30 $WARN = 0 unless defined $WARN;
  31
  32 our $max_id_length    = 30;
  33 my %global_names;
  34
  35 sub produce {
  36     my $translator     = shift;
  37     local $DEBUG       = $translator->debug;
  38     local $WARN        = $translator->show_warnings;
  39     my $no_comments    = $translator->no_comments;
  40     my $add_drop_table = $translator->add_drop_table;
  41     my $schema         = $translator->schema;
  42     my $producer_args  = $translator->producer_args;
  43     my $sqlite_version = parse_dbms_version(
  44         $producer_args->{sqlite_version}, 'perl'
  45     );
  46     my $no_txn         = $producer_args->{no_transaction};
  47
  48     debug("PKG: Beginning production\n");
  49
  50     %global_names = ();   #reset
  51
  52
  53     my $head = (header_comment() . "\n") unless $no_comments;
  54
  55     my @create = ();
  56
  57     push @create, "BEGIN TRANSACTION" unless $no_txn;
  58
  59     for my $table ( $schema->get_tables ) {
  60         push @create, create_table($table, { no_comments => $no_comments,
  61                                              sqlite_version => $sqlite_version,
  62                                           add_drop_table => $add_drop_table,});
  63     }
  64
  65     for my $view ( $schema->get_views ) {
  66       push @create, create_view($view, {
  67         add_drop_view => $add_drop_table,
  68         no_comments   => $no_comments,
  69       });
  70     }
  71
  72     for my $trigger ( $schema->get_triggers ) {
  73       push @create, create_trigger($trigger, {
  74         add_drop_trigger => $add_drop_table,
  75         no_comments   => $no_comments,
  76       });
  77     }
  78
  79     push @create, "COMMIT" unless $no_txn;
  80
  81     if (wantarray) {
  82       return ($head||(), @create);
  83     } else {
  84       return join ('',
  85         $head||(),
  86         join(";\n\n", @create ),
  87         ";\n",
  88       );
  89     }
  90 }
  91
  92 # -------------------------------------------------------------------
  93 sub mk_name {
  94     my ($name, $scope, $critical) = @_;
  95
  96     $scope ||= \%global_names;
  97     if ( my $prev = $scope->{ $name } ) {
  98         my $name_orig = $name;
  99         $name        .= sprintf( "%02d", ++$prev );
 100         substr($name, $max_id_length - 3) = "00"
 101             if length( $name ) > $max_id_length;
 102
 103         warn "The name '$name_orig' has been changed to ",
 104              "'$name' to make it unique.\n" if $WARN;
 105
 106         $scope->{ $name_orig }++;
 107     }
 108
 109     $scope->{ $name }++;
 110     return $name;
 111 }
 112
 113 sub create_view {
 114     my ($view, $options) = @_;
 115     my $add_drop_view = $options->{add_drop_view};
 116
 117     my $view_name = $view->name;
 118     debug("PKG: Looking at view '${view_name}'\n");
 119
 120     # Header.  Should this look like what mysqldump produces?
 121     my $extra = $view->extra;
 122     my @create;
 123     push @create, "DROP VIEW IF EXISTS $view_name" if $add_drop_view;
 124
 125     my $create_view = 'CREATE';
 126     $create_view .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 127     $create_view .= ' VIEW';
 128     $create_view .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 129     $create_view .= " ${view_name}";
 130
 131     if( my $sql = $view->sql ){
 132       $create_view .= " AS\n    ${sql}";
 133     }
 134     push @create, $create_view;
 135
 136     # Tack the comment onto the first statement.
 137     unless ($options->{no_comments}) {
 138       $create[0] = "--\n-- View: ${view_name}\n--\n" . $create[0];
 139     }
 140
 141     return @create;
 142 }
 143
 144
 145 sub create_table
 146 {
 147     my ($table, $options) = @_;
 148
 149     my $table_name = $table->name;
 150     my $no_comments = $options->{no_comments};
 151     my $add_drop_table = $options->{add_drop_table};
 152     my $sqlite_version = $options->{sqlite_version} || 0;
 153
 154     debug("PKG: Looking at table '$table_name'\n");
 155
 156     my ( @index_defs, @constraint_defs );
 157     my @fields = $table->get_fields or die "No fields in $table_name";
 158
 159     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 160     #
 161     # Header.
 162     #
 163     my $exists = ($sqlite_version >= 3.003) ? ' IF EXISTS' : '';
 164     my @create;
 165     my ($comment, $create_table) = "";
 166     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 167     if ($add_drop_table) {
 168       push @create, $comment . qq[DROP TABLE$exists $table_name];
 169     } else {
 170       $create_table = $comment;
 171     }
 172
 173     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 174
 175     #
 176     # Comments
 177     #
 178     if ( $table->comments and !$no_comments ){
 179         $create_table .= "-- Comments: \n-- ";
 180         $create_table .= join "\n-- ",  $table->comments;
 181         $create_table .= "\n--\n\n";
 182     }
 183
 184     #
 185     # How many fields in PK?
 186     #
 187     my $pk        = $table->primary_key;
 188     my @pk_fields = $pk ? $pk->fields : ();
 189
 190     #
 191     # Fields
 192     #
 193     my ( @field_defs, $pk_set );
 194     for my $field ( @fields ) {
 195         push @field_defs, create_field($field);
 196     }
 197
 198     if (
 199          scalar @pk_fields > 1
 200          ||
 201          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 202          ) {
 203         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 204     }
 205
 206     #
 207     # Indices
 208     #
 209     my $idx_name_default = 'A';
 210     for my $index ( $table->get_indices ) {
 211         push @index_defs, create_index($index);
 212     }
 213
 214     #
 215     # Constraints
 216     #
 217     my $c_name_default = 'A';
 218     for my $c ( $table->get_constraints ) {
 219         next unless $c->type eq UNIQUE;
 220         push @constraint_defs, create_constraint($c);
 221     }
 222
 223     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 224
 225     return (@create, $create_table, @index_defs, @constraint_defs );
 226 }
 227
 228 sub create_field
 229 {
 230     my ($field, $options) = @_;
 231
 232     my $field_name = $field->name;
 233     debug("PKG: Looking at field '$field_name'\n");
 234     my $field_comments = $field->comments
 235         ? "-- " . $field->comments . "\n  "
 236         : '';
 237
 238     my $field_def = $field_comments.$field_name;
 239
 240     # data type and size
 241     my $size      = $field->size;
 242     my $data_type = $field->data_type;
 243     $data_type    = 'varchar' if lc $data_type eq 'set';
 244     $data_type  = 'blob' if lc $data_type eq 'bytea';
 245
 246     if ( lc $data_type =~ /(text|blob)/i ) {
 247         $size = undef;
 248     }
 249
 250 #             if ( $data_type =~ /timestamp/i ) {
 251 #                 push @trigger_defs,
 252 #                     "CREATE TRIGGER ts_${table_name} ".
 253 #                     "after insert on $table_name\n".
 254 #                     "begin\n".
 255 #                     "  update $table_name set $field_name=timestamp() ".
 256 #                        "where id=new.id;\n".
 257 #                     "end;\n"
 258 #                 ;
 259 #
 260 #            }
 261
 262     #
 263     # SQLite is generally typeless, but newer versions will
 264     # make a field autoincrement if it is declared as (and
 265     # *only* as) INTEGER PRIMARY KEY
 266     #
 267     my $pk        = $field->table->primary_key;
 268     my @pk_fields = $pk ? $pk->fields : ();
 269
 270     if (
 271          $field->is_primary_key &&
 272          scalar @pk_fields == 1 &&
 273          (
 274           $data_type =~ /int(eger)?$/i
 275           ||
 276           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 277           )
 278          ) {
 279         $data_type = 'INTEGER PRIMARY KEY';
 280         $size      = undef;
 281 #        $pk_set    = 1;
 282     }
 283
 284     $field_def .= sprintf " %s%s", $data_type,
 285     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 286
 287     # Null?
 288     $field_def .= ' NOT NULL' unless $field->is_nullable;
 289
 290     # Default?
 291     SQL::Translator::Producer->_apply_default_value(
 292         $field,
 293         \$field_def,
 294         [
 295          'NULL'              => \'NULL',
 296          'now()'             => 'now()',
 297          'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 298         ],
 299     );
 300
 301     return $field_def;
 302
 303 }
 304
 305 sub create_index
 306 {
 307     my ($index, $options) = @_;
 308
 309     my $name   = $index->name;
 310     $name      = mk_name($name);
 311
 312     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 313
 314     # strip any field size qualifiers as SQLite doesn't like these
 315     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 316     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 317     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 318     my $index_def =
 319     "CREATE ${type}INDEX $name ON " . $index_table_name .
 320         ' (' . join( ', ', @fields ) . ')';
 321
 322     return $index_def;
 323 }
 324
 325 sub create_constraint
 326 {
 327     my ($c, $options) = @_;
 328
 329     my $name   = $c->name;
 330     $name      = mk_name($name);
 331     my @fields = $c->fields;
 332     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 333     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 334
 335     my $c_def =
 336     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 337         ' (' . join( ', ', @fields ) . ')';
 338
 339     return $c_def;
 340 }
 341
 342 sub create_trigger {
 343   my ($trigger, $options) = @_;
 344   my $add_drop = $options->{add_drop_trigger};
 345
 346   my @statements;
 347
 348   my $trigger_name = $trigger->name;
 349   my $events = $trigger->database_events;
 350   for my $evt ( @$events ) {
 351
 352     my $trig_name = $trigger_name;
 353     if (@$events > 1) {
 354       $trig_name .= "_$evt";
 355
 356       warn "Multiple database events supplied for trigger '$trigger_name', ",
 357         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 358     }
 359
 360     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 361
 362
 363     $DB::single = 1;
 364     my $action = "";
 365     if (not ref $trigger->action) {
 366       $action .= "BEGIN " . $trigger->action . " END";
 367     }
 368     else {
 369       $action = $trigger->action->{for_each} . " "
 370         if $trigger->action->{for_each};
 371
 372       $action = $trigger->action->{when} . " "
 373         if $trigger->action->{when};
 374
 375       my $steps = $trigger->action->{steps} || [];
 376
 377       $action .= "BEGIN ";
 378       $action .= $_ . "; " for (@$steps);
 379       $action .= "END";
 380     }
 381
 382     push @statements, sprintf (
 383       'CREATE TRIGGER %s %s %s on %s %s',
 384       $trig_name,
 385       $trigger->perform_action_when,
 386       $evt,
 387       $trigger->on_table,
 388       $action
 389     );
 390   }
 391
 392   return @statements;
 393 }
 394
 395 sub alter_table { } # Noop
 396
 397 sub add_field {
 398   my ($field) = @_;
 399
 400   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 401       $field->table->name, create_field($field))
 402 }
 403
 404 sub alter_create_index {
 405   my ($index) = @_;
 406
 407   # This might cause name collisions
 408   return create_index($index);
 409 }
 410
 411 sub alter_create_constraint {
 412   my ($constraint) = @_;
 413
 414   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 415 }
 416
 417 sub alter_drop_constraint { alter_drop_index(@_) }
 418
 419 sub alter_drop_index {
 420   my ($constraint) = @_;
 421
 422   return sprintf("DROP INDEX %s",
 423       $constraint->name);
 424 }
 425
 426 sub batch_alter_table {
 427   my ($table, $diffs) = @_;
 428
 429   # If we have any of the following
 430   #
 431   #  rename_field
 432   #  alter_field
 433   #  drop_field
 434   #
 435   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 436   #
 437   # BEGIN TRANSACTION;
 438   # CREATE TEMPORARY TABLE t1_backup(a,b);
 439   # INSERT INTO t1_backup SELECT a,b FROM t1;
 440   # DROP TABLE t1;
 441   # CREATE TABLE t1(a,b);
 442   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 443   # DROP TABLE t1_backup;
 444   # COMMIT;
 445   #
 446   # Fun, eh?
 447   #
 448   # If we have rename_field we do similarly.
 449
 450   my $table_name = $table->name;
 451   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 452
 453   if ( @{$diffs->{rename_field}} == 0 &&
 454        @{$diffs->{alter_field}}  == 0 &&
 455        @{$diffs->{drop_field}}   == 0
 456        ) {
 457 #    return join("\n", map {
 458     return map {
 459         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 460         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 461
 462       } grep { @{$diffs->{$_}} }
 463     qw/rename_table
 464        alter_drop_constraint
 465        alter_drop_index
 466        drop_field
 467        add_field
 468        alter_field
 469        rename_field
 470        alter_create_index
 471        alter_create_constraint
 472        alter_table/;
 473   }
 474
 475
 476   my @sql;
 477   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 478
 479   do {
 480     local $table->{name} = $table_name . '_temp_alter';
 481     # We only want the table - dont care about indexes on tmp table
 482     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 483     push @sql,$table_sql;
 484   };
 485
 486   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 487              "DROP TABLE @{[$old_table]}",
 488              create_table($table, { no_comments => 1 }),
 489              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 490              "DROP TABLE @{[$table_name]}_temp_alter";
 491
 492   return @sql;
 493 #  return join("", @sql, "");
 494 }
 495
 496 sub drop_table {
 497   my ($table) = @_;
 498   return "DROP TABLE $table";
 499 }
 500
 501 sub rename_table {
 502   my ($old_table, $new_table, $options) = @_;
 503
 504   my $qt = $options->{quote_table_names} || '';
 505
 506   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 507
 508 }
 509
 510 # No-op. Just here to signify that we are a new style parser.
 511 sub preproces_schema { }
 512
 513 1;
 514
 515 =pod
 516
 517 =head1 SEE ALSO
 518
 519 SQL::Translator, http://www.sqlite.org/.
 520
 521 =head1 AUTHOR
 522
 523 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 524
 525 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 526
 527 =cut