lib/SQL/Translator/Producer/SQLite.pm

   1 package SQL::Translator::Producer::SQLite;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Producer::SQLite - SQLite producer for SQL::Translator
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $t = SQL::Translator->new( parser => '...', producer => 'SQLite' );
  30   $t->translate;
  31
  32 =head1 DESCRIPTION
  33
  34 This module will produce text output of the schema suitable for SQLite.
  35
  36 =cut
  37
  38 use strict;
  39 use warnings;
  40 use Data::Dumper;
  41 use SQL::Translator::Schema::Constants;
  42 use SQL::Translator::Utils qw(debug header_comment parse_dbms_version);
  43
  44 use vars qw[ $VERSION $DEBUG $WARN ];
  45
  46 $VERSION = '1.59';
  47 $DEBUG = 0 unless defined $DEBUG;
  48 $WARN = 0 unless defined $WARN;
  49
  50 our $max_id_length    = 30;
  51 my %global_names;
  52
  53 sub produce {
  54     my $translator     = shift;
  55     local $DEBUG       = $translator->debug;
  56     local $WARN        = $translator->show_warnings;
  57     my $no_comments    = $translator->no_comments;
  58     my $add_drop_table = $translator->add_drop_table;
  59     my $schema         = $translator->schema;
  60     my $producer_args  = $translator->producer_args;
  61     my $sqlite_version = parse_dbms_version(
  62         $producer_args->{sqlite_version}, 'perl'
  63     );
  64     my $no_txn         = $producer_args->{no_transaction};
  65
  66     debug("PKG: Beginning production\n");
  67
  68     %global_names = ();   #reset
  69
  70
  71     my $head = (header_comment() . "\n") unless $no_comments;
  72
  73     my @create = ();
  74
  75     push @create, "BEGIN TRANSACTION" unless $no_txn;
  76
  77     for my $table ( $schema->get_tables ) {
  78         push @create, create_table($table, { no_comments => $no_comments,
  79                                              sqlite_version => $sqlite_version,
  80                                           add_drop_table => $add_drop_table,});
  81     }
  82
  83     for my $view ( $schema->get_views ) {
  84       push @create, create_view($view, {
  85         add_drop_view => $add_drop_table,
  86         no_comments   => $no_comments,
  87       });
  88     }
  89
  90     for my $trigger ( $schema->get_triggers ) {
  91       push @create, create_trigger($trigger, {
  92         add_drop_trigger => $add_drop_table,
  93         no_comments   => $no_comments,
  94       });
  95     }
  96
  97     push @create, "COMMIT" unless $no_txn;
  98
  99     if (wantarray) {
 100       return ($head||(), @create);
 101     } else {
 102       return join ('',
 103         $head||(),
 104         join(";\n\n", @create ),
 105         ";\n",
 106       );
 107     }
 108 }
 109
 110 # -------------------------------------------------------------------
 111 sub mk_name {
 112     my ($name, $scope, $critical) = @_;
 113
 114     $scope ||= \%global_names;
 115     if ( my $prev = $scope->{ $name } ) {
 116         my $name_orig = $name;
 117         $name        .= sprintf( "%02d", ++$prev );
 118         substr($name, $max_id_length - 3) = "00"
 119             if length( $name ) > $max_id_length;
 120
 121         warn "The name '$name_orig' has been changed to ",
 122              "'$name' to make it unique.\n" if $WARN;
 123
 124         $scope->{ $name_orig }++;
 125     }
 126
 127     $scope->{ $name }++;
 128     return $name;
 129 }
 130
 131 sub create_view {
 132     my ($view, $options) = @_;
 133     my $add_drop_view = $options->{add_drop_view};
 134
 135     my $view_name = $view->name;
 136     debug("PKG: Looking at view '${view_name}'\n");
 137
 138     # Header.  Should this look like what mysqldump produces?
 139     my $extra = $view->extra;
 140     my @create;
 141     push @create, "DROP VIEW IF EXISTS $view_name" if $add_drop_view;
 142
 143     my $create_view = 'CREATE';
 144     $create_view .= " TEMPORARY" if exists($extra->{temporary}) && $extra->{temporary};
 145     $create_view .= ' VIEW';
 146     $create_view .= " IF NOT EXISTS" if exists($extra->{if_not_exists}) && $extra->{if_not_exists};
 147     $create_view .= " ${view_name}";
 148
 149     if( my $sql = $view->sql ){
 150       $create_view .= " AS\n    ${sql}";
 151     }
 152     push @create, $create_view;
 153
 154     # Tack the comment onto the first statement.
 155     unless ($options->{no_comments}) {
 156       $create[0] = "--\n-- View: ${view_name}\n--\n" . $create[0];
 157     }
 158
 159     return @create;
 160 }
 161
 162
 163 sub create_table
 164 {
 165     my ($table, $options) = @_;
 166
 167     my $table_name = $table->name;
 168     my $no_comments = $options->{no_comments};
 169     my $add_drop_table = $options->{add_drop_table};
 170     my $sqlite_version = $options->{sqlite_version} || 0;
 171
 172     debug("PKG: Looking at table '$table_name'\n");
 173
 174     my ( @index_defs, @constraint_defs );
 175     my @fields = $table->get_fields or die "No fields in $table_name";
 176
 177     my $temp = $options->{temporary_table} ? 'TEMPORARY ' : '';
 178     #
 179     # Header.
 180     #
 181     my $exists = ($sqlite_version >= 3.003) ? ' IF EXISTS' : '';
 182     my @create;
 183     my ($comment, $create_table) = "";
 184     $comment =  "--\n-- Table: $table_name\n--\n" unless $no_comments;
 185     if ($add_drop_table) {
 186       push @create, $comment . qq[DROP TABLE$exists $table_name];
 187     } else {
 188       $create_table = $comment;
 189     }
 190
 191     $create_table .= "CREATE ${temp}TABLE $table_name (\n";
 192
 193     #
 194     # Comments
 195     #
 196     if ( $table->comments and !$no_comments ){
 197         $create_table .= "-- Comments: \n-- ";
 198         $create_table .= join "\n-- ",  $table->comments;
 199         $create_table .= "\n--\n\n";
 200     }
 201
 202     #
 203     # How many fields in PK?
 204     #
 205     my $pk        = $table->primary_key;
 206     my @pk_fields = $pk ? $pk->fields : ();
 207
 208     #
 209     # Fields
 210     #
 211     my ( @field_defs, $pk_set );
 212     for my $field ( @fields ) {
 213         push @field_defs, create_field($field);
 214     }
 215
 216     if (
 217          scalar @pk_fields > 1
 218          ||
 219          ( @pk_fields && !grep /INTEGER PRIMARY KEY/, @field_defs )
 220          ) {
 221         push @field_defs, 'PRIMARY KEY (' . join(', ', @pk_fields ) . ')';
 222     }
 223
 224     #
 225     # Indices
 226     #
 227     my $idx_name_default = 'A';
 228     for my $index ( $table->get_indices ) {
 229         push @index_defs, create_index($index);
 230     }
 231
 232     #
 233     # Constraints
 234     #
 235     my $c_name_default = 'A';
 236     for my $c ( $table->get_constraints ) {
 237         if ($c->type eq "FOREIGN KEY") {
 238             push @field_defs, create_foreignkey($c);
 239         }
 240         next unless $c->type eq UNIQUE;
 241         push @constraint_defs, create_constraint($c);
 242     }
 243
 244     $create_table .= join(",\n", map { "  $_" } @field_defs ) . "\n)";
 245
 246     return (@create, $create_table, @index_defs, @constraint_defs );
 247 }
 248
 249 sub create_foreignkey {
 250     my $c = shift;
 251
 252     my $fk_sql = "FOREIGN KEY($c->{fields}[0]) REFERENCES ";
 253     $fk_sql .= ( $c->{reference_table} || '' )."(".( $c->{reference_fields}[0] || '' ).")";
 254
 255     return $fk_sql;
 256 }
 257
 258 sub create_field
 259 {
 260     my ($field, $options) = @_;
 261
 262     my $field_name = $field->name;
 263     debug("PKG: Looking at field '$field_name'\n");
 264     my $field_comments = $field->comments
 265         ? "-- " . $field->comments . "\n  "
 266         : '';
 267
 268     my $field_def = $field_comments.$field_name;
 269
 270     # data type and size
 271     my $size      = $field->size;
 272     my $data_type = $field->data_type;
 273     $data_type    = 'varchar' if lc $data_type eq 'set';
 274     $data_type  = 'blob' if lc $data_type eq 'bytea';
 275
 276     if ( lc $data_type =~ /(text|blob)/i ) {
 277         $size = undef;
 278     }
 279
 280 #             if ( $data_type =~ /timestamp/i ) {
 281 #                 push @trigger_defs,
 282 #                     "CREATE TRIGGER ts_${table_name} ".
 283 #                     "after insert on $table_name\n".
 284 #                     "begin\n".
 285 #                     "  update $table_name set $field_name=timestamp() ".
 286 #                        "where id=new.id;\n".
 287 #                     "end;\n"
 288 #                 ;
 289 #
 290 #            }
 291
 292     #
 293     # SQLite is generally typeless, but newer versions will
 294     # make a field autoincrement if it is declared as (and
 295     # *only* as) INTEGER PRIMARY KEY
 296     #
 297     my $pk        = $field->table->primary_key;
 298     my @pk_fields = $pk ? $pk->fields : ();
 299
 300     if (
 301          $field->is_primary_key &&
 302          scalar @pk_fields == 1 &&
 303          (
 304           $data_type =~ /int(eger)?$/i
 305           ||
 306           ( $data_type =~ /^number?$/i && $size !~ /,/ )
 307           )
 308          ) {
 309         $data_type = 'INTEGER PRIMARY KEY';
 310         $size      = undef;
 311 #        $pk_set    = 1;
 312     }
 313
 314     $field_def .= sprintf " %s%s", $data_type,
 315     ( !$field->is_auto_increment && $size ) ? "($size)" : '';
 316
 317     # Null?
 318     $field_def .= ' NOT NULL' unless $field->is_nullable;
 319
 320     # Default?
 321     SQL::Translator::Producer->_apply_default_value(
 322         $field,
 323         \$field_def,
 324         [
 325          'NULL'              => \'NULL',
 326          'now()'             => 'now()',
 327          'CURRENT_TIMESTAMP' => 'CURRENT_TIMESTAMP',
 328         ],
 329     );
 330
 331     return $field_def;
 332
 333 }
 334
 335 sub create_index
 336 {
 337     my ($index, $options) = @_;
 338
 339     my $name   = $index->name;
 340     $name      = mk_name($name);
 341
 342     my $type   = $index->type eq 'UNIQUE' ? "UNIQUE " : '';
 343
 344     # strip any field size qualifiers as SQLite doesn't like these
 345     my @fields = map { s/\(\d+\)$//; $_ } $index->fields;
 346     (my $index_table_name = $index->table->name) =~ s/^.+?\.//; # table name may not specify schema
 347     warn "removing schema name from '" . $index->table->name . "' to make '$index_table_name'\n" if $WARN;
 348     my $index_def =
 349     "CREATE ${type}INDEX $name ON " . $index_table_name .
 350         ' (' . join( ', ', @fields ) . ')';
 351
 352     return $index_def;
 353 }
 354
 355 sub create_constraint
 356 {
 357     my ($c, $options) = @_;
 358
 359     my $name   = $c->name;
 360     $name      = mk_name($name);
 361     my @fields = $c->fields;
 362     (my $index_table_name = $c->table->name) =~ s/^.+?\.//; # table name may not specify schema
 363     warn "removing schema name from '" . $c->table->name . "' to make '$index_table_name'\n" if $WARN;
 364
 365     my $c_def =
 366     "CREATE UNIQUE INDEX $name ON " . $index_table_name .
 367         ' (' . join( ', ', @fields ) . ')';
 368
 369     return $c_def;
 370 }
 371
 372 sub create_trigger {
 373   my ($trigger, $options) = @_;
 374   my $add_drop = $options->{add_drop_trigger};
 375
 376   my @statements;
 377
 378   my $trigger_name = $trigger->name;
 379   my $events = $trigger->database_events;
 380   for my $evt ( @$events ) {
 381
 382     my $trig_name = $trigger_name;
 383     if (@$events > 1) {
 384       $trig_name .= "_$evt";
 385
 386       warn "Multiple database events supplied for trigger '$trigger_name', ",
 387         "creating trigger '$trig_name' for the '$evt' event.\n" if $WARN;
 388     }
 389
 390     push @statements,  "DROP TRIGGER IF EXISTS $trig_name" if $add_drop;
 391
 392
 393     $DB::single = 1;
 394     my $action = "";
 395     if (not ref $trigger->action) {
 396       $action .= "BEGIN " . $trigger->action . " END";
 397     }
 398     else {
 399       $action = $trigger->action->{for_each} . " "
 400         if $trigger->action->{for_each};
 401
 402       $action = $trigger->action->{when} . " "
 403         if $trigger->action->{when};
 404
 405       my $steps = $trigger->action->{steps} || [];
 406
 407       $action .= "BEGIN ";
 408       $action .= $_ . "; " for (@$steps);
 409       $action .= "END";
 410     }
 411
 412     push @statements, sprintf (
 413       'CREATE TRIGGER %s %s %s on %s %s',
 414       $trig_name,
 415       $trigger->perform_action_when,
 416       $evt,
 417       $trigger->on_table,
 418       $action
 419     );
 420   }
 421
 422   return @statements;
 423 }
 424
 425 sub alter_table { } # Noop
 426
 427 sub add_field {
 428   my ($field) = @_;
 429
 430   return sprintf("ALTER TABLE %s ADD COLUMN %s",
 431       $field->table->name, create_field($field))
 432 }
 433
 434 sub alter_create_index {
 435   my ($index) = @_;
 436
 437   # This might cause name collisions
 438   return create_index($index);
 439 }
 440
 441 sub alter_create_constraint {
 442   my ($constraint) = @_;
 443
 444   return create_constraint($constraint) if $constraint->type eq 'UNIQUE';
 445 }
 446
 447 sub alter_drop_constraint { alter_drop_index(@_) }
 448
 449 sub alter_drop_index {
 450   my ($constraint) = @_;
 451
 452   return sprintf("DROP INDEX %s",
 453       $constraint->name);
 454 }
 455
 456 sub batch_alter_table {
 457   my ($table, $diffs) = @_;
 458
 459   # If we have any of the following
 460   #
 461   #  rename_field
 462   #  alter_field
 463   #  drop_field
 464   #
 465   # we need to do the following <http://www.sqlite.org/faq.html#q11>
 466   #
 467   # BEGIN TRANSACTION;
 468   # CREATE TEMPORARY TABLE t1_backup(a,b);
 469   # INSERT INTO t1_backup SELECT a,b FROM t1;
 470   # DROP TABLE t1;
 471   # CREATE TABLE t1(a,b);
 472   # INSERT INTO t1 SELECT a,b FROM t1_backup;
 473   # DROP TABLE t1_backup;
 474   # COMMIT;
 475   #
 476   # Fun, eh?
 477   #
 478   # If we have rename_field we do similarly.
 479
 480   my $table_name = $table->name;
 481   my $renaming = $diffs->{rename_table} && @{$diffs->{rename_table}};
 482
 483   if ( @{$diffs->{rename_field}} == 0 &&
 484        @{$diffs->{alter_field}}  == 0 &&
 485        @{$diffs->{drop_field}}   == 0
 486        ) {
 487 #    return join("\n", map {
 488     return map {
 489         my $meth = __PACKAGE__->can($_) or die __PACKAGE__ . " cant $_";
 490         map { my $sql = $meth->(ref $_ eq 'ARRAY' ? @$_ : $_); $sql ?  ("$sql") : () } @{ $diffs->{$_} }
 491
 492       } grep { @{$diffs->{$_}} }
 493     qw/rename_table
 494        alter_drop_constraint
 495        alter_drop_index
 496        drop_field
 497        add_field
 498        alter_field
 499        rename_field
 500        alter_create_index
 501        alter_create_constraint
 502        alter_table/;
 503   }
 504
 505
 506   my @sql;
 507   my $old_table = $renaming ? $diffs->{rename_table}[0][0] : $table;
 508
 509   do {
 510     local $table->{name} = $table_name . '_temp_alter';
 511     # We only want the table - dont care about indexes on tmp table
 512     my ($table_sql) = create_table($table, {no_comments => 1, temporary_table => 1});
 513     push @sql,$table_sql;
 514   };
 515
 516   push @sql, "INSERT INTO @{[$table_name]}_temp_alter SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$old_table]}",
 517              "DROP TABLE @{[$old_table]}",
 518              create_table($table, { no_comments => 1 }),
 519              "INSERT INTO @{[$table_name]} SELECT @{[ join(', ', $old_table->get_fields)]} FROM @{[$table_name]}_temp_alter",
 520              "DROP TABLE @{[$table_name]}_temp_alter";
 521
 522   return @sql;
 523 #  return join("", @sql, "");
 524 }
 525
 526 sub drop_table {
 527   my ($table) = @_;
 528   return "DROP TABLE $table";
 529 }
 530
 531 sub rename_table {
 532   my ($old_table, $new_table, $options) = @_;
 533
 534   my $qt = $options->{quote_table_names} || '';
 535
 536   return "ALTER TABLE $qt$old_table$qt RENAME TO $qt$new_table$qt";
 537
 538 }
 539
 540 # No-op. Just here to signify that we are a new style parser.
 541 sub preproces_schema { }
 542
 543 1;
 544
 545 =pod
 546
 547 =head1 SEE ALSO
 548
 549 SQL::Translator, http://www.sqlite.org/.
 550
 551 =head1 AUTHOR
 552
 553 Ken Youens-Clark C<< <kclark@cpan.orgE> >>.
 554
 555 Diff code added by Ash Berlin C<< <ash@cpan.org> >>.
 556
 557 =cut