lib/SQL/Translator/Parser/xSV.pm

   1 package SQL::Translator::Parser::xSV;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Parser::xSV - parser for arbitrarily delimited text files
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28   use SQL::Translator::Parser::xSV;
  29
  30   my $translator  =  SQL::Translator->new(
  31       parser      => 'xSV',
  32       parser_args => { field_separator => "\t" },
  33   );
  34
  35 =head1 DESCRIPTION
  36
  37 Parses arbitrarily delimited text files.  See the
  38 Text::RecordParser manpage for arguments on how to parse the file
  39 (e.g., C<field_separator>, C<record_separator>).  Other arguments
  40 include:
  41
  42 =head1 OPTIONS
  43
  44 =over
  45
  46 =item * scan_fields
  47
  48 Indicates that the columns should be scanned to determine data types
  49 and field sizes.  True by default.
  50
  51 =item * trim_fields
  52
  53 A shortcut to sending filters to Text::RecordParser, will create
  54 callbacks that trim leading and trailing spaces from fields and headers.
  55 True by default.
  56
  57 =back
  58
  59 Field names will automatically be normalized by
  60 C<SQL::Translator::Utils::normalize_name>.
  61
  62 =cut
  63
  64 # -------------------------------------------------------------------
  65
  66 use strict;
  67 use vars qw($VERSION @EXPORT);
  68 $VERSION = '1.59';
  69
  70 use Exporter;
  71 use Text::ParseWords qw(quotewords);
  72 use Text::RecordParser;
  73 use SQL::Translator::Utils qw(debug normalize_name);
  74
  75 use base qw(Exporter);
  76 @EXPORT = qw(parse);
  77
  78 #
  79 # Passed a SQL::Translator instance and a string containing the data
  80 #
  81 sub parse {
  82     my ( $tr, $data )    = @_;
  83     my $args             = $tr->parser_args;
  84     my $parser           = Text::RecordParser->new(
  85         field_separator  => $args->{'field_separator'}  || ',',
  86         record_separator => $args->{'record_separator'} || "\n",
  87         data             => $data,
  88         header_filter    => \&normalize_name,
  89     );
  90
  91     $parser->field_filter( sub { $_ = shift || ''; s/^\s+|\s+$//g; $_ } )
  92         unless defined $args->{'trim_fields'} && $args->{'trim_fields'} == 0;
  93
  94     my $schema = $tr->schema;
  95     my $table = $schema->add_table( name => 'table1' );
  96
  97     #
  98     # Get the field names from the first row.
  99     #
 100     $parser->bind_header;
 101     my @field_names = $parser->field_list;
 102
 103     for ( my $i = 0; $i < @field_names; $i++ ) {
 104         my $field = $table->add_field(
 105             name              => $field_names[$i],
 106             data_type         => 'char',
 107             default_value     => '',
 108             size              => 255,
 109             is_nullable       => 1,
 110             is_auto_increment => undef,
 111         ) or die $table->error;
 112
 113         if ( $i == 0 ) {
 114             $table->primary_key( $field->name );
 115             $field->is_primary_key(1);
 116         }
 117     }
 118
 119     #
 120     # If directed, look at every field's values to guess size and type.
 121     #
 122     unless (
 123         defined $args->{'scan_fields'} &&
 124         $args->{'scan_fields'} == 0
 125     ) {
 126         my %field_info = map { $_, {} } @field_names;
 127         while ( my $rec = $parser->fetchrow_hashref ) {
 128             for my $field ( @field_names ) {
 129                 my $data = defined $rec->{ $field } ? $rec->{ $field } : '';
 130                 my $size = [ length $data ];
 131                 my $type;
 132
 133                 if ( $data =~ /^-?\d+$/ ) {
 134                     $type = 'integer';
 135                 }
 136                 elsif (
 137                     $data =~ /^-?[,\d]+\.[\d+]?$/
 138                     ||
 139                     $data =~ /^-?[,\d]+?\.\d+$/
 140                     ||
 141                     $data =~ /^-?\.\d+$/
 142                 ) {
 143                     $type = 'float';
 144                     my ( $w, $d ) =
 145                         map { s/,//g; length $_ || 1 } split( /\./, $data );
 146                     $size = [ $w + $d, $d ];
 147                 }
 148                 else {
 149                     $type = 'char';
 150                 }
 151
 152                 for my $i ( 0, 1 ) {
 153                     next unless defined $size->[ $i ];
 154                     my $fsize = $field_info{ $field }{'size'}[ $i ] || 0;
 155                     if ( $size->[ $i ] > $fsize ) {
 156                         $field_info{ $field }{'size'}[ $i ] = $size->[ $i ];
 157                     }
 158                 }
 159
 160                 $field_info{ $field }{ $type }++;
 161             }
 162         }
 163
 164         for my $field ( keys %field_info ) {
 165             my $size      = $field_info{ $field }{'size'} || [ 1 ];
 166             my $data_type =
 167                 $field_info{ $field }{'char'}    ? 'char'  :
 168                 $field_info{ $field }{'float'}   ? 'float' :
 169                 $field_info{ $field }{'integer'} ? 'integer' : 'char';
 170
 171             if ( $data_type eq 'char' && scalar @$size == 2 ) {
 172                 $size = [ $size->[0] + $size->[1] ];
 173             }
 174
 175             my $field = $table->get_field( $field );
 176             $field->size( $size );
 177             $field->data_type( $data_type );
 178         }
 179     }
 180
 181     return 1;
 182 }
 183
 184 1;
 185
 186 # -------------------------------------------------------------------
 187 =pod
 188
 189 =head1 AUTHORS
 190
 191 Darren Chamberlain E<lt>darren@cpan.orgE<gt>,
 192 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 193
 194 =head1 SEE ALSO
 195
 196 Text::RecordParser, SQL::Translator.
 197
 198 =cut