lib/SQL/Translator/Parser/XML/SQLFairy.pm

   1 package SQL::Translator::Parser::XML::SQLFairy;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2003 Mark Addison <mark.addison@itn.co.uk>,
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Parser::XML::SQLFairy - parser for SQL::Translator's XML.
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator;
  28
  29   my $translator = SQL::Translator->new( show_warnings  => 1 );
  30
  31   my $out = $obj->translate(
  32       from     => 'XML-SQLFairy',
  33       to       => 'MySQL',
  34       filename => 'schema.xml',
  35   ) or die $translator->error;
  36
  37   print $out;
  38
  39 =head1 DESCRIPTION
  40
  41 This parser handles the flavor of XML used natively by the SQLFairy
  42 project (L<SQL::Translator>).  The XML must be in the namespace
  43 "http://sqlfairy.sourceforge.net/sqlfairy.xml."
  44 See L<SQL::Translator::Producer::XML::SQLFairy> for details of this format.
  45
  46 You do not need to specify every attribute of the Schema objects as any missing
  47 from the XML will be set to their default values. e.g. A field could be written
  48 using only;
  49
  50  <sqlf:field name="email" data_type="varchar" size="255" />
  51
  52 Instead of the full;
  53
  54  <sqlf:field name="email" data_type="varchar" size="255" is_nullable="1"
  55    is_auto_increment="0" is_primary_key="0" is_foreign_key="0" order="4">
  56    <sqlf:comments></sqlf:comments>
  57  </sqlf:field>
  58
  59 If you do not explicitly set the order of items using order attributes on the
  60 tags then the order the tags appear in the XML will be used.
  61
  62 =head2 default_value
  63
  64 Leave the attribute out all together to use the default in L<Schema::Field>.
  65 Use empty quotes or 'EMPTY_STRING' for a zero lenth string. 'NULL' for an
  66 explicit null (currently sets default_value to undef in the
  67 Schema::Field obj).
  68
  69   <sqlf:field default_value="" />                <!-- Empty string -->
  70   <sqlf:field default_value="EMPTY_STRING" />    <!-- Empty string -->
  71   <sqlf:field default_value="NULL" />            <!-- NULL -->
  72
  73 =head2 ARGS
  74
  75 Doesn't take any extra parser args at the moment.
  76
  77 =head1 LEGACY FORMAT
  78
  79 The previous version of the SQLFairy XML allowed the attributes of the the
  80 schema objects to be written as either xml attributes or as data elements, in
  81 any combination. While this allows for lots of flexibility in writing the XML
  82 the result is a great many possible XML formats, not so good for DTD writing,
  83 XPathing etc! So we have moved to a fixed version described in
  84 L<SQL::Translator::Producer::XML::SQLFairy>.
  85
  86 This version of the parser will still parse the old formats and emmit warnings
  87 when it sees them being used but they should be considered B<heavily
  88 depreciated>.
  89
  90 To convert your old format files simply pass them through the translator :)
  91
  92  $ sqlt -f XML-SQLFairy -t XML-SQLFairy schema-old.xml > schema-new.xml
  93
  94 =cut
  95
  96 # -------------------------------------------------------------------
  97
  98 use strict;
  99
 100 use vars qw[ $DEBUG $VERSION @EXPORT_OK ];
 101 $VERSION = '1.59';
 102 $DEBUG   = 0 unless defined $DEBUG;
 103
 104 use Data::Dumper;
 105 use Carp::Clan qw/^SQL::Translator/;
 106 use Exporter;
 107 use base qw(Exporter);
 108 @EXPORT_OK = qw(parse);
 109
 110 use base qw/SQL::Translator::Parser/;  # Doesnt do anything at the mo!
 111 use SQL::Translator::Utils 'debug';
 112 use XML::XPath;
 113 use XML::XPath::XMLParser;
 114
 115 sub parse {
 116     my ( $translator, $data ) = @_;
 117     my $schema                = $translator->schema;
 118     local $DEBUG              = $translator->debug;
 119     my $xp                    = XML::XPath->new(xml => $data);
 120
 121     $xp->set_namespace("sqlf", "http://sqlfairy.sourceforge.net/sqlfairy.xml");
 122
 123     #
 124     # Work our way through the tables
 125     #
 126     my @nodes = $xp->findnodes(
 127         '/sqlf:schema/sqlf:table|/sqlf:schema/sqlf:tables/sqlf:table'
 128     );
 129     for my $tblnode (
 130         sort {
 131             ("".$xp->findvalue('sqlf:order|@order',$a) || 0)
 132             <=>
 133             ("".$xp->findvalue('sqlf:order|@order',$b) || 0)
 134         } @nodes
 135     ) {
 136         debug "Adding table:".$xp->findvalue('sqlf:name',$tblnode);
 137
 138         my $table = $schema->add_table(
 139             get_tagfields($xp, $tblnode, "sqlf:" => qw/name order extra/)
 140         ) or die $schema->error;
 141
 142         #
 143         # Fields
 144         #
 145         my @nodes = $xp->findnodes('sqlf:fields/sqlf:field',$tblnode);
 146         foreach (
 147             sort {
 148                 ("".$xp->findvalue('sqlf:order',$a) || 0)
 149                 <=>
 150                 ("".$xp->findvalue('sqlf:order',$b) || 0)
 151             } @nodes
 152         ) {
 153             my %fdata = get_tagfields($xp, $_, "sqlf:",
 154                 qw/name data_type size default_value is_nullable extra
 155                 is_auto_increment is_primary_key is_foreign_key comments/
 156             );
 157
 158             if (
 159                 exists $fdata{'default_value'} and
 160                 defined $fdata{'default_value'}
 161             ) {
 162                 if ( $fdata{'default_value'} =~ /^\s*NULL\s*$/ ) {
 163                     $fdata{'default_value'}= undef;
 164                 }
 165                 elsif ( $fdata{'default_value'} =~ /^\s*EMPTY_STRING\s*$/ ) {
 166                     $fdata{'default_value'} = "";
 167                 }
 168             }
 169
 170             my $field = $table->add_field( %fdata ) or die $table->error;
 171
 172             $table->primary_key( $field->name ) if $fdata{'is_primary_key'};
 173
 174             #
 175             # TODO:
 176             # - We should be able to make the table obj spot this when
 177             #   we use add_field.
 178             #
 179         }
 180
 181         #
 182         # Constraints
 183         #
 184         @nodes = $xp->findnodes('sqlf:constraints/sqlf:constraint',$tblnode);
 185         foreach (@nodes) {
 186             my %data = get_tagfields($xp, $_, "sqlf:",
 187                 qw/name type table fields reference_fields reference_table
 188                 match_type on_delete on_update extra/
 189             );
 190             $table->add_constraint( %data ) or die $table->error;
 191         }
 192
 193         #
 194         # Indexes
 195         #
 196         @nodes = $xp->findnodes('sqlf:indices/sqlf:index',$tblnode);
 197         foreach (@nodes) {
 198             my %data = get_tagfields($xp, $_, "sqlf:",
 199                 qw/name type fields options extra/);
 200             $table->add_index( %data ) or die $table->error;
 201         }
 202
 203
 204         #
 205         # Comments
 206         #
 207         @nodes = $xp->findnodes('sqlf:comments/sqlf:comment',$tblnode);
 208         foreach (@nodes) {
 209             my $data = $_->string_value;
 210             $table->comments( $data );
 211         }
 212
 213     } # tables loop
 214
 215     #
 216     # Views
 217     #
 218     @nodes = $xp->findnodes(
 219         '/sqlf:schema/sqlf:view|/sqlf:schema/sqlf:views/sqlf:view'
 220     );
 221     foreach (@nodes) {
 222         my %data = get_tagfields($xp, $_, "sqlf:",
 223             qw/name sql fields order extra/
 224         );
 225         $schema->add_view( %data ) or die $schema->error;
 226     }
 227
 228     #
 229     # Triggers
 230     #
 231     @nodes = $xp->findnodes(
 232         '/sqlf:schema/sqlf:trigger|/sqlf:schema/sqlf:triggers/sqlf:trigger'
 233     );
 234     foreach (@nodes) {
 235         my %data = get_tagfields($xp, $_, "sqlf:", qw/
 236             name perform_action_when database_event database_events fields on_table action order
 237             extra
 238         /);
 239
 240         # back compat
 241         if (my $evt = $data{database_event} and $translator->{show_warnings}) {
 242           carp 'The database_event tag is deprecated - please use database_events (which can take one or more comma separated event names)';
 243           $data{database_events} = join (', ',
 244             $data{database_events} || (),
 245             $evt,
 246           );
 247         }
 248
 249         # split into arrayref
 250         if (my $evts = $data{database_events}) {
 251           $data{database_events} = [split (/\s*,\s*/, $evts) ];
 252         }
 253
 254         $schema->add_trigger( %data ) or die $schema->error;
 255     }
 256
 257     #
 258     # Procedures
 259     #
 260     @nodes = $xp->findnodes(
 261        '/sqlf:schema/sqlf:procedure|/sqlf:schema/sqlf:procedures/sqlf:procedure'
 262     );
 263     foreach (@nodes) {
 264         my %data = get_tagfields($xp, $_, "sqlf:",
 265         qw/name sql parameters owner comments order extra/
 266         );
 267         $schema->add_procedure( %data ) or die $schema->error;
 268     }
 269
 270     return 1;
 271 }
 272
 273 # -------------------------------------------------------------------
 274 sub get_tagfields {
 275 #
 276 # get_tagfields XP, NODE, NAMESPACE => qw/TAGNAMES/;
 277 # get_tagfields $node, "sqlf:" => qw/name type fields reference/;
 278 #
 279 # Returns hash of data.
 280 # TODO - Add handling of an explicit NULL value.
 281 #
 282
 283     my ($xp, $node, @names) = @_;
 284     my (%data, $ns);
 285     foreach (@names) {
 286         if ( m/:$/ ) { $ns = $_; next; }  # Set def namespace
 287         my $thisns = (s/(^.*?:)// ? $1 : $ns);
 288
 289         my $is_attrib = m/^(sql|comments|action|extra)$/ ? 0 : 1;
 290
 291         my $attrib_path = "\@$thisns$_";
 292         my $tag_path    = "$thisns$_";
 293         if ( $xp->exists($attrib_path,$node) ) {
 294             $data{$_} = "".$xp->findvalue($attrib_path,$node);
 295             warn "Use of '$_' as an attribute is depricated."
 296                 ." Use a child tag instead."
 297                 ." To convert your file to the new version see the Docs.\n"
 298                 unless $is_attrib;
 299             debug "Got $_=".( defined $data{ $_ } ? $data{ $_ } : 'UNDEF' );
 300         }
 301         elsif ( $xp->exists($tag_path,$node) ) {
 302             if ($_ eq "extra") {
 303                 my %extra;
 304                 my $extra_nodes = $xp->find($tag_path,$node);
 305                 foreach ( $extra_nodes->pop->getAttributes ) {
 306                     $extra{$_->getName} = $_->getData;
 307                 }
 308                 $data{$_} = \%extra;
 309             }
 310             else {
 311                 $data{$_} = "".$xp->findvalue($tag_path,$node);
 312             }
 313             warn "Use of '$_' as a child tag is depricated."
 314                 ." Use an attribute instead."
 315                 ." To convert your file to the new version see the Docs.\n"
 316                 if $is_attrib;
 317             debug "Got $_=".( defined $data{ $_ } ? $data{ $_ } : 'UNDEF' );
 318         }
 319     }
 320
 321     return wantarray ? %data : \%data;
 322 }
 323
 324 1;
 325
 326 # -------------------------------------------------------------------
 327
 328 =pod
 329
 330 =head1 BUGS
 331
 332 Ignores the order attribute for Constraints, Views, Indices,
 333 Views, Triggers and Procedures, using the tag order instead. (This is the order
 334 output by the SQLFairy XML producer).
 335
 336 =head1 SEE ALSO
 337
 338 L<perl>, L<SQL::Translator>, L<SQL::Translator::Producer::XML::SQLFairy>,
 339 L<SQL::Translator::Schema>.
 340
 341 =head1 TODO
 342
 343 =over 4
 344
 345 =item *
 346
 347 Support options attribute.
 348
 349 =item *
 350
 351 Test foreign keys are parsed ok.
 352
 353 =item *
 354
 355 Control over defaulting.
 356
 357 =back
 358
 359 =head1 AUTHOR
 360
 361 Mark D. Addison E<lt>mark.addison@itn.co.ukE<gt>.
 362
 363 =cut