lib/SQL/Translator/Parser/Sybase.pm

   1 package SQL::Translator::Parser::Sybase;
   2
   3 # -------------------------------------------------------------------
   4 # $Id: Sybase.pm,v 1.10 2005-06-28 16:39:41 mwz444 Exp $
   5 # -------------------------------------------------------------------
   6 # Copyright (C) 2002-4 SQLFairy Authors
   7 #
   8 # This program is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU General Public License as
  10 # published by the Free Software Foundation; version 2.
  11 #
  12 # This program is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 # General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20 # 02111-1307  USA
  21 # -------------------------------------------------------------------
  22
  23 =head1 NAME
  24
  25 SQL::Translator::Parser::Sybase - parser for Sybase
  26
  27 =head1 SYNOPSIS
  28
  29   use SQL::Translator::Parser::Sybase;
  30
  31 =head1 DESCRIPTION
  32
  33 Mostly parses the output of "dbschema.pl," a Perl script freely
  34 available from http://www.midsomer.org.  The parsing is not complete,
  35 however, and you would probably have much better luck using the
  36 DBI-Sybase parser included with SQL::Translator.
  37
  38 =cut
  39
  40 use strict;
  41
  42 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
  43 $VERSION = sprintf "%d.%02d", q$Revision: 1.10 $ =~ /(\d+)\.(\d+)/;
  44 $DEBUG   = 0 unless defined $DEBUG;
  45
  46 use Data::Dumper;
  47 use Parse::RecDescent;
  48 use Exporter;
  49 use base qw(Exporter);
  50
  51 @EXPORT_OK = qw(parse);
  52
  53 $::RD_ERRORS = 1;
  54 $::RD_WARN   = 1;
  55 $::RD_HINT   = 1;
  56
  57 $GRAMMAR = q{
  58
  59 {
  60     my ( %tables, @table_comments, $table_order );
  61 }
  62
  63 startrule : statement(s) eofile { \%tables }
  64
  65 eofile : /^\Z/
  66
  67 statement : create_table
  68     | create_procedure
  69     | create_index
  70     | create_constraint
  71     | comment
  72     | use
  73     | setuser
  74     | if
  75     | print
  76     | grant
  77     | exec
  78     | <error>
  79
  80 use : /use/i WORD GO
  81     { @table_comments = () }
  82
  83 setuser : /setuser/i NAME GO
  84
  85 if : /if/i object_not_null begin if_command end GO
  86
  87 if_command : grant
  88     | create_index
  89     | create_constraint
  90
  91 object_not_null : /object_id/i '(' ident ')' /is not null/i
  92
  93 print : /\s*/ /print/i /.*/
  94
  95 else : /else/i /.*/
  96
  97 begin : /begin/i
  98
  99 end : /end/i
 100
 101 grant : /grant/i /[^\n]*/
 102
 103 exec : exec_statement(s) GO
 104
 105 exec_statement : /exec/i /[^\n]+/
 106
 107 comment : comment_start comment_middle comment_end
 108     {
 109         my $comment = $item[2];
 110         $comment =~ s/^\s*|\s*$//mg;
 111         $comment =~ s/^\**\s*//mg;
 112         push @table_comments, $comment;
 113     }
 114
 115 comment_start : /^\s*\/\*/
 116
 117 comment_end : /\s*\*\//
 118
 119 comment_middle : m{([^*]+|\*(?!/))*}
 120
 121 #
 122 # Create table.
 123 #
 124 create_table : /create/i /table/i ident '(' create_def(s /,/) ')' lock(?) on_system(?) GO
 125     {
 126         my $table_owner = $item[3]{'owner'};
 127         my $table_name  = $item[3]{'name'};
 128
 129         if ( @table_comments ) {
 130             $tables{ $table_name }{'comments'} = [ @table_comments ];
 131             @table_comments = ();
 132         }
 133
 134         $tables{ $table_name }{'order'}  = ++$table_order;
 135         $tables{ $table_name }{'name'}   = $table_name;
 136         $tables{ $table_name }{'owner'}  = $table_owner;
 137         $tables{ $table_name }{'system'} = $item[7];
 138
 139         my $i = 0;
 140         for my $def ( @{ $item[5] } ) {
 141             if ( $def->{'supertype'} eq 'field' ) {
 142                 my $field_name = $def->{'name'};
 143                 $tables{ $table_name }{'fields'}{ $field_name } =
 144                     { %$def, order => $i };
 145                 $i++;
 146
 147                 if ( $def->{'is_primary_key'} ) {
 148                     push @{ $tables{ $table_name }{'constraints'} }, {
 149                         type   => 'primary_key',
 150                         fields => [ $field_name ],
 151                     };
 152                 }
 153             }
 154             elsif ( $def->{'supertype'} eq 'constraint' ) {
 155                 push @{ $tables{ $table_name }{'constraints'} }, $def;
 156             }
 157             else {
 158                 push @{ $tables{ $table_name }{'indices'} }, $def;
 159             }
 160         }
 161     }
 162
 163 create_constraint : /create/i constraint
 164     {
 165         @table_comments = ();
 166         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 167     }
 168
 169 create_index : /create/i index
 170     {
 171         @table_comments = ();
 172         push @{ $tables{ $item[2]{'table'} }{'indices'} }, $item[2];
 173     }
 174
 175 create_procedure : /create/i /procedure/i procedure_body GO
 176     {
 177         @table_comments = ();
 178     }
 179
 180 procedure_body : not_go(s)
 181
 182 not_go : /((?!go).)*/
 183
 184 create_def : field
 185     | index
 186     | constraint
 187
 188 blank : /\s*/
 189
 190 field : field_name data_type nullable(?)
 191     {
 192         $return = {
 193             supertype      => 'field',
 194             name           => $item{'field_name'},
 195             data_type      => $item{'data_type'}{'type'},
 196             size           => $item{'data_type'}{'size'},
 197             nullable       => $item[3][0],
 198 #            default        => $item{'default_val'}[0],
 199 #            is_auto_inc    => $item{'auto_inc'}[0],
 200 #            is_primary_key => $item{'primary_key'}[0],
 201         }
 202     }
 203
 204 constraint : primary_key_constraint
 205     | unique_constraint
 206
 207 field_name : WORD
 208
 209 index_name : WORD
 210
 211 table_name : WORD
 212
 213 data_type : WORD field_size(?)
 214     {
 215         $return = {
 216             type => $item[1],
 217             size => $item[2][0]
 218         }
 219     }
 220
 221 lock : /lock/i /datarows/i
 222
 223 field_type : WORD
 224
 225 field_size : '(' num_range ')' { $item{'num_range'} }
 226
 227 num_range : DIGITS ',' DIGITS
 228     { $return = $item[1].','.$item[3] }
 229                | DIGITS
 230     { $return = $item[1] }
 231
 232
 233 nullable : /not/i /null/i
 234     { $return = 0 }
 235     | /null/i
 236     { $return = 1 }
 237
 238 default_val : /default/i /(?:')?[\w\d.-]*(?:')?/
 239     { $item[2]=~s/'//g; $return=$item[2] }
 240
 241 auto_inc : /auto_increment/i { 1 }
 242
 243 primary_key_constraint : /primary/i /key/i index_name(?) parens_field_list
 244     {
 245         $return = {
 246             supertype => 'constraint',
 247             name      => $item{'index_name'}[0],
 248             type      => 'primary_key',
 249             fields    => $item[4],
 250         }
 251     }
 252
 253 unique_constraint : /unique/i clustered(?) INDEX(?) index_name(?) on_table(?) parens_field_list
 254     {
 255         $return = {
 256             supertype => 'constraint',
 257             type      => 'unique',
 258             clustered => $item[2][0],
 259             name      => $item[4][0],
 260             table     => $item[5][0],
 261             fields    => $item[6],
 262         }
 263     }
 264
 265 clustered : /clustered/i
 266     { $return = 1 }
 267     | /nonclustered/i
 268     { $return = 0 }
 269
 270 INDEX : /index/i
 271
 272 on_table : /on/i table_name
 273     { $return = $item[2] }
 274
 275 on_system : /on/i /system/i
 276     { $return = 1 }
 277
 278 index : clustered(?) INDEX index_name(?) on_table(?) parens_field_list
 279     {
 280         $return = {
 281             supertype => 'index',
 282             type      => 'normal',
 283             clustered => $item[1][0],
 284             name      => $item[3][0],
 285             table     => $item[4][0],
 286             fields    => $item[5],
 287         }
 288     }
 289
 290 parens_field_list : '(' field_name(s /,/) ')'
 291     { $item[2] }
 292
 293 ident : QUOTE(?) WORD '.' WORD QUOTE(?)
 294     { $return = { owner => $item[2], name => $item[4] } }
 295     | WORD
 296     { $return = { name  => $item[2] } }
 297
 298 GO : /^go/i
 299
 300 NAME : QUOTE(?) /\w+/ QUOTE(?)
 301     { $item[2] }
 302
 303 WORD : /[\w#]+/
 304
 305 DIGITS : /\d+/
 306
 307 COMMA : ','
 308
 309 QUOTE : /'/
 310
 311 };
 312
 313 # -------------------------------------------------------------------
 314 sub parse {
 315     my ( $translator, $data ) = @_;
 316     my $parser = Parse::RecDescent->new($GRAMMAR);
 317
 318     local $::RD_TRACE  = $translator->trace ? 1 : undef;
 319     local $DEBUG       = $translator->debug;
 320
 321     unless (defined $parser) {
 322         return $translator->error("Error instantiating Parse::RecDescent ".
 323             "instance: Bad grammer");
 324     }
 325
 326     my $result = $parser->startrule($data);
 327     return $translator->error( "Parse failed." ) unless defined $result;
 328     warn Dumper( $result ) if $DEBUG;
 329
 330     my $schema = $translator->schema;
 331     my @tables = sort {
 332         $result->{ $a }->{'order'} <=> $result->{ $b }->{'order'}
 333     } keys %{ $result };
 334
 335     for my $table_name ( @tables ) {
 336         my $tdata = $result->{ $table_name };
 337         my $table = $schema->add_table( name => $tdata->{'name'} )
 338                     or die "Can't create table '$table_name': ", $schema->error;
 339
 340         $table->comments( $tdata->{'comments'} );
 341
 342         my @fields = sort {
 343             $tdata->{'fields'}->{$a}->{'order'}
 344             <=>
 345             $tdata->{'fields'}->{$b}->{'order'}
 346         } keys %{ $tdata->{'fields'} };
 347
 348         for my $fname ( @fields ) {
 349             my $fdata = $tdata->{'fields'}{ $fname };
 350             my $field = $table->add_field(
 351                 name              => $fdata->{'name'},
 352                 data_type         => $fdata->{'data_type'},
 353                 size              => $fdata->{'size'},
 354                 default_value     => $fdata->{'default'},
 355                 is_auto_increment => $fdata->{'is_auto_inc'},
 356                 is_nullable       => $fdata->{'nullable'},
 357                 comments          => $fdata->{'comments'},
 358             ) or die $table->error;
 359
 360             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 361
 362             for my $qual ( qw[ binary unsigned zerofill list ] ) {
 363                 if ( my $val = $fdata->{ $qual } || $fdata->{ uc $qual } ) {
 364                     next if ref $val eq 'ARRAY' && !@$val;
 365                     $field->extra( $qual, $val );
 366                 }
 367             }
 368
 369             if ( $field->data_type =~ /(set|enum)/i && !$field->size ) {
 370                 my %extra = $field->extra;
 371                 my $longest = 0;
 372                 for my $len ( map { length } @{ $extra{'list'} || [] } ) {
 373                     $longest = $len if $len > $longest;
 374                 }
 375                 $field->size( $longest ) if $longest;
 376             }
 377
 378             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 379                 next unless $cdata->{'type'} eq 'foreign_key';
 380                 $cdata->{'fields'} ||= [ $field->name ];
 381                 push @{ $tdata->{'constraints'} }, $cdata;
 382             }
 383         }
 384
 385         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 386             my $index  =  $table->add_index(
 387                 name   => $idata->{'name'},
 388                 type   => uc $idata->{'type'},
 389                 fields => $idata->{'fields'},
 390             ) or die $table->error;
 391         }
 392
 393         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 394             my $constraint       =  $table->add_constraint(
 395                 name             => $cdata->{'name'},
 396                 type             => $cdata->{'type'},
 397                 fields           => $cdata->{'fields'},
 398                 reference_table  => $cdata->{'reference_table'},
 399                 reference_fields => $cdata->{'reference_fields'},
 400                 match_type       => $cdata->{'match_type'} || '',
 401                 on_delete        => $cdata->{'on_delete'} || $cdata->{'on_delete_do'},
 402                 on_update        => $cdata->{'on_update'} || $cdata->{'on_update_do'},
 403             ) or die $table->error;
 404         }
 405     }
 406
 407     return 1;
 408 }
 409
 410 1;
 411
 412 # -------------------------------------------------------------------
 413 # Every hero becomes a bore at last.
 414 # Ralph Waldo Emerson
 415 # -------------------------------------------------------------------
 416
 417 =pod
 418
 419 =head1 AUTHOR
 420
 421 Ken Y. Clark E<lt>kclark@cpan.orgE<gt>.
 422
 423 =head1 SEE ALSO
 424
 425 SQL::Translator, SQL::Translator::Parser::DBI, L<http://www.midsomer.org/>.
 426
 427 =cut