lib/SQL/Translator/Parser/SQLServer.pm

   1 package SQL::Translator::Parser::SQLServer;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Parser::SQLServer - parser for SQL Server
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator::Parser::SQLServer;
  28
  29 =head1 DESCRIPTION
  30
  31 Adapted from Parser::Sybase and mostly parses the output of
  32 Producer::SQLServer.  The parsing is by no means complete and
  33 should probably be considered a work in progress.
  34
  35 =cut
  36
  37 use strict;
  38
  39 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
  40 $VERSION = '1.59';
  41 $DEBUG   = 0 unless defined $DEBUG;
  42
  43 use Data::Dumper;
  44 use Parse::RecDescent;
  45 use Exporter;
  46 use base qw(Exporter);
  47
  48 @EXPORT_OK = qw(parse);
  49
  50 $::RD_ERRORS = 1;
  51 $::RD_WARN   = 1;
  52 $::RD_HINT   = 1;
  53
  54 $GRAMMAR = q{
  55
  56 {
  57     my ( %tables, @table_comments, $table_order, %procedures, $proc_order, %views, $view_order );
  58
  59     sub _err {
  60       my $max_lines = 5;
  61       my @up_to_N_lines = split (/\n/, $_[1], $max_lines + 1);
  62       die sprintf ("Unable to parse line %d:\n%s\n",
  63         $_[0],
  64         join "\n", (map { "'$_'" } @up_to_N_lines[0..$max_lines - 1 ]), @up_to_N_lines > $max_lines ? '...' : ()
  65       );
  66     }
  67
  68 }
  69
  70 startrule : statement(s) eofile
  71    {
  72       return {
  73          tables     => \%tables,
  74          procedures => \%procedures,
  75          views      => \%views,
  76       }
  77    }
  78
  79 eofile : /^\Z/
  80
  81 statement : create_table
  82     | create_procedure
  83     | create_view
  84     | create_index
  85     | create_constraint
  86     | comment
  87     | disable_constraints
  88     | drop
  89     | use
  90     | setuser
  91     | if
  92     | print
  93     | grant
  94     | exec
  95     | /^\Z/ | { _err ($thisline, $text) }
  96
  97 use : /use/i WORD GO
  98     { @table_comments = () }
  99
 100 setuser : /setuser/i NAME GO
 101
 102 if : /if/i object_not_null begin if_command end GO
 103
 104 if_command : grant
 105     | create_index
 106     | create_constraint
 107
 108 object_not_null : /object_id/i '(' ident ')' /is not null/i
 109
 110 field_not_null : /where/i field_name /is \s+ not \s+ null/ix
 111
 112 print : /\s*/ /print/i /.*/
 113
 114 else : /else/i /.*/
 115
 116 begin : /begin/i
 117
 118 end : /end/i
 119
 120 grant : /grant/i /[^\n]*/
 121
 122 exec : exec_statement(s) GO
 123
 124 exec_statement : /exec/i /[^\n]+/
 125
 126 comment : /^\s*(?:#|-{2}).*\n/
 127     {
 128         my $comment =  $item[1];
 129         $comment    =~ s/^\s*(#|--)\s*//;
 130         $comment    =~ s/\s*$//;
 131         $return     = $comment;
 132         push @table_comments, $comment;
 133     }
 134
 135 comment : comment_start comment_middle comment_end
 136     {
 137         my $comment = $item[2];
 138         $comment =~ s/^\s*|\s*$//mg;
 139         $comment =~ s/^\**\s*//mg;
 140         push @table_comments, $comment;
 141     }
 142
 143 comment_start : m#^\s*\/\*#
 144
 145 comment_end : m#\s*\*\/#
 146
 147 comment_middle : m{([^*]+|\*(?!/))*}
 148
 149 drop : if_exists(?) /drop/i tbl_drop END_STATEMENT
 150
 151 tbl_drop : /table/i ident
 152
 153 if_exists : /if exists/i '(' /select/i 'name' /from/i 'sysobjects' /[^\)]+/ ')'
 154
 155 #
 156 # Create table.
 157 #
 158 create_table : /create/i /table/i ident '(' create_def(s /,/) ')' lock(?) on_system(?) END_STATEMENT
 159     {
 160         my $table_owner = $item[3]{'owner'};
 161         my $table_name  = $item[3]{'name'};
 162
 163         if ( @table_comments ) {
 164             $tables{ $table_name }{'comments'} = [ @table_comments ];
 165             @table_comments = ();
 166         }
 167
 168         $tables{ $table_name }{'order'}  = ++$table_order;
 169         $tables{ $table_name }{'name'}   = $table_name;
 170         $tables{ $table_name }{'owner'}  = $table_owner;
 171         $tables{ $table_name }{'system'} = $item[7];
 172
 173         my $i = 0;
 174         for my $def ( @{ $item[5] } ) {
 175             if ( $def->{'supertype'} eq 'field' ) {
 176                 my $field_name = $def->{'name'};
 177                 $tables{ $table_name }{'fields'}{ $field_name } =
 178                     { %$def, order => $i };
 179                 $i++;
 180
 181                 if ( $def->{'is_primary_key'} ) {
 182                     push @{ $tables{ $table_name }{'constraints'} }, {
 183                         type   => 'primary_key',
 184                         fields => [ $field_name ],
 185                     };
 186                 }
 187             }
 188             elsif ( $def->{'supertype'} eq 'constraint' ) {
 189                 push @{ $tables{ $table_name }{'constraints'} }, $def;
 190             }
 191             else {
 192                 push @{ $tables{ $table_name }{'indices'} }, $def;
 193             }
 194         }
 195     }
 196
 197 disable_constraints : if_exists(?) /alter/i /table/i ident /nocheck/i /constraint/i /all/i END_STATEMENT
 198
 199 # this is for the normal case
 200 create_constraint : /create/i constraint END_STATEMENT
 201     {
 202         @table_comments = ();
 203         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 204     }
 205
 206 # and this is for the BEGIN/END case
 207 create_constraint : /create/i constraint
 208     {
 209         @table_comments = ();
 210         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 211     }
 212
 213
 214 create_constraint : /alter/i /table/i ident /add/i foreign_key_constraint END_STATEMENT
 215     {
 216         push @{ $tables{ $item[3]{name} }{constraints} }, $item[5];
 217     }
 218
 219
 220 create_index : /create/i index
 221     {
 222         @table_comments = ();
 223         push @{ $tables{ $item[2]{'table'} }{'indices'} }, $item[2];
 224     }
 225
 226 create_procedure : /create/i PROCEDURE WORD not_go GO
 227     {
 228         @table_comments = ();
 229         my $proc_name = $item[3];
 230         my $owner = '';
 231         my $sql = "$item[1] $item[2] $proc_name $item[4]";
 232
 233         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 234         $procedures{ $proc_name }{'name'}   = $proc_name;
 235         $procedures{ $proc_name }{'owner'}  = $owner;
 236         $procedures{ $proc_name }{'sql'}    = $sql;
 237     }
 238
 239 create_procedure : /create/i PROCEDURE '[' WORD '].' WORD not_go GO
 240     {
 241         @table_comments = ();
 242         my $proc_name = $item[6];
 243         my $owner = $item[4];
 244         my $sql = "$item[1] $item[2] [$owner].$proc_name $item[7]";
 245
 246         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 247         $procedures{ $proc_name }{'name'}   = $proc_name;
 248         $procedures{ $proc_name }{'owner'}  = $owner;
 249         $procedures{ $proc_name }{'sql'}    = $sql;
 250     }
 251
 252 PROCEDURE : /procedure/i
 253    | /function/i
 254
 255 create_view : /create/i /view/i WORD not_go GO
 256     {
 257         @table_comments = ();
 258         my $view_name = $item[3];
 259         my $sql = "$item[1] $item[2] $item[3] $item[4]";
 260
 261         $views{ $view_name }{'order'}  = ++$view_order;
 262         $views{ $view_name }{'name'}   = $view_name;
 263         $views{ $view_name }{'sql'}    = $sql;
 264     }
 265
 266 not_go : /((?!\bgo\b).)*/is
 267
 268 create_def : constraint
 269     | index
 270     | field
 271
 272 blank : /\s*/
 273
 274 field : field_name data_type field_qualifier(s?)
 275     {
 276         my %qualifiers  = map { %$_ } @{ $item{'field_qualifier(s?)'} || [] };
 277         my $nullable = defined $qualifiers{'nullable'}
 278                    ? $qualifiers{'nullable'} : 1;
 279         $return = {
 280             supertype      => 'field',
 281             name           => $item{'field_name'},
 282             data_type      => $item{'data_type'}{'type'},
 283             size           => $item{'data_type'}{'size'},
 284             nullable       => $nullable,
 285             default        => $qualifiers{'default_val'},
 286             is_auto_inc    => $qualifiers{'is_auto_inc'},
 287 #            is_primary_key => $item{'primary_key'}[0],
 288         }
 289     }
 290
 291 field_qualifier : nullable
 292     {
 293         $return = {
 294              nullable => $item{'nullable'},
 295         }
 296     }
 297
 298 field_qualifier : default_val
 299     {
 300         $return = {
 301              default_val => $item{'default_val'},
 302         }
 303     }
 304
 305 field_qualifier : auto_inc
 306     {
 307         $return = {
 308              is_auto_inc => $item{'auto_inc'},
 309         }
 310     }
 311
 312 constraint : primary_key_constraint
 313     | foreign_key_constraint
 314     | unique_constraint
 315
 316 field_name : WORD
 317    { $return = $item[1] }
 318    | LQUOTE WORD RQUOTE
 319    { $return = $item[2] }
 320
 321 index_name : WORD
 322    { $return = $item[1] }
 323    | LQUOTE WORD RQUOTE
 324    { $return = $item[2] }
 325
 326 table_name : WORD
 327  { $return = $item[1] }
 328  | LQUOTE WORD RQUOTE
 329  { $return = $item[2] }
 330
 331 data_type : WORD field_size(?)
 332     {
 333         $return = {
 334             type => $item[1],
 335             size => $item[2][0]
 336         }
 337     }
 338
 339 lock : /lock/i /datarows/i
 340
 341 field_type : WORD
 342
 343 field_size : '(' num_range ')' { $item{'num_range'} }
 344
 345 num_range : DIGITS ',' DIGITS
 346     { $return = $item[1].','.$item[3] }
 347                | DIGITS
 348     { $return = $item[1] }
 349
 350
 351 nullable : /not/i /null/i
 352     { $return = 0 }
 353     | /null/i
 354     { $return = 1 }
 355
 356 default_val : /default/i /null/i
 357     { $return = 'null' }
 358    | /default/i /'[^']*'/
 359     { $item[2]=~ s/'//g; $return = $item[2] }
 360    | /default/i WORD
 361     { $return = $item[2] }
 362
 363 auto_inc : /identity/i { 1 }
 364
 365 primary_key_constraint : /constraint/i index_name(?) /primary/i /key/i parens_field_list
 366     {
 367         $return = {
 368             supertype => 'constraint',
 369             name      => $item[2][0],
 370             type      => 'primary_key',
 371             fields    => $item[5],
 372         }
 373     }
 374
 375 foreign_key_constraint : /constraint/i index_name(?) /foreign/i /key/i parens_field_list /references/i table_name parens_field_list(?) on_delete(?) on_update(?)
 376     {
 377         $return = {
 378             supertype        => 'constraint',
 379             name             => $item[2][0],
 380             type             => 'foreign_key',
 381             fields           => $item[5],
 382             reference_table  => $item[7],
 383             reference_fields => $item[8][0],
 384             on_delete        => $item[9][0],
 385             on_update        => $item[10][0],
 386         }
 387     }
 388
 389 unique_constraint : /constraint/i index_name(?) /unique/i parens_field_list
 390     {
 391         $return = {
 392             supertype => 'constraint',
 393             type      => 'unique',
 394             name      => $item[2][0],
 395             fields    => $item[4],
 396         }
 397     }
 398
 399 unique_constraint : /unique/i clustered(?) INDEX(?) index_name(?) on_table(?) parens_field_list field_not_null(?)
 400     {
 401         $return = {
 402             supertype => 'constraint',
 403             type      => 'unique',
 404             clustered => $item[2][0],
 405             name      => $item[4][0],
 406             table     => $item[5][0],
 407             fields    => $item[6],
 408         }
 409     }
 410
 411 on_delete : /on delete/i reference_option
 412     { $item[2] }
 413
 414 on_update : /on update/i reference_option
 415     { $item[2] }
 416
 417 reference_option: /cascade/i
 418     { $item[1] }
 419     | /no action/i
 420     { $item[1] }
 421
 422 clustered : /clustered/i
 423     { $return = 1 }
 424     | /nonclustered/i
 425     { $return = 0 }
 426
 427 INDEX : /index/i
 428
 429 on_table : /on/i table_name
 430     { $return = $item[2] }
 431
 432 on_system : /on/i /system/i
 433     { $return = 1 }
 434
 435 index : clustered(?) INDEX index_name(?) on_table(?) parens_field_list END_STATEMENT
 436     {
 437         $return = {
 438             supertype => 'index',
 439             type      => 'normal',
 440             clustered => $item[1][0],
 441             name      => $item[3][0],
 442             table     => $item[4][0],
 443             fields    => $item[5],
 444         }
 445     }
 446
 447 parens_field_list : '(' field_name(s /,/) ')'
 448     { $item[2] }
 449
 450 ident : QUOTE WORD '.' WORD QUOTE | LQUOTE WORD '.' WORD RQUOTE
 451     { $return = { owner => $item[2], name => $item[4] } }
 452     | LQUOTE WORD RQUOTE '.' LQUOTE WORD RQUOTE
 453     { $return = { owner => $item[2], name => $item[6] } }
 454     | LQUOTE WORD RQUOTE
 455     { $return = { name  => $item[2] } }
 456     | WORD '.' WORD
 457     { $return = { owner => $item[1], name => $item[3] } }
 458     | WORD
 459     { $return = { name  => $item[1] } }
 460
 461 END_STATEMENT : ';'
 462    | GO
 463
 464 GO : /^go/i
 465
 466 NAME : QUOTE(?) /\w+/ QUOTE(?)
 467     { $item[2] }
 468
 469 WORD : /[\w#]+/
 470
 471 DIGITS : /\d+/
 472
 473 COMMA : ','
 474
 475 QUOTE : /'/
 476
 477 LQUOTE : '['
 478
 479 RQUOTE : ']'
 480
 481 };
 482
 483 # -------------------------------------------------------------------
 484 sub parse {
 485     my ( $translator, $data ) = @_;
 486     my $parser = Parse::RecDescent->new($GRAMMAR);
 487
 488     local $::RD_TRACE  = $translator->trace ? 1 : undef;
 489     local $DEBUG       = $translator->debug;
 490
 491     unless (defined $parser) {
 492         return $translator->error("Error instantiating Parse::RecDescent ".
 493             "instance: Bad grammer");
 494     }
 495
 496     my $result = $parser->startrule($data);
 497     return $translator->error( "Parse failed." ) unless defined $result;
 498     warn Dumper( $result ) if $DEBUG;
 499
 500     my $schema = $translator->schema;
 501     my @tables = sort {
 502         $result->{tables}->{ $a }->{'order'} <=> $result->{tables}->{ $b }->{'order'}
 503     } keys %{ $result->{tables} };
 504
 505     for my $table_name ( @tables ) {
 506         my $tdata = $result->{tables}->{ $table_name };
 507         my $table = $schema->add_table( name => $tdata->{'name'} )
 508                     or die "Can't create table '$table_name': ", $schema->error;
 509
 510         $table->comments( $tdata->{'comments'} );
 511
 512         my @fields = sort {
 513             $tdata->{'fields'}->{$a}->{'order'}
 514             <=>
 515             $tdata->{'fields'}->{$b}->{'order'}
 516         } keys %{ $tdata->{'fields'} };
 517
 518         for my $fname ( @fields ) {
 519             my $fdata = $tdata->{'fields'}{ $fname };
 520             my $field = $table->add_field(
 521                 name              => $fdata->{'name'},
 522                 data_type         => $fdata->{'data_type'},
 523                 size              => $fdata->{'size'},
 524                 default_value     => $fdata->{'default'},
 525                 is_auto_increment => $fdata->{'is_auto_inc'},
 526                 is_nullable       => $fdata->{'nullable'},
 527                 comments          => $fdata->{'comments'},
 528             ) or die $table->error;
 529
 530             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 531
 532             for my $qual ( qw[ binary unsigned zerofill list ] ) {
 533                 if ( my $val = $fdata->{ $qual } || $fdata->{ uc $qual } ) {
 534                     next if ref $val eq 'ARRAY' && !@$val;
 535                     $field->extra( $qual, $val );
 536                 }
 537             }
 538
 539             if ( $field->data_type =~ /(set|enum)/i && !$field->size ) {
 540                 my %extra = $field->extra;
 541                 my $longest = 0;
 542                 for my $len ( map { length } @{ $extra{'list'} || [] } ) {
 543                     $longest = $len if $len > $longest;
 544                 }
 545                 $field->size( $longest ) if $longest;
 546             }
 547
 548             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 549                 next unless $cdata->{'type'} eq 'foreign_key';
 550                 $cdata->{'fields'} ||= [ $field->name ];
 551                 push @{ $tdata->{'constraints'} }, $cdata;
 552             }
 553         }
 554
 555         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 556             my $index  =  $table->add_index(
 557                 name   => $idata->{'name'},
 558                 type   => uc $idata->{'type'},
 559                 fields => $idata->{'fields'},
 560             ) or die $table->error;
 561         }
 562
 563         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 564             my $constraint       =  $table->add_constraint(
 565                 name             => $cdata->{'name'},
 566                 type             => $cdata->{'type'},
 567                 fields           => $cdata->{'fields'},
 568                 reference_table  => $cdata->{'reference_table'},
 569                 reference_fields => $cdata->{'reference_fields'},
 570                 match_type       => $cdata->{'match_type'} || '',
 571                 on_delete        => $cdata->{'on_delete'} || $cdata->{'on_delete_do'},
 572                 on_update        => $cdata->{'on_update'} || $cdata->{'on_update_do'},
 573             ) or die $table->error;
 574         }
 575     }
 576
 577     my @procedures = sort {
 578         $result->{procedures}->{ $a }->{'order'} <=> $result->{procedures}->{ $b }->{'order'}
 579     } keys %{ $result->{procedures} };
 580     for my $proc_name (@procedures) {
 581       $schema->add_procedure(
 582          name  => $proc_name,
 583          owner => $result->{procedures}->{$proc_name}->{owner},
 584          sql   => $result->{procedures}->{$proc_name}->{sql},
 585       );
 586     }
 587
 588     my @views = sort {
 589         $result->{views}->{ $a }->{'order'} <=> $result->{views}->{ $b }->{'order'}
 590     } keys %{ $result->{views} };
 591     for my $view_name (keys %{ $result->{views} }) {
 592       $schema->add_view(
 593          name => $view_name,
 594          sql  => $result->{views}->{$view_name}->{sql},
 595       );
 596     }
 597
 598     return 1;
 599 }
 600
 601 1;
 602
 603 # -------------------------------------------------------------------
 604 # Every hero becomes a bore at last.
 605 # Ralph Waldo Emerson
 606 # -------------------------------------------------------------------
 607
 608 =pod
 609
 610 =head1 AUTHOR
 611
 612 Chris Hilton E<lt>chris@dctank.comE<gt> - Bulk of code from
 613 Sybase parser, I just tweaked it for SQLServer. Thanks.
 614
 615 =head1 SEE ALSO
 616
 617 SQL::Translator, SQL::Translator::Parser::DBI, L<http://www.midsomer.org/>.
 618
 619 =cut