lib/SQL/Translator/Parser/SQLServer.pm

   1 package SQL::Translator::Parser::SQLServer;
   2
   3 =head1 NAME
   4
   5 SQL::Translator::Parser::SQLServer - parser for SQL Server
   6
   7 =head1 SYNOPSIS
   8
   9   use SQL::Translator::Parser::SQLServer;
  10
  11 =head1 DESCRIPTION
  12
  13 Adapted from Parser::Sybase and mostly parses the output of
  14 Producer::SQLServer.  The parsing is by no means complete and
  15 should probably be considered a work in progress.
  16
  17 =cut
  18
  19 use strict;
  20
  21 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
  22 $VERSION = '1.59';
  23 $DEBUG   = 0 unless defined $DEBUG;
  24
  25 use Data::Dumper;
  26 use Parse::RecDescent;
  27 use Exporter;
  28 use base qw(Exporter);
  29
  30 @EXPORT_OK = qw(parse);
  31
  32 $::RD_ERRORS = 1;
  33 $::RD_WARN   = 1;
  34 $::RD_HINT   = 1;
  35
  36 $GRAMMAR = q{
  37
  38 {
  39     my ( %tables, @table_comments, $table_order, %procedures, $proc_order, %views, $view_order );
  40
  41     sub _err {
  42       my $max_lines = 5;
  43       my @up_to_N_lines = split (/\n/, $_[1], $max_lines + 1);
  44       die sprintf ("Unable to parse line %d:\n%s\n",
  45         $_[0],
  46         join "\n", (map { "'$_'" } @up_to_N_lines[0..$max_lines - 1 ]), @up_to_N_lines > $max_lines ? '...' : ()
  47       );
  48     }
  49
  50 }
  51
  52 startrule : statement(s) eofile
  53    {
  54       return {
  55          tables     => \%tables,
  56          procedures => \%procedures,
  57          views      => \%views,
  58       }
  59    }
  60
  61 eofile : /^\Z/
  62
  63 statement : create_table
  64     | create_procedure
  65     | create_view
  66     | create_index
  67     | create_constraint
  68     | comment
  69     | disable_constraints
  70     | drop
  71     | use
  72     | setuser
  73     | if
  74     | print
  75     | grant
  76     | exec
  77     | /^\Z/ | { _err ($thisline, $text) }
  78
  79 use : /use/i WORD GO
  80     { @table_comments = () }
  81
  82 setuser : /setuser/i NAME GO
  83
  84 if : /if/i object_not_null begin if_command end GO
  85
  86 if_command : grant
  87     | create_index
  88     | create_constraint
  89
  90 object_not_null : /object_id/i '(' ident ')' /is not null/i
  91
  92 field_not_null : /where/i field_name /is \s+ not \s+ null/ix
  93
  94 print : /\s*/ /print/i /.*/
  95
  96 else : /else/i /.*/
  97
  98 begin : /begin/i
  99
 100 end : /end/i
 101
 102 grant : /grant/i /[^\n]*/
 103
 104 exec : exec_statement(s) GO
 105
 106 exec_statement : /exec/i /[^\n]+/
 107
 108 comment : /^\s*(?:#|-{2}).*\n/
 109     {
 110         my $comment =  $item[1];
 111         $comment    =~ s/^\s*(#|--)\s*//;
 112         $comment    =~ s/\s*$//;
 113         $return     = $comment;
 114         push @table_comments, $comment;
 115     }
 116
 117 comment : comment_start comment_middle comment_end
 118     {
 119         my $comment = $item[2];
 120         $comment =~ s/^\s*|\s*$//mg;
 121         $comment =~ s/^\**\s*//mg;
 122         push @table_comments, $comment;
 123     }
 124
 125 comment_start : m#^\s*\/\*#
 126
 127 comment_end : m#\s*\*\/#
 128
 129 comment_middle : m{([^*]+|\*(?!/))*}
 130
 131 drop : if_exists(?) /drop/i tbl_drop END_STATEMENT
 132
 133 tbl_drop : /table/i ident
 134
 135 if_exists : /if exists/i '(' /select/i 'name' /from/i 'sysobjects' /[^\)]+/ ')'
 136
 137 #
 138 # Create table.
 139 #
 140 create_table : /create/i /table/i ident '(' create_def(s /,/) ')' lock(?) on_system(?) END_STATEMENT
 141     {
 142         my $table_owner = $item[3]{'owner'};
 143         my $table_name  = $item[3]{'name'};
 144
 145         if ( @table_comments ) {
 146             $tables{ $table_name }{'comments'} = [ @table_comments ];
 147             @table_comments = ();
 148         }
 149
 150         $tables{ $table_name }{'order'}  = ++$table_order;
 151         $tables{ $table_name }{'name'}   = $table_name;
 152         $tables{ $table_name }{'owner'}  = $table_owner;
 153         $tables{ $table_name }{'system'} = $item[7];
 154
 155         my $i = 0;
 156         for my $def ( @{ $item[5] } ) {
 157             if ( $def->{'supertype'} eq 'field' ) {
 158                 my $field_name = $def->{'name'};
 159                 $tables{ $table_name }{'fields'}{ $field_name } =
 160                     { %$def, order => $i };
 161                 $i++;
 162
 163                 if ( $def->{'is_primary_key'} ) {
 164                     push @{ $tables{ $table_name }{'constraints'} }, {
 165                         type   => 'primary_key',
 166                         fields => [ $field_name ],
 167                     };
 168                 }
 169             }
 170             elsif ( $def->{'supertype'} eq 'constraint' ) {
 171                 push @{ $tables{ $table_name }{'constraints'} }, $def;
 172             }
 173             else {
 174                 push @{ $tables{ $table_name }{'indices'} }, $def;
 175             }
 176         }
 177     }
 178
 179 disable_constraints : if_exists(?) /alter/i /table/i ident /nocheck/i /constraint/i /all/i END_STATEMENT
 180
 181 # this is for the normal case
 182 create_constraint : /create/i constraint END_STATEMENT
 183     {
 184         @table_comments = ();
 185         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 186     }
 187
 188 # and this is for the BEGIN/END case
 189 create_constraint : /create/i constraint
 190     {
 191         @table_comments = ();
 192         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 193     }
 194
 195
 196 create_constraint : /alter/i /table/i ident /add/i foreign_key_constraint END_STATEMENT
 197     {
 198         push @{ $tables{ $item[3]{name} }{constraints} }, $item[5];
 199     }
 200
 201
 202 create_index : /create/i index
 203     {
 204         @table_comments = ();
 205         push @{ $tables{ $item[2]{'table'} }{'indices'} }, $item[2];
 206     }
 207
 208 create_procedure : /create/i PROCEDURE WORD not_go GO
 209     {
 210         @table_comments = ();
 211         my $proc_name = $item[3];
 212         my $owner = '';
 213         my $sql = "$item[1] $item[2] $proc_name $item[4]";
 214
 215         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 216         $procedures{ $proc_name }{'name'}   = $proc_name;
 217         $procedures{ $proc_name }{'owner'}  = $owner;
 218         $procedures{ $proc_name }{'sql'}    = $sql;
 219     }
 220
 221 create_procedure : /create/i PROCEDURE '[' WORD '].' WORD not_go GO
 222     {
 223         @table_comments = ();
 224         my $proc_name = $item[6];
 225         my $owner = $item[4];
 226         my $sql = "$item[1] $item[2] [$owner].$proc_name $item[7]";
 227
 228         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 229         $procedures{ $proc_name }{'name'}   = $proc_name;
 230         $procedures{ $proc_name }{'owner'}  = $owner;
 231         $procedures{ $proc_name }{'sql'}    = $sql;
 232     }
 233
 234 PROCEDURE : /procedure/i
 235    | /function/i
 236
 237 create_view : /create/i /view/i WORD not_go GO
 238     {
 239         @table_comments = ();
 240         my $view_name = $item[3];
 241         my $sql = "$item[1] $item[2] $item[3] $item[4]";
 242
 243         $views{ $view_name }{'order'}  = ++$view_order;
 244         $views{ $view_name }{'name'}   = $view_name;
 245         $views{ $view_name }{'sql'}    = $sql;
 246     }
 247
 248 not_go : /((?!\bgo\b).)*/is
 249
 250 create_def : constraint
 251     | index
 252     | field
 253
 254 blank : /\s*/
 255
 256 field : field_name data_type field_qualifier(s?)
 257     {
 258         my %qualifiers  = map { %$_ } @{ $item{'field_qualifier(s?)'} || [] };
 259         my $nullable = defined $qualifiers{'nullable'}
 260                    ? $qualifiers{'nullable'} : 1;
 261         $return = {
 262             supertype      => 'field',
 263             name           => $item{'field_name'},
 264             data_type      => $item{'data_type'}{'type'},
 265             size           => $item{'data_type'}{'size'},
 266             nullable       => $nullable,
 267             default        => $qualifiers{'default_val'},
 268             is_auto_inc    => $qualifiers{'is_auto_inc'},
 269 #            is_primary_key => $item{'primary_key'}[0],
 270         }
 271     }
 272
 273 field_qualifier : nullable
 274     {
 275         $return = {
 276              nullable => $item{'nullable'},
 277         }
 278     }
 279
 280 field_qualifier : default_val
 281     {
 282         $return = {
 283              default_val => $item{'default_val'},
 284         }
 285     }
 286
 287 field_qualifier : auto_inc
 288     {
 289         $return = {
 290              is_auto_inc => $item{'auto_inc'},
 291         }
 292     }
 293
 294 constraint : primary_key_constraint
 295     | foreign_key_constraint
 296     | unique_constraint
 297
 298 field_name : WORD
 299    { $return = $item[1] }
 300    | LQUOTE WORD RQUOTE
 301    { $return = $item[2] }
 302
 303 index_name : WORD
 304    { $return = $item[1] }
 305    | LQUOTE WORD RQUOTE
 306    { $return = $item[2] }
 307
 308 table_name : WORD
 309  { $return = $item[1] }
 310  | LQUOTE WORD RQUOTE
 311  { $return = $item[2] }
 312
 313 data_type : WORD field_size(?)
 314     {
 315         $return = {
 316             type => $item[1],
 317             size => $item[2][0]
 318         }
 319     }
 320
 321 lock : /lock/i /datarows/i
 322
 323 field_type : WORD
 324
 325 field_size : '(' num_range ')' { $item{'num_range'} }
 326
 327 num_range : DIGITS ',' DIGITS
 328     { $return = $item[1].','.$item[3] }
 329                | DIGITS
 330     { $return = $item[1] }
 331
 332
 333 nullable : /not/i /null/i
 334     { $return = 0 }
 335     | /null/i
 336     { $return = 1 }
 337
 338 default_val : /default/i /null/i
 339     { $return = 'null' }
 340    | /default/i /'[^']*'/
 341     { $item[2]=~ s/'//g; $return = $item[2] }
 342    | /default/i WORD
 343     { $return = $item[2] }
 344
 345 auto_inc : /identity/i { 1 }
 346
 347 primary_key_constraint : /constraint/i index_name(?) /primary/i /key/i parens_field_list
 348     {
 349         $return = {
 350             supertype => 'constraint',
 351             name      => $item[2][0],
 352             type      => 'primary_key',
 353             fields    => $item[5],
 354         }
 355     }
 356
 357 foreign_key_constraint : /constraint/i index_name(?) /foreign/i /key/i parens_field_list /references/i table_name parens_field_list(?) on_delete(?) on_update(?)
 358     {
 359         $return = {
 360             supertype        => 'constraint',
 361             name             => $item[2][0],
 362             type             => 'foreign_key',
 363             fields           => $item[5],
 364             reference_table  => $item[7],
 365             reference_fields => $item[8][0],
 366             on_delete        => $item[9][0],
 367             on_update        => $item[10][0],
 368         }
 369     }
 370
 371 unique_constraint : /constraint/i index_name(?) /unique/i parens_field_list
 372     {
 373         $return = {
 374             supertype => 'constraint',
 375             type      => 'unique',
 376             name      => $item[2][0],
 377             fields    => $item[4],
 378         }
 379     }
 380
 381 unique_constraint : /unique/i clustered(?) INDEX(?) index_name(?) on_table(?) parens_field_list field_not_null(?)
 382     {
 383         $return = {
 384             supertype => 'constraint',
 385             type      => 'unique',
 386             clustered => $item[2][0],
 387             name      => $item[4][0],
 388             table     => $item[5][0],
 389             fields    => $item[6],
 390         }
 391     }
 392
 393 on_delete : /on delete/i reference_option
 394     { $item[2] }
 395
 396 on_update : /on update/i reference_option
 397     { $item[2] }
 398
 399 reference_option: /cascade/i
 400     { $item[1] }
 401     | /no action/i
 402     { $item[1] }
 403
 404 clustered : /clustered/i
 405     { $return = 1 }
 406     | /nonclustered/i
 407     { $return = 0 }
 408
 409 INDEX : /index/i
 410
 411 on_table : /on/i table_name
 412     { $return = $item[2] }
 413
 414 on_system : /on/i /system/i
 415     { $return = 1 }
 416
 417 index : clustered(?) INDEX index_name(?) on_table(?) parens_field_list END_STATEMENT
 418     {
 419         $return = {
 420             supertype => 'index',
 421             type      => 'normal',
 422             clustered => $item[1][0],
 423             name      => $item[3][0],
 424             table     => $item[4][0],
 425             fields    => $item[5],
 426         }
 427     }
 428
 429 parens_field_list : '(' field_name(s /,/) ')'
 430     { $item[2] }
 431
 432 ident : QUOTE WORD '.' WORD QUOTE | LQUOTE WORD '.' WORD RQUOTE
 433     { $return = { owner => $item[2], name => $item[4] } }
 434     | LQUOTE WORD RQUOTE '.' LQUOTE WORD RQUOTE
 435     { $return = { owner => $item[2], name => $item[6] } }
 436     | LQUOTE WORD RQUOTE
 437     { $return = { name  => $item[2] } }
 438     | WORD '.' WORD
 439     { $return = { owner => $item[1], name => $item[3] } }
 440     | WORD
 441     { $return = { name  => $item[1] } }
 442
 443 END_STATEMENT : ';'
 444    | GO
 445
 446 GO : /^go/i
 447
 448 NAME : QUOTE(?) /\w+/ QUOTE(?)
 449     { $item[2] }
 450
 451 WORD : /[\w#]+/
 452
 453 DIGITS : /\d+/
 454
 455 COMMA : ','
 456
 457 QUOTE : /'/
 458
 459 LQUOTE : '['
 460
 461 RQUOTE : ']'
 462
 463 };
 464
 465 sub parse {
 466     my ( $translator, $data ) = @_;
 467     my $parser = Parse::RecDescent->new($GRAMMAR);
 468
 469     local $::RD_TRACE  = $translator->trace ? 1 : undef;
 470     local $DEBUG       = $translator->debug;
 471
 472     unless (defined $parser) {
 473         return $translator->error("Error instantiating Parse::RecDescent ".
 474             "instance: Bad grammer");
 475     }
 476
 477     my $result = $parser->startrule($data);
 478     return $translator->error( "Parse failed." ) unless defined $result;
 479     warn Dumper( $result ) if $DEBUG;
 480
 481     my $schema = $translator->schema;
 482     my @tables = sort {
 483         $result->{tables}->{ $a }->{'order'} <=> $result->{tables}->{ $b }->{'order'}
 484     } keys %{ $result->{tables} };
 485
 486     for my $table_name ( @tables ) {
 487         my $tdata = $result->{tables}->{ $table_name };
 488         my $table = $schema->add_table( name => $tdata->{'name'} )
 489                     or die "Can't create table '$table_name': ", $schema->error;
 490
 491         $table->comments( $tdata->{'comments'} );
 492
 493         my @fields = sort {
 494             $tdata->{'fields'}->{$a}->{'order'}
 495             <=>
 496             $tdata->{'fields'}->{$b}->{'order'}
 497         } keys %{ $tdata->{'fields'} };
 498
 499         for my $fname ( @fields ) {
 500             my $fdata = $tdata->{'fields'}{ $fname };
 501             my $field = $table->add_field(
 502                 name              => $fdata->{'name'},
 503                 data_type         => $fdata->{'data_type'},
 504                 size              => $fdata->{'size'},
 505                 default_value     => $fdata->{'default'},
 506                 is_auto_increment => $fdata->{'is_auto_inc'},
 507                 is_nullable       => $fdata->{'nullable'},
 508                 comments          => $fdata->{'comments'},
 509             ) or die $table->error;
 510
 511             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 512
 513             for my $qual ( qw[ binary unsigned zerofill list ] ) {
 514                 if ( my $val = $fdata->{ $qual } || $fdata->{ uc $qual } ) {
 515                     next if ref $val eq 'ARRAY' && !@$val;
 516                     $field->extra( $qual, $val );
 517                 }
 518             }
 519
 520             if ( $field->data_type =~ /(set|enum)/i && !$field->size ) {
 521                 my %extra = $field->extra;
 522                 my $longest = 0;
 523                 for my $len ( map { length } @{ $extra{'list'} || [] } ) {
 524                     $longest = $len if $len > $longest;
 525                 }
 526                 $field->size( $longest ) if $longest;
 527             }
 528
 529             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 530                 next unless $cdata->{'type'} eq 'foreign_key';
 531                 $cdata->{'fields'} ||= [ $field->name ];
 532                 push @{ $tdata->{'constraints'} }, $cdata;
 533             }
 534         }
 535
 536         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 537             my $index  =  $table->add_index(
 538                 name   => $idata->{'name'},
 539                 type   => uc $idata->{'type'},
 540                 fields => $idata->{'fields'},
 541             ) or die $table->error;
 542         }
 543
 544         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 545             my $constraint       =  $table->add_constraint(
 546                 name             => $cdata->{'name'},
 547                 type             => $cdata->{'type'},
 548                 fields           => $cdata->{'fields'},
 549                 reference_table  => $cdata->{'reference_table'},
 550                 reference_fields => $cdata->{'reference_fields'},
 551                 match_type       => $cdata->{'match_type'} || '',
 552                 on_delete        => $cdata->{'on_delete'} || $cdata->{'on_delete_do'},
 553                 on_update        => $cdata->{'on_update'} || $cdata->{'on_update_do'},
 554             ) or die $table->error;
 555         }
 556     }
 557
 558     my @procedures = sort {
 559         $result->{procedures}->{ $a }->{'order'} <=> $result->{procedures}->{ $b }->{'order'}
 560     } keys %{ $result->{procedures} };
 561     for my $proc_name (@procedures) {
 562       $schema->add_procedure(
 563          name  => $proc_name,
 564          owner => $result->{procedures}->{$proc_name}->{owner},
 565          sql   => $result->{procedures}->{$proc_name}->{sql},
 566       );
 567     }
 568
 569     my @views = sort {
 570         $result->{views}->{ $a }->{'order'} <=> $result->{views}->{ $b }->{'order'}
 571     } keys %{ $result->{views} };
 572     for my $view_name (keys %{ $result->{views} }) {
 573       $schema->add_view(
 574          name => $view_name,
 575          sql  => $result->{views}->{$view_name}->{sql},
 576       );
 577     }
 578
 579     return 1;
 580 }
 581
 582 1;
 583
 584 # -------------------------------------------------------------------
 585 # Every hero becomes a bore at last.
 586 # Ralph Waldo Emerson
 587 # -------------------------------------------------------------------
 588
 589 =pod
 590
 591 =head1 AUTHOR
 592
 593 Chris Hilton E<lt>chris@dctank.comE<gt> - Bulk of code from
 594 Sybase parser, I just tweaked it for SQLServer. Thanks.
 595
 596 =head1 SEE ALSO
 597
 598 SQL::Translator, SQL::Translator::Parser::DBI, L<http://www.midsomer.org/>.
 599
 600 =cut