lib/SQL/Translator/Parser/SQLServer.pm

   1 package SQL::Translator::Parser::SQLServer;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Parser::SQLServer - parser for SQL Server
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator::Parser::SQLServer;
  28
  29 =head1 DESCRIPTION
  30
  31 Adapted from Parser::Sybase and mostly parses the output of
  32 Producer::SQLServer.  The parsing is by no means complete and
  33 should probably be considered a work in progress.
  34
  35 =cut
  36
  37 use strict;
  38
  39 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
  40 $VERSION = '1.59';
  41 $DEBUG   = 0 unless defined $DEBUG;
  42
  43 use Data::Dumper;
  44 use Parse::RecDescent;
  45 use Exporter;
  46 use base qw(Exporter);
  47
  48 @EXPORT_OK = qw(parse);
  49
  50 $::RD_ERRORS = 1;
  51 $::RD_WARN   = 1;
  52 $::RD_HINT   = 1;
  53
  54 $GRAMMAR = q{
  55
  56 {
  57     my ( %tables, @table_comments, $table_order, %procedures, $proc_order, %views, $view_order );
  58 }
  59
  60 startrule : statement(s) eofile
  61         {
  62                 return {
  63                         tables     => \%tables,
  64                         procedures => \%procedures,
  65                         views      => \%views,
  66                 }
  67         }
  68
  69 eofile : /^\Z/
  70
  71 statement : create_table
  72     | create_procedure
  73     | create_view
  74     | create_index
  75     | create_constraint
  76     | comment
  77     | use
  78     | setuser
  79     | if
  80     | print
  81     | grant
  82     | exec
  83     | <error>
  84
  85 use : /use/i WORD GO
  86     { @table_comments = () }
  87
  88 setuser : /setuser/i NAME GO
  89
  90 if : /if/i object_not_null begin if_command end GO
  91
  92 if_command : grant
  93     | create_index
  94     | create_constraint
  95
  96 object_not_null : /object_id/i '(' ident ')' /is not null/i
  97
  98 print : /\s*/ /print/i /.*/
  99
 100 else : /else/i /.*/
 101
 102 begin : /begin/i
 103
 104 end : /end/i
 105
 106 grant : /grant/i /[^\n]*/
 107
 108 exec : exec_statement(s) GO
 109
 110 exec_statement : /exec/i /[^\n]+/
 111
 112 comment : /^\s*(?:#|-{2}).*\n/
 113     {
 114         my $comment =  $item[1];
 115         $comment    =~ s/^\s*(#|--)\s*//;
 116         $comment    =~ s/\s*$//;
 117         $return     = $comment;
 118         push @table_comments, $comment;
 119     }
 120
 121 comment : comment_start comment_middle comment_end
 122     {
 123         my $comment = $item[2];
 124         $comment =~ s/^\s*|\s*$//mg;
 125         $comment =~ s/^\**\s*//mg;
 126         push @table_comments, $comment;
 127     }
 128
 129 comment_start : m#^\s*\/\*#
 130
 131 comment_end : m#\s*\*\/#
 132
 133 comment_middle : m{([^*]+|\*(?!/))*}
 134
 135 #
 136 # Create table.
 137 #
 138 create_table : /create/i /table/i ident '(' create_def(s /,/) ')' lock(?) on_system(?) END_STATEMENT
 139     {
 140         my $table_owner = $item[3]{'owner'};
 141         my $table_name  = $item[3]{'name'};
 142
 143         if ( @table_comments ) {
 144             $tables{ $table_name }{'comments'} = [ @table_comments ];
 145             @table_comments = ();
 146         }
 147
 148         $tables{ $table_name }{'order'}  = ++$table_order;
 149         $tables{ $table_name }{'name'}   = $table_name;
 150         $tables{ $table_name }{'owner'}  = $table_owner;
 151         $tables{ $table_name }{'system'} = $item[7];
 152
 153         my $i = 0;
 154         for my $def ( @{ $item[5] } ) {
 155             if ( $def->{'supertype'} eq 'field' ) {
 156                 my $field_name = $def->{'name'};
 157                 $tables{ $table_name }{'fields'}{ $field_name } =
 158                     { %$def, order => $i };
 159                 $i++;
 160
 161                 if ( $def->{'is_primary_key'} ) {
 162                     push @{ $tables{ $table_name }{'constraints'} }, {
 163                         type   => 'primary_key',
 164                         fields => [ $field_name ],
 165                     };
 166                 }
 167             }
 168             elsif ( $def->{'supertype'} eq 'constraint' ) {
 169                 push @{ $tables{ $table_name }{'constraints'} }, $def;
 170             }
 171             else {
 172                 push @{ $tables{ $table_name }{'indices'} }, $def;
 173             }
 174         }
 175     }
 176
 177 create_constraint : /create/i constraint
 178     {
 179         @table_comments = ();
 180         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 181     }
 182
 183 create_index : /create/i index
 184     {
 185         @table_comments = ();
 186         push @{ $tables{ $item[2]{'table'} }{'indices'} }, $item[2];
 187     }
 188
 189 create_procedure : /create/i PROCEDURE WORD not_go GO
 190     {
 191         @table_comments = ();
 192         my $proc_name = $item[3];
 193         my $owner = '';
 194         my $sql = "$item[1] $item[2] $proc_name $item[4]";
 195
 196         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 197         $procedures{ $proc_name }{'name'}   = $proc_name;
 198         $procedures{ $proc_name }{'owner'}  = $owner;
 199         $procedures{ $proc_name }{'sql'}    = $sql;
 200     }
 201
 202 create_procedure : /create/i PROCEDURE '[' WORD '].' WORD not_go GO
 203     {
 204         @table_comments = ();
 205         my $proc_name = $item[6];
 206         my $owner = $item[4];
 207         my $sql = "$item[1] $item[2] [$owner].$proc_name $item[7]";
 208
 209         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 210         $procedures{ $proc_name }{'name'}   = $proc_name;
 211         $procedures{ $proc_name }{'owner'}  = $owner;
 212         $procedures{ $proc_name }{'sql'}    = $sql;
 213     }
 214
 215 PROCEDURE : /procedure/i
 216         | /function/i
 217
 218 create_view : /create/i /view/i WORD not_go GO
 219     {
 220         @table_comments = ();
 221         my $view_name = $item[3];
 222         my $sql = "$item[1] $item[2] $item[3] $item[4]";
 223
 224         $views{ $view_name }{'order'}  = ++$view_order;
 225         $views{ $view_name }{'name'}   = $view_name;
 226         $views{ $view_name }{'sql'}    = $sql;
 227     }
 228
 229 not_go : /((?!\bgo\b).)*/is
 230
 231 create_def : constraint
 232     | index
 233     | field
 234
 235 blank : /\s*/
 236
 237 field : field_name data_type field_qualifier(s?)
 238     {
 239         my %qualifiers  = map { %$_ } @{ $item{'field_qualifier(s?)'} || [] };
 240         my $nullable = defined $qualifiers{'nullable'}
 241                    ? $qualifiers{'nullable'} : 1;
 242         $return = {
 243             supertype      => 'field',
 244             name           => $item{'field_name'},
 245             data_type      => $item{'data_type'}{'type'},
 246             size           => $item{'data_type'}{'size'},
 247             nullable       => $nullable,
 248             default        => $qualifiers{'default_val'},
 249             is_auto_inc    => $qualifiers{'is_auto_inc'},
 250 #            is_primary_key => $item{'primary_key'}[0],
 251         }
 252     }
 253
 254 field_qualifier : nullable
 255     {
 256         $return = {
 257              nullable => $item{'nullable'},
 258         }
 259     }
 260
 261 field_qualifier : default_val
 262     {
 263         $return = {
 264              default_val => $item{'default_val'},
 265         }
 266     }
 267
 268 field_qualifier : auto_inc
 269     {
 270         $return = {
 271              is_auto_inc => $item{'auto_inc'},
 272         }
 273     }
 274
 275 constraint : primary_key_constraint
 276     | foreign_key_constraint
 277     | unique_constraint
 278
 279 field_name : WORD
 280
 281 index_name : WORD
 282
 283 table_name : WORD
 284
 285 data_type : WORD field_size(?)
 286     {
 287         $return = {
 288             type => $item[1],
 289             size => $item[2][0]
 290         }
 291     }
 292
 293 lock : /lock/i /datarows/i
 294
 295 field_type : WORD
 296
 297 field_size : '(' num_range ')' { $item{'num_range'} }
 298
 299 num_range : DIGITS ',' DIGITS
 300     { $return = $item[1].','.$item[3] }
 301                | DIGITS
 302     { $return = $item[1] }
 303
 304
 305 nullable : /not/i /null/i
 306     { $return = 0 }
 307     | /null/i
 308     { $return = 1 }
 309
 310 default_val : /default/i /null/i
 311     { $return = 'null' }
 312         | /default/i /'[^']*'/
 313     { $item[2]=~ s/'//g; $return = $item[2] }
 314
 315 auto_inc : /identity/i { 1 }
 316
 317 primary_key_constraint : /constraint/i index_name(?) /primary/i /key/i parens_field_list
 318     {
 319         $return = {
 320             supertype => 'constraint',
 321             name      => $item[2][0],
 322             type      => 'primary_key',
 323             fields    => $item[5],
 324         }
 325     }
 326
 327 foreign_key_constraint : /constraint/i index_name(?) /foreign/i /key/i parens_field_list /references/i table_name parens_field_list(?) on_delete(?) on_update(?)
 328     {
 329         $return = {
 330             supertype        => 'constraint',
 331             name             => $item[2][0],
 332             type             => 'foreign_key',
 333             fields           => $item[5],
 334             reference_table  => $item[7],
 335             reference_fields => $item[8][0],
 336             on_delete        => $item[9][0],
 337             on_update        => $item[10][0],
 338         }
 339     }
 340
 341 unique_constraint : /unique/i clustered(?) INDEX(?) index_name(?) on_table(?) parens_field_list
 342     {
 343         $return = {
 344             supertype => 'constraint',
 345             type      => 'unique',
 346             clustered => $item[2][0],
 347             name      => $item[4][0],
 348             table     => $item[5][0],
 349             fields    => $item[6],
 350         }
 351     }
 352
 353 on_delete : /on delete/i reference_option
 354     { $item[2] }
 355
 356 on_update : /on update/i reference_option
 357     { $item[2] }
 358
 359 reference_option: /cascade/i
 360     { $item[1] }
 361     | /no action/i
 362     { $item[1] }
 363
 364 clustered : /clustered/i
 365     { $return = 1 }
 366     | /nonclustered/i
 367     { $return = 0 }
 368
 369 INDEX : /index/i
 370
 371 on_table : /on/i table_name
 372     { $return = $item[2] }
 373
 374 on_system : /on/i /system/i
 375     { $return = 1 }
 376
 377 index : clustered(?) INDEX index_name(?) on_table(?) parens_field_list ';'
 378     {
 379         $return = {
 380             supertype => 'index',
 381             type      => 'normal',
 382             clustered => $item[1][0],
 383             name      => $item[3][0],
 384             table     => $item[4][0],
 385             fields    => $item[5],
 386         }
 387     }
 388
 389 parens_field_list : '(' field_name(s /,/) ')'
 390     { $item[2] }
 391
 392 ident : QUOTE(?) WORD '.' WORD QUOTE(?)
 393     { $return = { owner => $item[2], name => $item[4] } }
 394     | WORD
 395     { $return = { name  => $item[1] } }
 396
 397 END_STATEMENT : ';'
 398         | GO
 399
 400 GO : /^go/i
 401
 402 NAME : QUOTE(?) /\w+/ QUOTE(?)
 403     { $item[2] }
 404
 405 WORD : /[\w#]+/
 406
 407 DIGITS : /\d+/
 408
 409 COMMA : ','
 410
 411 QUOTE : /'/
 412
 413 };
 414
 415 # -------------------------------------------------------------------
 416 sub parse {
 417     my ( $translator, $data ) = @_;
 418     my $parser = Parse::RecDescent->new($GRAMMAR);
 419
 420     local $::RD_TRACE  = $translator->trace ? 1 : undef;
 421     local $DEBUG       = $translator->debug;
 422
 423     unless (defined $parser) {
 424         return $translator->error("Error instantiating Parse::RecDescent ".
 425             "instance: Bad grammer");
 426     }
 427
 428     my $result = $parser->startrule($data);
 429     return $translator->error( "Parse failed." ) unless defined $result;
 430     warn Dumper( $result ) if $DEBUG;
 431
 432     my $schema = $translator->schema;
 433     my @tables = sort {
 434         $result->{tables}->{ $a }->{'order'} <=> $result->{tables}->{ $b }->{'order'}
 435     } keys %{ $result->{tables} };
 436
 437     for my $table_name ( @tables ) {
 438         my $tdata = $result->{tables}->{ $table_name };
 439         my $table = $schema->add_table( name => $tdata->{'name'} )
 440                     or die "Can't create table '$table_name': ", $schema->error;
 441
 442         $table->comments( $tdata->{'comments'} );
 443
 444         my @fields = sort {
 445             $tdata->{'fields'}->{$a}->{'order'}
 446             <=>
 447             $tdata->{'fields'}->{$b}->{'order'}
 448         } keys %{ $tdata->{'fields'} };
 449
 450         for my $fname ( @fields ) {
 451             my $fdata = $tdata->{'fields'}{ $fname };
 452             my $field = $table->add_field(
 453                 name              => $fdata->{'name'},
 454                 data_type         => $fdata->{'data_type'},
 455                 size              => $fdata->{'size'},
 456                 default_value     => $fdata->{'default'},
 457                 is_auto_increment => $fdata->{'is_auto_inc'},
 458                 is_nullable       => $fdata->{'nullable'},
 459                 comments          => $fdata->{'comments'},
 460             ) or die $table->error;
 461
 462             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 463
 464             for my $qual ( qw[ binary unsigned zerofill list ] ) {
 465                 if ( my $val = $fdata->{ $qual } || $fdata->{ uc $qual } ) {
 466                     next if ref $val eq 'ARRAY' && !@$val;
 467                     $field->extra( $qual, $val );
 468                 }
 469             }
 470
 471             if ( $field->data_type =~ /(set|enum)/i && !$field->size ) {
 472                 my %extra = $field->extra;
 473                 my $longest = 0;
 474                 for my $len ( map { length } @{ $extra{'list'} || [] } ) {
 475                     $longest = $len if $len > $longest;
 476                 }
 477                 $field->size( $longest ) if $longest;
 478             }
 479
 480             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 481                 next unless $cdata->{'type'} eq 'foreign_key';
 482                 $cdata->{'fields'} ||= [ $field->name ];
 483                 push @{ $tdata->{'constraints'} }, $cdata;
 484             }
 485         }
 486
 487         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 488             my $index  =  $table->add_index(
 489                 name   => $idata->{'name'},
 490                 type   => uc $idata->{'type'},
 491                 fields => $idata->{'fields'},
 492             ) or die $table->error;
 493         }
 494
 495         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 496             my $constraint       =  $table->add_constraint(
 497                 name             => $cdata->{'name'},
 498                 type             => $cdata->{'type'},
 499                 fields           => $cdata->{'fields'},
 500                 reference_table  => $cdata->{'reference_table'},
 501                 reference_fields => $cdata->{'reference_fields'},
 502                 match_type       => $cdata->{'match_type'} || '',
 503                 on_delete        => $cdata->{'on_delete'} || $cdata->{'on_delete_do'},
 504                 on_update        => $cdata->{'on_update'} || $cdata->{'on_update_do'},
 505             ) or die $table->error;
 506         }
 507     }
 508
 509     my @procedures = sort {
 510         $result->{procedures}->{ $a }->{'order'} <=> $result->{procedures}->{ $b }->{'order'}
 511     } keys %{ $result->{procedures} };
 512     for my $proc_name (@procedures) {
 513         $schema->add_procedure(
 514                 name  => $proc_name,
 515                 owner => $result->{procedures}->{$proc_name}->{owner},
 516                 sql   => $result->{procedures}->{$proc_name}->{sql},
 517                 );
 518     }
 519
 520     my @views = sort {
 521         $result->{views}->{ $a }->{'order'} <=> $result->{views}->{ $b }->{'order'}
 522     } keys %{ $result->{views} };
 523     for my $view_name (keys %{ $result->{views} }) {
 524         $schema->add_view(
 525                 name => $view_name,
 526                 sql  => $result->{views}->{$view_name}->{sql},
 527                 );
 528     }
 529
 530     return 1;
 531 }
 532
 533 1;
 534
 535 # -------------------------------------------------------------------
 536 # Every hero becomes a bore at last.
 537 # Ralph Waldo Emerson
 538 # -------------------------------------------------------------------
 539
 540 =pod
 541
 542 =head1 AUTHOR
 543
 544 Chris Hilton E<lt>chris@dctank.comE<gt> - Bulk of code from
 545 Sybase parser, I just tweaked it for SQLServer. Thanks.
 546
 547 =head1 SEE ALSO
 548
 549 SQL::Translator, SQL::Translator::Parser::DBI, L<http://www.midsomer.org/>.
 550
 551 =cut