lib/SQL/Translator/Parser/SQLServer.pm

   1 package SQL::Translator::Parser::SQLServer;
   2
   3 # -------------------------------------------------------------------
   4 # Copyright (C) 2002-2009 SQLFairy Authors
   5 #
   6 # This program is free software; you can redistribute it and/or
   7 # modify it under the terms of the GNU General Public License as
   8 # published by the Free Software Foundation; version 2.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18 # 02111-1307  USA
  19 # -------------------------------------------------------------------
  20
  21 =head1 NAME
  22
  23 SQL::Translator::Parser::SQLServer - parser for SQL Server
  24
  25 =head1 SYNOPSIS
  26
  27   use SQL::Translator::Parser::SQLServer;
  28
  29 =head1 DESCRIPTION
  30
  31 Adapted from Parser::Sybase and mostly parses the output of
  32 Producer::SQLServer.  The parsing is by no means complete and
  33 should probably be considered a work in progress.
  34
  35 =cut
  36
  37 use strict;
  38
  39 use vars qw[ $DEBUG $VERSION $GRAMMAR @EXPORT_OK ];
  40 $VERSION = '1.59';
  41 $DEBUG   = 0 unless defined $DEBUG;
  42
  43 use Data::Dumper;
  44 use Parse::RecDescent;
  45 use Exporter;
  46 use base qw(Exporter);
  47
  48 @EXPORT_OK = qw(parse);
  49
  50 $::RD_ERRORS = 1;
  51 $::RD_WARN   = 1;
  52 $::RD_HINT   = 1;
  53
  54 $GRAMMAR = q{
  55
  56 {
  57     my ( %tables, @table_comments, $table_order, %procedures, $proc_order, %views, $view_order );
  58 }
  59
  60 startrule : statement(s) eofile
  61         {
  62                 return {
  63                         tables     => \%tables,
  64                         procedures => \%procedures,
  65                         views      => \%views,
  66                 }
  67         }
  68
  69 eofile : /^\Z/
  70
  71 statement : create_table
  72     | create_procedure
  73     | create_view
  74     | create_index
  75     | create_constraint
  76     | comment
  77     | drop
  78     | use
  79     | setuser
  80     | if
  81     | print
  82     | grant
  83     | exec
  84     | <error>
  85
  86 use : /use/i WORD GO
  87     { @table_comments = () }
  88
  89 setuser : /setuser/i NAME GO
  90
  91 if : /if/i object_not_null begin if_command end GO
  92
  93 if_command : grant
  94     | create_index
  95     | create_constraint
  96
  97 object_not_null : /object_id/i '(' ident ')' /is not null/i
  98
  99 print : /\s*/ /print/i /.*/
 100
 101 else : /else/i /.*/
 102
 103 begin : /begin/i
 104
 105 end : /end/i
 106
 107 grant : /grant/i /[^\n]*/
 108
 109 exec : exec_statement(s) GO
 110
 111 exec_statement : /exec/i /[^\n]+/
 112
 113 comment : /^\s*(?:#|-{2}).*\n/
 114     {
 115         my $comment =  $item[1];
 116         $comment    =~ s/^\s*(#|--)\s*//;
 117         $comment    =~ s/\s*$//;
 118         $return     = $comment;
 119         push @table_comments, $comment;
 120     }
 121
 122 comment : comment_start comment_middle comment_end
 123     {
 124         my $comment = $item[2];
 125         $comment =~ s/^\s*|\s*$//mg;
 126         $comment =~ s/^\**\s*//mg;
 127         push @table_comments, $comment;
 128     }
 129
 130 comment_start : m#^\s*\/\*#
 131
 132 comment_end : m#\s*\*\/#
 133
 134 comment_middle : m{([^*]+|\*(?!/))*}
 135
 136 drop : if_exists(?) /drop/i tbl_drop END_STATEMENT
 137
 138 tbl_drop : /table/i NAME
 139
 140 if_exists : /if exists/i '(' /select/i 'name' /from/i 'sysobjects' /[^\)]+/ ')'
 141
 142 #
 143 # Create table.
 144 #
 145 create_table : /create/i /table/i ident '(' create_def(s /,/) ')' lock(?) on_system(?) END_STATEMENT
 146     {
 147         my $table_owner = $item[3]{'owner'};
 148         my $table_name  = $item[3]{'name'};
 149
 150         if ( @table_comments ) {
 151             $tables{ $table_name }{'comments'} = [ @table_comments ];
 152             @table_comments = ();
 153         }
 154
 155         $tables{ $table_name }{'order'}  = ++$table_order;
 156         $tables{ $table_name }{'name'}   = $table_name;
 157         $tables{ $table_name }{'owner'}  = $table_owner;
 158         $tables{ $table_name }{'system'} = $item[7];
 159
 160         my $i = 0;
 161         for my $def ( @{ $item[5] } ) {
 162             if ( $def->{'supertype'} eq 'field' ) {
 163                 my $field_name = $def->{'name'};
 164                 $tables{ $table_name }{'fields'}{ $field_name } =
 165                     { %$def, order => $i };
 166                 $i++;
 167
 168                 if ( $def->{'is_primary_key'} ) {
 169                     push @{ $tables{ $table_name }{'constraints'} }, {
 170                         type   => 'primary_key',
 171                         fields => [ $field_name ],
 172                     };
 173                 }
 174             }
 175             elsif ( $def->{'supertype'} eq 'constraint' ) {
 176                 push @{ $tables{ $table_name }{'constraints'} }, $def;
 177             }
 178             else {
 179                 push @{ $tables{ $table_name }{'indices'} }, $def;
 180             }
 181         }
 182     }
 183
 184 create_constraint : /create/i constraint
 185     {
 186         @table_comments = ();
 187         push @{ $tables{ $item[2]{'table'} }{'constraints'} }, $item[2];
 188     }
 189
 190 create_constraint : /alter/i /table/i ident /add/i foreign_key_constraint END_STATEMENT
 191     {
 192         push @{ $tables{ $item[3]{name} }{constraints} }, $item[5];
 193     }
 194
 195 create_index : /create/i index
 196     {
 197         @table_comments = ();
 198         push @{ $tables{ $item[2]{'table'} }{'indices'} }, $item[2];
 199     }
 200
 201 create_procedure : /create/i PROCEDURE WORD not_go GO
 202     {
 203         @table_comments = ();
 204         my $proc_name = $item[3];
 205         my $owner = '';
 206         my $sql = "$item[1] $item[2] $proc_name $item[4]";
 207
 208         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 209         $procedures{ $proc_name }{'name'}   = $proc_name;
 210         $procedures{ $proc_name }{'owner'}  = $owner;
 211         $procedures{ $proc_name }{'sql'}    = $sql;
 212     }
 213
 214 create_procedure : /create/i PROCEDURE '[' WORD '].' WORD not_go GO
 215     {
 216         @table_comments = ();
 217         my $proc_name = $item[6];
 218         my $owner = $item[4];
 219         my $sql = "$item[1] $item[2] [$owner].$proc_name $item[7]";
 220
 221         $procedures{ $proc_name }{'order'}  = ++$proc_order;
 222         $procedures{ $proc_name }{'name'}   = $proc_name;
 223         $procedures{ $proc_name }{'owner'}  = $owner;
 224         $procedures{ $proc_name }{'sql'}    = $sql;
 225     }
 226
 227 PROCEDURE : /procedure/i
 228         | /function/i
 229
 230 create_view : /create/i /view/i WORD not_go GO
 231     {
 232         @table_comments = ();
 233         my $view_name = $item[3];
 234         my $sql = "$item[1] $item[2] $item[3] $item[4]";
 235
 236         $views{ $view_name }{'order'}  = ++$view_order;
 237         $views{ $view_name }{'name'}   = $view_name;
 238         $views{ $view_name }{'sql'}    = $sql;
 239     }
 240
 241 not_go : /((?!\bgo\b).)*/is
 242
 243 create_def : constraint
 244     | index
 245     | field
 246
 247 blank : /\s*/
 248
 249 field : field_name data_type field_qualifier(s?)
 250     {
 251         my %qualifiers  = map { %$_ } @{ $item{'field_qualifier(s?)'} || [] };
 252         my $nullable = defined $qualifiers{'nullable'}
 253                    ? $qualifiers{'nullable'} : 1;
 254         $return = {
 255             supertype      => 'field',
 256             name           => $item{'field_name'},
 257             data_type      => $item{'data_type'}{'type'},
 258             size           => $item{'data_type'}{'size'},
 259             nullable       => $nullable,
 260             default        => $qualifiers{'default_val'},
 261             is_auto_inc    => $qualifiers{'is_auto_inc'},
 262 #            is_primary_key => $item{'primary_key'}[0],
 263         }
 264     }
 265
 266 field_qualifier : nullable
 267     {
 268         $return = {
 269              nullable => $item{'nullable'},
 270         }
 271     }
 272
 273 field_qualifier : default_val
 274     {
 275         $return = {
 276              default_val => $item{'default_val'},
 277         }
 278     }
 279
 280 field_qualifier : auto_inc
 281     {
 282         $return = {
 283              is_auto_inc => $item{'auto_inc'},
 284         }
 285     }
 286
 287 constraint : primary_key_constraint
 288     | foreign_key_constraint
 289     | unique_constraint
 290
 291 field_name : WORD
 292
 293 index_name : WORD
 294
 295 table_name : WORD
 296
 297 data_type : WORD field_size(?)
 298     {
 299         $return = {
 300             type => $item[1],
 301             size => $item[2][0]
 302         }
 303     }
 304
 305 lock : /lock/i /datarows/i
 306
 307 field_type : WORD
 308
 309 field_size : '(' num_range ')' { $item{'num_range'} }
 310
 311 num_range : DIGITS ',' DIGITS
 312     { $return = $item[1].','.$item[3] }
 313                | DIGITS
 314     { $return = $item[1] }
 315
 316
 317 nullable : /not/i /null/i
 318     { $return = 0 }
 319     | /null/i
 320     { $return = 1 }
 321
 322 default_val : /default/i /null/i
 323     { $return = 'null' }
 324         | /default/i /'[^']*'/
 325     { $item[2]=~ s/'//g; $return = $item[2] }
 326         | /default/i WORD
 327     { $return = $item[2] }
 328
 329 auto_inc : /identity/i { 1 }
 330
 331 primary_key_constraint : /constraint/i index_name(?) /primary/i /key/i parens_field_list
 332     {
 333         $return = {
 334             supertype => 'constraint',
 335             name      => $item[2][0],
 336             type      => 'primary_key',
 337             fields    => $item[5],
 338         }
 339     }
 340
 341 foreign_key_constraint : /constraint/i index_name(?) /foreign/i /key/i parens_field_list /references/i table_name parens_field_list(?) on_delete(?) on_update(?)
 342     {
 343         $return = {
 344             supertype        => 'constraint',
 345             name             => $item[2][0],
 346             type             => 'foreign_key',
 347             fields           => $item[5],
 348             reference_table  => $item[7],
 349             reference_fields => $item[8][0],
 350             on_delete        => $item[9][0],
 351             on_update        => $item[10][0],
 352         }
 353     }
 354
 355 unique_constraint : /constraint/i index_name(?) /unique/i parens_field_list
 356     {
 357         $return = {
 358             supertype => 'constraint',
 359             type      => 'unique',
 360             name      => $item[2][0],
 361             fields    => $item[4],
 362         }
 363     }
 364
 365 unique_constraint : /unique/i clustered(?) INDEX(?) index_name(?) on_table(?) parens_field_list
 366     {
 367         $return = {
 368             supertype => 'constraint',
 369             type      => 'unique',
 370             clustered => $item[2][0],
 371             name      => $item[4][0],
 372             table     => $item[5][0],
 373             fields    => $item[6],
 374         }
 375     }
 376
 377 on_delete : /on delete/i reference_option
 378     { $item[2] }
 379
 380 on_update : /on update/i reference_option
 381     { $item[2] }
 382
 383 reference_option: /cascade/i
 384     { $item[1] }
 385     | /no action/i
 386     { $item[1] }
 387
 388 clustered : /clustered/i
 389     { $return = 1 }
 390     | /nonclustered/i
 391     { $return = 0 }
 392
 393 INDEX : /index/i
 394
 395 on_table : /on/i table_name
 396     { $return = $item[2] }
 397
 398 on_system : /on/i /system/i
 399     { $return = 1 }
 400
 401 index : clustered(?) INDEX index_name(?) on_table(?) parens_field_list END_STATEMENT
 402     {
 403         $return = {
 404             supertype => 'index',
 405             type      => 'normal',
 406             clustered => $item[1][0],
 407             name      => $item[3][0],
 408             table     => $item[4][0],
 409             fields    => $item[5],
 410         }
 411     }
 412
 413 parens_field_list : '(' field_name(s /,/) ')'
 414     { $item[2] }
 415
 416 ident : QUOTE(?) WORD '.' WORD QUOTE(?)
 417     { $return = { owner => $item[2], name => $item[4] } }
 418     | WORD
 419     { $return = { name  => $item[1] } }
 420
 421 END_STATEMENT : ';'
 422         | GO
 423
 424 GO : /^go/i
 425
 426 NAME : QUOTE(?) /\w+/ QUOTE(?)
 427     { $item[2] }
 428
 429 WORD : /[\w#]+/
 430
 431 DIGITS : /\d+/
 432
 433 COMMA : ','
 434
 435 QUOTE : /'/
 436
 437 };
 438
 439 # -------------------------------------------------------------------
 440 sub parse {
 441     my ( $translator, $data ) = @_;
 442     my $parser = Parse::RecDescent->new($GRAMMAR);
 443
 444     local $::RD_TRACE  = $translator->trace ? 1 : undef;
 445     local $DEBUG       = $translator->debug;
 446
 447     unless (defined $parser) {
 448         return $translator->error("Error instantiating Parse::RecDescent ".
 449             "instance: Bad grammer");
 450     }
 451
 452     my $result = $parser->startrule($data);
 453     return $translator->error( "Parse failed." ) unless defined $result;
 454     warn Dumper( $result ) if $DEBUG;
 455
 456     my $schema = $translator->schema;
 457     my @tables = sort {
 458         $result->{tables}->{ $a }->{'order'} <=> $result->{tables}->{ $b }->{'order'}
 459     } keys %{ $result->{tables} };
 460
 461     for my $table_name ( @tables ) {
 462         my $tdata = $result->{tables}->{ $table_name };
 463         my $table = $schema->add_table( name => $tdata->{'name'} )
 464                     or die "Can't create table '$table_name': ", $schema->error;
 465
 466         $table->comments( $tdata->{'comments'} );
 467
 468         my @fields = sort {
 469             $tdata->{'fields'}->{$a}->{'order'}
 470             <=>
 471             $tdata->{'fields'}->{$b}->{'order'}
 472         } keys %{ $tdata->{'fields'} };
 473
 474         for my $fname ( @fields ) {
 475             my $fdata = $tdata->{'fields'}{ $fname };
 476             my $field = $table->add_field(
 477                 name              => $fdata->{'name'},
 478                 data_type         => $fdata->{'data_type'},
 479                 size              => $fdata->{'size'},
 480                 default_value     => $fdata->{'default'},
 481                 is_auto_increment => $fdata->{'is_auto_inc'},
 482                 is_nullable       => $fdata->{'nullable'},
 483                 comments          => $fdata->{'comments'},
 484             ) or die $table->error;
 485
 486             $table->primary_key( $field->name ) if $fdata->{'is_primary_key'};
 487
 488             for my $qual ( qw[ binary unsigned zerofill list ] ) {
 489                 if ( my $val = $fdata->{ $qual } || $fdata->{ uc $qual } ) {
 490                     next if ref $val eq 'ARRAY' && !@$val;
 491                     $field->extra( $qual, $val );
 492                 }
 493             }
 494
 495             if ( $field->data_type =~ /(set|enum)/i && !$field->size ) {
 496                 my %extra = $field->extra;
 497                 my $longest = 0;
 498                 for my $len ( map { length } @{ $extra{'list'} || [] } ) {
 499                     $longest = $len if $len > $longest;
 500                 }
 501                 $field->size( $longest ) if $longest;
 502             }
 503
 504             for my $cdata ( @{ $fdata->{'constraints'} } ) {
 505                 next unless $cdata->{'type'} eq 'foreign_key';
 506                 $cdata->{'fields'} ||= [ $field->name ];
 507                 push @{ $tdata->{'constraints'} }, $cdata;
 508             }
 509         }
 510
 511         for my $idata ( @{ $tdata->{'indices'} || [] } ) {
 512             my $index  =  $table->add_index(
 513                 name   => $idata->{'name'},
 514                 type   => uc $idata->{'type'},
 515                 fields => $idata->{'fields'},
 516             ) or die $table->error;
 517         }
 518
 519         for my $cdata ( @{ $tdata->{'constraints'} || [] } ) {
 520             my $constraint       =  $table->add_constraint(
 521                 name             => $cdata->{'name'},
 522                 type             => $cdata->{'type'},
 523                 fields           => $cdata->{'fields'},
 524                 reference_table  => $cdata->{'reference_table'},
 525                 reference_fields => $cdata->{'reference_fields'},
 526                 match_type       => $cdata->{'match_type'} || '',
 527                 on_delete        => $cdata->{'on_delete'} || $cdata->{'on_delete_do'},
 528                 on_update        => $cdata->{'on_update'} || $cdata->{'on_update_do'},
 529             ) or die $table->error;
 530         }
 531     }
 532
 533     my @procedures = sort {
 534         $result->{procedures}->{ $a }->{'order'} <=> $result->{procedures}->{ $b }->{'order'}
 535     } keys %{ $result->{procedures} };
 536     for my $proc_name (@procedures) {
 537         $schema->add_procedure(
 538                 name  => $proc_name,
 539                 owner => $result->{procedures}->{$proc_name}->{owner},
 540                 sql   => $result->{procedures}->{$proc_name}->{sql},
 541                 );
 542     }
 543
 544     my @views = sort {
 545         $result->{views}->{ $a }->{'order'} <=> $result->{views}->{ $b }->{'order'}
 546     } keys %{ $result->{views} };
 547     for my $view_name (keys %{ $result->{views} }) {
 548         $schema->add_view(
 549                 name => $view_name,
 550                 sql  => $result->{views}->{$view_name}->{sql},
 551                 );
 552     }
 553
 554     return 1;
 555 }
 556
 557 1;
 558
 559 # -------------------------------------------------------------------
 560 # Every hero becomes a bore at last.
 561 # Ralph Waldo Emerson
 562 # -------------------------------------------------------------------
 563
 564 =pod
 565
 566 =head1 AUTHOR
 567
 568 Chris Hilton E<lt>chris@dctank.comE<gt> - Bulk of code from
 569 Sybase parser, I just tweaked it for SQLServer. Thanks.
 570
 571 =head1 SEE ALSO
 572
 573 SQL::Translator, SQL::Translator::Parser::DBI, L<http://www.midsomer.org/>.
 574
 575 =cut